basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes classes.struct locals
   8 source-files.errors slots parser generic.parser strings
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 ! Mapping _label IDs to label instances
  36 SYMBOL: labels
  37
  38 : init-generator ( -- )
  39     H{ } clone labels set
  40     V{ } clone calls set ;
  41
  42 : generate-insns ( asm -- code )
  43     dup label>> [
  44         init-generator
  45         instructions>> [
  46             [ class insn-counts get inc-at ]
  47             [ generate-insn ]
  48             bi
  49         ] each
  50     ] with-fixup ;
  51
  52 : generate ( mr -- asm )
  53     [
  54         [ label>> ] [ generate-insns ] bi calls get
  55         asm boa
  56     ] with-scope ;
  57
  58 : lookup-label ( id -- label )
  59     labels get [ drop <label> ] cache ;
  60
  61 ! Special cases
  62 M: ##no-tco generate-insn drop ;
  63
  64 M: ##call generate-insn word>> [ add-call ] [ %call ] bi ;
  65
  66 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  67
  68 M: _dispatch-label generate-insn
  69     label>> lookup-label
  70     cell 0 <repetition> %
  71     rc-absolute-cell label-fixup ;
  72
  73 M: _prologue generate-insn
  74     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  75
  76 M: _epilogue generate-insn
  77     stack-frame>> total-size>> %epilogue ;
  78
  79 M: _spill-area-size generate-insn drop ;
  80
  81 ! Some meta-programming to generate simple code generators, where
  82 ! the instruction is unpacked and then a %word is called
  83 <<
  84
  85 : insn-slot-quot ( spec -- quot )
  86     name>> [ reader-word ] [ "label" = ] bi
  87     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
  88
  89 : codegen-method-body ( class word -- quot )
  90     [
  91         "insn-slots" word-prop
  92         [ insn-slot-quot ] map cleave>quot
  93     ] dip suffix ;
  94
  95 SYNTAX: CODEGEN:
  96     scan-word [ \ generate-insn create-method-in ] keep scan-word
  97     codegen-method-body define ;
  98 >>
  99
 100 CODEGEN: ##load-immediate %load-immediate
 101 CODEGEN: ##load-reference %load-reference
 102 CODEGEN: ##load-constant %load-reference
 103 CODEGEN: ##peek %peek
 104 CODEGEN: ##replace %replace
 105 CODEGEN: ##inc-d %inc-d
 106 CODEGEN: ##inc-r %inc-r
 107 CODEGEN: ##return %return
 108 CODEGEN: ##slot %slot
 109 CODEGEN: ##slot-imm %slot-imm
 110 CODEGEN: ##set-slot %set-slot
 111 CODEGEN: ##set-slot-imm %set-slot-imm
 112 CODEGEN: ##string-nth %string-nth
 113 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 114 CODEGEN: ##add %add
 115 CODEGEN: ##add-imm %add-imm
 116 CODEGEN: ##sub %sub
 117 CODEGEN: ##sub-imm %sub-imm
 118 CODEGEN: ##mul %mul
 119 CODEGEN: ##mul-imm %mul-imm
 120 CODEGEN: ##and %and
 121 CODEGEN: ##and-imm %and-imm
 122 CODEGEN: ##or %or
 123 CODEGEN: ##or-imm %or-imm
 124 CODEGEN: ##xor %xor
 125 CODEGEN: ##xor-imm %xor-imm
 126 CODEGEN: ##shl %shl
 127 CODEGEN: ##shl-imm %shl-imm
 128 CODEGEN: ##shr %shr
 129 CODEGEN: ##shr-imm %shr-imm
 130 CODEGEN: ##sar %sar
 131 CODEGEN: ##sar-imm %sar-imm
 132 CODEGEN: ##min %min
 133 CODEGEN: ##max %max
 134 CODEGEN: ##not %not
 135 CODEGEN: ##neg %neg
 136 CODEGEN: ##log2 %log2
 137 CODEGEN: ##copy %copy
 138 CODEGEN: ##add-float %add-float
 139 CODEGEN: ##sub-float %sub-float
 140 CODEGEN: ##mul-float %mul-float
 141 CODEGEN: ##div-float %div-float
 142 CODEGEN: ##min-float %min-float
 143 CODEGEN: ##max-float %max-float
 144 CODEGEN: ##sqrt %sqrt
 145 CODEGEN: ##unary-float-function %unary-float-function
 146 CODEGEN: ##binary-float-function %binary-float-function
 147 CODEGEN: ##single>double-float %single>double-float
 148 CODEGEN: ##double>single-float %double>single-float
 149 CODEGEN: ##integer>float %integer>float
 150 CODEGEN: ##float>integer %float>integer
 151 CODEGEN: ##zero-vector %zero-vector
 152 CODEGEN: ##fill-vector %fill-vector
 153 CODEGEN: ##gather-vector-2 %gather-vector-2
 154 CODEGEN: ##gather-vector-4 %gather-vector-4
 155 CODEGEN: ##shuffle-vector-imm %shuffle-vector-imm
 156 CODEGEN: ##shuffle-vector %shuffle-vector
 157 CODEGEN: ##tail>head-vector %tail>head-vector
 158 CODEGEN: ##merge-vector-head %merge-vector-head
 159 CODEGEN: ##merge-vector-tail %merge-vector-tail
 160 CODEGEN: ##signed-pack-vector %signed-pack-vector
 161 CODEGEN: ##unsigned-pack-vector %unsigned-pack-vector
 162 CODEGEN: ##unpack-vector-head %unpack-vector-head
 163 CODEGEN: ##unpack-vector-tail %unpack-vector-tail
 164 CODEGEN: ##integer>float-vector %integer>float-vector
 165 CODEGEN: ##float>integer-vector %float>integer-vector
 166 CODEGEN: ##compare-vector %compare-vector
 167 CODEGEN: ##test-vector %test-vector
 168 CODEGEN: ##add-vector %add-vector
 169 CODEGEN: ##saturated-add-vector %saturated-add-vector
 170 CODEGEN: ##add-sub-vector %add-sub-vector
 171 CODEGEN: ##sub-vector %sub-vector
 172 CODEGEN: ##saturated-sub-vector %saturated-sub-vector
 173 CODEGEN: ##mul-vector %mul-vector
 174 CODEGEN: ##mul-high-vector %mul-high-vector
 175 CODEGEN: ##mul-horizontal-add-vector %mul-horizontal-add-vector
 176 CODEGEN: ##saturated-mul-vector %saturated-mul-vector
 177 CODEGEN: ##div-vector %div-vector
 178 CODEGEN: ##min-vector %min-vector
 179 CODEGEN: ##max-vector %max-vector
 180 CODEGEN: ##avg-vector %avg-vector
 181 CODEGEN: ##dot-vector %dot-vector
 182 CODEGEN: ##sad-vector %sad-vector
 183 CODEGEN: ##sqrt-vector %sqrt-vector
 184 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 185 CODEGEN: ##horizontal-sub-vector %horizontal-sub-vector
 186 CODEGEN: ##horizontal-shl-vector-imm %horizontal-shl-vector-imm
 187 CODEGEN: ##horizontal-shr-vector-imm %horizontal-shr-vector-imm
 188 CODEGEN: ##abs-vector %abs-vector
 189 CODEGEN: ##and-vector %and-vector
 190 CODEGEN: ##andn-vector %andn-vector
 191 CODEGEN: ##or-vector %or-vector
 192 CODEGEN: ##xor-vector %xor-vector
 193 CODEGEN: ##not-vector %not-vector
 194 CODEGEN: ##shl-vector-imm %shl-vector-imm
 195 CODEGEN: ##shr-vector-imm %shr-vector-imm
 196 CODEGEN: ##shl-vector %shl-vector
 197 CODEGEN: ##shr-vector %shr-vector
 198 CODEGEN: ##integer>scalar %integer>scalar
 199 CODEGEN: ##scalar>integer %scalar>integer
 200 CODEGEN: ##vector>scalar %vector>scalar
 201 CODEGEN: ##scalar>vector %scalar>vector
 202 CODEGEN: ##box-alien %box-alien
 203 CODEGEN: ##box-displaced-alien %box-displaced-alien
 204 CODEGEN: ##unbox-alien %unbox-alien
 205 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 206 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 207 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 208 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 209 CODEGEN: ##alien-signed-1 %alien-signed-1
 210 CODEGEN: ##alien-signed-2 %alien-signed-2
 211 CODEGEN: ##alien-signed-4 %alien-signed-4
 212 CODEGEN: ##alien-cell %alien-cell
 213 CODEGEN: ##alien-float %alien-float
 214 CODEGEN: ##alien-double %alien-double
 215 CODEGEN: ##alien-vector %alien-vector
 216 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 217 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 218 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 219 CODEGEN: ##set-alien-cell %set-alien-cell
 220 CODEGEN: ##set-alien-float %set-alien-float
 221 CODEGEN: ##set-alien-double %set-alien-double
 222 CODEGEN: ##set-alien-vector %set-alien-vector
 223 CODEGEN: ##allot %allot
 224 CODEGEN: ##write-barrier %write-barrier
 225 CODEGEN: ##write-barrier-imm %write-barrier-imm
 226 CODEGEN: ##compare %compare
 227 CODEGEN: ##compare-imm %compare-imm
 228 CODEGEN: ##compare-float-ordered %compare-float-ordered
 229 CODEGEN: ##compare-float-unordered %compare-float-unordered
 230 CODEGEN: ##save-context %save-context
 231 CODEGEN: ##vm-field-ptr %vm-field-ptr
 232
 233 CODEGEN: _fixnum-add %fixnum-add
 234 CODEGEN: _fixnum-sub %fixnum-sub
 235 CODEGEN: _fixnum-mul %fixnum-mul
 236 CODEGEN: _label resolve-label
 237 CODEGEN: _branch %jump-label
 238 CODEGEN: _compare-branch %compare-branch
 239 CODEGEN: _compare-imm-branch %compare-imm-branch
 240 CODEGEN: _compare-float-ordered-branch %compare-float-ordered-branch
 241 CODEGEN: _compare-float-unordered-branch %compare-float-unordered-branch
 242 CODEGEN: _test-vector-branch %test-vector-branch
 243 CODEGEN: _dispatch %dispatch
 244 CODEGEN: _spill %spill
 245 CODEGEN: _reload %reload
 246
 247 ! ##gc
 248 : wipe-locs ( locs temp -- )
 249     '[
 250         _
 251         [ 0 %load-immediate ]
 252         [ swap [ %replace ] with each ] bi
 253     ] unless-empty ;
 254
 255 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 256
 257 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 258     temp int-rep operand %reload
 259     gc-root temp %save-gc-root ;
 260
 261 M: object save-gc-root drop %save-gc-root ;
 262
 263 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 264
 265 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 266
 267 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 268
 269 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 270     gc-root temp %load-gc-root
 271     temp int-rep operand %spill ;
 272
 273 M: object load-gc-root drop %load-gc-root ;
 274
 275 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 276
 277 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 278
 279 M: ##gc generate-insn
 280     "no-gc" define-label
 281     {
 282         [ [ "no-gc" get ] dip [ size>> ] [ temp1>> ] [ temp2>> ] tri %check-nursery ]
 283         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 284         [ data-values>> save-data-regs ]
 285         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 286         [ [ temp1>> ] [ temp2>> ] bi %save-context ]
 287         [ [ tagged-values>> length ] [ temp1>> ] bi %call-gc ]
 288         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 289         [ data-values>> load-data-regs ]
 290     } cleave
 291     "no-gc" resolve-label ;
 292
 293 M: _loop-entry generate-insn drop %loop-entry ;
 294
 295 M: ##alien-global generate-insn
 296     [ dst>> ] [ symbol>> ] [ library>> ] tri
 297     %alien-global ;
 298
 299 ! ##alien-invoke
 300 GENERIC: next-fastcall-param ( rep -- )
 301
 302 : ?dummy-stack-params ( rep -- )
 303     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 304
 305 : ?dummy-int-params ( rep -- )
 306     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 307
 308 : ?dummy-fp-params ( rep -- )
 309     drop dummy-fp-params? [ float-regs inc ] when ;
 310
 311 M: int-rep next-fastcall-param
 312     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 313
 314 M: float-rep next-fastcall-param
 315     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 316
 317 M: double-rep next-fastcall-param
 318     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 319
 320 GENERIC: reg-class-full? ( reg-class -- ? )
 321
 322 M: stack-params reg-class-full? drop t ;
 323
 324 M: reg-class reg-class-full?
 325     [ get ] [ param-regs length ] bi >= ;
 326
 327 : alloc-stack-param ( rep -- n reg-class rep )
 328     stack-params get
 329     [ rep-size cell align stack-params +@ ] dip
 330     stack-params dup ;
 331
 332 : alloc-fastcall-param ( rep -- n reg-class rep )
 333     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 334
 335 : alloc-parameter ( parameter -- reg rep )
 336     c-type-rep dup reg-class-of reg-class-full?
 337     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 338     [ param-reg ] dip ;
 339
 340 : (flatten-int-type) ( type -- seq )
 341     stack-size cell align cell /i void* c-type <repetition> ;
 342
 343 GENERIC: flatten-value-type ( type -- types )
 344
 345 M: object flatten-value-type 1array ;
 346 M: struct-c-type flatten-value-type (flatten-int-type) ;
 347 M: long-long-type flatten-value-type (flatten-int-type) ;
 348 M: c-type-name flatten-value-type c-type flatten-value-type ;
 349
 350 : flatten-value-types ( params -- params )
 351     #! Convert value type structs to consecutive void*s.
 352     [
 353         0 [
 354             c-type
 355             [ parameter-align cell /i void* c-type <repetition> % ] keep
 356             [ stack-size cell align + ] keep
 357             flatten-value-type %
 358         ] reduce drop
 359     ] { } make ;
 360
 361 : each-parameter ( parameters quot -- )
 362     [ [ parameter-offsets nip ] keep ] dip 2each ; inline
 363
 364 : reset-fastcall-counts ( -- )
 365     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 366
 367 : with-param-regs ( quot -- )
 368     #! In quot you can call alloc-parameter
 369     [ reset-fastcall-counts call ] with-scope ; inline
 370
 371 : move-parameters ( node word -- )
 372     #! Moves values from C stack to registers (if word is
 373     #! %load-param-reg) and registers to C stack (if word is
 374     #! %save-param-reg).
 375     [ alien-parameters flatten-value-types ]
 376     [ '[ alloc-parameter _ execute ] ]
 377     bi* each-parameter ; inline
 378
 379 : reverse-each-parameter ( parameters quot -- )
 380     [ [ parameter-offsets nip ] keep ] dip 2reverse-each ; inline
 381
 382 : prepare-unbox-parameters ( parameters -- offsets types indices )
 383     [ parameter-offsets nip ] [ ] [ length iota <reversed> ] tri ;
 384
 385 : unbox-parameters ( offset node -- )
 386     parameters>> swap
 387     '[ prepare-unbox-parameters [ %pop-stack [ _ + ] dip unbox-parameter ] 3each ]
 388     [ length neg %inc-d ]
 389     bi ;
 390
 391 : prepare-box-struct ( node -- offset )
 392     #! Return offset on C stack where to store unboxed
 393     #! parameters. If the C function is returning a structure,
 394     #! the first parameter is an implicit target area pointer,
 395     #! so we need to use a different offset.
 396     return>> large-struct?
 397     [ %prepare-box-struct cell ] [ 0 ] if ;
 398
 399 : objects>registers ( params -- )
 400     #! Generate code for unboxing a list of C types, then
 401     #! generate code for moving these parameters to registers on
 402     #! architectures where parameters are passed in registers.
 403     [
 404         [ prepare-box-struct ] keep
 405         [ unbox-parameters ] keep
 406         \ %load-param-reg move-parameters
 407     ] with-param-regs ;
 408
 409 : box-return* ( node -- )
 410     return>> [ ] [ box-return %push-stack ] if-void ;
 411
 412 GENERIC# dlsym-valid? 1 ( symbols dll -- ? )
 413
 414 M: string dlsym-valid? dlsym ;
 415
 416 M: array dlsym-valid? '[ _ dlsym ] any? ;
 417
 418 : check-dlsym ( symbols dll -- )
 419     dup dll-valid? [
 420         dupd dlsym-valid?
 421         [ drop ] [ compiling-word get no-such-symbol ] if
 422     ] [
 423         dll-path compiling-word get no-such-library drop
 424     ] if ;
 425
 426 : stdcall-mangle ( params -- symbols )
 427     [ function>> ] [ parameters>> parameter-offsets drop number>string ] bi
 428     [ drop ] [ "@" glue ] [ "@" glue "_" prepend ] 2tri
 429     3array ;
 430
 431 : alien-invoke-dlsym ( params -- symbols dll )
 432     [ dup abi>> "stdcall" = [ stdcall-mangle ] [ function>> ] if ]
 433     [ library>> load-library ]
 434     bi 2dup check-dlsym ;
 435
 436 M: ##alien-invoke generate-insn
 437     params>>
 438     ! Unbox parameters
 439     dup objects>registers
 440     %prepare-var-args
 441     ! Call function
 442     dup alien-invoke-dlsym %alien-invoke
 443     ! Box return value
 444     dup %cleanup
 445     box-return* ;
 446
 447 M: ##alien-assembly generate-insn
 448     params>>
 449     ! Unbox parameters
 450     dup objects>registers
 451     %prepare-var-args
 452     ! Generate assembly
 453     dup quot>> call( -- )
 454     ! Box return value
 455     box-return* ;
 456
 457 ! ##alien-indirect
 458 M: ##alien-indirect generate-insn
 459     params>>
 460     ! Save alien at top of stack to temporary storage
 461     %prepare-alien-indirect
 462     ! Unbox parameters
 463     dup objects>registers
 464     %prepare-var-args
 465     ! Call alien in temporary storage
 466     %alien-indirect
 467     ! Box return value
 468     dup %cleanup
 469     box-return* ;
 470
 471 ! ##alien-callback
 472 : box-parameters ( params -- )
 473     alien-parameters [ box-parameter %push-context-stack ] each-parameter ;
 474
 475 : registers>objects ( node -- )
 476     ! Generate code for boxing input parameters in a callback.
 477     [
 478         dup \ %save-param-reg move-parameters
 479         %nest-stacks
 480         box-parameters
 481     ] with-param-regs ;
 482
 483 TUPLE: callback-context ;
 484
 485 : current-callback ( -- id ) 2 special-object ;
 486
 487 : wait-to-return ( token -- )
 488     dup current-callback eq? [
 489         drop
 490     ] [
 491         yield-hook get call( -- ) wait-to-return
 492     ] if ;
 493
 494 : do-callback ( quot token -- )
 495     init-catchstack
 496     [ 2 set-special-object call ] keep
 497     wait-to-return ; inline
 498
 499 : callback-return-quot ( ctype -- quot )
 500     return>> {
 501         { [ dup void? ] [ drop [ ] ] }
 502         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 503         [ c-type c-type-unboxer-quot ]
 504     } cond ;
 505
 506 : callback-prep-quot ( params -- quot )
 507     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 508
 509 : wrap-callback-quot ( params -- quot )
 510     [
 511         [ callback-prep-quot ]
 512         [ quot>> ]
 513         [ callback-return-quot ] tri 3append ,
 514         [ callback-context new do-callback ] %
 515     ] [ ] make ;
 516
 517 M: ##alien-callback generate-insn
 518     params>>
 519     [ registers>objects ]
 520     [ wrap-callback-quot %alien-callback ]
 521     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 522     tri ;