basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 GENERIC: generate-insn ( insn -- )
  22
  23 SYMBOL: registers
  24
  25 : register ( vreg -- operand )
  26     registers get at [ "Bad value" throw ] unless* ;
  27
  28 : ?register ( obj -- operand )
  29     dup vreg? [ register ] when ;
  30
  31 TUPLE: asm label code calls ;
  32
  33 SYMBOL: calls
  34
  35 : add-call ( word -- )
  36     #! Compile this word later.
  37     calls get push ;
  38
  39 SYMBOL: compiling-word
  40
  41 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  42
  43 ! Mapping _label IDs to label instances
  44 SYMBOL: labels
  45
  46 : init-generator ( word -- )
  47     H{ } clone labels set
  48     V{ } clone calls set
  49     compiling-word set
  50     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  51
  52 : generate-insns ( asm -- code )
  53     [
  54         [ word>> init-generator ]
  55         [
  56             instructions>>
  57             [ [ regs>> registers set ] [ generate-insn ] bi ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> register ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> register ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> register ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> register ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> register ] [ temp>> register ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     {
 106         [ dst>> register ]
 107         [ obj>> register ]
 108         [ slot>> ?register ]
 109         [ tag>> ]
 110     } cleave ; inline
 111
 112 M: ##slot generate-insn
 113     [ >slot< ] [ temp>> register ] bi %slot ;
 114
 115 M: ##slot-imm generate-insn
 116     >slot< %slot-imm ;
 117
 118 : >set-slot< ( insn -- src obj slot tag )
 119     {
 120         [ src>> register ]
 121         [ obj>> register ]
 122         [ slot>> ?register ]
 123         [ tag>> ]
 124     } cleave ; inline
 125
 126 M: ##set-slot generate-insn
 127     [ >set-slot< ] [ temp>> register ] bi %set-slot ;
 128
 129 M: ##set-slot-imm generate-insn
 130     >set-slot< %set-slot-imm ;
 131
 132 M: ##string-nth generate-insn
 133     {
 134         [ dst>> register ]
 135         [ obj>> register ]
 136         [ index>> register ]
 137         [ temp>> register ]
 138     } cleave %string-nth ;
 139
 140 M: ##set-string-nth-fast generate-insn
 141     {
 142         [ src>> register ]
 143         [ obj>> register ]
 144         [ index>> register ]
 145         [ temp>> register ]
 146     } cleave %set-string-nth-fast ;
 147
 148 : dst/src ( insn -- dst src )
 149     [ dst>> register ] [ src>> register ] bi ; inline
 150
 151 : dst/src1/src2 ( insn -- dst src1 src2 )
 152     [ dst>> register ]
 153     [ src1>> register ]
 154     [ src2>> ?register ] tri ; inline
 155
 156 M: ##add     generate-insn dst/src1/src2 %add     ;
 157 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 158 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 159 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 160 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 161 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 162 M: ##and     generate-insn dst/src1/src2 %and     ;
 163 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 164 M: ##or      generate-insn dst/src1/src2 %or      ;
 165 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 166 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 167 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 168 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 169 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 170 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 171 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 172 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 173 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 174 M: ##not     generate-insn dst/src       %not     ;
 175 M: ##log2    generate-insn dst/src       %log2    ;
 176
 177 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 178     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 179
 180 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 181 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 182 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 183
 184 : dst/src/temp ( insn -- dst src temp )
 185     [ dst/src ] [ temp>> register ] bi ; inline
 186
 187 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 188 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 189
 190 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 191 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 192 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 193 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 194
 195 M: ##integer>float generate-insn dst/src %integer>float ;
 196 M: ##float>integer generate-insn dst/src %float>integer ;
 197
 198 M: ##copy             generate-insn dst/src %copy ;
 199 M: ##copy-float       generate-insn dst/src %copy-float ;
 200 M: ##unbox-float      generate-insn dst/src %unbox-float ;
 201 M: ##unbox-any-c-ptr  generate-insn dst/src/temp %unbox-any-c-ptr ;
 202 M: ##box-float        generate-insn dst/src/temp %box-float ;
 203 M: ##box-alien        generate-insn dst/src/temp %box-alien ;
 204
 205 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 206 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 207 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 208 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 209 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 210 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 211 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 212 M: ##alien-float      generate-insn dst/src %alien-float      ;
 213 M: ##alien-double     generate-insn dst/src %alien-double     ;
 214
 215 : >alien-setter< ( insn -- src value )
 216     [ src>> register ] [ value>> register ] bi ; inline
 217
 218 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 219 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 220 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 221 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 222 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 223 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 224
 225 M: ##allot generate-insn
 226     {
 227         [ dst>> register ]
 228         [ size>> ]
 229         [ class>> ]
 230         [ temp>> register ]
 231     } cleave
 232     %allot ;
 233
 234 M: ##write-barrier generate-insn
 235     [ src>> register ]
 236     [ card#>> register ]
 237     [ table>> register ]
 238     tri %write-barrier ;
 239
 240 M: _gc generate-insn
 241     {
 242         [ temp1>> register ]
 243         [ temp2>> register ]
 244         [ gc-roots>> ]
 245         [ gc-root-count>> ]
 246     } cleave %gc ;
 247
 248 M: ##loop-entry generate-insn drop %loop-entry ;
 249
 250 M: ##alien-global generate-insn
 251     [ dst>> register ] [ symbol>> ] [ library>> ] tri
 252     %alien-global ;
 253
 254 ! ##alien-invoke
 255 GENERIC: reg-class-variable ( register-class -- symbol )
 256
 257 M: reg-class reg-class-variable ;
 258
 259 M: float-regs reg-class-variable drop float-regs ;
 260
 261 GENERIC: inc-reg-class ( register-class -- )
 262
 263 : ?dummy-stack-params ( reg-class -- )
 264     dummy-stack-params? [ reg-size cell align stack-params +@ ] [ drop ] if ;
 265
 266 : ?dummy-int-params ( reg-class -- )
 267     dummy-int-params? [ reg-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 268
 269 : ?dummy-fp-params ( reg-class -- )
 270     drop dummy-fp-params? [ float-regs inc ] when ;
 271
 272 M: int-regs inc-reg-class
 273     [ reg-class-variable inc ]
 274     [ ?dummy-stack-params ]
 275     [ ?dummy-fp-params ]
 276     tri ;
 277
 278 M: float-regs inc-reg-class
 279     [ reg-class-variable inc ]
 280     [ ?dummy-stack-params ]
 281     [ ?dummy-int-params ]
 282     tri ;
 283
 284 GENERIC: reg-class-full? ( class -- ? )
 285
 286 M: stack-params reg-class-full? drop t ;
 287
 288 M: object reg-class-full?
 289     [ reg-class-variable get ] [ param-regs length ] bi >= ;
 290
 291 : spill-param ( reg-class -- n reg-class )
 292     stack-params get
 293     [ reg-size cell align stack-params +@ ] dip
 294     stack-params ;
 295
 296 : fastcall-param ( reg-class -- n reg-class )
 297     [ reg-class-variable get ] [ inc-reg-class ] [ ] tri ;
 298
 299 : alloc-parameter ( parameter -- reg reg-class )
 300     c-type-reg-class dup reg-class-full?
 301     [ spill-param ] [ fastcall-param ] if
 302     [ param-reg ] keep ;
 303
 304 : (flatten-int-type) ( size -- seq )
 305     cell /i "void*" c-type <repetition> ;
 306
 307 GENERIC: flatten-value-type ( type -- types )
 308
 309 M: object flatten-value-type 1array ;
 310
 311 M: struct-type flatten-value-type ( type -- types )
 312     stack-size cell align (flatten-int-type) ;
 313
 314 M: long-long-type flatten-value-type ( type -- types )
 315     stack-size cell align (flatten-int-type) ;
 316
 317 : flatten-value-types ( params -- params )
 318     #! Convert value type structs to consecutive void*s.
 319     [
 320         0 [
 321             c-type
 322             [ parameter-align (flatten-int-type) % ] keep
 323             [ stack-size cell align + ] keep
 324             flatten-value-type %
 325         ] reduce drop
 326     ] { } make ;
 327
 328 : each-parameter ( parameters quot -- )
 329     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 330
 331 : reverse-each-parameter ( parameters quot -- )
 332     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 333
 334 : reset-freg-counts ( -- )
 335     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 336
 337 : with-param-regs ( quot -- )
 338     #! In quot you can call alloc-parameter
 339     [ reset-freg-counts call ] with-scope ; inline
 340
 341 : move-parameters ( node word -- )
 342     #! Moves values from C stack to registers (if word is
 343     #! %load-param-reg) and registers to C stack (if word is
 344     #! %save-param-reg).
 345     [ alien-parameters flatten-value-types ]
 346     [ '[ alloc-parameter _ execute ] ]
 347     bi* each-parameter ; inline
 348
 349 : unbox-parameters ( offset node -- )
 350     parameters>> [
 351         %prepare-unbox [ over + ] dip unbox-parameter
 352     ] reverse-each-parameter drop ;
 353
 354 : prepare-box-struct ( node -- offset )
 355     #! Return offset on C stack where to store unboxed
 356     #! parameters. If the C function is returning a structure,
 357     #! the first parameter is an implicit target area pointer,
 358     #! so we need to use a different offset.
 359     return>> large-struct?
 360     [ %prepare-box-struct cell ] [ 0 ] if ;
 361
 362 : objects>registers ( params -- )
 363     #! Generate code for unboxing a list of C types, then
 364     #! generate code for moving these parameters to register on
 365     #! architectures where parameters are passed in registers.
 366     [
 367         [ prepare-box-struct ] keep
 368         [ unbox-parameters ] keep
 369         \ %load-param-reg move-parameters
 370     ] with-param-regs ;
 371
 372 : box-return* ( node -- )
 373     return>> [ ] [ box-return ] if-void ;
 374
 375 : check-dlsym ( symbols dll -- )
 376     dup dll-valid? [
 377         dupd '[ _ dlsym ] any?
 378         [ drop ] [ compiling-word get no-such-symbol ] if
 379     ] [
 380         dll-path compiling-word get no-such-library drop
 381     ] if ;
 382
 383 : stdcall-mangle ( symbol params -- symbol )
 384     parameters>> parameter-sizes drop number>string "@" glue ;
 385
 386 : alien-invoke-dlsym ( params -- symbols dll )
 387     [ [ function>> dup ] keep stdcall-mangle 2array ]
 388     [ library>> library dup [ dll>> ] when ]
 389     bi 2dup check-dlsym ;
 390
 391 M: ##alien-invoke generate-insn
 392     params>>
 393     ! Save registers for GC
 394     %prepare-alien-invoke
 395     ! Unbox parameters
 396     dup objects>registers
 397     %prepare-var-args
 398     ! Call function
 399     dup alien-invoke-dlsym %alien-invoke
 400     ! Box return value
 401     dup %cleanup
 402     box-return* ;
 403
 404 ! ##alien-indirect
 405 M: ##alien-indirect generate-insn
 406     params>>
 407     ! Save registers for GC
 408     %prepare-alien-invoke
 409     ! Save alien at top of stack to temporary storage
 410     %prepare-alien-indirect
 411     ! Unbox parameters
 412     dup objects>registers
 413     %prepare-var-args
 414     ! Call alien in temporary storage
 415     %alien-indirect
 416     ! Box return value
 417     dup %cleanup
 418     box-return* ;
 419
 420 ! ##alien-callback
 421 : box-parameters ( params -- )
 422     alien-parameters [ box-parameter ] each-parameter ;
 423
 424 : registers>objects ( node -- )
 425     [
 426         dup \ %save-param-reg move-parameters
 427         "nest_stacks" f %alien-invoke
 428         box-parameters
 429     ] with-param-regs ;
 430
 431 TUPLE: callback-context ;
 432
 433 : current-callback ( -- id ) 2 getenv ;
 434
 435 : wait-to-return ( token -- )
 436     dup current-callback eq? [
 437         drop
 438     ] [
 439         yield-hook get call( -- ) wait-to-return
 440     ] if ;
 441
 442 : do-callback ( quot token -- )
 443     init-catchstack
 444     [ 2 setenv call ] keep
 445     wait-to-return ; inline
 446
 447 : callback-return-quot ( ctype -- quot )
 448     return>> {
 449         { [ dup "void" = ] [ drop [ ] ] }
 450         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 451         [ c-type c-type-unboxer-quot ]
 452     } cond ;
 453
 454 : callback-prep-quot ( params -- quot )
 455     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 456
 457 : wrap-callback-quot ( params -- quot )
 458     [
 459         [ callback-prep-quot ]
 460         [ quot>> ]
 461         [ callback-return-quot ] tri 3append ,
 462         [ callback-context new do-callback ] %
 463     ] [ ] make ;
 464
 465 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 466
 467 M: ##callback-return generate-insn
 468     #! All the extra book-keeping for %unwind is only for x86.
 469     #! On other platforms its an alias for %return.
 470     params>> %callback-return ;
 471
 472 M: ##alien-callback generate-insn
 473     params>>
 474     [ registers>objects ]
 475     [ wrap-callback-quot %alien-callback ]
 476     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 477     tri ;
 478
 479 M: _prologue generate-insn
 480     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 481
 482 M: _epilogue generate-insn
 483     stack-frame>> total-size>> %epilogue ;
 484
 485 M: _label generate-insn
 486     id>> lookup-label resolve-label ;
 487
 488 M: _branch generate-insn
 489     label>> lookup-label %jump-label ;
 490
 491 : >compare< ( insn -- dst temp cc src1 src2 )
 492     {
 493         [ dst>> register ]
 494         [ temp>> register ]
 495         [ cc>> ]
 496         [ src1>> register ]
 497         [ src2>> ?register ]
 498     } cleave ; inline
 499
 500 M: ##compare generate-insn >compare< %compare ;
 501 M: ##compare-imm generate-insn >compare< %compare-imm ;
 502 M: ##compare-float generate-insn >compare< %compare-float ;
 503
 504 : >binary-branch< ( insn -- label cc src1 src2 )
 505     {
 506         [ label>> lookup-label ]
 507         [ cc>> ]
 508         [ src1>> register ]
 509         [ src2>> ?register ]
 510     } cleave ; inline
 511
 512 M: _compare-branch generate-insn
 513     >binary-branch< %compare-branch ;
 514
 515 M: _compare-imm-branch generate-insn
 516     >binary-branch< %compare-imm-branch ;
 517
 518 M: _compare-float-branch generate-insn
 519     >binary-branch< %compare-float-branch ;
 520
 521 M: _spill generate-insn
 522     [ src>> ] [ n>> ] [ class>> ] tri {
 523         { int-regs [ %spill-integer ] }
 524         { double-float-regs [ %spill-float ] }
 525     } case ;
 526
 527 M: _reload generate-insn
 528     [ dst>> ] [ n>> ] [ class>> ] tri {
 529         { int-regs [ %reload-integer ] }
 530         { double-float-regs [ %reload-float ] }
 531     } case ;
 532
 533 M: _copy generate-insn
 534     [ dst>> ] [ src>> ] [ class>> ] tri {
 535         { int-regs [ %copy ] }
 536         { double-float-regs [ %copy-float ] }
 537     } case ;
 538
 539 M: _spill-counts generate-insn drop ;