basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 SYMBOL: registers
  28
  29 : register ( vreg -- operand )
  30     registers get at [ "Bad value" throw ] unless* ;
  31
  32 : ?register ( obj -- operand )
  33     dup vreg? [ register ] when ;
  34
  35 TUPLE: asm label code calls ;
  36
  37 SYMBOL: calls
  38
  39 : add-call ( word -- )
  40     #! Compile this word later.
  41     calls get push ;
  42
  43 SYMBOL: compiling-word
  44
  45 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  46
  47 ! Mapping _label IDs to label instances
  48 SYMBOL: labels
  49
  50 : init-generator ( word -- )
  51     H{ } clone labels set
  52     V{ } clone calls set
  53     compiling-word set
  54     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  55
  56 : generate-insns ( asm -- code )
  57     [
  58         [ word>> init-generator ]
  59         [
  60             instructions>>
  61             [
  62                 [ class insn-counts get inc-at ]
  63                 [ regs>> registers set ]
  64                 [ generate-insn ]
  65                 tri
  66             ] each
  67         ] bi
  68     ] with-fixup ;
  69
  70 : generate ( mr -- asm )
  71     [
  72         [ label>> ] [ generate-insns ] bi calls get
  73         asm boa
  74     ] with-scope ;
  75
  76 : lookup-label ( id -- label )
  77     labels get [ drop <label> ] cache ;
  78
  79 M: ##no-tco generate-insn drop ;
  80
  81 M: ##load-immediate generate-insn
  82     [ dst>> register ] [ val>> ] bi %load-immediate ;
  83
  84 M: ##load-reference generate-insn
  85     [ dst>> register ] [ obj>> ] bi %load-reference ;
  86
  87 M: ##peek generate-insn
  88     [ dst>> register ] [ loc>> ] bi %peek ;
  89
  90 M: ##replace generate-insn
  91     [ src>> register ] [ loc>> ] bi %replace ;
  92
  93 M: ##inc-d generate-insn n>> %inc-d ;
  94
  95 M: ##inc-r generate-insn n>> %inc-r ;
  96
  97 M: ##call generate-insn
  98     word>> dup sub-primitive>>
  99     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
 100
 101 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
 102
 103 M: ##return generate-insn drop %return ;
 104
 105 M: _dispatch generate-insn
 106     [ src>> register ] [ temp>> register ] bi %dispatch ;
 107
 108 M: _dispatch-label generate-insn
 109     label>> lookup-label
 110     cell 0 <repetition> %
 111     rc-absolute-cell label-fixup ;
 112
 113 : >slot< ( insn -- dst obj slot tag )
 114     {
 115         [ dst>> register ]
 116         [ obj>> register ]
 117         [ slot>> ?register ]
 118         [ tag>> ]
 119     } cleave ; inline
 120
 121 M: ##slot generate-insn
 122     [ >slot< ] [ temp>> register ] bi %slot ;
 123
 124 M: ##slot-imm generate-insn
 125     >slot< %slot-imm ;
 126
 127 : >set-slot< ( insn -- src obj slot tag )
 128     {
 129         [ src>> register ]
 130         [ obj>> register ]
 131         [ slot>> ?register ]
 132         [ tag>> ]
 133     } cleave ; inline
 134
 135 M: ##set-slot generate-insn
 136     [ >set-slot< ] [ temp>> register ] bi %set-slot ;
 137
 138 M: ##set-slot-imm generate-insn
 139     >set-slot< %set-slot-imm ;
 140
 141 M: ##string-nth generate-insn
 142     {
 143         [ dst>> register ]
 144         [ obj>> register ]
 145         [ index>> register ]
 146         [ temp>> register ]
 147     } cleave %string-nth ;
 148
 149 M: ##set-string-nth-fast generate-insn
 150     {
 151         [ src>> register ]
 152         [ obj>> register ]
 153         [ index>> register ]
 154         [ temp>> register ]
 155     } cleave %set-string-nth-fast ;
 156
 157 : dst/src ( insn -- dst src )
 158     [ dst>> register ] [ src>> register ] bi ; inline
 159
 160 : dst/src1/src2 ( insn -- dst src1 src2 )
 161     [ dst>> register ]
 162     [ src1>> register ]
 163     [ src2>> ?register ] tri ; inline
 164
 165 M: ##add     generate-insn dst/src1/src2 %add     ;
 166 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 167 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 168 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 169 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 170 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 171 M: ##and     generate-insn dst/src1/src2 %and     ;
 172 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 173 M: ##or      generate-insn dst/src1/src2 %or      ;
 174 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 175 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 176 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 177 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 178 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 179 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 180 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 181 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 182 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 183 M: ##not     generate-insn dst/src       %not     ;
 184 M: ##log2    generate-insn dst/src       %log2    ;
 185
 186 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 187     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 188
 189 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 190 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 191 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 192
 193 : dst/src/temp ( insn -- dst src temp )
 194     [ dst/src ] [ temp>> register ] bi ; inline
 195
 196 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 197 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 198
 199 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 200 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 201 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 202 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 203
 204 M: ##integer>float generate-insn dst/src %integer>float ;
 205 M: ##float>integer generate-insn dst/src %float>integer ;
 206
 207 M: ##copy             generate-insn dst/src %copy ;
 208 M: ##copy-float       generate-insn dst/src %copy-float ;
 209 M: ##unbox-float      generate-insn dst/src %unbox-float ;
 210 M: ##unbox-any-c-ptr  generate-insn dst/src/temp %unbox-any-c-ptr ;
 211 M: ##box-float        generate-insn dst/src/temp %box-float ;
 212 M: ##box-alien        generate-insn dst/src/temp %box-alien ;
 213
 214 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 215 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 216 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 217 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 218 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 219 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 220 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 221 M: ##alien-float      generate-insn dst/src %alien-float      ;
 222 M: ##alien-double     generate-insn dst/src %alien-double     ;
 223
 224 : >alien-setter< ( insn -- src value )
 225     [ src>> register ] [ value>> register ] bi ; inline
 226
 227 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 228 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 229 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 230 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 231 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 232 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 233
 234 M: ##allot generate-insn
 235     {
 236         [ dst>> register ]
 237         [ size>> ]
 238         [ class>> ]
 239         [ temp>> register ]
 240     } cleave
 241     %allot ;
 242
 243 M: ##write-barrier generate-insn
 244     [ src>> register ]
 245     [ card#>> register ]
 246     [ table>> register ]
 247     tri %write-barrier ;
 248
 249 M: _gc generate-insn
 250     {
 251         [ temp1>> register ]
 252         [ temp2>> register ]
 253         [ gc-roots>> ]
 254         [ gc-root-count>> ]
 255     } cleave %gc ;
 256
 257 M: _loop-entry generate-insn drop %loop-entry ;
 258
 259 M: ##alien-global generate-insn
 260     [ dst>> register ] [ symbol>> ] [ library>> ] tri
 261     %alien-global ;
 262
 263 ! ##alien-invoke
 264 GENERIC: reg-class-variable ( register-class -- symbol )
 265
 266 M: reg-class reg-class-variable ;
 267
 268 M: float-regs reg-class-variable drop float-regs ;
 269
 270 GENERIC: inc-reg-class ( register-class -- )
 271
 272 : ?dummy-stack-params ( reg-class -- )
 273     dummy-stack-params? [ reg-size cell align stack-params +@ ] [ drop ] if ;
 274
 275 : ?dummy-int-params ( reg-class -- )
 276     dummy-int-params? [ reg-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 277
 278 : ?dummy-fp-params ( reg-class -- )
 279     drop dummy-fp-params? [ float-regs inc ] when ;
 280
 281 M: int-regs inc-reg-class
 282     [ reg-class-variable inc ]
 283     [ ?dummy-stack-params ]
 284     [ ?dummy-fp-params ]
 285     tri ;
 286
 287 M: float-regs inc-reg-class
 288     [ reg-class-variable inc ]
 289     [ ?dummy-stack-params ]
 290     [ ?dummy-int-params ]
 291     tri ;
 292
 293 GENERIC: reg-class-full? ( class -- ? )
 294
 295 M: stack-params reg-class-full? drop t ;
 296
 297 M: object reg-class-full?
 298     [ reg-class-variable get ] [ param-regs length ] bi >= ;
 299
 300 : spill-param ( reg-class -- n reg-class )
 301     stack-params get
 302     [ reg-size cell align stack-params +@ ] dip
 303     stack-params ;
 304
 305 : fastcall-param ( reg-class -- n reg-class )
 306     [ reg-class-variable get ] [ inc-reg-class ] [ ] tri ;
 307
 308 : alloc-parameter ( parameter -- reg reg-class )
 309     c-type-reg-class dup reg-class-full?
 310     [ spill-param ] [ fastcall-param ] if
 311     [ param-reg ] keep ;
 312
 313 : (flatten-int-type) ( size -- seq )
 314     cell /i "void*" c-type <repetition> ;
 315
 316 GENERIC: flatten-value-type ( type -- types )
 317
 318 M: object flatten-value-type 1array ;
 319
 320 M: struct-type flatten-value-type ( type -- types )
 321     stack-size cell align (flatten-int-type) ;
 322
 323 M: long-long-type flatten-value-type ( type -- types )
 324     stack-size cell align (flatten-int-type) ;
 325
 326 : flatten-value-types ( params -- params )
 327     #! Convert value type structs to consecutive void*s.
 328     [
 329         0 [
 330             c-type
 331             [ parameter-align (flatten-int-type) % ] keep
 332             [ stack-size cell align + ] keep
 333             flatten-value-type %
 334         ] reduce drop
 335     ] { } make ;
 336
 337 : each-parameter ( parameters quot -- )
 338     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 339
 340 : reverse-each-parameter ( parameters quot -- )
 341     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 342
 343 : reset-freg-counts ( -- )
 344     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 345
 346 : with-param-regs ( quot -- )
 347     #! In quot you can call alloc-parameter
 348     [ reset-freg-counts call ] with-scope ; inline
 349
 350 : move-parameters ( node word -- )
 351     #! Moves values from C stack to registers (if word is
 352     #! %load-param-reg) and registers to C stack (if word is
 353     #! %save-param-reg).
 354     [ alien-parameters flatten-value-types ]
 355     [ '[ alloc-parameter _ execute ] ]
 356     bi* each-parameter ; inline
 357
 358 : unbox-parameters ( offset node -- )
 359     parameters>> [
 360         %prepare-unbox [ over + ] dip unbox-parameter
 361     ] reverse-each-parameter drop ;
 362
 363 : prepare-box-struct ( node -- offset )
 364     #! Return offset on C stack where to store unboxed
 365     #! parameters. If the C function is returning a structure,
 366     #! the first parameter is an implicit target area pointer,
 367     #! so we need to use a different offset.
 368     return>> large-struct?
 369     [ %prepare-box-struct cell ] [ 0 ] if ;
 370
 371 : objects>registers ( params -- )
 372     #! Generate code for unboxing a list of C types, then
 373     #! generate code for moving these parameters to register on
 374     #! architectures where parameters are passed in registers.
 375     [
 376         [ prepare-box-struct ] keep
 377         [ unbox-parameters ] keep
 378         \ %load-param-reg move-parameters
 379     ] with-param-regs ;
 380
 381 : box-return* ( node -- )
 382     return>> [ ] [ box-return ] if-void ;
 383
 384 : check-dlsym ( symbols dll -- )
 385     dup dll-valid? [
 386         dupd '[ _ dlsym ] any?
 387         [ drop ] [ compiling-word get no-such-symbol ] if
 388     ] [
 389         dll-path compiling-word get no-such-library drop
 390     ] if ;
 391
 392 : stdcall-mangle ( symbol params -- symbol )
 393     parameters>> parameter-sizes drop number>string "@" glue ;
 394
 395 : alien-invoke-dlsym ( params -- symbols dll )
 396     [ [ function>> dup ] keep stdcall-mangle 2array ]
 397     [ library>> library dup [ dll>> ] when ]
 398     bi 2dup check-dlsym ;
 399
 400 M: ##alien-invoke generate-insn
 401     params>>
 402     ! Save registers for GC
 403     %prepare-alien-invoke
 404     ! Unbox parameters
 405     dup objects>registers
 406     %prepare-var-args
 407     ! Call function
 408     dup alien-invoke-dlsym %alien-invoke
 409     ! Box return value
 410     dup %cleanup
 411     box-return* ;
 412
 413 ! ##alien-indirect
 414 M: ##alien-indirect generate-insn
 415     params>>
 416     ! Save registers for GC
 417     %prepare-alien-invoke
 418     ! Save alien at top of stack to temporary storage
 419     %prepare-alien-indirect
 420     ! Unbox parameters
 421     dup objects>registers
 422     %prepare-var-args
 423     ! Call alien in temporary storage
 424     %alien-indirect
 425     ! Box return value
 426     dup %cleanup
 427     box-return* ;
 428
 429 ! ##alien-callback
 430 : box-parameters ( params -- )
 431     alien-parameters [ box-parameter ] each-parameter ;
 432
 433 : registers>objects ( node -- )
 434     [
 435         dup \ %save-param-reg move-parameters
 436         "nest_stacks" f %alien-invoke
 437         box-parameters
 438     ] with-param-regs ;
 439
 440 TUPLE: callback-context ;
 441
 442 : current-callback ( -- id ) 2 getenv ;
 443
 444 : wait-to-return ( token -- )
 445     dup current-callback eq? [
 446         drop
 447     ] [
 448         yield-hook get call( -- ) wait-to-return
 449     ] if ;
 450
 451 : do-callback ( quot token -- )
 452     init-catchstack
 453     [ 2 setenv call ] keep
 454     wait-to-return ; inline
 455
 456 : callback-return-quot ( ctype -- quot )
 457     return>> {
 458         { [ dup "void" = ] [ drop [ ] ] }
 459         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 460         [ c-type c-type-unboxer-quot ]
 461     } cond ;
 462
 463 : callback-prep-quot ( params -- quot )
 464     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 465
 466 : wrap-callback-quot ( params -- quot )
 467     [
 468         [ callback-prep-quot ]
 469         [ quot>> ]
 470         [ callback-return-quot ] tri 3append ,
 471         [ callback-context new do-callback ] %
 472     ] [ ] make ;
 473
 474 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 475
 476 M: ##callback-return generate-insn
 477     #! All the extra book-keeping for %unwind is only for x86.
 478     #! On other platforms its an alias for %return.
 479     params>> %callback-return ;
 480
 481 M: ##alien-callback generate-insn
 482     params>>
 483     [ registers>objects ]
 484     [ wrap-callback-quot %alien-callback ]
 485     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 486     tri ;
 487
 488 M: _prologue generate-insn
 489     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 490
 491 M: _epilogue generate-insn
 492     stack-frame>> total-size>> %epilogue ;
 493
 494 M: _label generate-insn
 495     id>> lookup-label resolve-label ;
 496
 497 M: _branch generate-insn
 498     label>> lookup-label %jump-label ;
 499
 500 : >compare< ( insn -- dst temp cc src1 src2 )
 501     {
 502         [ dst>> register ]
 503         [ temp>> register ]
 504         [ cc>> ]
 505         [ src1>> register ]
 506         [ src2>> ?register ]
 507     } cleave ; inline
 508
 509 M: ##compare generate-insn >compare< %compare ;
 510 M: ##compare-imm generate-insn >compare< %compare-imm ;
 511 M: ##compare-float generate-insn >compare< %compare-float ;
 512
 513 : >binary-branch< ( insn -- label cc src1 src2 )
 514     {
 515         [ label>> lookup-label ]
 516         [ cc>> ]
 517         [ src1>> register ]
 518         [ src2>> ?register ]
 519     } cleave ; inline
 520
 521 M: _compare-branch generate-insn
 522     >binary-branch< %compare-branch ;
 523
 524 M: _compare-imm-branch generate-insn
 525     >binary-branch< %compare-imm-branch ;
 526
 527 M: _compare-float-branch generate-insn
 528     >binary-branch< %compare-float-branch ;
 529
 530 M: _spill generate-insn
 531     [ src>> ] [ n>> ] [ class>> ] tri {
 532         { int-regs [ %spill-integer ] }
 533         { double-float-regs [ %spill-float ] }
 534     } case ;
 535
 536 M: _reload generate-insn
 537     [ dst>> ] [ n>> ] [ class>> ] tri {
 538         { int-regs [ %reload-integer ] }
 539         { double-float-regs [ %reload-float ] }
 540     } case ;
 541
 542 M: _copy generate-insn
 543     [ dst>> ] [ src>> ] [ class>> ] tri {
 544         { int-regs [ %copy ] }
 545         { double-float-regs [ %copy-float ] }
 546     } case ;
 547
 548 M: _spill-counts generate-insn drop ;