basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors slots parser generic.parser
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 ! Special cases
  71 M: ##no-tco generate-insn drop ;
  72
  73 M: ##call generate-insn
  74     word>> dup sub-primitive>>
  75     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  76
  77 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  78
  79 M: _dispatch-label generate-insn
  80     label>> lookup-label
  81     cell 0 <repetition> %
  82     rc-absolute-cell label-fixup ;
  83
  84 M: _prologue generate-insn
  85     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  86
  87 M: _epilogue generate-insn
  88     stack-frame>> total-size>> %epilogue ;
  89
  90 M: _spill-area-size generate-insn drop ;
  91
  92 ! Some meta-programming to generate simple code generators, where
  93 ! the instruction is unpacked and then a %word is called
  94 <<
  95
  96 : insn-slot-quot ( spec -- quot )
  97     name>> [ reader-word ] [ "label" = ] bi
  98     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
  99
 100 : codegen-method-body ( class word -- quot )
 101     [
 102         "insn-slots" word-prop
 103         [ insn-slot-quot ] map
 104     ] dip
 105     '[ _ cleave _ execute ] ;
 106
 107 SYNTAX: CODEGEN:
 108     scan-word [ \ generate-insn create-method-in ] keep scan-word
 109     codegen-method-body define ;
 110 >>
 111
 112 CODEGEN: ##load-immediate %load-immediate
 113 CODEGEN: ##load-reference %load-reference
 114 CODEGEN: ##peek %peek
 115 CODEGEN: ##replace %replace
 116 CODEGEN: ##inc-d %inc-d
 117 CODEGEN: ##inc-r %inc-r
 118 CODEGEN: ##return %return
 119 CODEGEN: ##slot %slot
 120 CODEGEN: ##slot-imm %slot-imm
 121 CODEGEN: ##set-slot %set-slot
 122 CODEGEN: ##set-slot-imm %set-slot-imm
 123 CODEGEN: ##string-nth %string-nth
 124 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 125 CODEGEN: ##add %add
 126 CODEGEN: ##add-imm %add-imm
 127 CODEGEN: ##sub %sub
 128 CODEGEN: ##sub-imm %sub-imm
 129 CODEGEN: ##mul %mul
 130 CODEGEN: ##mul-imm %mul-imm
 131 CODEGEN: ##and %and
 132 CODEGEN: ##and-imm %and-imm
 133 CODEGEN: ##or %or
 134 CODEGEN: ##or-imm %or-imm
 135 CODEGEN: ##xor %xor
 136 CODEGEN: ##xor-imm %xor-imm
 137 CODEGEN: ##shl %shl
 138 CODEGEN: ##shl-imm %shl-imm
 139 CODEGEN: ##shr %shr
 140 CODEGEN: ##shr-imm %shr-imm
 141 CODEGEN: ##sar %sar
 142 CODEGEN: ##sar-imm %sar-imm
 143 CODEGEN: ##min %min
 144 CODEGEN: ##max %max
 145 CODEGEN: ##not %not
 146 CODEGEN: ##log2 %log2
 147 CODEGEN: ##integer>bignum %integer>bignum
 148 CODEGEN: ##bignum>integer %bignum>integer
 149 CODEGEN: ##add-float %add-float
 150 CODEGEN: ##sub-float %sub-float
 151 CODEGEN: ##mul-float %mul-float
 152 CODEGEN: ##div-float %div-float
 153 CODEGEN: ##min-float %min-float
 154 CODEGEN: ##max-float %max-float
 155 CODEGEN: ##sqrt %sqrt
 156 CODEGEN: ##unary-float-function %unary-float-function
 157 CODEGEN: ##binary-float-function %binary-float-function
 158 CODEGEN: ##integer>float %integer>float
 159 CODEGEN: ##float>integer %float>integer
 160 CODEGEN: ##copy %copy
 161 CODEGEN: ##unbox-float %unbox-float
 162 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 163 CODEGEN: ##box-float %box-float
 164 CODEGEN: ##box-alien %box-alien
 165 CODEGEN: ##box-displaced-alien %box-displaced-alien
 166 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 167 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 168 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 169 CODEGEN: ##alien-signed-1 %alien-signed-1
 170 CODEGEN: ##alien-signed-2 %alien-signed-2
 171 CODEGEN: ##alien-signed-4 %alien-signed-4
 172 CODEGEN: ##alien-cell %alien-cell
 173 CODEGEN: ##alien-float %alien-float
 174 CODEGEN: ##alien-double %alien-double
 175 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 176 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 177 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 178 CODEGEN: ##set-alien-cell %set-alien-cell
 179 CODEGEN: ##set-alien-float %set-alien-float
 180 CODEGEN: ##set-alien-double %set-alien-double
 181 CODEGEN: ##allot %allot
 182 CODEGEN: ##write-barrier %write-barrier
 183 CODEGEN: ##compare %compare
 184 CODEGEN: ##compare-imm %compare-imm
 185 CODEGEN: ##compare-float %compare-float
 186
 187 CODEGEN: _fixnum-add %fixnum-add
 188 CODEGEN: _fixnum-sub %fixnum-sub
 189 CODEGEN: _fixnum-mul %fixnum-mul
 190 CODEGEN: _label resolve-label
 191 CODEGEN: _branch %jump-label
 192 CODEGEN: _compare-branch %compare-branch
 193 CODEGEN: _compare-imm-branch %compare-imm-branch
 194 CODEGEN: _compare-float-branch %compare-float-branch
 195 CODEGEN: _dispatch %dispatch
 196 CODEGEN: _spill %spill
 197 CODEGEN: _reload %reload
 198
 199 ! ##gc
 200 : wipe-locs ( locs temp -- )
 201     '[
 202         _
 203         [ 0 %load-immediate ]
 204         [ swap [ %replace ] with each ] bi
 205     ] unless-empty ;
 206
 207 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 208
 209 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 210     temp int-rep operand n>> %reload
 211     gc-root temp %save-gc-root ;
 212
 213 M: object save-gc-root drop %save-gc-root ;
 214
 215 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 216
 217 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 218
 219 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 220
 221 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 222     gc-root temp %load-gc-root
 223     temp int-rep operand n>> %spill ;
 224
 225 M: object load-gc-root drop %load-gc-root ;
 226
 227 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 228
 229 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 230
 231 M: _gc generate-insn
 232     "no-gc" define-label
 233     {
 234         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 235         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 236         [ data-values>> save-data-regs ]
 237         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 238         [ tagged-values>> length %call-gc ]
 239         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 240         [ data-values>> load-data-regs ]
 241     } cleave
 242     "no-gc" resolve-label ;
 243
 244 M: _loop-entry generate-insn drop %loop-entry ;
 245
 246 M: ##alien-global generate-insn
 247     [ dst>> ] [ symbol>> ] [ library>> ] tri
 248     %alien-global ;
 249
 250 ! ##alien-invoke
 251 GENERIC: next-fastcall-param ( rep -- )
 252
 253 : ?dummy-stack-params ( rep -- )
 254     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 255
 256 : ?dummy-int-params ( rep -- )
 257     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 258
 259 : ?dummy-fp-params ( rep -- )
 260     drop dummy-fp-params? [ float-regs inc ] when ;
 261
 262 M: int-rep next-fastcall-param
 263     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 264
 265 M: single-float-rep next-fastcall-param
 266     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 267
 268 M: double-float-rep next-fastcall-param
 269     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 270
 271 GENERIC: reg-class-full? ( reg-class -- ? )
 272
 273 M: stack-params reg-class-full? drop t ;
 274
 275 M: reg-class reg-class-full?
 276     [ get ] [ param-regs length ] bi >= ;
 277
 278 : alloc-stack-param ( rep -- n reg-class rep )
 279     stack-params get
 280     [ rep-size cell align stack-params +@ ] dip
 281     stack-params dup ;
 282
 283 : alloc-fastcall-param ( rep -- n reg-class rep )
 284     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 285
 286 : alloc-parameter ( parameter -- reg rep )
 287     c-type-rep dup reg-class-of reg-class-full?
 288     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 289     [ param-reg ] dip ;
 290
 291 : (flatten-int-type) ( size -- seq )
 292     cell /i "void*" c-type <repetition> ;
 293
 294 GENERIC: flatten-value-type ( type -- types )
 295
 296 M: object flatten-value-type 1array ;
 297
 298 M: struct-type flatten-value-type ( type -- types )
 299     stack-size cell align (flatten-int-type) ;
 300
 301 M: long-long-type flatten-value-type ( type -- types )
 302     stack-size cell align (flatten-int-type) ;
 303
 304 : flatten-value-types ( params -- params )
 305     #! Convert value type structs to consecutive void*s.
 306     [
 307         0 [
 308             c-type
 309             [ parameter-align (flatten-int-type) % ] keep
 310             [ stack-size cell align + ] keep
 311             flatten-value-type %
 312         ] reduce drop
 313     ] { } make ;
 314
 315 : each-parameter ( parameters quot -- )
 316     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 317
 318 : reverse-each-parameter ( parameters quot -- )
 319     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 320
 321 : reset-fastcall-counts ( -- )
 322     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 323
 324 : with-param-regs ( quot -- )
 325     #! In quot you can call alloc-parameter
 326     [ reset-fastcall-counts call ] with-scope ; inline
 327
 328 : move-parameters ( node word -- )
 329     #! Moves values from C stack to registers (if word is
 330     #! %load-param-reg) and registers to C stack (if word is
 331     #! %save-param-reg).
 332     [ alien-parameters flatten-value-types ]
 333     [ '[ alloc-parameter _ execute ] ]
 334     bi* each-parameter ; inline
 335
 336 : unbox-parameters ( offset node -- )
 337     parameters>> [
 338         %prepare-unbox [ over + ] dip unbox-parameter
 339     ] reverse-each-parameter drop ;
 340
 341 : prepare-box-struct ( node -- offset )
 342     #! Return offset on C stack where to store unboxed
 343     #! parameters. If the C function is returning a structure,
 344     #! the first parameter is an implicit target area pointer,
 345     #! so we need to use a different offset.
 346     return>> large-struct?
 347     [ %prepare-box-struct cell ] [ 0 ] if ;
 348
 349 : objects>registers ( params -- )
 350     #! Generate code for unboxing a list of C types, then
 351     #! generate code for moving these parameters to registers on
 352     #! architectures where parameters are passed in registers.
 353     [
 354         [ prepare-box-struct ] keep
 355         [ unbox-parameters ] keep
 356         \ %load-param-reg move-parameters
 357     ] with-param-regs ;
 358
 359 : box-return* ( node -- )
 360     return>> [ ] [ box-return ] if-void ;
 361
 362 : check-dlsym ( symbols dll -- )
 363     dup dll-valid? [
 364         dupd '[ _ dlsym ] any?
 365         [ drop ] [ compiling-word get no-such-symbol ] if
 366     ] [
 367         dll-path compiling-word get no-such-library drop
 368     ] if ;
 369
 370 : stdcall-mangle ( symbol params -- symbol )
 371     parameters>> parameter-sizes drop number>string "@" glue ;
 372
 373 : alien-invoke-dlsym ( params -- symbols dll )
 374     [ [ function>> dup ] keep stdcall-mangle 2array ]
 375     [ library>> library dup [ dll>> ] when ]
 376     bi 2dup check-dlsym ;
 377
 378 M: ##alien-invoke generate-insn
 379     params>>
 380     ! Save registers for GC
 381     %prepare-alien-invoke
 382     ! Unbox parameters
 383     dup objects>registers
 384     %prepare-var-args
 385     ! Call function
 386     dup alien-invoke-dlsym %alien-invoke
 387     ! Box return value
 388     dup %cleanup
 389     box-return* ;
 390
 391 ! ##alien-indirect
 392 M: ##alien-indirect generate-insn
 393     params>>
 394     ! Save registers for GC
 395     %prepare-alien-invoke
 396     ! Save alien at top of stack to temporary storage
 397     %prepare-alien-indirect
 398     ! Unbox parameters
 399     dup objects>registers
 400     %prepare-var-args
 401     ! Call alien in temporary storage
 402     %alien-indirect
 403     ! Box return value
 404     dup %cleanup
 405     box-return* ;
 406
 407 ! ##alien-callback
 408 : box-parameters ( params -- )
 409     alien-parameters [ box-parameter ] each-parameter ;
 410
 411 : registers>objects ( node -- )
 412     ! Generate code for boxing input parameters in a callback.
 413     [
 414         dup \ %save-param-reg move-parameters
 415         "nest_stacks" f %alien-invoke
 416         box-parameters
 417     ] with-param-regs ;
 418
 419 TUPLE: callback-context ;
 420
 421 : current-callback ( -- id ) 2 getenv ;
 422
 423 : wait-to-return ( token -- )
 424     dup current-callback eq? [
 425         drop
 426     ] [
 427         yield-hook get call( -- ) wait-to-return
 428     ] if ;
 429
 430 : do-callback ( quot token -- )
 431     init-catchstack
 432     [ 2 setenv call ] keep
 433     wait-to-return ; inline
 434
 435 : callback-return-quot ( ctype -- quot )
 436     return>> {
 437         { [ dup "void" = ] [ drop [ ] ] }
 438         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 439         [ c-type c-type-unboxer-quot ]
 440     } cond ;
 441
 442 : callback-prep-quot ( params -- quot )
 443     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 444
 445 : wrap-callback-quot ( params -- quot )
 446     [
 447         [ callback-prep-quot ]
 448         [ quot>> ]
 449         [ callback-return-quot ] tri 3append ,
 450         [ callback-context new do-callback ] %
 451     ] [ ] make ;
 452
 453 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 454
 455 M: ##callback-return generate-insn
 456     #! All the extra book-keeping for %unwind is only for x86.
 457     #! On other platforms its an alias for %return.
 458     params>> %callback-return ;
 459
 460 M: ##alien-callback generate-insn
 461     params>>
 462     [ registers>objects ]
 463     [ wrap-callback-quot %alien-callback ]
 464     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 465     tri ;