basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs byte-arrays classes combinators
   4 compiler.cfg compiler.cfg.comparisons compiler.cfg.instructions
   5 compiler.cfg.linearization compiler.cfg.stack-frame
   6 compiler.codegen.gc-maps compiler.codegen.labels
   7 compiler.codegen.relocation compiler.constants cpu.architecture
   8 fry generic.parser kernel layouts locals make math namespaces
   9 parser quotations sequences sequences.generalizations slots
  10 words ;
  11 FROM: namespaces => set ;
  12 IN: compiler.codegen
  13
  14 SYMBOL: insn-counts
  15
  16 H{ } clone insn-counts set-global
  17
  18 GENERIC: generate-insn ( insn -- )
  19
  20 ! Control flow
  21 SYMBOL: labels
  22
  23 : lookup-label ( bb -- label )
  24     labels get [ drop <label> ] cache ;
  25
  26 : useless-branch? ( bb successor -- ? )
  27     ! If our successor immediately follows us in linearization
  28     ! order then we don't need to branch.
  29     [ block-number ] bi@ 1 - = ; inline
  30
  31 : emit-branch ( bb successor -- )
  32     2dup useless-branch?
  33     [ 2drop ] [ nip lookup-label %jump-label ] if ;
  34
  35 M: ##branch generate-insn
  36     drop basic-block get dup successors>> first emit-branch ;
  37
  38 GENERIC: generate-conditional-insn ( label insn -- )
  39
  40 GENERIC: negate-insn-cc ( insn -- )
  41
  42 M: conditional-branch-insn negate-insn-cc
  43     [ negate-cc ] change-cc drop ;
  44
  45 M: ##test-vector-branch negate-insn-cc
  46     [ negate-vcc ] change-vcc drop ;
  47
  48 M:: conditional-branch-insn generate-insn ( insn -- )
  49     basic-block get :> bb
  50     bb successors>> first2 :> ( first second )
  51     bb second useless-branch?
  52     [ bb second first ]
  53     [ bb first second insn negate-insn-cc ] if
  54     lookup-label insn generate-conditional-insn
  55     emit-branch ;
  56
  57 : %dispatch-label ( label -- )
  58     cell 0 <repetition> %
  59     rc-absolute-cell label-fixup ;
  60
  61 M: ##dispatch generate-insn
  62     [ src>> ] [ temp>> ] bi %dispatch
  63     basic-block get successors>>
  64     [ lookup-label %dispatch-label ] each ;
  65
  66 : generate-block ( bb -- )
  67     [ basic-block set ]
  68     [ lookup-label resolve-label ]
  69     [
  70         instructions>> [
  71             [ class-of insn-counts get-global inc-at ]
  72             [ generate-insn ]
  73             bi
  74         ] each
  75     ] tri ;
  76
  77 : init-fixup ( -- )
  78     V{ } clone label-table set
  79     V{ } clone binary-literal-table set ;
  80
  81 : check-fixup ( seq -- )
  82     length data-alignment get mod 0 assert= ;
  83
  84 : with-fixup ( quot -- code )
  85     '[
  86         init-relocation
  87         init-gc-maps
  88         init-fixup
  89         [
  90             @
  91             emit-binary-literals
  92             emit-gc-maps
  93             label-table [ compute-labels ] change
  94             parameter-table get >array
  95             literal-table get >array
  96             relocation-table get >byte-array
  97             label-table get
  98         ] B{ } make
  99         dup check-fixup
 100         cfg get [ stack-frame>> [ total-size>> ] [ 0 ] if* ] [ 0 ] if*
 101     ] call 6 narray ; inline
 102
 103 : generate ( cfg -- code )
 104     [
 105         H{ } clone labels set
 106         linearization-order
 107         [ number-blocks ] [ [ generate-block ] each ] bi
 108     ] with-fixup ;
 109
 110 ! Special cases
 111 M: ##no-tco generate-insn drop ;
 112
 113 M: ##prologue generate-insn
 114     drop
 115     cfg get stack-frame>> [ total-size>> %prologue ] when* ;
 116
 117 M: ##epilogue generate-insn
 118     drop
 119     cfg get stack-frame>> [ total-size>> %epilogue ] when* ;
 120
 121 ! Some meta-programming to generate simple code generators, where
 122 ! the instruction is unpacked and then a %word is called
 123 <<
 124
 125 : insn-slot-quot ( spec -- quot )
 126     name>> reader-word 1quotation ;
 127
 128 : codegen-method-body ( class word -- quot )
 129     [
 130         "insn-slots" word-prop
 131         [ insn-slot-quot ] map cleave>quot
 132     ] dip suffix ;
 133
 134 SYNTAX: CODEGEN:
 135     scan-word [ \ generate-insn create-method-in ] keep scan-word
 136     codegen-method-body define ;
 137
 138 >>
 139
 140 CODEGEN: ##load-integer %load-immediate
 141 CODEGEN: ##load-tagged %load-immediate
 142 CODEGEN: ##load-reference %load-reference
 143 CODEGEN: ##load-float %load-float
 144 CODEGEN: ##load-double %load-double
 145 CODEGEN: ##load-vector %load-vector
 146 CODEGEN: ##peek %peek
 147 CODEGEN: ##replace %replace
 148 CODEGEN: ##replace-imm %replace-imm
 149 CODEGEN: ##clear %clear
 150 CODEGEN: ##inc %inc
 151 CODEGEN: ##call %call
 152 CODEGEN: ##jump %jump
 153 CODEGEN: ##return %return
 154 CODEGEN: ##safepoint %safepoint
 155 CODEGEN: ##slot %slot
 156 CODEGEN: ##slot-imm %slot-imm
 157 CODEGEN: ##set-slot %set-slot
 158 CODEGEN: ##set-slot-imm %set-slot-imm
 159 CODEGEN: ##add %add
 160 CODEGEN: ##add-imm %add-imm
 161 CODEGEN: ##sub %sub
 162 CODEGEN: ##sub-imm %sub-imm
 163 CODEGEN: ##mul %mul
 164 CODEGEN: ##mul-imm %mul-imm
 165 CODEGEN: ##and %and
 166 CODEGEN: ##and-imm %and-imm
 167 CODEGEN: ##or %or
 168 CODEGEN: ##or-imm %or-imm
 169 CODEGEN: ##xor %xor
 170 CODEGEN: ##xor-imm %xor-imm
 171 CODEGEN: ##shl %shl
 172 CODEGEN: ##shl-imm %shl-imm
 173 CODEGEN: ##shr %shr
 174 CODEGEN: ##shr-imm %shr-imm
 175 CODEGEN: ##sar %sar
 176 CODEGEN: ##sar-imm %sar-imm
 177 CODEGEN: ##min %min
 178 CODEGEN: ##max %max
 179 CODEGEN: ##not %not
 180 CODEGEN: ##neg %neg
 181 CODEGEN: ##log2 %log2
 182 CODEGEN: ##bit-count %bit-count
 183 CODEGEN: ##bit-test %bit-test
 184 CODEGEN: ##copy %copy
 185 CODEGEN: ##tagged>integer %tagged>integer
 186 CODEGEN: ##add-float %add-float
 187 CODEGEN: ##sub-float %sub-float
 188 CODEGEN: ##mul-float %mul-float
 189 CODEGEN: ##div-float %div-float
 190 CODEGEN: ##min-float %min-float
 191 CODEGEN: ##max-float %max-float
 192 CODEGEN: ##sqrt %sqrt
 193 CODEGEN: ##single>double-float %single>double-float
 194 CODEGEN: ##double>single-float %double>single-float
 195 CODEGEN: ##integer>float %integer>float
 196 CODEGEN: ##float>integer %float>integer
 197 CODEGEN: ##zero-vector %zero-vector
 198 CODEGEN: ##fill-vector %fill-vector
 199 CODEGEN: ##gather-vector-2 %gather-vector-2
 200 CODEGEN: ##gather-vector-4 %gather-vector-4
 201 CODEGEN: ##gather-int-vector-2 %gather-int-vector-2
 202 CODEGEN: ##gather-int-vector-4 %gather-int-vector-4
 203 CODEGEN: ##select-vector %select-vector
 204 CODEGEN: ##shuffle-vector-imm %shuffle-vector-imm
 205 CODEGEN: ##shuffle-vector-halves-imm %shuffle-vector-halves-imm
 206 CODEGEN: ##shuffle-vector %shuffle-vector
 207 CODEGEN: ##tail>head-vector %tail>head-vector
 208 CODEGEN: ##merge-vector-head %merge-vector-head
 209 CODEGEN: ##merge-vector-tail %merge-vector-tail
 210 CODEGEN: ##float-pack-vector %float-pack-vector
 211 CODEGEN: ##signed-pack-vector %signed-pack-vector
 212 CODEGEN: ##unsigned-pack-vector %unsigned-pack-vector
 213 CODEGEN: ##unpack-vector-head %unpack-vector-head
 214 CODEGEN: ##unpack-vector-tail %unpack-vector-tail
 215 CODEGEN: ##integer>float-vector %integer>float-vector
 216 CODEGEN: ##float>integer-vector %float>integer-vector
 217 CODEGEN: ##compare-vector %compare-vector
 218 CODEGEN: ##move-vector-mask %move-vector-mask
 219 CODEGEN: ##test-vector %test-vector
 220 CODEGEN: ##add-vector %add-vector
 221 CODEGEN: ##saturated-add-vector %saturated-add-vector
 222 CODEGEN: ##add-sub-vector %add-sub-vector
 223 CODEGEN: ##sub-vector %sub-vector
 224 CODEGEN: ##saturated-sub-vector %saturated-sub-vector
 225 CODEGEN: ##mul-vector %mul-vector
 226 CODEGEN: ##mul-high-vector %mul-high-vector
 227 CODEGEN: ##mul-horizontal-add-vector %mul-horizontal-add-vector
 228 CODEGEN: ##saturated-mul-vector %saturated-mul-vector
 229 CODEGEN: ##div-vector %div-vector
 230 CODEGEN: ##min-vector %min-vector
 231 CODEGEN: ##max-vector %max-vector
 232 CODEGEN: ##avg-vector %avg-vector
 233 CODEGEN: ##dot-vector %dot-vector
 234 CODEGEN: ##sad-vector %sad-vector
 235 CODEGEN: ##sqrt-vector %sqrt-vector
 236 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 237 CODEGEN: ##horizontal-sub-vector %horizontal-sub-vector
 238 CODEGEN: ##horizontal-shl-vector-imm %horizontal-shl-vector-imm
 239 CODEGEN: ##horizontal-shr-vector-imm %horizontal-shr-vector-imm
 240 CODEGEN: ##abs-vector %abs-vector
 241 CODEGEN: ##and-vector %and-vector
 242 CODEGEN: ##andn-vector %andn-vector
 243 CODEGEN: ##or-vector %or-vector
 244 CODEGEN: ##xor-vector %xor-vector
 245 CODEGEN: ##not-vector %not-vector
 246 CODEGEN: ##shl-vector-imm %shl-vector-imm
 247 CODEGEN: ##shr-vector-imm %shr-vector-imm
 248 CODEGEN: ##shl-vector %shl-vector
 249 CODEGEN: ##shr-vector %shr-vector
 250 CODEGEN: ##integer>scalar %integer>scalar
 251 CODEGEN: ##scalar>integer %scalar>integer
 252 CODEGEN: ##vector>scalar %vector>scalar
 253 CODEGEN: ##scalar>vector %scalar>vector
 254 CODEGEN: ##box-alien %box-alien
 255 CODEGEN: ##box-displaced-alien %box-displaced-alien
 256 CODEGEN: ##unbox-alien %unbox-alien
 257 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 258 CODEGEN: ##convert-integer %convert-integer
 259 CODEGEN: ##load-memory %load-memory
 260 CODEGEN: ##load-memory-imm %load-memory-imm
 261 CODEGEN: ##store-memory %store-memory
 262 CODEGEN: ##store-memory-imm %store-memory-imm
 263 CODEGEN: ##allot %allot
 264 CODEGEN: ##write-barrier %write-barrier
 265 CODEGEN: ##write-barrier-imm %write-barrier-imm
 266 CODEGEN: ##compare %compare
 267 CODEGEN: ##compare-imm %compare-imm
 268 CODEGEN: ##test %test
 269 CODEGEN: ##test-imm %test-imm
 270 CODEGEN: ##compare-integer %compare
 271 CODEGEN: ##compare-integer-imm %compare-integer-imm
 272 CODEGEN: ##compare-float-ordered %compare-float-ordered
 273 CODEGEN: ##compare-float-unordered %compare-float-unordered
 274 CODEGEN: ##save-context %save-context
 275 CODEGEN: ##vm-field %vm-field
 276 CODEGEN: ##set-vm-field %set-vm-field
 277 CODEGEN: ##alien-global %alien-global
 278 CODEGEN: ##call-gc %call-gc
 279 CODEGEN: ##spill %spill
 280 CODEGEN: ##reload %reload
 281
 282 ! Conditional branches
 283 <<
 284
 285 SYNTAX: CONDITIONAL:
 286     scan-word [ \ generate-conditional-insn create-method-in ] keep scan-word
 287     codegen-method-body define ;
 288
 289 >>
 290
 291 CONDITIONAL: ##compare-branch %compare-branch
 292 CONDITIONAL: ##compare-imm-branch %compare-imm-branch
 293 CONDITIONAL: ##compare-integer-branch %compare-branch
 294 CONDITIONAL: ##compare-integer-imm-branch %compare-integer-imm-branch
 295 CONDITIONAL: ##test-branch %test-branch
 296 CONDITIONAL: ##test-imm-branch %test-imm-branch
 297 CONDITIONAL: ##compare-float-ordered-branch %compare-float-ordered-branch
 298 CONDITIONAL: ##compare-float-unordered-branch %compare-float-unordered-branch
 299 CONDITIONAL: ##test-vector-branch %test-vector-branch
 300 CONDITIONAL: ##check-nursery-branch %check-nursery-branch
 301 CONDITIONAL: ##fixnum-add %fixnum-add
 302 CONDITIONAL: ##fixnum-sub %fixnum-sub
 303 CONDITIONAL: ##fixnum-mul %fixnum-mul
 304
 305 ! FFI
 306 CODEGEN: ##unbox %unbox
 307 CODEGEN: ##unbox-long-long %unbox-long-long
 308 CODEGEN: ##local-allot %local-allot
 309 CODEGEN: ##box %box
 310 CODEGEN: ##box-long-long %box-long-long
 311 CODEGEN: ##alien-invoke %alien-invoke
 312 CODEGEN: ##alien-indirect %alien-indirect
 313 CODEGEN: ##alien-assembly %alien-assembly
 314 CODEGEN: ##callback-inputs %callback-inputs
 315 CODEGEN: ##callback-outputs %callback-outputs