basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes classes.struct locals
   8 source-files.errors slots parser generic.parser
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 ! Mapping _label IDs to label instances
  36 SYMBOL: labels
  37
  38 : init-generator ( -- )
  39     H{ } clone labels set
  40     V{ } clone calls set ;
  41
  42 : generate-insns ( asm -- code )
  43     dup word>> [
  44         init-generator
  45         instructions>> [
  46             [ class insn-counts get inc-at ]
  47             [ generate-insn ]
  48             bi
  49         ] each
  50     ] with-fixup ;
  51
  52 : generate ( mr -- asm )
  53     [
  54         [ label>> ] [ generate-insns ] bi calls get
  55         asm boa
  56     ] with-scope ;
  57
  58 : lookup-label ( id -- label )
  59     labels get [ drop <label> ] cache ;
  60
  61 ! Special cases
  62 M: ##no-tco generate-insn drop ;
  63
  64 M: ##call generate-insn
  65     word>> dup sub-primitive>>
  66     [ second first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  67
  68 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  69
  70 M: _dispatch-label generate-insn
  71     label>> lookup-label
  72     cell 0 <repetition> %
  73     rc-absolute-cell label-fixup ;
  74
  75 M: _prologue generate-insn
  76     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  77
  78 M: _epilogue generate-insn
  79     stack-frame>> total-size>> %epilogue ;
  80
  81 M: _spill-area-size generate-insn drop ;
  82
  83 ! Some meta-programming to generate simple code generators, where
  84 ! the instruction is unpacked and then a %word is called
  85 <<
  86
  87 : insn-slot-quot ( spec -- quot )
  88     name>> [ reader-word ] [ "label" = ] bi
  89     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
  90
  91 : codegen-method-body ( class word -- quot )
  92     [
  93         "insn-slots" word-prop
  94         [ insn-slot-quot ] map cleave>quot
  95     ] dip suffix ;
  96
  97 SYNTAX: CODEGEN:
  98     scan-word [ \ generate-insn create-method-in ] keep scan-word
  99     codegen-method-body define ;
 100 >>
 101
 102 CODEGEN: ##load-immediate %load-immediate
 103 CODEGEN: ##load-reference %load-reference
 104 CODEGEN: ##load-constant %load-reference
 105 CODEGEN: ##peek %peek
 106 CODEGEN: ##replace %replace
 107 CODEGEN: ##inc-d %inc-d
 108 CODEGEN: ##inc-r %inc-r
 109 CODEGEN: ##return %return
 110 CODEGEN: ##slot %slot
 111 CODEGEN: ##slot-imm %slot-imm
 112 CODEGEN: ##set-slot %set-slot
 113 CODEGEN: ##set-slot-imm %set-slot-imm
 114 CODEGEN: ##string-nth %string-nth
 115 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 116 CODEGEN: ##add %add
 117 CODEGEN: ##add-imm %add-imm
 118 CODEGEN: ##sub %sub
 119 CODEGEN: ##sub-imm %sub-imm
 120 CODEGEN: ##mul %mul
 121 CODEGEN: ##mul-imm %mul-imm
 122 CODEGEN: ##and %and
 123 CODEGEN: ##and-imm %and-imm
 124 CODEGEN: ##or %or
 125 CODEGEN: ##or-imm %or-imm
 126 CODEGEN: ##xor %xor
 127 CODEGEN: ##xor-imm %xor-imm
 128 CODEGEN: ##shl %shl
 129 CODEGEN: ##shl-imm %shl-imm
 130 CODEGEN: ##shr %shr
 131 CODEGEN: ##shr-imm %shr-imm
 132 CODEGEN: ##sar %sar
 133 CODEGEN: ##sar-imm %sar-imm
 134 CODEGEN: ##min %min
 135 CODEGEN: ##max %max
 136 CODEGEN: ##not %not
 137 CODEGEN: ##neg %neg
 138 CODEGEN: ##log2 %log2
 139 CODEGEN: ##copy %copy
 140 CODEGEN: ##add-float %add-float
 141 CODEGEN: ##sub-float %sub-float
 142 CODEGEN: ##mul-float %mul-float
 143 CODEGEN: ##div-float %div-float
 144 CODEGEN: ##min-float %min-float
 145 CODEGEN: ##max-float %max-float
 146 CODEGEN: ##sqrt %sqrt
 147 CODEGEN: ##unary-float-function %unary-float-function
 148 CODEGEN: ##binary-float-function %binary-float-function
 149 CODEGEN: ##single>double-float %single>double-float
 150 CODEGEN: ##double>single-float %double>single-float
 151 CODEGEN: ##integer>float %integer>float
 152 CODEGEN: ##float>integer %float>integer
 153 CODEGEN: ##zero-vector %zero-vector
 154 CODEGEN: ##fill-vector %fill-vector
 155 CODEGEN: ##gather-vector-2 %gather-vector-2
 156 CODEGEN: ##gather-vector-4 %gather-vector-4
 157 CODEGEN: ##shuffle-vector-imm %shuffle-vector-imm
 158 CODEGEN: ##shuffle-vector %shuffle-vector
 159 CODEGEN: ##tail>head-vector %tail>head-vector
 160 CODEGEN: ##merge-vector-head %merge-vector-head
 161 CODEGEN: ##merge-vector-tail %merge-vector-tail
 162 CODEGEN: ##signed-pack-vector %signed-pack-vector
 163 CODEGEN: ##unsigned-pack-vector %unsigned-pack-vector
 164 CODEGEN: ##unpack-vector-head %unpack-vector-head
 165 CODEGEN: ##unpack-vector-tail %unpack-vector-tail
 166 CODEGEN: ##integer>float-vector %integer>float-vector
 167 CODEGEN: ##float>integer-vector %float>integer-vector
 168 CODEGEN: ##compare-vector %compare-vector
 169 CODEGEN: ##test-vector %test-vector
 170 CODEGEN: ##add-vector %add-vector
 171 CODEGEN: ##saturated-add-vector %saturated-add-vector
 172 CODEGEN: ##add-sub-vector %add-sub-vector
 173 CODEGEN: ##sub-vector %sub-vector
 174 CODEGEN: ##saturated-sub-vector %saturated-sub-vector
 175 CODEGEN: ##mul-vector %mul-vector
 176 CODEGEN: ##saturated-mul-vector %saturated-mul-vector
 177 CODEGEN: ##div-vector %div-vector
 178 CODEGEN: ##min-vector %min-vector
 179 CODEGEN: ##max-vector %max-vector
 180 CODEGEN: ##dot-vector %dot-vector
 181 CODEGEN: ##sqrt-vector %sqrt-vector
 182 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 183 CODEGEN: ##horizontal-sub-vector %horizontal-sub-vector
 184 CODEGEN: ##horizontal-shl-vector %horizontal-shl-vector
 185 CODEGEN: ##horizontal-shr-vector %horizontal-shr-vector
 186 CODEGEN: ##abs-vector %abs-vector
 187 CODEGEN: ##and-vector %and-vector
 188 CODEGEN: ##andn-vector %andn-vector
 189 CODEGEN: ##or-vector %or-vector
 190 CODEGEN: ##xor-vector %xor-vector
 191 CODEGEN: ##not-vector %not-vector
 192 CODEGEN: ##shl-vector %shl-vector
 193 CODEGEN: ##shr-vector %shr-vector
 194 CODEGEN: ##integer>scalar %integer>scalar
 195 CODEGEN: ##scalar>integer %scalar>integer
 196 CODEGEN: ##vector>scalar %vector>scalar
 197 CODEGEN: ##scalar>vector %scalar>vector
 198 CODEGEN: ##box-alien %box-alien
 199 CODEGEN: ##box-displaced-alien %box-displaced-alien
 200 CODEGEN: ##unbox-alien %unbox-alien
 201 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 202 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 203 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 204 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 205 CODEGEN: ##alien-signed-1 %alien-signed-1
 206 CODEGEN: ##alien-signed-2 %alien-signed-2
 207 CODEGEN: ##alien-signed-4 %alien-signed-4
 208 CODEGEN: ##alien-cell %alien-cell
 209 CODEGEN: ##alien-float %alien-float
 210 CODEGEN: ##alien-double %alien-double
 211 CODEGEN: ##alien-vector %alien-vector
 212 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 213 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 214 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 215 CODEGEN: ##set-alien-cell %set-alien-cell
 216 CODEGEN: ##set-alien-float %set-alien-float
 217 CODEGEN: ##set-alien-double %set-alien-double
 218 CODEGEN: ##set-alien-vector %set-alien-vector
 219 CODEGEN: ##allot %allot
 220 CODEGEN: ##write-barrier %write-barrier
 221 CODEGEN: ##write-barrier-imm %write-barrier-imm
 222 CODEGEN: ##compare %compare
 223 CODEGEN: ##compare-imm %compare-imm
 224 CODEGEN: ##compare-float-ordered %compare-float-ordered
 225 CODEGEN: ##compare-float-unordered %compare-float-unordered
 226 CODEGEN: ##save-context %save-context
 227 CODEGEN: ##vm-field-ptr %vm-field-ptr
 228
 229 CODEGEN: _fixnum-add %fixnum-add
 230 CODEGEN: _fixnum-sub %fixnum-sub
 231 CODEGEN: _fixnum-mul %fixnum-mul
 232 CODEGEN: _label resolve-label
 233 CODEGEN: _branch %jump-label
 234 CODEGEN: _compare-branch %compare-branch
 235 CODEGEN: _compare-imm-branch %compare-imm-branch
 236 CODEGEN: _compare-float-ordered-branch %compare-float-ordered-branch
 237 CODEGEN: _compare-float-unordered-branch %compare-float-unordered-branch
 238 CODEGEN: _test-vector-branch %test-vector-branch
 239 CODEGEN: _dispatch %dispatch
 240 CODEGEN: _spill %spill
 241 CODEGEN: _reload %reload
 242
 243 ! ##gc
 244 : wipe-locs ( locs temp -- )
 245     '[
 246         _
 247         [ 0 %load-immediate ]
 248         [ swap [ %replace ] with each ] bi
 249     ] unless-empty ;
 250
 251 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 252
 253 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 254     temp int-rep operand %reload
 255     gc-root temp %save-gc-root ;
 256
 257 M: object save-gc-root drop %save-gc-root ;
 258
 259 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 260
 261 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 262
 263 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 264
 265 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 266     gc-root temp %load-gc-root
 267     temp int-rep operand %spill ;
 268
 269 M: object load-gc-root drop %load-gc-root ;
 270
 271 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 272
 273 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 274
 275 M: ##gc generate-insn
 276     "no-gc" define-label
 277     {
 278         [ [ "no-gc" get ] dip [ size>> ] [ temp1>> ] [ temp2>> ] tri %check-nursery ]
 279         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 280         [ data-values>> save-data-regs ]
 281         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 282         [ [ temp1>> ] [ temp2>> ] bi t %save-context ]
 283         [ [ tagged-values>> length ] [ temp1>> ] bi %call-gc ]
 284         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 285         [ data-values>> load-data-regs ]
 286     } cleave
 287     "no-gc" resolve-label ;
 288
 289 M: _loop-entry generate-insn drop %loop-entry ;
 290
 291 M: ##alien-global generate-insn
 292     [ dst>> ] [ symbol>> ] [ library>> ] tri
 293     %alien-global ;
 294
 295 ! ##alien-invoke
 296 GENERIC: next-fastcall-param ( rep -- )
 297
 298 : ?dummy-stack-params ( rep -- )
 299     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 300
 301 : ?dummy-int-params ( rep -- )
 302     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 303
 304 : ?dummy-fp-params ( rep -- )
 305     drop dummy-fp-params? [ float-regs inc ] when ;
 306
 307 M: int-rep next-fastcall-param
 308     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 309
 310 M: float-rep next-fastcall-param
 311     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 312
 313 M: double-rep next-fastcall-param
 314     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 315
 316 GENERIC: reg-class-full? ( reg-class -- ? )
 317
 318 M: stack-params reg-class-full? drop t ;
 319
 320 M: reg-class reg-class-full?
 321     [ get ] [ param-regs length ] bi >= ;
 322
 323 : alloc-stack-param ( rep -- n reg-class rep )
 324     stack-params get
 325     [ rep-size cell align stack-params +@ ] dip
 326     stack-params dup ;
 327
 328 : alloc-fastcall-param ( rep -- n reg-class rep )
 329     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 330
 331 : alloc-parameter ( parameter -- reg rep )
 332     c-type-rep dup reg-class-of reg-class-full?
 333     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 334     [ param-reg ] dip ;
 335
 336 : (flatten-int-type) ( type -- seq )
 337     stack-size cell align cell /i void* c-type <repetition> ;
 338
 339 GENERIC: flatten-value-type ( type -- types )
 340
 341 M: object flatten-value-type 1array ;
 342 M: struct-c-type flatten-value-type (flatten-int-type) ;
 343 M: long-long-type flatten-value-type (flatten-int-type) ;
 344 M: c-type-name flatten-value-type c-type flatten-value-type ;
 345
 346 : flatten-value-types ( params -- params )
 347     #! Convert value type structs to consecutive void*s.
 348     [
 349         0 [
 350             c-type
 351             [ parameter-align cell /i void* c-type <repetition> % ] keep
 352             [ stack-size cell align + ] keep
 353             flatten-value-type %
 354         ] reduce drop
 355     ] { } make ;
 356
 357 : each-parameter ( parameters quot -- )
 358     [ [ parameter-offsets nip ] keep ] dip 2each ; inline
 359
 360 : reset-fastcall-counts ( -- )
 361     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 362
 363 : with-param-regs ( quot -- )
 364     #! In quot you can call alloc-parameter
 365     [ reset-fastcall-counts call ] with-scope ; inline
 366
 367 : move-parameters ( node word -- )
 368     #! Moves values from C stack to registers (if word is
 369     #! %load-param-reg) and registers to C stack (if word is
 370     #! %save-param-reg).
 371     [ alien-parameters flatten-value-types ]
 372     [ '[ alloc-parameter _ execute ] ]
 373     bi* each-parameter ; inline
 374
 375 : reverse-each-parameter ( parameters quot -- )
 376     [ [ parameter-offsets nip ] keep ] dip 2reverse-each ; inline
 377
 378 : prepare-unbox-parameters ( parameters -- offsets types indices )
 379     [ parameter-offsets nip ] [ ] [ length iota reverse ] tri ;
 380
 381 : unbox-parameters ( offset node -- )
 382     parameters>> swap
 383     '[ prepare-unbox-parameters [ %prepare-unbox [ _ + ] dip unbox-parameter ] 3each ]
 384     [ length neg %inc-d ]
 385     bi ;
 386
 387 : prepare-box-struct ( node -- offset )
 388     #! Return offset on C stack where to store unboxed
 389     #! parameters. If the C function is returning a structure,
 390     #! the first parameter is an implicit target area pointer,
 391     #! so we need to use a different offset.
 392     return>> large-struct?
 393     [ %prepare-box-struct cell ] [ 0 ] if ;
 394
 395 : objects>registers ( params -- )
 396     #! Generate code for unboxing a list of C types, then
 397     #! generate code for moving these parameters to registers on
 398     #! architectures where parameters are passed in registers.
 399     [
 400         [ prepare-box-struct ] keep
 401         [ unbox-parameters ] keep
 402         \ %load-param-reg move-parameters
 403     ] with-param-regs ;
 404
 405 : box-return* ( node -- )
 406     return>> [ ] [ box-return ] if-void ;
 407
 408 : check-dlsym ( symbols dll -- )
 409     dup dll-valid? [
 410         dupd '[ _ dlsym ] any?
 411         [ drop ] [ compiling-word get no-such-symbol ] if
 412     ] [
 413         dll-path compiling-word get no-such-library drop
 414     ] if ;
 415
 416 : stdcall-mangle ( symbol params -- symbol )
 417     parameters>> parameter-offsets drop number>string "@" glue ;
 418
 419 : alien-invoke-dlsym ( params -- symbols dll )
 420     [ [ function>> dup ] keep stdcall-mangle 2array ]
 421     [ library>> library dup [ dll>> ] when ]
 422     bi 2dup check-dlsym ;
 423
 424 M: ##alien-invoke generate-insn
 425     params>>
 426     ! Unbox parameters
 427     dup objects>registers
 428     %prepare-var-args
 429     ! Call function
 430     dup alien-invoke-dlsym %alien-invoke
 431     ! Box return value
 432     dup %cleanup
 433     box-return* ;
 434
 435 ! ##alien-indirect
 436 M: ##alien-indirect generate-insn
 437     params>>
 438     ! Save alien at top of stack to temporary storage
 439     %prepare-alien-indirect
 440     ! Unbox parameters
 441     dup objects>registers
 442     %prepare-var-args
 443     ! Call alien in temporary storage
 444     %alien-indirect
 445     ! Box return value
 446     dup %cleanup
 447     box-return* ;
 448
 449 ! ##alien-callback
 450 : box-parameters ( params -- )
 451     alien-parameters [ box-parameter ] each-parameter ;
 452
 453 : registers>objects ( node -- )
 454     ! Generate code for boxing input parameters in a callback.
 455     [
 456         dup \ %save-param-reg move-parameters
 457         %nest-stacks
 458         box-parameters
 459     ] with-param-regs ;
 460
 461 TUPLE: callback-context ;
 462
 463 : current-callback ( -- id ) 2 getenv ;
 464
 465 : wait-to-return ( token -- )
 466     dup current-callback eq? [
 467         drop
 468     ] [
 469         yield-hook get call( -- ) wait-to-return
 470     ] if ;
 471
 472 : do-callback ( quot token -- )
 473     init-catchstack
 474     [ 2 setenv call ] keep
 475     wait-to-return ; inline
 476
 477 : callback-return-quot ( ctype -- quot )
 478     return>> {
 479         { [ dup void? ] [ drop [ ] ] }
 480         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 481         [ c-type c-type-unboxer-quot ]
 482     } cond ;
 483
 484 : callback-prep-quot ( params -- quot )
 485     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 486
 487 : wrap-callback-quot ( params -- quot )
 488     [
 489         [ callback-prep-quot ]
 490         [ quot>> ]
 491         [ callback-return-quot ] tri 3append ,
 492         [ callback-context new do-callback ] %
 493     ] [ ] make ;
 494
 495 M: ##callback-return generate-insn
 496     #! All the extra book-keeping for %unwind is only for x86.
 497     #! On other platforms its an alias for %return.
 498     params>> %callback-return ;
 499
 500 M: ##alien-callback generate-insn
 501     params>>
 502     [ registers>objects ]
 503     [ wrap-callback-quot %alien-callback ]
 504     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 505     tri ;