basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> ] [ temp>> ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     { [ dst>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 106
 107 M: ##slot generate-insn
 108     [ >slot< ] [ temp>> ] bi %slot ;
 109
 110 M: ##slot-imm generate-insn
 111     >slot< %slot-imm ;
 112
 113 : >set-slot< ( insn -- src obj slot tag )
 114     { [ src>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 115
 116 M: ##set-slot generate-insn
 117     [ >set-slot< ] [ temp>> ] bi %set-slot ;
 118
 119 M: ##set-slot-imm generate-insn
 120     >set-slot< %set-slot-imm ;
 121
 122 M: ##string-nth generate-insn
 123     { [ dst>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %string-nth ;
 124
 125 M: ##set-string-nth-fast generate-insn
 126     { [ src>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %set-string-nth-fast ;
 127
 128 : dst/src ( insn -- dst src )
 129     [ dst>> ] [ src>> ] bi ; inline
 130
 131 : dst/src1/src2 ( insn -- dst src1 src2 )
 132     [ dst>> ] [ src1>> ] [ src2>> ] tri ; inline
 133
 134 M: ##add     generate-insn dst/src1/src2 %add     ;
 135 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 136 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 137 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 138 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 139 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 140 M: ##and     generate-insn dst/src1/src2 %and     ;
 141 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 142 M: ##or      generate-insn dst/src1/src2 %or      ;
 143 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 144 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 145 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 146 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 147 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 148 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 149 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 150 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 151 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 152 M: ##not     generate-insn dst/src       %not     ;
 153 M: ##log2    generate-insn dst/src       %log2    ;
 154
 155 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 156     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 157
 158 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 159 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 160 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 161
 162 : dst/src/temp ( insn -- dst src temp )
 163     [ dst/src ] [ temp>> ] bi ; inline
 164
 165 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 166 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 167
 168 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 169 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 170 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 171 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 172
 173 M: ##integer>float generate-insn dst/src %integer>float ;
 174 M: ##float>integer generate-insn dst/src %float>integer ;
 175
 176 M: ##copy             generate-insn dst/src %copy ;
 177 M: ##copy-float       generate-insn dst/src %copy-float ;
 178 M: ##unbox-float      generate-insn dst/src %unbox-float ;
 179 M: ##unbox-any-c-ptr  generate-insn dst/src/temp %unbox-any-c-ptr ;
 180 M: ##box-float        generate-insn dst/src/temp %box-float ;
 181 M: ##box-alien        generate-insn dst/src/temp %box-alien ;
 182
 183 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 184 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 185 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 186 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 187 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 188 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 189 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 190 M: ##alien-float      generate-insn dst/src %alien-float      ;
 191 M: ##alien-double     generate-insn dst/src %alien-double     ;
 192
 193 : >alien-setter< ( insn -- src value )
 194     [ src>> ] [ value>> ] bi ; inline
 195
 196 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 197 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 198 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 199 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 200 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 201 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 202
 203 M: ##allot generate-insn
 204     {
 205         [ dst>> ]
 206         [ size>> ]
 207         [ class>> ]
 208         [ temp>> ]
 209     } cleave
 210     %allot ;
 211
 212 M: ##write-barrier generate-insn
 213     [ src>> ]
 214     [ card#>> ]
 215     [ table>> ]
 216     tri %write-barrier ;
 217
 218 M: _gc generate-insn
 219     {
 220         [ temp1>> ]
 221         [ temp2>> ]
 222         [ gc-roots>> ]
 223         [ gc-root-count>> ]
 224     } cleave %gc ;
 225
 226 M: _loop-entry generate-insn drop %loop-entry ;
 227
 228 M: ##alien-global generate-insn
 229     [ dst>> ] [ symbol>> ] [ library>> ] tri
 230     %alien-global ;
 231
 232 ! ##alien-invoke
 233 GENERIC: reg-class-variable ( register-class -- symbol )
 234
 235 M: reg-class reg-class-variable ;
 236
 237 M: float-regs reg-class-variable drop float-regs ;
 238
 239 GENERIC: inc-reg-class ( register-class -- )
 240
 241 : ?dummy-stack-params ( reg-class -- )
 242     dummy-stack-params? [ reg-size cell align stack-params +@ ] [ drop ] if ;
 243
 244 : ?dummy-int-params ( reg-class -- )
 245     dummy-int-params? [ reg-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 246
 247 : ?dummy-fp-params ( reg-class -- )
 248     drop dummy-fp-params? [ float-regs inc ] when ;
 249
 250 M: int-regs inc-reg-class
 251     [ reg-class-variable inc ]
 252     [ ?dummy-stack-params ]
 253     [ ?dummy-fp-params ]
 254     tri ;
 255
 256 M: float-regs inc-reg-class
 257     [ reg-class-variable inc ]
 258     [ ?dummy-stack-params ]
 259     [ ?dummy-int-params ]
 260     tri ;
 261
 262 GENERIC: reg-class-full? ( class -- ? )
 263
 264 M: stack-params reg-class-full? drop t ;
 265
 266 M: object reg-class-full?
 267     [ reg-class-variable get ] [ param-regs length ] bi >= ;
 268
 269 : spill-param ( reg-class -- n reg-class )
 270     stack-params get
 271     [ reg-size cell align stack-params +@ ] dip
 272     stack-params ;
 273
 274 : fastcall-param ( reg-class -- n reg-class )
 275     [ reg-class-variable get ] [ inc-reg-class ] [ ] tri ;
 276
 277 : alloc-parameter ( parameter -- reg reg-class )
 278     c-type-reg-class dup reg-class-full?
 279     [ spill-param ] [ fastcall-param ] if
 280     [ param-reg ] keep ;
 281
 282 : (flatten-int-type) ( size -- seq )
 283     cell /i "void*" c-type <repetition> ;
 284
 285 GENERIC: flatten-value-type ( type -- types )
 286
 287 M: object flatten-value-type 1array ;
 288
 289 M: struct-type flatten-value-type ( type -- types )
 290     stack-size cell align (flatten-int-type) ;
 291
 292 M: long-long-type flatten-value-type ( type -- types )
 293     stack-size cell align (flatten-int-type) ;
 294
 295 : flatten-value-types ( params -- params )
 296     #! Convert value type structs to consecutive void*s.
 297     [
 298         0 [
 299             c-type
 300             [ parameter-align (flatten-int-type) % ] keep
 301             [ stack-size cell align + ] keep
 302             flatten-value-type %
 303         ] reduce drop
 304     ] { } make ;
 305
 306 : each-parameter ( parameters quot -- )
 307     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 308
 309 : reverse-each-parameter ( parameters quot -- )
 310     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 311
 312 : reset-freg-counts ( -- )
 313     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 314
 315 : with-param-regs ( quot -- )
 316     #! In quot you can call alloc-parameter
 317     [ reset-freg-counts call ] with-scope ; inline
 318
 319 : move-parameters ( node word -- )
 320     #! Moves values from C stack to registers (if word is
 321     #! %load-param-reg) and registers to C stack (if word is
 322     #! %save-param-reg).
 323     [ alien-parameters flatten-value-types ]
 324     [ '[ alloc-parameter _ execute ] ]
 325     bi* each-parameter ; inline
 326
 327 : unbox-parameters ( offset node -- )
 328     parameters>> [
 329         %prepare-unbox [ over + ] dip unbox-parameter
 330     ] reverse-each-parameter drop ;
 331
 332 : prepare-box-struct ( node -- offset )
 333     #! Return offset on C stack where to store unboxed
 334     #! parameters. If the C function is returning a structure,
 335     #! the first parameter is an implicit target area pointer,
 336     #! so we need to use a different offset.
 337     return>> large-struct?
 338     [ %prepare-box-struct cell ] [ 0 ] if ;
 339
 340 : objects>registers ( params -- )
 341     #! Generate code for unboxing a list of C types, then
 342     #! generate code for moving these parameters to registers on
 343     #! architectures where parameters are passed in registers.
 344     [
 345         [ prepare-box-struct ] keep
 346         [ unbox-parameters ] keep
 347         \ %load-param-reg move-parameters
 348     ] with-param-regs ;
 349
 350 : box-return* ( node -- )
 351     return>> [ ] [ box-return ] if-void ;
 352
 353 : check-dlsym ( symbols dll -- )
 354     dup dll-valid? [
 355         dupd '[ _ dlsym ] any?
 356         [ drop ] [ compiling-word get no-such-symbol ] if
 357     ] [
 358         dll-path compiling-word get no-such-library drop
 359     ] if ;
 360
 361 : stdcall-mangle ( symbol params -- symbol )
 362     parameters>> parameter-sizes drop number>string "@" glue ;
 363
 364 : alien-invoke-dlsym ( params -- symbols dll )
 365     [ [ function>> dup ] keep stdcall-mangle 2array ]
 366     [ library>> library dup [ dll>> ] when ]
 367     bi 2dup check-dlsym ;
 368
 369 M: ##alien-invoke generate-insn
 370     params>>
 371     ! Save registers for GC
 372     %prepare-alien-invoke
 373     ! Unbox parameters
 374     dup objects>registers
 375     %prepare-var-args
 376     ! Call function
 377     dup alien-invoke-dlsym %alien-invoke
 378     ! Box return value
 379     dup %cleanup
 380     box-return* ;
 381
 382 ! ##alien-indirect
 383 M: ##alien-indirect generate-insn
 384     params>>
 385     ! Save registers for GC
 386     %prepare-alien-invoke
 387     ! Save alien at top of stack to temporary storage
 388     %prepare-alien-indirect
 389     ! Unbox parameters
 390     dup objects>registers
 391     %prepare-var-args
 392     ! Call alien in temporary storage
 393     %alien-indirect
 394     ! Box return value
 395     dup %cleanup
 396     box-return* ;
 397
 398 ! ##alien-callback
 399 : box-parameters ( params -- )
 400     alien-parameters [ box-parameter ] each-parameter ;
 401
 402 : registers>objects ( node -- )
 403     [
 404         dup \ %save-param-reg move-parameters
 405         "nest_stacks" f %alien-invoke
 406         box-parameters
 407     ] with-param-regs ;
 408
 409 TUPLE: callback-context ;
 410
 411 : current-callback ( -- id ) 2 getenv ;
 412
 413 : wait-to-return ( token -- )
 414     dup current-callback eq? [
 415         drop
 416     ] [
 417         yield-hook get call( -- ) wait-to-return
 418     ] if ;
 419
 420 : do-callback ( quot token -- )
 421     init-catchstack
 422     [ 2 setenv call ] keep
 423     wait-to-return ; inline
 424
 425 : callback-return-quot ( ctype -- quot )
 426     return>> {
 427         { [ dup "void" = ] [ drop [ ] ] }
 428         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 429         [ c-type c-type-unboxer-quot ]
 430     } cond ;
 431
 432 : callback-prep-quot ( params -- quot )
 433     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 434
 435 : wrap-callback-quot ( params -- quot )
 436     [
 437         [ callback-prep-quot ]
 438         [ quot>> ]
 439         [ callback-return-quot ] tri 3append ,
 440         [ callback-context new do-callback ] %
 441     ] [ ] make ;
 442
 443 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 444
 445 M: ##callback-return generate-insn
 446     #! All the extra book-keeping for %unwind is only for x86.
 447     #! On other platforms its an alias for %return.
 448     params>> %callback-return ;
 449
 450 M: ##alien-callback generate-insn
 451     params>>
 452     [ registers>objects ]
 453     [ wrap-callback-quot %alien-callback ]
 454     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 455     tri ;
 456
 457 M: _prologue generate-insn
 458     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 459
 460 M: _epilogue generate-insn
 461     stack-frame>> total-size>> %epilogue ;
 462
 463 M: _label generate-insn
 464     id>> lookup-label resolve-label ;
 465
 466 M: _branch generate-insn
 467     label>> lookup-label %jump-label ;
 468
 469 : >compare< ( insn -- dst temp cc src1 src2 )
 470     {
 471         [ dst>> ]
 472         [ temp>> ]
 473         [ cc>> ]
 474         [ src1>> ]
 475         [ src2>> ]
 476     } cleave ; inline
 477
 478 M: ##compare generate-insn >compare< %compare ;
 479 M: ##compare-imm generate-insn >compare< %compare-imm ;
 480 M: ##compare-float generate-insn >compare< %compare-float ;
 481
 482 : >binary-branch< ( insn -- label cc src1 src2 )
 483     {
 484         [ label>> lookup-label ]
 485         [ cc>> ]
 486         [ src1>> ]
 487         [ src2>> ]
 488     } cleave ; inline
 489
 490 M: _compare-branch generate-insn
 491     >binary-branch< %compare-branch ;
 492
 493 M: _compare-imm-branch generate-insn
 494     >binary-branch< %compare-imm-branch ;
 495
 496 M: _compare-float-branch generate-insn
 497     >binary-branch< %compare-float-branch ;
 498
 499 M: _spill generate-insn
 500     [ src>> ] [ n>> ] [ class>> ] tri {
 501         { int-regs [ %spill-integer ] }
 502         { double-float-regs [ %spill-float ] }
 503     } case ;
 504
 505 M: _reload generate-insn
 506     [ dst>> ] [ n>> ] [ class>> ] tri {
 507         { int-regs [ %reload-integer ] }
 508         { double-float-regs [ %reload-float ] }
 509     } case ;
 510
 511 M: _copy generate-insn
 512     [ dst>> ] [ src>> ] [ class>> ] tri {
 513         { int-regs [ %copy ] }
 514         { double-float-regs [ %copy-float ] }
 515     } case ;
 516
 517 M: _spill-counts generate-insn drop ;