basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors slots parser generic.parser
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 QUALIFIED: classes.struct
  20 QUALIFIED: alien.structs
  21 IN: compiler.codegen
  22
  23 SYMBOL: insn-counts
  24
  25 H{ } clone insn-counts set-global
  26
  27 GENERIC: generate-insn ( insn -- )
  28
  29 TUPLE: asm label code calls ;
  30
  31 SYMBOL: calls
  32
  33 : add-call ( word -- )
  34     #! Compile this word later.
  35     calls get push ;
  36
  37 SYMBOL: compiling-word
  38
  39 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  40
  41 ! Mapping _label IDs to label instances
  42 SYMBOL: labels
  43
  44 : init-generator ( word -- )
  45     H{ } clone labels set
  46     V{ } clone calls set
  47     compiling-word set
  48     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  49
  50 : generate-insns ( asm -- code )
  51     [
  52         [ word>> init-generator ]
  53         [
  54             instructions>>
  55             [
  56                 [ class insn-counts get inc-at ]
  57                 [ generate-insn ]
  58                 bi
  59             ] each
  60         ] bi
  61     ] with-fixup ;
  62
  63 : generate ( mr -- asm )
  64     [
  65         [ label>> ] [ generate-insns ] bi calls get
  66         asm boa
  67     ] with-scope ;
  68
  69 : lookup-label ( id -- label )
  70     labels get [ drop <label> ] cache ;
  71
  72 ! Special cases
  73 M: ##no-tco generate-insn drop ;
  74
  75 M: ##call generate-insn
  76     word>> dup sub-primitive>>
  77     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  78
  79 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  80
  81 M: _dispatch-label generate-insn
  82     label>> lookup-label
  83     cell 0 <repetition> %
  84     rc-absolute-cell label-fixup ;
  85
  86 M: _prologue generate-insn
  87     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  88
  89 M: _epilogue generate-insn
  90     stack-frame>> total-size>> %epilogue ;
  91
  92 M: _spill-area-size generate-insn drop ;
  93
  94 ! Some meta-programming to generate simple code generators, where
  95 ! the instruction is unpacked and then a %word is called
  96 <<
  97
  98 : insn-slot-quot ( spec -- quot )
  99     name>> [ reader-word ] [ "label" = ] bi
 100     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
 101
 102 : codegen-method-body ( class word -- quot )
 103     [
 104         "insn-slots" word-prop
 105         [ insn-slot-quot ] map cleave>quot
 106     ] dip suffix ;
 107
 108 SYNTAX: CODEGEN:
 109     scan-word [ \ generate-insn create-method-in ] keep scan-word
 110     codegen-method-body define ;
 111 >>
 112
 113 CODEGEN: ##load-immediate %load-immediate
 114 CODEGEN: ##load-reference %load-reference
 115 CODEGEN: ##peek %peek
 116 CODEGEN: ##replace %replace
 117 CODEGEN: ##inc-d %inc-d
 118 CODEGEN: ##inc-r %inc-r
 119 CODEGEN: ##return %return
 120 CODEGEN: ##slot %slot
 121 CODEGEN: ##slot-imm %slot-imm
 122 CODEGEN: ##set-slot %set-slot
 123 CODEGEN: ##set-slot-imm %set-slot-imm
 124 CODEGEN: ##string-nth %string-nth
 125 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 126 CODEGEN: ##add %add
 127 CODEGEN: ##add-imm %add-imm
 128 CODEGEN: ##sub %sub
 129 CODEGEN: ##sub-imm %sub-imm
 130 CODEGEN: ##mul %mul
 131 CODEGEN: ##mul-imm %mul-imm
 132 CODEGEN: ##and %and
 133 CODEGEN: ##and-imm %and-imm
 134 CODEGEN: ##or %or
 135 CODEGEN: ##or-imm %or-imm
 136 CODEGEN: ##xor %xor
 137 CODEGEN: ##xor-imm %xor-imm
 138 CODEGEN: ##shl %shl
 139 CODEGEN: ##shl-imm %shl-imm
 140 CODEGEN: ##shr %shr
 141 CODEGEN: ##shr-imm %shr-imm
 142 CODEGEN: ##sar %sar
 143 CODEGEN: ##sar-imm %sar-imm
 144 CODEGEN: ##min %min
 145 CODEGEN: ##max %max
 146 CODEGEN: ##not %not
 147 CODEGEN: ##log2 %log2
 148 CODEGEN: ##copy %copy
 149 CODEGEN: ##integer>bignum %integer>bignum
 150 CODEGEN: ##bignum>integer %bignum>integer
 151 CODEGEN: ##unbox-float %unbox-float
 152 CODEGEN: ##box-float %box-float
 153 CODEGEN: ##add-float %add-float
 154 CODEGEN: ##sub-float %sub-float
 155 CODEGEN: ##mul-float %mul-float
 156 CODEGEN: ##div-float %div-float
 157 CODEGEN: ##min-float %min-float
 158 CODEGEN: ##max-float %max-float
 159 CODEGEN: ##sqrt %sqrt
 160 CODEGEN: ##unary-float-function %unary-float-function
 161 CODEGEN: ##binary-float-function %binary-float-function
 162 CODEGEN: ##single>double-float %single>double-float
 163 CODEGEN: ##double>single-float %double>single-float
 164 CODEGEN: ##integer>float %integer>float
 165 CODEGEN: ##float>integer %float>integer
 166 CODEGEN: ##unbox-vector %unbox-vector
 167 CODEGEN: ##broadcast-vector %broadcast-vector
 168 CODEGEN: ##gather-vector-2 %gather-vector-2
 169 CODEGEN: ##gather-vector-4 %gather-vector-4
 170 CODEGEN: ##box-vector %box-vector
 171 CODEGEN: ##add-vector %add-vector
 172 CODEGEN: ##sub-vector %sub-vector
 173 CODEGEN: ##mul-vector %mul-vector
 174 CODEGEN: ##div-vector %div-vector
 175 CODEGEN: ##min-vector %min-vector
 176 CODEGEN: ##max-vector %max-vector
 177 CODEGEN: ##sqrt-vector %sqrt-vector
 178 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 179 CODEGEN: ##box-alien %box-alien
 180 CODEGEN: ##box-displaced-alien %box-displaced-alien
 181 CODEGEN: ##unbox-alien %unbox-alien
 182 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 183 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 184 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 185 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 186 CODEGEN: ##alien-signed-1 %alien-signed-1
 187 CODEGEN: ##alien-signed-2 %alien-signed-2
 188 CODEGEN: ##alien-signed-4 %alien-signed-4
 189 CODEGEN: ##alien-cell %alien-cell
 190 CODEGEN: ##alien-float %alien-float
 191 CODEGEN: ##alien-double %alien-double
 192 CODEGEN: ##alien-vector %alien-vector
 193 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 194 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 195 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 196 CODEGEN: ##set-alien-cell %set-alien-cell
 197 CODEGEN: ##set-alien-float %set-alien-float
 198 CODEGEN: ##set-alien-double %set-alien-double
 199 CODEGEN: ##set-alien-vector %set-alien-vector
 200 CODEGEN: ##allot %allot
 201 CODEGEN: ##write-barrier %write-barrier
 202 CODEGEN: ##compare %compare
 203 CODEGEN: ##compare-imm %compare-imm
 204 CODEGEN: ##compare-float-ordered %compare-float-ordered
 205 CODEGEN: ##compare-float-unordered %compare-float-unordered
 206 CODEGEN: ##save-context %save-context
 207
 208 CODEGEN: _fixnum-add %fixnum-add
 209 CODEGEN: _fixnum-sub %fixnum-sub
 210 CODEGEN: _fixnum-mul %fixnum-mul
 211 CODEGEN: _label resolve-label
 212 CODEGEN: _branch %jump-label
 213 CODEGEN: _compare-branch %compare-branch
 214 CODEGEN: _compare-imm-branch %compare-imm-branch
 215 CODEGEN: _compare-float-ordered-branch %compare-float-ordered-branch
 216 CODEGEN: _compare-float-unordered-branch %compare-float-unordered-branch
 217 CODEGEN: _dispatch %dispatch
 218 CODEGEN: _spill %spill
 219 CODEGEN: _reload %reload
 220
 221 ! ##gc
 222 : wipe-locs ( locs temp -- )
 223     '[
 224         _
 225         [ 0 %load-immediate ]
 226         [ swap [ %replace ] with each ] bi
 227     ] unless-empty ;
 228
 229 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 230
 231 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 232     temp int-rep operand n>> %reload
 233     gc-root temp %save-gc-root ;
 234
 235 M: object save-gc-root drop %save-gc-root ;
 236
 237 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 238
 239 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 240
 241 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 242
 243 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 244     gc-root temp %load-gc-root
 245     temp int-rep operand n>> %spill ;
 246
 247 M: object load-gc-root drop %load-gc-root ;
 248
 249 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 250
 251 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 252
 253 M: _gc generate-insn
 254     "no-gc" define-label
 255     {
 256         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 257         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 258         [ data-values>> save-data-regs ]
 259         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 260         [ [ temp1>> ] [ temp2>> ] bi t %save-context ]
 261         [ tagged-values>> length %call-gc ]
 262         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 263         [ data-values>> load-data-regs ]
 264     } cleave
 265     "no-gc" resolve-label ;
 266
 267 M: _loop-entry generate-insn drop %loop-entry ;
 268
 269 M: ##alien-global generate-insn
 270     [ dst>> ] [ symbol>> ] [ library>> ] tri
 271     %alien-global ;
 272
 273 M: ##vm-field-ptr generate-insn
 274     [ dst>> ] [ fieldname>> ] bi %vm-field-ptr ;
 275
 276 ! ##alien-invoke
 277 GENERIC: next-fastcall-param ( rep -- )
 278
 279 : ?dummy-stack-params ( rep -- )
 280     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 281
 282 : ?dummy-int-params ( rep -- )
 283     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 284
 285 : ?dummy-fp-params ( rep -- )
 286     drop dummy-fp-params? [ float-regs inc ] when ;
 287
 288 M: int-rep next-fastcall-param
 289     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 290
 291 M: float-rep next-fastcall-param
 292     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 293
 294 M: double-rep next-fastcall-param
 295     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 296
 297 GENERIC: reg-class-full? ( reg-class -- ? )
 298
 299 M: stack-params reg-class-full? drop t ;
 300
 301 M: reg-class reg-class-full?
 302     [ get ] [ param-regs length ] bi >= ;
 303
 304 : alloc-stack-param ( rep -- n reg-class rep )
 305     stack-params get
 306     [ rep-size cell align stack-params +@ ] dip
 307     stack-params dup ;
 308
 309 : alloc-fastcall-param ( rep -- n reg-class rep )
 310     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 311
 312 : alloc-parameter ( parameter -- reg rep )
 313     c-type-rep dup reg-class-of reg-class-full?
 314     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 315     [ param-reg ] dip ;
 316
 317 : (flatten-int-type) ( size -- seq )
 318     cell /i "void*" c-type <repetition> ;
 319
 320 GENERIC: flatten-value-type ( type -- types )
 321
 322 M: object flatten-value-type 1array ;
 323
 324 M: alien.structs:struct-type flatten-value-type ( type -- types )
 325     stack-size cell align (flatten-int-type) ;
 326
 327 M: classes.struct:struct-c-type flatten-value-type ( type -- types )
 328     stack-size cell align (flatten-int-type) ;
 329
 330 M: long-long-type flatten-value-type ( type -- types )
 331     stack-size cell align (flatten-int-type) ;
 332
 333 : flatten-value-types ( params -- params )
 334     #! Convert value type structs to consecutive void*s.
 335     [
 336         0 [
 337             c-type
 338             [ parameter-align (flatten-int-type) % ] keep
 339             [ stack-size cell align + ] keep
 340             flatten-value-type %
 341         ] reduce drop
 342     ] { } make ;
 343
 344 : each-parameter ( parameters quot -- )
 345     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 346
 347 : reverse-each-parameter ( parameters quot -- )
 348     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 349
 350 : reset-fastcall-counts ( -- )
 351     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 352
 353 : with-param-regs ( quot -- )
 354     #! In quot you can call alloc-parameter
 355     [ reset-fastcall-counts call ] with-scope ; inline
 356
 357 : move-parameters ( node word -- )
 358     #! Moves values from C stack to registers (if word is
 359     #! %load-param-reg) and registers to C stack (if word is
 360     #! %save-param-reg).
 361     [ alien-parameters flatten-value-types ]
 362     [ '[ alloc-parameter _ execute ] ]
 363     bi* each-parameter ; inline
 364
 365 : unbox-parameters ( offset node -- )
 366     parameters>> [
 367         %prepare-unbox [ over + ] dip unbox-parameter
 368     ] reverse-each-parameter drop ;
 369
 370 : prepare-box-struct ( node -- offset )
 371     #! Return offset on C stack where to store unboxed
 372     #! parameters. If the C function is returning a structure,
 373     #! the first parameter is an implicit target area pointer,
 374     #! so we need to use a different offset.
 375     return>> large-struct?
 376     [ %prepare-box-struct cell ] [ 0 ] if ;
 377
 378 : objects>registers ( params -- )
 379     #! Generate code for unboxing a list of C types, then
 380     #! generate code for moving these parameters to registers on
 381     #! architectures where parameters are passed in registers.
 382     [
 383         [ prepare-box-struct ] keep
 384         [ unbox-parameters ] keep
 385         \ %load-param-reg move-parameters
 386     ] with-param-regs ;
 387
 388 : box-return* ( node -- )
 389     return>> [ ] [ box-return ] if-void ;
 390
 391 : check-dlsym ( symbols dll -- )
 392     dup dll-valid? [
 393         dupd '[ _ dlsym ] any?
 394         [ drop ] [ compiling-word get no-such-symbol ] if
 395     ] [
 396         dll-path compiling-word get no-such-library drop
 397     ] if ;
 398
 399 : stdcall-mangle ( symbol params -- symbol )
 400     parameters>> parameter-sizes drop number>string "@" glue ;
 401
 402 : alien-invoke-dlsym ( params -- symbols dll )
 403     [ [ function>> dup ] keep stdcall-mangle 2array ]
 404     [ library>> library dup [ dll>> ] when ]
 405     bi 2dup check-dlsym ;
 406
 407 M: ##alien-invoke generate-insn
 408     params>>
 409     ! Unbox parameters
 410     dup objects>registers
 411     %prepare-var-args
 412     ! Call function
 413     dup alien-invoke-dlsym %alien-invoke
 414     ! Box return value
 415     dup %cleanup
 416     box-return* ;
 417
 418 ! ##alien-indirect
 419 M: ##alien-indirect generate-insn
 420     params>>
 421     ! Save alien at top of stack to temporary storage
 422     %prepare-alien-indirect
 423     ! Unbox parameters
 424     dup objects>registers
 425     %prepare-var-args
 426     ! Call alien in temporary storage
 427     %alien-indirect
 428     ! Box return value
 429     dup %cleanup
 430     box-return* ;
 431
 432 ! ##alien-callback
 433 : box-parameters ( params -- )
 434     alien-parameters [ box-parameter ] each-parameter ;
 435
 436 : registers>objects ( node -- )
 437     ! Generate code for boxing input parameters in a callback.
 438     [
 439         dup \ %save-param-reg move-parameters
 440         "nest_stacks" %vm-invoke-1st-arg
 441         box-parameters
 442     ] with-param-regs ;
 443
 444 TUPLE: callback-context ;
 445
 446 : current-callback ( -- id ) 2 getenv ;
 447
 448 : wait-to-return ( token -- )
 449     dup current-callback eq? [
 450         drop
 451     ] [
 452         yield-hook get call( -- ) wait-to-return
 453     ] if ;
 454
 455 : do-callback ( quot token -- )
 456     init-catchstack
 457     [ 2 setenv call ] keep
 458     wait-to-return ; inline
 459
 460 : callback-return-quot ( ctype -- quot )
 461     return>> {
 462         { [ dup void? ] [ drop [ ] ] }
 463         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 464         [ c-type c-type-unboxer-quot ]
 465     } cond ;
 466
 467 : callback-prep-quot ( params -- quot )
 468     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 469
 470 : wrap-callback-quot ( params -- quot )
 471     [
 472         [ callback-prep-quot ]
 473         [ quot>> ]
 474         [ callback-return-quot ] tri 3append ,
 475         [ callback-context new do-callback ] %
 476     ] [ ] make ;
 477
 478 : %unnest-stacks ( -- ) "unnest_stacks" %vm-invoke-1st-arg ;
 479
 480 M: ##callback-return generate-insn
 481     #! All the extra book-keeping for %unwind is only for x86.
 482     #! On other platforms its an alias for %return.
 483     params>> %callback-return ;
 484
 485 M: ##alien-callback generate-insn
 486     params>>
 487     [ registers>objects ]
 488     [ wrap-callback-quot %alien-callback ]
 489     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 490     tri ;