basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> ] [ temp>> ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     { [ dst>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 106
 107 M: ##slot generate-insn
 108     [ >slot< ] [ temp>> ] bi %slot ;
 109
 110 M: ##slot-imm generate-insn
 111     >slot< %slot-imm ;
 112
 113 : >set-slot< ( insn -- src obj slot tag )
 114     { [ src>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 115
 116 M: ##set-slot generate-insn
 117     [ >set-slot< ] [ temp>> ] bi %set-slot ;
 118
 119 M: ##set-slot-imm generate-insn
 120     >set-slot< %set-slot-imm ;
 121
 122 M: ##string-nth generate-insn
 123     { [ dst>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %string-nth ;
 124
 125 M: ##set-string-nth-fast generate-insn
 126     { [ src>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %set-string-nth-fast ;
 127
 128 : dst/src ( insn -- dst src )
 129     [ dst>> ] [ src>> ] bi ; inline
 130
 131 : dst/src1/src2 ( insn -- dst src1 src2 )
 132     [ dst>> ] [ src1>> ] [ src2>> ] tri ; inline
 133
 134 M: ##add     generate-insn dst/src1/src2 %add     ;
 135 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 136 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 137 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 138 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 139 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 140 M: ##and     generate-insn dst/src1/src2 %and     ;
 141 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 142 M: ##or      generate-insn dst/src1/src2 %or      ;
 143 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 144 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 145 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 146 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 147 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 148 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 149 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 150 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 151 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 152 M: ##not     generate-insn dst/src       %not     ;
 153 M: ##log2    generate-insn dst/src       %log2    ;
 154
 155 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 156     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 157
 158 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 159 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 160 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 161
 162 : dst/src/temp ( insn -- dst src temp )
 163     [ dst/src ] [ temp>> ] bi ; inline
 164
 165 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 166 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 167
 168 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 169 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 170 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 171 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 172
 173 M: ##integer>float generate-insn dst/src %integer>float ;
 174 M: ##float>integer generate-insn dst/src %float>integer ;
 175
 176 M: ##copy             generate-insn dst/src %copy ;
 177 M: ##copy-float       generate-insn dst/src %copy-float ;
 178 M: ##unbox-float      generate-insn dst/src %unbox-float ;
 179 M: ##unbox-any-c-ptr  generate-insn dst/src/temp %unbox-any-c-ptr ;
 180 M: ##box-float        generate-insn dst/src/temp %box-float ;
 181 M: ##box-alien        generate-insn dst/src/temp %box-alien ;
 182
 183 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 184 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 185 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 186 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 187 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 188 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 189 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 190 M: ##alien-float      generate-insn dst/src %alien-float      ;
 191 M: ##alien-double     generate-insn dst/src %alien-double     ;
 192
 193 : >alien-setter< ( insn -- src value )
 194     [ src>> ] [ value>> ] bi ; inline
 195
 196 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 197 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 198 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 199 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 200 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 201 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 202
 203 M: ##allot generate-insn
 204     {
 205         [ dst>> ]
 206         [ size>> ]
 207         [ class>> ]
 208         [ temp>> ]
 209     } cleave
 210     %allot ;
 211
 212 M: ##write-barrier generate-insn
 213     [ src>> ]
 214     [ card#>> ]
 215     [ table>> ]
 216     tri %write-barrier ;
 217
 218 M: _gc generate-insn
 219     {
 220         [ temp1>> ]
 221         [ temp2>> ]
 222         [ gc-roots>> ]
 223         [ gc-root-count>> ]
 224         [ uninitialized-locs>> ]
 225     } cleave %gc ;
 226
 227 M: _loop-entry generate-insn drop %loop-entry ;
 228
 229 M: ##alien-global generate-insn
 230     [ dst>> ] [ symbol>> ] [ library>> ] tri
 231     %alien-global ;
 232
 233 ! ##alien-invoke
 234 GENERIC: reg-class-variable ( register-class -- symbol )
 235
 236 M: reg-class reg-class-variable ;
 237
 238 M: float-regs reg-class-variable drop float-regs ;
 239
 240 GENERIC: inc-reg-class ( register-class -- )
 241
 242 : ?dummy-stack-params ( reg-class -- )
 243     dummy-stack-params? [ reg-size cell align stack-params +@ ] [ drop ] if ;
 244
 245 : ?dummy-int-params ( reg-class -- )
 246     dummy-int-params? [ reg-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 247
 248 : ?dummy-fp-params ( reg-class -- )
 249     drop dummy-fp-params? [ float-regs inc ] when ;
 250
 251 M: int-regs inc-reg-class
 252     [ reg-class-variable inc ]
 253     [ ?dummy-stack-params ]
 254     [ ?dummy-fp-params ]
 255     tri ;
 256
 257 M: float-regs inc-reg-class
 258     [ reg-class-variable inc ]
 259     [ ?dummy-stack-params ]
 260     [ ?dummy-int-params ]
 261     tri ;
 262
 263 GENERIC: reg-class-full? ( class -- ? )
 264
 265 M: stack-params reg-class-full? drop t ;
 266
 267 M: object reg-class-full?
 268     [ reg-class-variable get ] [ param-regs length ] bi >= ;
 269
 270 : spill-param ( reg-class -- n reg-class )
 271     stack-params get
 272     [ reg-size cell align stack-params +@ ] dip
 273     stack-params ;
 274
 275 : fastcall-param ( reg-class -- n reg-class )
 276     [ reg-class-variable get ] [ inc-reg-class ] [ ] tri ;
 277
 278 : alloc-parameter ( parameter -- reg reg-class )
 279     c-type-reg-class dup reg-class-full?
 280     [ spill-param ] [ fastcall-param ] if
 281     [ param-reg ] keep ;
 282
 283 : (flatten-int-type) ( size -- seq )
 284     cell /i "void*" c-type <repetition> ;
 285
 286 GENERIC: flatten-value-type ( type -- types )
 287
 288 M: object flatten-value-type 1array ;
 289
 290 M: struct-type flatten-value-type ( type -- types )
 291     stack-size cell align (flatten-int-type) ;
 292
 293 M: long-long-type flatten-value-type ( type -- types )
 294     stack-size cell align (flatten-int-type) ;
 295
 296 : flatten-value-types ( params -- params )
 297     #! Convert value type structs to consecutive void*s.
 298     [
 299         0 [
 300             c-type
 301             [ parameter-align (flatten-int-type) % ] keep
 302             [ stack-size cell align + ] keep
 303             flatten-value-type %
 304         ] reduce drop
 305     ] { } make ;
 306
 307 : each-parameter ( parameters quot -- )
 308     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 309
 310 : reverse-each-parameter ( parameters quot -- )
 311     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 312
 313 : reset-freg-counts ( -- )
 314     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 315
 316 : with-param-regs ( quot -- )
 317     #! In quot you can call alloc-parameter
 318     [ reset-freg-counts call ] with-scope ; inline
 319
 320 : move-parameters ( node word -- )
 321     #! Moves values from C stack to registers (if word is
 322     #! %load-param-reg) and registers to C stack (if word is
 323     #! %save-param-reg).
 324     [ alien-parameters flatten-value-types ]
 325     [ '[ alloc-parameter _ execute ] ]
 326     bi* each-parameter ; inline
 327
 328 : unbox-parameters ( offset node -- )
 329     parameters>> [
 330         %prepare-unbox [ over + ] dip unbox-parameter
 331     ] reverse-each-parameter drop ;
 332
 333 : prepare-box-struct ( node -- offset )
 334     #! Return offset on C stack where to store unboxed
 335     #! parameters. If the C function is returning a structure,
 336     #! the first parameter is an implicit target area pointer,
 337     #! so we need to use a different offset.
 338     return>> large-struct?
 339     [ %prepare-box-struct cell ] [ 0 ] if ;
 340
 341 : objects>registers ( params -- )
 342     #! Generate code for unboxing a list of C types, then
 343     #! generate code for moving these parameters to registers on
 344     #! architectures where parameters are passed in registers.
 345     [
 346         [ prepare-box-struct ] keep
 347         [ unbox-parameters ] keep
 348         \ %load-param-reg move-parameters
 349     ] with-param-regs ;
 350
 351 : box-return* ( node -- )
 352     return>> [ ] [ box-return ] if-void ;
 353
 354 : check-dlsym ( symbols dll -- )
 355     dup dll-valid? [
 356         dupd '[ _ dlsym ] any?
 357         [ drop ] [ compiling-word get no-such-symbol ] if
 358     ] [
 359         dll-path compiling-word get no-such-library drop
 360     ] if ;
 361
 362 : stdcall-mangle ( symbol params -- symbol )
 363     parameters>> parameter-sizes drop number>string "@" glue ;
 364
 365 : alien-invoke-dlsym ( params -- symbols dll )
 366     [ [ function>> dup ] keep stdcall-mangle 2array ]
 367     [ library>> library dup [ dll>> ] when ]
 368     bi 2dup check-dlsym ;
 369
 370 M: ##alien-invoke generate-insn
 371     params>>
 372     ! Save registers for GC
 373     %prepare-alien-invoke
 374     ! Unbox parameters
 375     dup objects>registers
 376     %prepare-var-args
 377     ! Call function
 378     dup alien-invoke-dlsym %alien-invoke
 379     ! Box return value
 380     dup %cleanup
 381     box-return* ;
 382
 383 ! ##alien-indirect
 384 M: ##alien-indirect generate-insn
 385     params>>
 386     ! Save registers for GC
 387     %prepare-alien-invoke
 388     ! Save alien at top of stack to temporary storage
 389     %prepare-alien-indirect
 390     ! Unbox parameters
 391     dup objects>registers
 392     %prepare-var-args
 393     ! Call alien in temporary storage
 394     %alien-indirect
 395     ! Box return value
 396     dup %cleanup
 397     box-return* ;
 398
 399 ! ##alien-callback
 400 : box-parameters ( params -- )
 401     alien-parameters [ box-parameter ] each-parameter ;
 402
 403 : registers>objects ( node -- )
 404     [
 405         dup \ %save-param-reg move-parameters
 406         "nest_stacks" f %alien-invoke
 407         box-parameters
 408     ] with-param-regs ;
 409
 410 TUPLE: callback-context ;
 411
 412 : current-callback ( -- id ) 2 getenv ;
 413
 414 : wait-to-return ( token -- )
 415     dup current-callback eq? [
 416         drop
 417     ] [
 418         yield-hook get call( -- ) wait-to-return
 419     ] if ;
 420
 421 : do-callback ( quot token -- )
 422     init-catchstack
 423     [ 2 setenv call ] keep
 424     wait-to-return ; inline
 425
 426 : callback-return-quot ( ctype -- quot )
 427     return>> {
 428         { [ dup "void" = ] [ drop [ ] ] }
 429         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 430         [ c-type c-type-unboxer-quot ]
 431     } cond ;
 432
 433 : callback-prep-quot ( params -- quot )
 434     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 435
 436 : wrap-callback-quot ( params -- quot )
 437     [
 438         [ callback-prep-quot ]
 439         [ quot>> ]
 440         [ callback-return-quot ] tri 3append ,
 441         [ callback-context new do-callback ] %
 442     ] [ ] make ;
 443
 444 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 445
 446 M: ##callback-return generate-insn
 447     #! All the extra book-keeping for %unwind is only for x86.
 448     #! On other platforms its an alias for %return.
 449     params>> %callback-return ;
 450
 451 M: ##alien-callback generate-insn
 452     params>>
 453     [ registers>objects ]
 454     [ wrap-callback-quot %alien-callback ]
 455     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 456     tri ;
 457
 458 M: _prologue generate-insn
 459     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 460
 461 M: _epilogue generate-insn
 462     stack-frame>> total-size>> %epilogue ;
 463
 464 M: _label generate-insn
 465     id>> lookup-label resolve-label ;
 466
 467 M: _branch generate-insn
 468     label>> lookup-label %jump-label ;
 469
 470 : >compare< ( insn -- dst temp cc src1 src2 )
 471     {
 472         [ dst>> ]
 473         [ temp>> ]
 474         [ cc>> ]
 475         [ src1>> ]
 476         [ src2>> ]
 477     } cleave ; inline
 478
 479 M: ##compare generate-insn >compare< %compare ;
 480 M: ##compare-imm generate-insn >compare< %compare-imm ;
 481 M: ##compare-float generate-insn >compare< %compare-float ;
 482
 483 : >binary-branch< ( insn -- label cc src1 src2 )
 484     {
 485         [ label>> lookup-label ]
 486         [ cc>> ]
 487         [ src1>> ]
 488         [ src2>> ]
 489     } cleave ; inline
 490
 491 M: _compare-branch generate-insn
 492     >binary-branch< %compare-branch ;
 493
 494 M: _compare-imm-branch generate-insn
 495     >binary-branch< %compare-imm-branch ;
 496
 497 M: _compare-float-branch generate-insn
 498     >binary-branch< %compare-float-branch ;
 499
 500 M: _spill generate-insn
 501     [ src>> ] [ n>> ] [ class>> ] tri {
 502         { int-regs [ %spill-integer ] }
 503         { double-float-regs [ %spill-float ] }
 504     } case ;
 505
 506 M: _reload generate-insn
 507     [ dst>> ] [ n>> ] [ class>> ] tri {
 508         { int-regs [ %reload-integer ] }
 509         { double-float-regs [ %reload-float ] }
 510     } case ;
 511
 512 M: _copy generate-insn
 513     [ dst>> ] [ src>> ] [ class>> ] tri {
 514         { int-regs [ %copy ] }
 515         { double-float-regs [ %copy-float ] }
 516     } case ;
 517
 518 M: _spill-counts generate-insn drop ;