basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences
   4 accessors kernel layouts assocs words summary arrays combinators
   5 classes.algebra alien alien.private alien.c-types alien.strings
   6 alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes
   8 classes.struct locals source-files.errors slots parser
   9 generic.parser strings quotations
  10 compiler.errors
  11 compiler.alien
  12 compiler.constants
  13 compiler.cfg
  14 compiler.cfg.instructions
  15 compiler.cfg.stack-frame
  16 compiler.cfg.registers
  17 compiler.cfg.builder
  18 compiler.codegen.fixup
  19 compiler.utilities ;
  20 FROM: namespaces => set ;
  21 IN: compiler.codegen
  22
  23 SYMBOL: insn-counts
  24
  25 H{ } clone insn-counts set-global
  26
  27 GENERIC: generate-insn ( insn -- )
  28
  29 ! Mapping _label IDs to label instances
  30 SYMBOL: labels
  31
  32 : generate ( mr -- code )
  33     dup label>> [
  34         H{ } clone labels set
  35         instructions>> [
  36             [ class insn-counts get inc-at ]
  37             [ generate-insn ]
  38             bi
  39         ] each
  40     ] with-fixup ;
  41
  42 : lookup-label ( id -- label )
  43     labels get [ drop <label> ] cache ;
  44
  45 ! Special cases
  46 M: ##no-tco generate-insn drop ;
  47
  48 M: _dispatch-label generate-insn
  49     label>> lookup-label
  50     cell 0 <repetition> %
  51     rc-absolute-cell label-fixup ;
  52
  53 M: _prologue generate-insn
  54     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  55
  56 M: _epilogue generate-insn
  57     stack-frame>> total-size>> %epilogue ;
  58
  59 M: _spill-area-size generate-insn drop ;
  60
  61 ! Some meta-programming to generate simple code generators, where
  62 ! the instruction is unpacked and then a %word is called
  63 <<
  64
  65 : insn-slot-quot ( spec -- quot )
  66     name>> [ reader-word ] [ "label" = ] bi
  67     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
  68
  69 : codegen-method-body ( class word -- quot )
  70     [
  71         "insn-slots" word-prop
  72         [ insn-slot-quot ] map cleave>quot
  73     ] dip suffix ;
  74
  75 SYNTAX: CODEGEN:
  76     scan-word [ \ generate-insn create-method-in ] keep scan-word
  77     codegen-method-body define ;
  78 >>
  79
  80 CODEGEN: ##load-immediate %load-immediate
  81 CODEGEN: ##load-reference %load-reference
  82 CODEGEN: ##load-constant %load-reference
  83 CODEGEN: ##peek %peek
  84 CODEGEN: ##replace %replace
  85 CODEGEN: ##inc-d %inc-d
  86 CODEGEN: ##inc-r %inc-r
  87 CODEGEN: ##call %call
  88 CODEGEN: ##jump %jump
  89 CODEGEN: ##return %return
  90 CODEGEN: ##slot %slot
  91 CODEGEN: ##slot-imm %slot-imm
  92 CODEGEN: ##set-slot %set-slot
  93 CODEGEN: ##set-slot-imm %set-slot-imm
  94 CODEGEN: ##string-nth %string-nth
  95 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
  96 CODEGEN: ##add %add
  97 CODEGEN: ##add-imm %add-imm
  98 CODEGEN: ##sub %sub
  99 CODEGEN: ##sub-imm %sub-imm
 100 CODEGEN: ##mul %mul
 101 CODEGEN: ##mul-imm %mul-imm
 102 CODEGEN: ##and %and
 103 CODEGEN: ##and-imm %and-imm
 104 CODEGEN: ##or %or
 105 CODEGEN: ##or-imm %or-imm
 106 CODEGEN: ##xor %xor
 107 CODEGEN: ##xor-imm %xor-imm
 108 CODEGEN: ##shl %shl
 109 CODEGEN: ##shl-imm %shl-imm
 110 CODEGEN: ##shr %shr
 111 CODEGEN: ##shr-imm %shr-imm
 112 CODEGEN: ##sar %sar
 113 CODEGEN: ##sar-imm %sar-imm
 114 CODEGEN: ##min %min
 115 CODEGEN: ##max %max
 116 CODEGEN: ##not %not
 117 CODEGEN: ##neg %neg
 118 CODEGEN: ##log2 %log2
 119 CODEGEN: ##copy %copy
 120 CODEGEN: ##add-float %add-float
 121 CODEGEN: ##sub-float %sub-float
 122 CODEGEN: ##mul-float %mul-float
 123 CODEGEN: ##div-float %div-float
 124 CODEGEN: ##min-float %min-float
 125 CODEGEN: ##max-float %max-float
 126 CODEGEN: ##sqrt %sqrt
 127 CODEGEN: ##unary-float-function %unary-float-function
 128 CODEGEN: ##binary-float-function %binary-float-function
 129 CODEGEN: ##single>double-float %single>double-float
 130 CODEGEN: ##double>single-float %double>single-float
 131 CODEGEN: ##integer>float %integer>float
 132 CODEGEN: ##float>integer %float>integer
 133 CODEGEN: ##zero-vector %zero-vector
 134 CODEGEN: ##fill-vector %fill-vector
 135 CODEGEN: ##gather-vector-2 %gather-vector-2
 136 CODEGEN: ##gather-vector-4 %gather-vector-4
 137 CODEGEN: ##shuffle-vector-imm %shuffle-vector-imm
 138 CODEGEN: ##shuffle-vector %shuffle-vector
 139 CODEGEN: ##tail>head-vector %tail>head-vector
 140 CODEGEN: ##merge-vector-head %merge-vector-head
 141 CODEGEN: ##merge-vector-tail %merge-vector-tail
 142 CODEGEN: ##signed-pack-vector %signed-pack-vector
 143 CODEGEN: ##unsigned-pack-vector %unsigned-pack-vector
 144 CODEGEN: ##unpack-vector-head %unpack-vector-head
 145 CODEGEN: ##unpack-vector-tail %unpack-vector-tail
 146 CODEGEN: ##integer>float-vector %integer>float-vector
 147 CODEGEN: ##float>integer-vector %float>integer-vector
 148 CODEGEN: ##compare-vector %compare-vector
 149 CODEGEN: ##test-vector %test-vector
 150 CODEGEN: ##add-vector %add-vector
 151 CODEGEN: ##saturated-add-vector %saturated-add-vector
 152 CODEGEN: ##add-sub-vector %add-sub-vector
 153 CODEGEN: ##sub-vector %sub-vector
 154 CODEGEN: ##saturated-sub-vector %saturated-sub-vector
 155 CODEGEN: ##mul-vector %mul-vector
 156 CODEGEN: ##mul-high-vector %mul-high-vector
 157 CODEGEN: ##mul-horizontal-add-vector %mul-horizontal-add-vector
 158 CODEGEN: ##saturated-mul-vector %saturated-mul-vector
 159 CODEGEN: ##div-vector %div-vector
 160 CODEGEN: ##min-vector %min-vector
 161 CODEGEN: ##max-vector %max-vector
 162 CODEGEN: ##avg-vector %avg-vector
 163 CODEGEN: ##dot-vector %dot-vector
 164 CODEGEN: ##sad-vector %sad-vector
 165 CODEGEN: ##sqrt-vector %sqrt-vector
 166 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 167 CODEGEN: ##horizontal-sub-vector %horizontal-sub-vector
 168 CODEGEN: ##horizontal-shl-vector-imm %horizontal-shl-vector-imm
 169 CODEGEN: ##horizontal-shr-vector-imm %horizontal-shr-vector-imm
 170 CODEGEN: ##abs-vector %abs-vector
 171 CODEGEN: ##and-vector %and-vector
 172 CODEGEN: ##andn-vector %andn-vector
 173 CODEGEN: ##or-vector %or-vector
 174 CODEGEN: ##xor-vector %xor-vector
 175 CODEGEN: ##not-vector %not-vector
 176 CODEGEN: ##shl-vector-imm %shl-vector-imm
 177 CODEGEN: ##shr-vector-imm %shr-vector-imm
 178 CODEGEN: ##shl-vector %shl-vector
 179 CODEGEN: ##shr-vector %shr-vector
 180 CODEGEN: ##integer>scalar %integer>scalar
 181 CODEGEN: ##scalar>integer %scalar>integer
 182 CODEGEN: ##vector>scalar %vector>scalar
 183 CODEGEN: ##scalar>vector %scalar>vector
 184 CODEGEN: ##box-alien %box-alien
 185 CODEGEN: ##box-displaced-alien %box-displaced-alien
 186 CODEGEN: ##unbox-alien %unbox-alien
 187 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 188 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 189 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 190 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 191 CODEGEN: ##alien-signed-1 %alien-signed-1
 192 CODEGEN: ##alien-signed-2 %alien-signed-2
 193 CODEGEN: ##alien-signed-4 %alien-signed-4
 194 CODEGEN: ##alien-cell %alien-cell
 195 CODEGEN: ##alien-float %alien-float
 196 CODEGEN: ##alien-double %alien-double
 197 CODEGEN: ##alien-vector %alien-vector
 198 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 199 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 200 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 201 CODEGEN: ##set-alien-cell %set-alien-cell
 202 CODEGEN: ##set-alien-float %set-alien-float
 203 CODEGEN: ##set-alien-double %set-alien-double
 204 CODEGEN: ##set-alien-vector %set-alien-vector
 205 CODEGEN: ##allot %allot
 206 CODEGEN: ##write-barrier %write-barrier
 207 CODEGEN: ##write-barrier-imm %write-barrier-imm
 208 CODEGEN: ##compare %compare
 209 CODEGEN: ##compare-imm %compare-imm
 210 CODEGEN: ##compare-float-ordered %compare-float-ordered
 211 CODEGEN: ##compare-float-unordered %compare-float-unordered
 212 CODEGEN: ##save-context %save-context
 213 CODEGEN: ##vm-field-ptr %vm-field-ptr
 214
 215 CODEGEN: _fixnum-add %fixnum-add
 216 CODEGEN: _fixnum-sub %fixnum-sub
 217 CODEGEN: _fixnum-mul %fixnum-mul
 218 CODEGEN: _label resolve-label
 219 CODEGEN: _branch %jump-label
 220 CODEGEN: _compare-branch %compare-branch
 221 CODEGEN: _compare-imm-branch %compare-imm-branch
 222 CODEGEN: _compare-float-ordered-branch %compare-float-ordered-branch
 223 CODEGEN: _compare-float-unordered-branch %compare-float-unordered-branch
 224 CODEGEN: _test-vector-branch %test-vector-branch
 225 CODEGEN: _dispatch %dispatch
 226 CODEGEN: _spill %spill
 227 CODEGEN: _reload %reload
 228
 229 ! ##gc
 230 : wipe-locs ( locs temp -- )
 231     '[
 232         _
 233         [ 0 %load-immediate ]
 234         [ swap [ %replace ] with each ] bi
 235     ] unless-empty ;
 236
 237 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 238
 239 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 240     temp int-rep operand %reload
 241     gc-root temp %save-gc-root ;
 242
 243 M: object save-gc-root drop %save-gc-root ;
 244
 245 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 246
 247 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 248
 249 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 250
 251 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 252     gc-root temp %load-gc-root
 253     temp int-rep operand %spill ;
 254
 255 M: object load-gc-root drop %load-gc-root ;
 256
 257 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 258
 259 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 260
 261 M: ##gc generate-insn
 262     "no-gc" define-label
 263     {
 264         [ [ "no-gc" get ] dip [ size>> ] [ temp1>> ] [ temp2>> ] tri %check-nursery ]
 265         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 266         [ data-values>> save-data-regs ]
 267         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 268         [ [ temp1>> ] [ temp2>> ] bi %save-context ]
 269         [ [ tagged-values>> length ] [ temp1>> ] bi %call-gc ]
 270         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 271         [ data-values>> load-data-regs ]
 272     } cleave
 273     "no-gc" resolve-label ;
 274
 275 M: _loop-entry generate-insn drop %loop-entry ;
 276
 277 M: ##alien-global generate-insn
 278     [ dst>> ] [ symbol>> ] [ library>> ] tri
 279     %alien-global ;
 280
 281 ! ##alien-invoke
 282 GENERIC: next-fastcall-param ( rep -- )
 283
 284 : ?dummy-stack-params ( rep -- )
 285     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 286
 287 : ?dummy-int-params ( rep -- )
 288     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 289
 290 : ?dummy-fp-params ( rep -- )
 291     drop dummy-fp-params? [ float-regs inc ] when ;
 292
 293 M: int-rep next-fastcall-param
 294     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 295
 296 M: float-rep next-fastcall-param
 297     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 298
 299 M: double-rep next-fastcall-param
 300     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 301
 302 GENERIC: reg-class-full? ( reg-class -- ? )
 303
 304 M: stack-params reg-class-full? drop t ;
 305
 306 M: reg-class reg-class-full?
 307     [ get ] [ param-regs length ] bi >= ;
 308
 309 : alloc-stack-param ( rep -- n reg-class rep )
 310     stack-params get
 311     [ rep-size cell align stack-params +@ ] dip
 312     stack-params dup ;
 313
 314 : alloc-fastcall-param ( rep -- n reg-class rep )
 315     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 316
 317 : alloc-parameter ( parameter -- reg rep )
 318     c-type-rep dup reg-class-of reg-class-full?
 319     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 320     [ param-reg ] dip ;
 321
 322 : (flatten-int-type) ( type -- seq )
 323     stack-size cell align cell /i void* c-type <repetition> ;
 324
 325 GENERIC: flatten-value-type ( type -- types )
 326
 327 M: object flatten-value-type 1array ;
 328 M: struct-c-type flatten-value-type (flatten-int-type) ;
 329 M: long-long-type flatten-value-type (flatten-int-type) ;
 330 M: c-type-name flatten-value-type c-type flatten-value-type ;
 331
 332 : flatten-value-types ( params -- params )
 333     #! Convert value type structs to consecutive void*s.
 334     [
 335         0 [
 336             c-type
 337             [ parameter-align cell /i void* c-type <repetition> % ] keep
 338             [ stack-size cell align + ] keep
 339             flatten-value-type %
 340         ] reduce drop
 341     ] { } make ;
 342
 343 : each-parameter ( parameters quot -- )
 344     [ [ parameter-offsets nip ] keep ] dip 2each ; inline
 345
 346 : reset-fastcall-counts ( -- )
 347     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 348
 349 : with-param-regs ( quot -- )
 350     #! In quot you can call alloc-parameter
 351     [ reset-fastcall-counts call ] with-scope ; inline
 352
 353 : move-parameters ( node word -- )
 354     #! Moves values from C stack to registers (if word is
 355     #! %load-param-reg) and registers to C stack (if word is
 356     #! %save-param-reg).
 357     [ alien-parameters flatten-value-types ]
 358     [ '[ alloc-parameter _ execute ] ]
 359     bi* each-parameter ; inline
 360
 361 : reverse-each-parameter ( parameters quot -- )
 362     [ [ parameter-offsets nip ] keep ] dip 2reverse-each ; inline
 363
 364 : prepare-unbox-parameters ( parameters -- offsets types indices )
 365     [ parameter-offsets nip ] [ ] [ length iota <reversed> ] tri ;
 366
 367 : unbox-parameters ( offset node -- )
 368     parameters>> swap
 369     '[ prepare-unbox-parameters [ %pop-stack [ _ + ] dip unbox-parameter ] 3each ]
 370     [ length neg %inc-d ]
 371     bi ;
 372
 373 : prepare-box-struct ( node -- offset )
 374     #! Return offset on C stack where to store unboxed
 375     #! parameters. If the C function is returning a structure,
 376     #! the first parameter is an implicit target area pointer,
 377     #! so we need to use a different offset.
 378     return>> large-struct?
 379     [ %prepare-box-struct cell ] [ 0 ] if ;
 380
 381 : objects>registers ( params -- )
 382     #! Generate code for unboxing a list of C types, then
 383     #! generate code for moving these parameters to registers on
 384     #! architectures where parameters are passed in registers.
 385     [
 386         [ prepare-box-struct ] keep
 387         [ unbox-parameters ] keep
 388         \ %load-param-reg move-parameters
 389     ] with-param-regs ;
 390
 391 : box-return* ( node -- )
 392     return>> [ ] [ box-return %push-stack ] if-void ;
 393
 394 GENERIC# dlsym-valid? 1 ( symbols dll -- ? )
 395
 396 M: string dlsym-valid? dlsym ;
 397
 398 M: array dlsym-valid? '[ _ dlsym ] any? ;
 399
 400 : check-dlsym ( symbols dll -- )
 401     dup dll-valid? [
 402         dupd dlsym-valid?
 403         [ drop ] [ compiling-word get no-such-symbol ] if
 404     ] [
 405         dll-path compiling-word get no-such-library drop
 406     ] if ;
 407
 408 : stdcall-mangle ( params -- symbols )
 409     [ function>> ] [ parameters>> parameter-offsets drop number>string ] bi
 410     [ drop ] [ "@" glue ] [ "@" glue "_" prepend ] 2tri
 411     3array ;
 412
 413 : alien-invoke-dlsym ( params -- symbols dll )
 414     [ dup abi>> "stdcall" = [ stdcall-mangle ] [ function>> ] if ]
 415     [ library>> load-library ]
 416     bi 2dup check-dlsym ;
 417
 418 M: ##alien-invoke generate-insn
 419     params>>
 420     ! Unbox parameters
 421     dup objects>registers
 422     %prepare-var-args
 423     ! Call function
 424     dup alien-invoke-dlsym %alien-invoke
 425     ! Box return value
 426     dup %cleanup
 427     box-return* ;
 428
 429 M: ##alien-assembly generate-insn
 430     params>>
 431     ! Unbox parameters
 432     dup objects>registers
 433     %prepare-var-args
 434     ! Generate assembly
 435     dup quot>> call( -- )
 436     ! Box return value
 437     box-return* ;
 438
 439 ! ##alien-indirect
 440 M: ##alien-indirect generate-insn
 441     params>>
 442     ! Save alien at top of stack to temporary storage
 443     %prepare-alien-indirect
 444     ! Unbox parameters
 445     dup objects>registers
 446     %prepare-var-args
 447     ! Call alien in temporary storage
 448     %alien-indirect
 449     ! Box return value
 450     dup %cleanup
 451     box-return* ;
 452
 453 ! ##alien-callback
 454 : box-parameters ( params -- )
 455     alien-parameters [ box-parameter %push-context-stack ] each-parameter ;
 456
 457 : registers>objects ( node -- )
 458     ! Generate code for boxing input parameters in a callback.
 459     [
 460         dup \ %save-param-reg move-parameters
 461         %nest-stacks
 462         box-parameters
 463     ] with-param-regs ;
 464
 465 : callback-return-quot ( ctype -- quot )
 466     return>> {
 467         { [ dup void? ] [ drop [ ] ] }
 468         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 469         [ c-type c-type-unboxer-quot ]
 470     } cond ;
 471
 472 : callback-prep-quot ( params -- quot )
 473     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 474
 475 : wrap-callback-quot ( params -- quot )
 476     [ callback-prep-quot ] [ quot>> ] [ callback-return-quot ] tri 3append
 477      yield-hook get
 478      '[ _ _ do-callback ]
 479      >quotation ;
 480
 481 M: ##alien-callback generate-insn
 482     params>>
 483     [ registers>objects ]
 484     [ wrap-callback-quot %alien-callback ]
 485     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 486     tri ;