basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors slots parser generic.parser
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 QUALIFIED: classes.struct
  20 QUALIFIED: alien.structs
  21 IN: compiler.codegen
  22
  23 SYMBOL: insn-counts
  24
  25 H{ } clone insn-counts set-global
  26
  27 GENERIC: generate-insn ( insn -- )
  28
  29 TUPLE: asm label code calls ;
  30
  31 SYMBOL: calls
  32
  33 : add-call ( word -- )
  34     #! Compile this word later.
  35     calls get push ;
  36
  37 SYMBOL: compiling-word
  38
  39 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  40
  41 ! Mapping _label IDs to label instances
  42 SYMBOL: labels
  43
  44 : init-generator ( word -- )
  45     H{ } clone labels set
  46     V{ } clone calls set
  47     compiling-word set
  48     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  49
  50 : generate-insns ( asm -- code )
  51     [
  52         [ word>> init-generator ]
  53         [
  54             instructions>>
  55             [
  56                 [ class insn-counts get inc-at ]
  57                 [ generate-insn ]
  58                 bi
  59             ] each
  60         ] bi
  61     ] with-fixup ;
  62
  63 : generate ( mr -- asm )
  64     [
  65         [ label>> ] [ generate-insns ] bi calls get
  66         asm boa
  67     ] with-scope ;
  68
  69 : lookup-label ( id -- label )
  70     labels get [ drop <label> ] cache ;
  71
  72 ! Special cases
  73 M: ##no-tco generate-insn drop ;
  74
  75 M: ##call generate-insn
  76     word>> dup sub-primitive>>
  77     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  78
  79 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  80
  81 M: _dispatch-label generate-insn
  82     label>> lookup-label
  83     cell 0 <repetition> %
  84     rc-absolute-cell label-fixup ;
  85
  86 M: _prologue generate-insn
  87     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  88
  89 M: _epilogue generate-insn
  90     stack-frame>> total-size>> %epilogue ;
  91
  92 M: _spill-area-size generate-insn drop ;
  93
  94 ! Some meta-programming to generate simple code generators, where
  95 ! the instruction is unpacked and then a %word is called
  96 <<
  97
  98 : insn-slot-quot ( spec -- quot )
  99     name>> [ reader-word ] [ "label" = ] bi
 100     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
 101
 102 : codegen-method-body ( class word -- quot )
 103     [
 104         "insn-slots" word-prop
 105         [ insn-slot-quot ] map cleave>quot
 106     ] dip suffix ;
 107
 108 SYNTAX: CODEGEN:
 109     scan-word [ \ generate-insn create-method-in ] keep scan-word
 110     codegen-method-body define ;
 111 >>
 112
 113 CODEGEN: ##load-immediate %load-immediate
 114 CODEGEN: ##load-reference %load-reference
 115 CODEGEN: ##peek %peek
 116 CODEGEN: ##replace %replace
 117 CODEGEN: ##inc-d %inc-d
 118 CODEGEN: ##inc-r %inc-r
 119 CODEGEN: ##return %return
 120 CODEGEN: ##slot %slot
 121 CODEGEN: ##slot-imm %slot-imm
 122 CODEGEN: ##set-slot %set-slot
 123 CODEGEN: ##set-slot-imm %set-slot-imm
 124 CODEGEN: ##string-nth %string-nth
 125 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 126 CODEGEN: ##add %add
 127 CODEGEN: ##add-imm %add-imm
 128 CODEGEN: ##sub %sub
 129 CODEGEN: ##sub-imm %sub-imm
 130 CODEGEN: ##mul %mul
 131 CODEGEN: ##mul-imm %mul-imm
 132 CODEGEN: ##and %and
 133 CODEGEN: ##and-imm %and-imm
 134 CODEGEN: ##or %or
 135 CODEGEN: ##or-imm %or-imm
 136 CODEGEN: ##xor %xor
 137 CODEGEN: ##xor-imm %xor-imm
 138 CODEGEN: ##shl %shl
 139 CODEGEN: ##shl-imm %shl-imm
 140 CODEGEN: ##shr %shr
 141 CODEGEN: ##shr-imm %shr-imm
 142 CODEGEN: ##sar %sar
 143 CODEGEN: ##sar-imm %sar-imm
 144 CODEGEN: ##min %min
 145 CODEGEN: ##max %max
 146 CODEGEN: ##not %not
 147 CODEGEN: ##log2 %log2
 148 CODEGEN: ##copy %copy
 149 CODEGEN: ##integer>bignum %integer>bignum
 150 CODEGEN: ##bignum>integer %bignum>integer
 151 CODEGEN: ##unbox-float %unbox-float
 152 CODEGEN: ##box-float %box-float
 153 CODEGEN: ##add-float %add-float
 154 CODEGEN: ##sub-float %sub-float
 155 CODEGEN: ##mul-float %mul-float
 156 CODEGEN: ##div-float %div-float
 157 CODEGEN: ##min-float %min-float
 158 CODEGEN: ##max-float %max-float
 159 CODEGEN: ##sqrt %sqrt
 160 CODEGEN: ##unary-float-function %unary-float-function
 161 CODEGEN: ##binary-float-function %binary-float-function
 162 CODEGEN: ##single>double-float %single>double-float
 163 CODEGEN: ##double>single-float %double>single-float
 164 CODEGEN: ##integer>float %integer>float
 165 CODEGEN: ##float>integer %float>integer
 166 CODEGEN: ##unbox-vector %unbox-vector
 167 CODEGEN: ##broadcast-vector %broadcast-vector
 168 CODEGEN: ##gather-vector-2 %gather-vector-2
 169 CODEGEN: ##gather-vector-4 %gather-vector-4
 170 CODEGEN: ##box-vector %box-vector
 171 CODEGEN: ##add-vector %add-vector
 172 CODEGEN: ##saturated-add-vector %saturated-add-vector
 173 CODEGEN: ##add-sub-vector %add-sub-vector
 174 CODEGEN: ##sub-vector %sub-vector
 175 CODEGEN: ##saturated-sub-vector %saturated-sub-vector
 176 CODEGEN: ##mul-vector %mul-vector
 177 CODEGEN: ##saturated-mul-vector %saturated-mul-vector
 178 CODEGEN: ##div-vector %div-vector
 179 CODEGEN: ##min-vector %min-vector
 180 CODEGEN: ##max-vector %max-vector
 181 CODEGEN: ##sqrt-vector %sqrt-vector
 182 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 183 CODEGEN: ##abs-vector %abs-vector
 184 CODEGEN: ##and-vector %and-vector
 185 CODEGEN: ##or-vector %or-vector
 186 CODEGEN: ##xor-vector %xor-vector
 187 CODEGEN: ##shl-vector %shl-vector
 188 CODEGEN: ##shr-vector %shr-vector
 189 CODEGEN: ##integer>scalar %integer>scalar
 190 CODEGEN: ##scalar>integer %scalar>integer
 191 CODEGEN: ##box-alien %box-alien
 192 CODEGEN: ##box-displaced-alien %box-displaced-alien
 193 CODEGEN: ##unbox-alien %unbox-alien
 194 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 195 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 196 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 197 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 198 CODEGEN: ##alien-signed-1 %alien-signed-1
 199 CODEGEN: ##alien-signed-2 %alien-signed-2
 200 CODEGEN: ##alien-signed-4 %alien-signed-4
 201 CODEGEN: ##alien-cell %alien-cell
 202 CODEGEN: ##alien-float %alien-float
 203 CODEGEN: ##alien-double %alien-double
 204 CODEGEN: ##alien-vector %alien-vector
 205 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 206 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 207 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 208 CODEGEN: ##set-alien-cell %set-alien-cell
 209 CODEGEN: ##set-alien-float %set-alien-float
 210 CODEGEN: ##set-alien-double %set-alien-double
 211 CODEGEN: ##set-alien-vector %set-alien-vector
 212 CODEGEN: ##allot %allot
 213 CODEGEN: ##write-barrier %write-barrier
 214 CODEGEN: ##compare %compare
 215 CODEGEN: ##compare-imm %compare-imm
 216 CODEGEN: ##compare-float-ordered %compare-float-ordered
 217 CODEGEN: ##compare-float-unordered %compare-float-unordered
 218 CODEGEN: ##save-context %save-context
 219 CODEGEN: ##vm-field-ptr %vm-field-ptr
 220
 221 CODEGEN: _fixnum-add %fixnum-add
 222 CODEGEN: _fixnum-sub %fixnum-sub
 223 CODEGEN: _fixnum-mul %fixnum-mul
 224 CODEGEN: _label resolve-label
 225 CODEGEN: _branch %jump-label
 226 CODEGEN: _compare-branch %compare-branch
 227 CODEGEN: _compare-imm-branch %compare-imm-branch
 228 CODEGEN: _compare-float-ordered-branch %compare-float-ordered-branch
 229 CODEGEN: _compare-float-unordered-branch %compare-float-unordered-branch
 230 CODEGEN: _dispatch %dispatch
 231 CODEGEN: _spill %spill
 232 CODEGEN: _reload %reload
 233
 234 ! ##gc
 235 : wipe-locs ( locs temp -- )
 236     '[
 237         _
 238         [ 0 %load-immediate ]
 239         [ swap [ %replace ] with each ] bi
 240     ] unless-empty ;
 241
 242 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 243
 244 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 245     temp int-rep operand n>> %reload
 246     gc-root temp %save-gc-root ;
 247
 248 M: object save-gc-root drop %save-gc-root ;
 249
 250 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 251
 252 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 253
 254 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 255
 256 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 257     gc-root temp %load-gc-root
 258     temp int-rep operand n>> %spill ;
 259
 260 M: object load-gc-root drop %load-gc-root ;
 261
 262 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 263
 264 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 265
 266 M: _gc generate-insn
 267     "no-gc" define-label
 268     {
 269         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 270         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 271         [ data-values>> save-data-regs ]
 272         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 273         [ [ temp1>> ] [ temp2>> ] bi t %save-context ]
 274         [ [ tagged-values>> length ] [ temp1>> ] bi %call-gc ]
 275         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 276         [ data-values>> load-data-regs ]
 277     } cleave
 278     "no-gc" resolve-label ;
 279
 280 M: _loop-entry generate-insn drop %loop-entry ;
 281
 282 M: ##alien-global generate-insn
 283     [ dst>> ] [ symbol>> ] [ library>> ] tri
 284     %alien-global ;
 285
 286 ! ##alien-invoke
 287 GENERIC: next-fastcall-param ( rep -- )
 288
 289 : ?dummy-stack-params ( rep -- )
 290     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 291
 292 : ?dummy-int-params ( rep -- )
 293     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 294
 295 : ?dummy-fp-params ( rep -- )
 296     drop dummy-fp-params? [ float-regs inc ] when ;
 297
 298 M: int-rep next-fastcall-param
 299     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 300
 301 M: float-rep next-fastcall-param
 302     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 303
 304 M: double-rep next-fastcall-param
 305     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 306
 307 GENERIC: reg-class-full? ( reg-class -- ? )
 308
 309 M: stack-params reg-class-full? drop t ;
 310
 311 M: reg-class reg-class-full?
 312     [ get ] [ param-regs length ] bi >= ;
 313
 314 : alloc-stack-param ( rep -- n reg-class rep )
 315     stack-params get
 316     [ rep-size cell align stack-params +@ ] dip
 317     stack-params dup ;
 318
 319 : alloc-fastcall-param ( rep -- n reg-class rep )
 320     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 321
 322 : alloc-parameter ( parameter -- reg rep )
 323     c-type-rep dup reg-class-of reg-class-full?
 324     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 325     [ param-reg ] dip ;
 326
 327 : (flatten-int-type) ( size -- seq )
 328     cell /i "void*" c-type <repetition> ;
 329
 330 GENERIC: flatten-value-type ( type -- types )
 331
 332 M: object flatten-value-type 1array ;
 333
 334 M: alien.structs:struct-type flatten-value-type ( type -- types )
 335     stack-size cell align (flatten-int-type) ;
 336
 337 M: classes.struct:struct-c-type flatten-value-type ( type -- types )
 338     stack-size cell align (flatten-int-type) ;
 339
 340 M: long-long-type flatten-value-type ( type -- types )
 341     stack-size cell align (flatten-int-type) ;
 342
 343 : flatten-value-types ( params -- params )
 344     #! Convert value type structs to consecutive void*s.
 345     [
 346         0 [
 347             c-type
 348             [ parameter-align (flatten-int-type) % ] keep
 349             [ stack-size cell align + ] keep
 350             flatten-value-type %
 351         ] reduce drop
 352     ] { } make ;
 353
 354 : each-parameter ( parameters quot -- )
 355     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 356
 357 : reverse-each-parameter ( parameters quot -- )
 358     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 359
 360 : reset-fastcall-counts ( -- )
 361     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 362
 363 : with-param-regs ( quot -- )
 364     #! In quot you can call alloc-parameter
 365     [ reset-fastcall-counts call ] with-scope ; inline
 366
 367 : move-parameters ( node word -- )
 368     #! Moves values from C stack to registers (if word is
 369     #! %load-param-reg) and registers to C stack (if word is
 370     #! %save-param-reg).
 371     [ alien-parameters flatten-value-types ]
 372     [ '[ alloc-parameter _ execute ] ]
 373     bi* each-parameter ; inline
 374
 375 : unbox-parameters ( offset node -- )
 376     parameters>> [
 377         %prepare-unbox [ over + ] dip unbox-parameter
 378     ] reverse-each-parameter drop ;
 379
 380 : prepare-box-struct ( node -- offset )
 381     #! Return offset on C stack where to store unboxed
 382     #! parameters. If the C function is returning a structure,
 383     #! the first parameter is an implicit target area pointer,
 384     #! so we need to use a different offset.
 385     return>> large-struct?
 386     [ %prepare-box-struct cell ] [ 0 ] if ;
 387
 388 : objects>registers ( params -- )
 389     #! Generate code for unboxing a list of C types, then
 390     #! generate code for moving these parameters to registers on
 391     #! architectures where parameters are passed in registers.
 392     [
 393         [ prepare-box-struct ] keep
 394         [ unbox-parameters ] keep
 395         \ %load-param-reg move-parameters
 396     ] with-param-regs ;
 397
 398 : box-return* ( node -- )
 399     return>> [ ] [ box-return ] if-void ;
 400
 401 : check-dlsym ( symbols dll -- )
 402     dup dll-valid? [
 403         dupd '[ _ dlsym ] any?
 404         [ drop ] [ compiling-word get no-such-symbol ] if
 405     ] [
 406         dll-path compiling-word get no-such-library drop
 407     ] if ;
 408
 409 : stdcall-mangle ( symbol params -- symbol )
 410     parameters>> parameter-sizes drop number>string "@" glue ;
 411
 412 : alien-invoke-dlsym ( params -- symbols dll )
 413     [ [ function>> dup ] keep stdcall-mangle 2array ]
 414     [ library>> library dup [ dll>> ] when ]
 415     bi 2dup check-dlsym ;
 416
 417 M: ##alien-invoke generate-insn
 418     params>>
 419     ! Unbox parameters
 420     dup objects>registers
 421     %prepare-var-args
 422     ! Call function
 423     dup alien-invoke-dlsym %alien-invoke
 424     ! Box return value
 425     dup %cleanup
 426     box-return* ;
 427
 428 ! ##alien-indirect
 429 M: ##alien-indirect generate-insn
 430     params>>
 431     ! Save alien at top of stack to temporary storage
 432     %prepare-alien-indirect
 433     ! Unbox parameters
 434     dup objects>registers
 435     %prepare-var-args
 436     ! Call alien in temporary storage
 437     %alien-indirect
 438     ! Box return value
 439     dup %cleanup
 440     box-return* ;
 441
 442 ! ##alien-callback
 443 : box-parameters ( params -- )
 444     alien-parameters [ box-parameter ] each-parameter ;
 445
 446 : registers>objects ( node -- )
 447     ! Generate code for boxing input parameters in a callback.
 448     [
 449         dup \ %save-param-reg move-parameters
 450         %nest-stacks
 451         box-parameters
 452     ] with-param-regs ;
 453
 454 TUPLE: callback-context ;
 455
 456 : current-callback ( -- id ) 2 getenv ;
 457
 458 : wait-to-return ( token -- )
 459     dup current-callback eq? [
 460         drop
 461     ] [
 462         yield-hook get call( -- ) wait-to-return
 463     ] if ;
 464
 465 : do-callback ( quot token -- )
 466     init-catchstack
 467     [ 2 setenv call ] keep
 468     wait-to-return ; inline
 469
 470 : callback-return-quot ( ctype -- quot )
 471     return>> {
 472         { [ dup void? ] [ drop [ ] ] }
 473         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 474         [ c-type c-type-unboxer-quot ]
 475     } cond ;
 476
 477 : callback-prep-quot ( params -- quot )
 478     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 479
 480 : wrap-callback-quot ( params -- quot )
 481     [
 482         [ callback-prep-quot ]
 483         [ quot>> ]
 484         [ callback-return-quot ] tri 3append ,
 485         [ callback-context new do-callback ] %
 486     ] [ ] make ;
 487
 488 M: ##callback-return generate-insn
 489     #! All the extra book-keeping for %unwind is only for x86.
 490     #! On other platforms its an alias for %return.
 491     params>> %callback-return ;
 492
 493 M: ##alien-callback generate-insn
 494     params>>
 495     [ registers>objects ]
 496     [ wrap-callback-quot %alien-callback ]
 497     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 498     tri ;