basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors slots parser generic.parser
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 ! Special cases
  71 M: ##no-tco generate-insn drop ;
  72
  73 M: ##call generate-insn
  74     word>> dup sub-primitive>>
  75     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  76
  77 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  78
  79 M: _dispatch-label generate-insn
  80     label>> lookup-label
  81     cell 0 <repetition> %
  82     rc-absolute-cell label-fixup ;
  83
  84 M: _prologue generate-insn
  85     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  86
  87 M: _epilogue generate-insn
  88     stack-frame>> total-size>> %epilogue ;
  89
  90 M: _spill-area-size generate-insn drop ;
  91
  92 ! Some meta-programming to generate simple code generators, where
  93 ! the instruction is unpacked and then a %word is called
  94 <<
  95
  96 : insn-slot-quot ( spec -- quot )
  97     name>> [ reader-word ] [ "label" = ] bi
  98     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
  99
 100 : codegen-method-body ( class word -- quot )
 101     [
 102         "insn-slots" word-prop
 103         [ insn-slot-quot ] map
 104     ] dip
 105     '[ _ cleave _ execute ] ;
 106
 107 SYNTAX: CODEGEN:
 108     scan-word [ \ generate-insn create-method-in ] keep scan-word
 109     codegen-method-body define ;
 110 >>
 111
 112 CODEGEN: ##load-immediate %load-immediate
 113 CODEGEN: ##load-reference %load-reference
 114 CODEGEN: ##peek %peek
 115 CODEGEN: ##replace %replace
 116 CODEGEN: ##inc-d %inc-d
 117 CODEGEN: ##inc-r %inc-r
 118 CODEGEN: ##return %return
 119 CODEGEN: ##slot %slot
 120 CODEGEN: ##slot-imm %slot-imm
 121 CODEGEN: ##set-slot %set-slot
 122 CODEGEN: ##set-slot-imm %set-slot-imm
 123 CODEGEN: ##string-nth %string-nth
 124 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 125 CODEGEN: ##add %add
 126 CODEGEN: ##add-imm %add-imm
 127 CODEGEN: ##sub %sub
 128 CODEGEN: ##sub-imm %sub-imm
 129 CODEGEN: ##mul %mul
 130 CODEGEN: ##mul-imm %mul-imm
 131 CODEGEN: ##and %and
 132 CODEGEN: ##and-imm %and-imm
 133 CODEGEN: ##or %or
 134 CODEGEN: ##or-imm %or-imm
 135 CODEGEN: ##xor %xor
 136 CODEGEN: ##xor-imm %xor-imm
 137 CODEGEN: ##shl %shl
 138 CODEGEN: ##shl-imm %shl-imm
 139 CODEGEN: ##shr %shr
 140 CODEGEN: ##shr-imm %shr-imm
 141 CODEGEN: ##sar %sar
 142 CODEGEN: ##sar-imm %sar-imm
 143 CODEGEN: ##min %min
 144 CODEGEN: ##max %max
 145 CODEGEN: ##not %not
 146 CODEGEN: ##log2 %log2
 147 CODEGEN: ##copy %copy
 148 CODEGEN: ##integer>bignum %integer>bignum
 149 CODEGEN: ##bignum>integer %bignum>integer
 150 CODEGEN: ##unbox-float %unbox-float
 151 CODEGEN: ##box-float %box-float
 152 CODEGEN: ##add-float %add-float
 153 CODEGEN: ##sub-float %sub-float
 154 CODEGEN: ##mul-float %mul-float
 155 CODEGEN: ##div-float %div-float
 156 CODEGEN: ##min-float %min-float
 157 CODEGEN: ##max-float %max-float
 158 CODEGEN: ##sqrt %sqrt
 159 CODEGEN: ##unary-float-function %unary-float-function
 160 CODEGEN: ##binary-float-function %binary-float-function
 161 CODEGEN: ##single>double-float %single>double-float
 162 CODEGEN: ##double>single-float %double>single-float
 163 CODEGEN: ##integer>float %integer>float
 164 CODEGEN: ##float>integer %float>integer
 165 CODEGEN: ##unbox-vector %unbox-vector
 166 CODEGEN: ##broadcast-vector %broadcast-vector
 167 CODEGEN: ##gather-vector-2 %gather-vector-2
 168 CODEGEN: ##gather-vector-4 %gather-vector-4
 169 CODEGEN: ##box-vector %box-vector
 170 CODEGEN: ##add-vector %add-vector
 171 CODEGEN: ##sub-vector %sub-vector
 172 CODEGEN: ##mul-vector %mul-vector
 173 CODEGEN: ##div-vector %div-vector
 174 CODEGEN: ##min-vector %min-vector
 175 CODEGEN: ##max-vector %max-vector
 176 CODEGEN: ##sqrt-vector %sqrt-vector
 177 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 178 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 179 CODEGEN: ##box-alien %box-alien
 180 CODEGEN: ##box-displaced-alien %box-displaced-alien
 181 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 182 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 183 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 184 CODEGEN: ##alien-signed-1 %alien-signed-1
 185 CODEGEN: ##alien-signed-2 %alien-signed-2
 186 CODEGEN: ##alien-signed-4 %alien-signed-4
 187 CODEGEN: ##alien-cell %alien-cell
 188 CODEGEN: ##alien-float %alien-float
 189 CODEGEN: ##alien-double %alien-double
 190 CODEGEN: ##alien-vector %alien-vector
 191 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 192 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 193 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 194 CODEGEN: ##set-alien-cell %set-alien-cell
 195 CODEGEN: ##set-alien-float %set-alien-float
 196 CODEGEN: ##set-alien-double %set-alien-double
 197 CODEGEN: ##set-alien-vector %set-alien-vector
 198 CODEGEN: ##allot %allot
 199 CODEGEN: ##write-barrier %write-barrier
 200 CODEGEN: ##compare %compare
 201 CODEGEN: ##compare-imm %compare-imm
 202 CODEGEN: ##compare-float %compare-float
 203
 204 CODEGEN: _fixnum-add %fixnum-add
 205 CODEGEN: _fixnum-sub %fixnum-sub
 206 CODEGEN: _fixnum-mul %fixnum-mul
 207 CODEGEN: _label resolve-label
 208 CODEGEN: _branch %jump-label
 209 CODEGEN: _compare-branch %compare-branch
 210 CODEGEN: _compare-imm-branch %compare-imm-branch
 211 CODEGEN: _compare-float-branch %compare-float-branch
 212 CODEGEN: _dispatch %dispatch
 213 CODEGEN: _spill %spill
 214 CODEGEN: _reload %reload
 215
 216 ! ##gc
 217 : wipe-locs ( locs temp -- )
 218     '[
 219         _
 220         [ 0 %load-immediate ]
 221         [ swap [ %replace ] with each ] bi
 222     ] unless-empty ;
 223
 224 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 225
 226 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 227     temp int-rep operand n>> %reload
 228     gc-root temp %save-gc-root ;
 229
 230 M: object save-gc-root drop %save-gc-root ;
 231
 232 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 233
 234 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 235
 236 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 237
 238 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 239     gc-root temp %load-gc-root
 240     temp int-rep operand n>> %spill ;
 241
 242 M: object load-gc-root drop %load-gc-root ;
 243
 244 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 245
 246 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 247
 248 M: _gc generate-insn
 249     "no-gc" define-label
 250     {
 251         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 252         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 253         [ data-values>> save-data-regs ]
 254         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 255         [ tagged-values>> length %call-gc ]
 256         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 257         [ data-values>> load-data-regs ]
 258     } cleave
 259     "no-gc" resolve-label ;
 260
 261 M: _loop-entry generate-insn drop %loop-entry ;
 262
 263 M: ##alien-global generate-insn
 264     [ dst>> ] [ symbol>> ] [ library>> ] tri
 265     %alien-global ;
 266
 267 ! ##alien-invoke
 268 GENERIC: next-fastcall-param ( rep -- )
 269
 270 : ?dummy-stack-params ( rep -- )
 271     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 272
 273 : ?dummy-int-params ( rep -- )
 274     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 275
 276 : ?dummy-fp-params ( rep -- )
 277     drop dummy-fp-params? [ float-regs inc ] when ;
 278
 279 M: int-rep next-fastcall-param
 280     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 281
 282 M: float-rep next-fastcall-param
 283     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 284
 285 M: double-rep next-fastcall-param
 286     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 287
 288 GENERIC: reg-class-full? ( reg-class -- ? )
 289
 290 M: stack-params reg-class-full? drop t ;
 291
 292 M: reg-class reg-class-full?
 293     [ get ] [ param-regs length ] bi >= ;
 294
 295 : alloc-stack-param ( rep -- n reg-class rep )
 296     stack-params get
 297     [ rep-size cell align stack-params +@ ] dip
 298     stack-params dup ;
 299
 300 : alloc-fastcall-param ( rep -- n reg-class rep )
 301     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 302
 303 : alloc-parameter ( parameter -- reg rep )
 304     c-type-rep dup reg-class-of reg-class-full?
 305     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 306     [ param-reg ] dip ;
 307
 308 : (flatten-int-type) ( size -- seq )
 309     cell /i "void*" c-type <repetition> ;
 310
 311 GENERIC: flatten-value-type ( type -- types )
 312
 313 M: object flatten-value-type 1array ;
 314
 315 M: struct-type flatten-value-type ( type -- types )
 316     stack-size cell align (flatten-int-type) ;
 317
 318 M: long-long-type flatten-value-type ( type -- types )
 319     stack-size cell align (flatten-int-type) ;
 320
 321 : flatten-value-types ( params -- params )
 322     #! Convert value type structs to consecutive void*s.
 323     [
 324         0 [
 325             c-type
 326             [ parameter-align (flatten-int-type) % ] keep
 327             [ stack-size cell align + ] keep
 328             flatten-value-type %
 329         ] reduce drop
 330     ] { } make ;
 331
 332 : each-parameter ( parameters quot -- )
 333     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 334
 335 : reverse-each-parameter ( parameters quot -- )
 336     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 337
 338 : reset-fastcall-counts ( -- )
 339     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 340
 341 : with-param-regs ( quot -- )
 342     #! In quot you can call alloc-parameter
 343     [ reset-fastcall-counts call ] with-scope ; inline
 344
 345 : move-parameters ( node word -- )
 346     #! Moves values from C stack to registers (if word is
 347     #! %load-param-reg) and registers to C stack (if word is
 348     #! %save-param-reg).
 349     [ alien-parameters flatten-value-types ]
 350     [ '[ alloc-parameter _ execute ] ]
 351     bi* each-parameter ; inline
 352
 353 : unbox-parameters ( offset node -- )
 354     parameters>> [
 355         %prepare-unbox [ over + ] dip unbox-parameter
 356     ] reverse-each-parameter drop ;
 357
 358 : prepare-box-struct ( node -- offset )
 359     #! Return offset on C stack where to store unboxed
 360     #! parameters. If the C function is returning a structure,
 361     #! the first parameter is an implicit target area pointer,
 362     #! so we need to use a different offset.
 363     return>> large-struct?
 364     [ %prepare-box-struct cell ] [ 0 ] if ;
 365
 366 : objects>registers ( params -- )
 367     #! Generate code for unboxing a list of C types, then
 368     #! generate code for moving these parameters to registers on
 369     #! architectures where parameters are passed in registers.
 370     [
 371         [ prepare-box-struct ] keep
 372         [ unbox-parameters ] keep
 373         \ %load-param-reg move-parameters
 374     ] with-param-regs ;
 375
 376 : box-return* ( node -- )
 377     return>> [ ] [ box-return ] if-void ;
 378
 379 : check-dlsym ( symbols dll -- )
 380     dup dll-valid? [
 381         dupd '[ _ dlsym ] any?
 382         [ drop ] [ compiling-word get no-such-symbol ] if
 383     ] [
 384         dll-path compiling-word get no-such-library drop
 385     ] if ;
 386
 387 : stdcall-mangle ( symbol params -- symbol )
 388     parameters>> parameter-sizes drop number>string "@" glue ;
 389
 390 : alien-invoke-dlsym ( params -- symbols dll )
 391     [ [ function>> dup ] keep stdcall-mangle 2array ]
 392     [ library>> library dup [ dll>> ] when ]
 393     bi 2dup check-dlsym ;
 394
 395 M: ##alien-invoke generate-insn
 396     params>>
 397     ! Save registers for GC
 398     %prepare-alien-invoke
 399     ! Unbox parameters
 400     dup objects>registers
 401     %prepare-var-args
 402     ! Call function
 403     dup alien-invoke-dlsym %alien-invoke
 404     ! Box return value
 405     dup %cleanup
 406     box-return* ;
 407
 408 ! ##alien-indirect
 409 M: ##alien-indirect generate-insn
 410     params>>
 411     ! Save registers for GC
 412     %prepare-alien-invoke
 413     ! Save alien at top of stack to temporary storage
 414     %prepare-alien-indirect
 415     ! Unbox parameters
 416     dup objects>registers
 417     %prepare-var-args
 418     ! Call alien in temporary storage
 419     %alien-indirect
 420     ! Box return value
 421     dup %cleanup
 422     box-return* ;
 423
 424 ! ##alien-callback
 425 : box-parameters ( params -- )
 426     alien-parameters [ box-parameter ] each-parameter ;
 427
 428 : registers>objects ( node -- )
 429     ! Generate code for boxing input parameters in a callback.
 430     [
 431         dup \ %save-param-reg move-parameters
 432         "nest_stacks" f %alien-invoke
 433         box-parameters
 434     ] with-param-regs ;
 435
 436 TUPLE: callback-context ;
 437
 438 : current-callback ( -- id ) 2 getenv ;
 439
 440 : wait-to-return ( token -- )
 441     dup current-callback eq? [
 442         drop
 443     ] [
 444         yield-hook get call( -- ) wait-to-return
 445     ] if ;
 446
 447 : do-callback ( quot token -- )
 448     init-catchstack
 449     [ 2 setenv call ] keep
 450     wait-to-return ; inline
 451
 452 : callback-return-quot ( ctype -- quot )
 453     return>> {
 454         { [ dup "void" = ] [ drop [ ] ] }
 455         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 456         [ c-type c-type-unboxer-quot ]
 457     } cond ;
 458
 459 : callback-prep-quot ( params -- quot )
 460     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 461
 462 : wrap-callback-quot ( params -- quot )
 463     [
 464         [ callback-prep-quot ]
 465         [ quot>> ]
 466         [ callback-return-quot ] tri 3append ,
 467         [ callback-context new do-callback ] %
 468     ] [ ] make ;
 469
 470 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 471
 472 M: ##callback-return generate-insn
 473     #! All the extra book-keeping for %unwind is only for x86.
 474     #! On other platforms its an alias for %return.
 475     params>> %callback-return ;
 476
 477 M: ##alien-callback generate-insn
 478     params>>
 479     [ registers>objects ]
 480     [ wrap-callback-quot %alien-callback ]
 481     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 482     tri ;