basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> ] [ temp>> ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     { [ dst>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 106
 107 M: ##slot generate-insn
 108     [ >slot< ] [ temp>> ] bi %slot ;
 109
 110 M: ##slot-imm generate-insn
 111     >slot< %slot-imm ;
 112
 113 : >set-slot< ( insn -- src obj slot tag )
 114     { [ src>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 115
 116 M: ##set-slot generate-insn
 117     [ >set-slot< ] [ temp>> ] bi %set-slot ;
 118
 119 M: ##set-slot-imm generate-insn
 120     >set-slot< %set-slot-imm ;
 121
 122 M: ##string-nth generate-insn
 123     { [ dst>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %string-nth ;
 124
 125 M: ##set-string-nth-fast generate-insn
 126     { [ src>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %set-string-nth-fast ;
 127
 128 : dst/src ( insn -- dst src )
 129     [ dst>> ] [ src>> ] bi ; inline
 130
 131 : dst/src1/src2 ( insn -- dst src1 src2 )
 132     [ dst>> ] [ src1>> ] [ src2>> ] tri ; inline
 133
 134 M: ##add     generate-insn dst/src1/src2 %add     ;
 135 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 136 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 137 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 138 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 139 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 140 M: ##and     generate-insn dst/src1/src2 %and     ;
 141 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 142 M: ##or      generate-insn dst/src1/src2 %or      ;
 143 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 144 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 145 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 146 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 147 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 148 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 149 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 150 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 151 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 152 M: ##not     generate-insn dst/src       %not     ;
 153 M: ##log2    generate-insn dst/src       %log2    ;
 154
 155 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 156     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 157
 158 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 159 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 160 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 161
 162 : dst/src/temp ( insn -- dst src temp )
 163     [ dst/src ] [ temp>> ] bi ; inline
 164
 165 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 166 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 167
 168 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 169 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 170 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 171 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 172
 173 M: ##integer>float generate-insn dst/src %integer>float ;
 174 M: ##float>integer generate-insn dst/src %float>integer ;
 175
 176 M: ##copy             generate-insn dst/src %copy ;
 177 M: ##copy-float       generate-insn dst/src %copy-float ;
 178 M: ##unbox-float      generate-insn dst/src %unbox-float ;
 179 M: ##unbox-any-c-ptr  generate-insn dst/src/temp %unbox-any-c-ptr ;
 180 M: ##box-float        generate-insn dst/src/temp %box-float ;
 181 M: ##box-alien        generate-insn dst/src/temp %box-alien ;
 182
 183 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 184 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 185 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 186 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 187 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 188 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 189 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 190 M: ##alien-float      generate-insn dst/src %alien-float      ;
 191 M: ##alien-double     generate-insn dst/src %alien-double     ;
 192
 193 : >alien-setter< ( insn -- src value )
 194     [ src>> ] [ value>> ] bi ; inline
 195
 196 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 197 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 198 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 199 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 200 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 201 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 202
 203 M: ##allot generate-insn
 204     {
 205         [ dst>> ]
 206         [ size>> ]
 207         [ class>> ]
 208         [ temp>> ]
 209     } cleave
 210     %allot ;
 211
 212 M: ##write-barrier generate-insn
 213     [ src>> ]
 214     [ card#>> ]
 215     [ table>> ]
 216     tri %write-barrier ;
 217
 218 ! GC checks
 219 : wipe-locs ( locs temp -- )
 220     '[
 221         _
 222         [ 0 %load-immediate ]
 223         [ swap [ %replace ] with each ] bi
 224     ] unless-empty ;
 225
 226 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 227
 228 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 229     temp operand n>> %reload-integer
 230     gc-root temp %save-gc-root ;
 231
 232 M: object save-gc-root drop %save-gc-root ;
 233
 234 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 235
 236 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 237
 238 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 239     gc-root temp %load-gc-root
 240     temp operand n>> %spill-integer ;
 241
 242 M: object load-gc-root drop %load-gc-root ;
 243
 244 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 245
 246 M: _gc generate-insn
 247     "no-gc" define-label
 248     {
 249         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 250         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 251         [ [ gc-roots>> ] [ temp1>> ] bi save-gc-roots ]
 252         [ gc-root-count>> %call-gc ]
 253         [ [ gc-roots>> ] [ temp1>> ] bi load-gc-roots ]
 254     } cleave
 255     "no-gc" resolve-label ;
 256
 257 M: _loop-entry generate-insn drop %loop-entry ;
 258
 259 M: ##alien-global generate-insn
 260     [ dst>> ] [ symbol>> ] [ library>> ] tri
 261     %alien-global ;
 262
 263 ! ##alien-invoke
 264 GENERIC: reg-class-variable ( register-class -- symbol )
 265
 266 M: reg-class reg-class-variable ;
 267
 268 M: float-regs reg-class-variable drop float-regs ;
 269
 270 GENERIC: inc-reg-class ( register-class -- )
 271
 272 : ?dummy-stack-params ( reg-class -- )
 273     dummy-stack-params? [ reg-size cell align stack-params +@ ] [ drop ] if ;
 274
 275 : ?dummy-int-params ( reg-class -- )
 276     dummy-int-params? [ reg-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 277
 278 : ?dummy-fp-params ( reg-class -- )
 279     drop dummy-fp-params? [ float-regs inc ] when ;
 280
 281 M: int-regs inc-reg-class
 282     [ reg-class-variable inc ]
 283     [ ?dummy-stack-params ]
 284     [ ?dummy-fp-params ]
 285     tri ;
 286
 287 M: float-regs inc-reg-class
 288     [ reg-class-variable inc ]
 289     [ ?dummy-stack-params ]
 290     [ ?dummy-int-params ]
 291     tri ;
 292
 293 GENERIC: reg-class-full? ( class -- ? )
 294
 295 M: stack-params reg-class-full? drop t ;
 296
 297 M: object reg-class-full?
 298     [ reg-class-variable get ] [ param-regs length ] bi >= ;
 299
 300 : spill-param ( reg-class -- n reg-class )
 301     stack-params get
 302     [ reg-size cell align stack-params +@ ] dip
 303     stack-params ;
 304
 305 : fastcall-param ( reg-class -- n reg-class )
 306     [ reg-class-variable get ] [ inc-reg-class ] [ ] tri ;
 307
 308 : alloc-parameter ( parameter -- reg reg-class )
 309     c-type-reg-class dup reg-class-full?
 310     [ spill-param ] [ fastcall-param ] if
 311     [ param-reg ] keep ;
 312
 313 : (flatten-int-type) ( size -- seq )
 314     cell /i "void*" c-type <repetition> ;
 315
 316 GENERIC: flatten-value-type ( type -- types )
 317
 318 M: object flatten-value-type 1array ;
 319
 320 M: struct-type flatten-value-type ( type -- types )
 321     stack-size cell align (flatten-int-type) ;
 322
 323 M: long-long-type flatten-value-type ( type -- types )
 324     stack-size cell align (flatten-int-type) ;
 325
 326 : flatten-value-types ( params -- params )
 327     #! Convert value type structs to consecutive void*s.
 328     [
 329         0 [
 330             c-type
 331             [ parameter-align (flatten-int-type) % ] keep
 332             [ stack-size cell align + ] keep
 333             flatten-value-type %
 334         ] reduce drop
 335     ] { } make ;
 336
 337 : each-parameter ( parameters quot -- )
 338     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 339
 340 : reverse-each-parameter ( parameters quot -- )
 341     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 342
 343 : reset-freg-counts ( -- )
 344     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 345
 346 : with-param-regs ( quot -- )
 347     #! In quot you can call alloc-parameter
 348     [ reset-freg-counts call ] with-scope ; inline
 349
 350 : move-parameters ( node word -- )
 351     #! Moves values from C stack to registers (if word is
 352     #! %load-param-reg) and registers to C stack (if word is
 353     #! %save-param-reg).
 354     [ alien-parameters flatten-value-types ]
 355     [ '[ alloc-parameter _ execute ] ]
 356     bi* each-parameter ; inline
 357
 358 : unbox-parameters ( offset node -- )
 359     parameters>> [
 360         %prepare-unbox [ over + ] dip unbox-parameter
 361     ] reverse-each-parameter drop ;
 362
 363 : prepare-box-struct ( node -- offset )
 364     #! Return offset on C stack where to store unboxed
 365     #! parameters. If the C function is returning a structure,
 366     #! the first parameter is an implicit target area pointer,
 367     #! so we need to use a different offset.
 368     return>> large-struct?
 369     [ %prepare-box-struct cell ] [ 0 ] if ;
 370
 371 : objects>registers ( params -- )
 372     #! Generate code for unboxing a list of C types, then
 373     #! generate code for moving these parameters to registers on
 374     #! architectures where parameters are passed in registers.
 375     [
 376         [ prepare-box-struct ] keep
 377         [ unbox-parameters ] keep
 378         \ %load-param-reg move-parameters
 379     ] with-param-regs ;
 380
 381 : box-return* ( node -- )
 382     return>> [ ] [ box-return ] if-void ;
 383
 384 : check-dlsym ( symbols dll -- )
 385     dup dll-valid? [
 386         dupd '[ _ dlsym ] any?
 387         [ drop ] [ compiling-word get no-such-symbol ] if
 388     ] [
 389         dll-path compiling-word get no-such-library drop
 390     ] if ;
 391
 392 : stdcall-mangle ( symbol params -- symbol )
 393     parameters>> parameter-sizes drop number>string "@" glue ;
 394
 395 : alien-invoke-dlsym ( params -- symbols dll )
 396     [ [ function>> dup ] keep stdcall-mangle 2array ]
 397     [ library>> library dup [ dll>> ] when ]
 398     bi 2dup check-dlsym ;
 399
 400 M: ##alien-invoke generate-insn
 401     params>>
 402     ! Save registers for GC
 403     %prepare-alien-invoke
 404     ! Unbox parameters
 405     dup objects>registers
 406     %prepare-var-args
 407     ! Call function
 408     dup alien-invoke-dlsym %alien-invoke
 409     ! Box return value
 410     dup %cleanup
 411     box-return* ;
 412
 413 ! ##alien-indirect
 414 M: ##alien-indirect generate-insn
 415     params>>
 416     ! Save registers for GC
 417     %prepare-alien-invoke
 418     ! Save alien at top of stack to temporary storage
 419     %prepare-alien-indirect
 420     ! Unbox parameters
 421     dup objects>registers
 422     %prepare-var-args
 423     ! Call alien in temporary storage
 424     %alien-indirect
 425     ! Box return value
 426     dup %cleanup
 427     box-return* ;
 428
 429 ! ##alien-callback
 430 : box-parameters ( params -- )
 431     alien-parameters [ box-parameter ] each-parameter ;
 432
 433 : registers>objects ( node -- )
 434     [
 435         dup \ %save-param-reg move-parameters
 436         "nest_stacks" f %alien-invoke
 437         box-parameters
 438     ] with-param-regs ;
 439
 440 TUPLE: callback-context ;
 441
 442 : current-callback ( -- id ) 2 getenv ;
 443
 444 : wait-to-return ( token -- )
 445     dup current-callback eq? [
 446         drop
 447     ] [
 448         yield-hook get call( -- ) wait-to-return
 449     ] if ;
 450
 451 : do-callback ( quot token -- )
 452     init-catchstack
 453     [ 2 setenv call ] keep
 454     wait-to-return ; inline
 455
 456 : callback-return-quot ( ctype -- quot )
 457     return>> {
 458         { [ dup "void" = ] [ drop [ ] ] }
 459         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 460         [ c-type c-type-unboxer-quot ]
 461     } cond ;
 462
 463 : callback-prep-quot ( params -- quot )
 464     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 465
 466 : wrap-callback-quot ( params -- quot )
 467     [
 468         [ callback-prep-quot ]
 469         [ quot>> ]
 470         [ callback-return-quot ] tri 3append ,
 471         [ callback-context new do-callback ] %
 472     ] [ ] make ;
 473
 474 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 475
 476 M: ##callback-return generate-insn
 477     #! All the extra book-keeping for %unwind is only for x86.
 478     #! On other platforms its an alias for %return.
 479     params>> %callback-return ;
 480
 481 M: ##alien-callback generate-insn
 482     params>>
 483     [ registers>objects ]
 484     [ wrap-callback-quot %alien-callback ]
 485     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 486     tri ;
 487
 488 M: _prologue generate-insn
 489     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 490
 491 M: _epilogue generate-insn
 492     stack-frame>> total-size>> %epilogue ;
 493
 494 M: _label generate-insn
 495     id>> lookup-label resolve-label ;
 496
 497 M: _branch generate-insn
 498     label>> lookup-label %jump-label ;
 499
 500 : >compare< ( insn -- dst temp cc src1 src2 )
 501     {
 502         [ dst>> ]
 503         [ temp>> ]
 504         [ cc>> ]
 505         [ src1>> ]
 506         [ src2>> ]
 507     } cleave ; inline
 508
 509 M: ##compare generate-insn >compare< %compare ;
 510 M: ##compare-imm generate-insn >compare< %compare-imm ;
 511 M: ##compare-float generate-insn >compare< %compare-float ;
 512
 513 : >binary-branch< ( insn -- label cc src1 src2 )
 514     {
 515         [ label>> lookup-label ]
 516         [ cc>> ]
 517         [ src1>> ]
 518         [ src2>> ]
 519     } cleave ; inline
 520
 521 M: _compare-branch generate-insn
 522     >binary-branch< %compare-branch ;
 523
 524 M: _compare-imm-branch generate-insn
 525     >binary-branch< %compare-imm-branch ;
 526
 527 M: _compare-float-branch generate-insn
 528     >binary-branch< %compare-float-branch ;
 529
 530 M: _spill generate-insn
 531     [ src>> ] [ n>> ] [ class>> ] tri {
 532         { int-regs [ %spill-integer ] }
 533         { double-float-regs [ %spill-float ] }
 534     } case ;
 535
 536 M: _reload generate-insn
 537     [ dst>> ] [ n>> ] [ class>> ] tri {
 538         { int-regs [ %reload-integer ] }
 539         { double-float-regs [ %reload-float ] }
 540     } case ;
 541
 542 M: _copy generate-insn
 543     [ dst>> ] [ src>> ] [ class>> ] tri {
 544         { int-regs [ %copy ] }
 545         { double-float-regs [ %copy-float ] }
 546     } case ;
 547
 548 M: _spill-counts generate-insn drop ;