basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> ] [ temp>> ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     { [ dst>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 106
 107 M: ##slot generate-insn
 108     [ >slot< ] [ temp>> ] bi %slot ;
 109
 110 M: ##slot-imm generate-insn
 111     >slot< %slot-imm ;
 112
 113 : >set-slot< ( insn -- src obj slot tag )
 114     { [ src>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 115
 116 M: ##set-slot generate-insn
 117     [ >set-slot< ] [ temp>> ] bi %set-slot ;
 118
 119 M: ##set-slot-imm generate-insn
 120     >set-slot< %set-slot-imm ;
 121
 122 M: ##string-nth generate-insn
 123     { [ dst>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %string-nth ;
 124
 125 M: ##set-string-nth-fast generate-insn
 126     { [ src>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %set-string-nth-fast ;
 127
 128 : dst/src ( insn -- dst src )
 129     [ dst>> ] [ src>> ] bi ; inline
 130
 131 : dst/src1/src2 ( insn -- dst src1 src2 )
 132     [ dst>> ] [ src1>> ] [ src2>> ] tri ; inline
 133
 134 M: ##add     generate-insn dst/src1/src2 %add     ;
 135 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 136 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 137 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 138 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 139 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 140 M: ##and     generate-insn dst/src1/src2 %and     ;
 141 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 142 M: ##or      generate-insn dst/src1/src2 %or      ;
 143 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 144 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 145 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 146 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 147 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 148 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 149 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 150 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 151 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 152 M: ##not     generate-insn dst/src       %not     ;
 153 M: ##log2    generate-insn dst/src       %log2    ;
 154
 155 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 156     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 157
 158 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 159 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 160 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 161
 162 : dst/src/temp ( insn -- dst src temp )
 163     [ dst/src ] [ temp>> ] bi ; inline
 164
 165 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 166 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 167
 168 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 169 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 170 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 171 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 172 M: ##min-float generate-insn dst/src1/src2 %min-float ;
 173 M: ##max-float generate-insn dst/src1/src2 %max-float ;
 174
 175 M: ##sqrt generate-insn dst/src %sqrt ;
 176
 177 M: ##integer>float generate-insn dst/src %integer>float ;
 178 M: ##float>integer generate-insn dst/src %float>integer ;
 179
 180 M: ##copy generate-insn [ dst/src ] [ rep>> ] bi %copy ;
 181
 182 M: ##unbox-float generate-insn dst/src %unbox-float ;
 183 M: ##unbox-any-c-ptr generate-insn dst/src/temp %unbox-any-c-ptr ;
 184 M: ##box-float generate-insn dst/src/temp %box-float ;
 185 M: ##box-alien generate-insn dst/src/temp %box-alien ;
 186
 187 M: ##box-displaced-alien generate-insn
 188     [ dst/src1/src2 ] [ temp>> ] bi %box-displaced-alien ;
 189
 190 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 191 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 192 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 193 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 194 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 195 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 196 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 197 M: ##alien-float      generate-insn dst/src %alien-float      ;
 198 M: ##alien-double     generate-insn dst/src %alien-double     ;
 199
 200 : >alien-setter< ( insn -- src value )
 201     [ src>> ] [ value>> ] bi ; inline
 202
 203 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 204 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 205 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 206 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 207 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 208 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 209
 210 M: ##allot generate-insn
 211     {
 212         [ dst>> ]
 213         [ size>> ]
 214         [ class>> ]
 215         [ temp>> ]
 216     } cleave
 217     %allot ;
 218
 219 M: ##write-barrier generate-insn
 220     [ src>> ]
 221     [ card#>> ]
 222     [ table>> ]
 223     tri %write-barrier ;
 224
 225 ! GC checks
 226 : wipe-locs ( locs temp -- )
 227     '[
 228         _
 229         [ 0 %load-immediate ]
 230         [ swap [ %replace ] with each ] bi
 231     ] unless-empty ;
 232
 233 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 234
 235 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 236     temp operand n>> int-rep %reload
 237     gc-root temp %save-gc-root ;
 238
 239 M: object save-gc-root drop %save-gc-root ;
 240
 241 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 242
 243 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 244
 245 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 246
 247 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 248     gc-root temp %load-gc-root
 249     temp operand n>> int-rep %spill ;
 250
 251 M: object load-gc-root drop %load-gc-root ;
 252
 253 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 254
 255 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 256
 257 M: _gc generate-insn
 258     "no-gc" define-label
 259     {
 260         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 261         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 262         [ data-values>> save-data-regs ]
 263         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 264         [ tagged-values>> length %call-gc ]
 265         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 266         [ data-values>> load-data-regs ]
 267     } cleave
 268     "no-gc" resolve-label ;
 269
 270 M: _loop-entry generate-insn drop %loop-entry ;
 271
 272 M: ##alien-global generate-insn
 273     [ dst>> ] [ symbol>> ] [ library>> ] tri
 274     %alien-global ;
 275
 276 ! ##alien-invoke
 277 GENERIC: next-fastcall-param ( rep -- )
 278
 279 : ?dummy-stack-params ( rep -- )
 280     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 281
 282 : ?dummy-int-params ( rep -- )
 283     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 284
 285 : ?dummy-fp-params ( rep -- )
 286     drop dummy-fp-params? [ float-regs inc ] when ;
 287
 288 M: int-rep next-fastcall-param
 289     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 290
 291 M: single-float-rep next-fastcall-param
 292     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 293
 294 M: double-float-rep next-fastcall-param
 295     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 296
 297 GENERIC: reg-class-full? ( reg-class -- ? )
 298
 299 M: stack-params reg-class-full? drop t ;
 300
 301 M: reg-class reg-class-full?
 302     [ get ] [ param-regs length ] bi >= ;
 303
 304 : alloc-stack-param ( rep -- n reg-class rep )
 305     stack-params get
 306     [ rep-size cell align stack-params +@ ] dip
 307     stack-params dup ;
 308
 309 : alloc-fastcall-param ( rep -- n reg-class rep )
 310     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 311
 312 : alloc-parameter ( parameter -- reg rep )
 313     c-type-rep dup reg-class-of reg-class-full?
 314     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 315     [ param-reg ] dip ;
 316
 317 : (flatten-int-type) ( size -- seq )
 318     cell /i "void*" c-type <repetition> ;
 319
 320 GENERIC: flatten-value-type ( type -- types )
 321
 322 M: object flatten-value-type 1array ;
 323
 324 M: struct-type flatten-value-type ( type -- types )
 325     stack-size cell align (flatten-int-type) ;
 326
 327 M: long-long-type flatten-value-type ( type -- types )
 328     stack-size cell align (flatten-int-type) ;
 329
 330 : flatten-value-types ( params -- params )
 331     #! Convert value type structs to consecutive void*s.
 332     [
 333         0 [
 334             c-type
 335             [ parameter-align (flatten-int-type) % ] keep
 336             [ stack-size cell align + ] keep
 337             flatten-value-type %
 338         ] reduce drop
 339     ] { } make ;
 340
 341 : each-parameter ( parameters quot -- )
 342     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 343
 344 : reverse-each-parameter ( parameters quot -- )
 345     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 346
 347 : reset-fastcall-counts ( -- )
 348     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 349
 350 : with-param-regs ( quot -- )
 351     #! In quot you can call alloc-parameter
 352     [ reset-fastcall-counts call ] with-scope ; inline
 353
 354 : move-parameters ( node word -- )
 355     #! Moves values from C stack to registers (if word is
 356     #! %load-param-reg) and registers to C stack (if word is
 357     #! %save-param-reg).
 358     [ alien-parameters flatten-value-types ]
 359     [ '[ alloc-parameter _ execute ] ]
 360     bi* each-parameter ; inline
 361
 362 : unbox-parameters ( offset node -- )
 363     parameters>> [
 364         %prepare-unbox [ over + ] dip unbox-parameter
 365     ] reverse-each-parameter drop ;
 366
 367 : prepare-box-struct ( node -- offset )
 368     #! Return offset on C stack where to store unboxed
 369     #! parameters. If the C function is returning a structure,
 370     #! the first parameter is an implicit target area pointer,
 371     #! so we need to use a different offset.
 372     return>> large-struct?
 373     [ %prepare-box-struct cell ] [ 0 ] if ;
 374
 375 : objects>registers ( params -- )
 376     #! Generate code for unboxing a list of C types, then
 377     #! generate code for moving these parameters to registers on
 378     #! architectures where parameters are passed in registers.
 379     [
 380         [ prepare-box-struct ] keep
 381         [ unbox-parameters ] keep
 382         \ %load-param-reg move-parameters
 383     ] with-param-regs ;
 384
 385 : box-return* ( node -- )
 386     return>> [ ] [ box-return ] if-void ;
 387
 388 : check-dlsym ( symbols dll -- )
 389     dup dll-valid? [
 390         dupd '[ _ dlsym ] any?
 391         [ drop ] [ compiling-word get no-such-symbol ] if
 392     ] [
 393         dll-path compiling-word get no-such-library drop
 394     ] if ;
 395
 396 : stdcall-mangle ( symbol params -- symbol )
 397     parameters>> parameter-sizes drop number>string "@" glue ;
 398
 399 : alien-invoke-dlsym ( params -- symbols dll )
 400     [ [ function>> dup ] keep stdcall-mangle 2array ]
 401     [ library>> library dup [ dll>> ] when ]
 402     bi 2dup check-dlsym ;
 403
 404 M: ##alien-invoke generate-insn
 405     params>>
 406     ! Save registers for GC
 407     %prepare-alien-invoke
 408     ! Unbox parameters
 409     dup objects>registers
 410     %prepare-var-args
 411     ! Call function
 412     dup alien-invoke-dlsym %alien-invoke
 413     ! Box return value
 414     dup %cleanup
 415     box-return* ;
 416
 417 ! ##alien-indirect
 418 M: ##alien-indirect generate-insn
 419     params>>
 420     ! Save registers for GC
 421     %prepare-alien-invoke
 422     ! Save alien at top of stack to temporary storage
 423     %prepare-alien-indirect
 424     ! Unbox parameters
 425     dup objects>registers
 426     %prepare-var-args
 427     ! Call alien in temporary storage
 428     %alien-indirect
 429     ! Box return value
 430     dup %cleanup
 431     box-return* ;
 432
 433 ! ##alien-callback
 434 : box-parameters ( params -- )
 435     alien-parameters [ box-parameter ] each-parameter ;
 436
 437 : registers>objects ( node -- )
 438     ! Generate code for boxing input parameters in a callback.
 439     [
 440         dup \ %save-param-reg move-parameters
 441         "nest_stacks" f %alien-invoke
 442         box-parameters
 443     ] with-param-regs ;
 444
 445 TUPLE: callback-context ;
 446
 447 : current-callback ( -- id ) 2 getenv ;
 448
 449 : wait-to-return ( token -- )
 450     dup current-callback eq? [
 451         drop
 452     ] [
 453         yield-hook get call( -- ) wait-to-return
 454     ] if ;
 455
 456 : do-callback ( quot token -- )
 457     init-catchstack
 458     [ 2 setenv call ] keep
 459     wait-to-return ; inline
 460
 461 : callback-return-quot ( ctype -- quot )
 462     return>> {
 463         { [ dup "void" = ] [ drop [ ] ] }
 464         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 465         [ c-type c-type-unboxer-quot ]
 466     } cond ;
 467
 468 : callback-prep-quot ( params -- quot )
 469     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 470
 471 : wrap-callback-quot ( params -- quot )
 472     [
 473         [ callback-prep-quot ]
 474         [ quot>> ]
 475         [ callback-return-quot ] tri 3append ,
 476         [ callback-context new do-callback ] %
 477     ] [ ] make ;
 478
 479 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 480
 481 M: ##callback-return generate-insn
 482     #! All the extra book-keeping for %unwind is only for x86.
 483     #! On other platforms its an alias for %return.
 484     params>> %callback-return ;
 485
 486 M: ##alien-callback generate-insn
 487     params>>
 488     [ registers>objects ]
 489     [ wrap-callback-quot %alien-callback ]
 490     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 491     tri ;
 492
 493 M: _prologue generate-insn
 494     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 495
 496 M: _epilogue generate-insn
 497     stack-frame>> total-size>> %epilogue ;
 498
 499 M: _label generate-insn
 500     id>> lookup-label resolve-label ;
 501
 502 M: _branch generate-insn
 503     label>> lookup-label %jump-label ;
 504
 505 : >compare< ( insn -- dst temp cc src1 src2 )
 506     {
 507         [ dst>> ]
 508         [ temp>> ]
 509         [ cc>> ]
 510         [ src1>> ]
 511         [ src2>> ]
 512     } cleave ; inline
 513
 514 M: ##compare generate-insn >compare< %compare ;
 515 M: ##compare-imm generate-insn >compare< %compare-imm ;
 516 M: ##compare-float generate-insn >compare< %compare-float ;
 517
 518 : >binary-branch< ( insn -- label cc src1 src2 )
 519     {
 520         [ label>> lookup-label ]
 521         [ cc>> ]
 522         [ src1>> ]
 523         [ src2>> ]
 524     } cleave ; inline
 525
 526 M: _compare-branch generate-insn
 527     >binary-branch< %compare-branch ;
 528
 529 M: _compare-imm-branch generate-insn
 530     >binary-branch< %compare-imm-branch ;
 531
 532 M: _compare-float-branch generate-insn
 533     >binary-branch< %compare-float-branch ;
 534
 535 M: _spill generate-insn
 536     [ src>> ] [ n>> ] [ rep>> ] tri %spill ;
 537
 538 M: _reload generate-insn
 539     [ dst>> ] [ n>> ] [ rep>> ] tri %reload ;
 540
 541 M: _spill-area-size generate-insn drop ;