basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> ] [ temp>> ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     { [ dst>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 106
 107 M: ##slot generate-insn
 108     [ >slot< ] [ temp>> ] bi %slot ;
 109
 110 M: ##slot-imm generate-insn
 111     >slot< %slot-imm ;
 112
 113 : >set-slot< ( insn -- src obj slot tag )
 114     { [ src>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 115
 116 M: ##set-slot generate-insn
 117     [ >set-slot< ] [ temp>> ] bi %set-slot ;
 118
 119 M: ##set-slot-imm generate-insn
 120     >set-slot< %set-slot-imm ;
 121
 122 M: ##string-nth generate-insn
 123     { [ dst>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %string-nth ;
 124
 125 M: ##set-string-nth-fast generate-insn
 126     { [ src>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %set-string-nth-fast ;
 127
 128 : dst/src ( insn -- dst src )
 129     [ dst>> ] [ src>> ] bi ; inline
 130
 131 : dst/src1/src2 ( insn -- dst src1 src2 )
 132     [ dst>> ] [ src1>> ] [ src2>> ] tri ; inline
 133
 134 M: ##add     generate-insn dst/src1/src2 %add     ;
 135 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 136 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 137 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 138 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 139 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 140 M: ##and     generate-insn dst/src1/src2 %and     ;
 141 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 142 M: ##or      generate-insn dst/src1/src2 %or      ;
 143 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 144 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 145 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 146 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 147 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 148 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 149 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 150 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 151 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 152 M: ##min     generate-insn dst/src1/src2 %min     ;
 153 M: ##max     generate-insn dst/src1/src2 %max     ;
 154 M: ##not     generate-insn dst/src       %not     ;
 155 M: ##log2    generate-insn dst/src       %log2    ;
 156
 157 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 158     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 159
 160 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 161 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 162 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 163
 164 : dst/src/temp ( insn -- dst src temp )
 165     [ dst/src ] [ temp>> ] bi ; inline
 166
 167 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 168 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 169
 170 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 171 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 172 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 173 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 174 M: ##min-float generate-insn dst/src1/src2 %min-float ;
 175 M: ##max-float generate-insn dst/src1/src2 %max-float ;
 176
 177 M: ##sqrt generate-insn dst/src %sqrt ;
 178
 179 M: ##unary-float-function generate-insn
 180     [ dst/src ] [ func>> ] bi %unary-float-function ;
 181
 182 M: ##binary-float-function generate-insn
 183     [ dst/src1/src2 ] [ func>> ] bi %binary-float-function ;
 184
 185 M: ##integer>float generate-insn dst/src %integer>float ;
 186 M: ##float>integer generate-insn dst/src %float>integer ;
 187
 188 M: ##copy generate-insn [ dst/src ] [ rep>> ] bi %copy ;
 189
 190 M: ##unbox-float generate-insn dst/src %unbox-float ;
 191 M: ##unbox-any-c-ptr generate-insn dst/src/temp %unbox-any-c-ptr ;
 192 M: ##box-float generate-insn dst/src/temp %box-float ;
 193 M: ##box-alien generate-insn dst/src/temp %box-alien ;
 194
 195 M: ##box-displaced-alien generate-insn
 196     [ dst/src1/src2 ] [ temp1>> ] [ temp2>> ] tri %box-displaced-alien ;
 197
 198 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 199 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 200 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 201 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 202 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 203 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 204 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 205 M: ##alien-float      generate-insn dst/src %alien-float      ;
 206 M: ##alien-double     generate-insn dst/src %alien-double     ;
 207
 208 : >alien-setter< ( insn -- src value )
 209     [ src>> ] [ value>> ] bi ; inline
 210
 211 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 212 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 213 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 214 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 215 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 216 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 217
 218 M: ##allot generate-insn
 219     {
 220         [ dst>> ]
 221         [ size>> ]
 222         [ class>> ]
 223         [ temp>> ]
 224     } cleave
 225     %allot ;
 226
 227 M: ##write-barrier generate-insn
 228     [ src>> ]
 229     [ card#>> ]
 230     [ table>> ]
 231     tri %write-barrier ;
 232
 233 ! GC checks
 234 : wipe-locs ( locs temp -- )
 235     '[
 236         _
 237         [ 0 %load-immediate ]
 238         [ swap [ %replace ] with each ] bi
 239     ] unless-empty ;
 240
 241 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 242
 243 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 244     temp operand n>> int-rep %reload
 245     gc-root temp %save-gc-root ;
 246
 247 M: object save-gc-root drop %save-gc-root ;
 248
 249 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 250
 251 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 252
 253 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 254
 255 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 256     gc-root temp %load-gc-root
 257     temp operand n>> int-rep %spill ;
 258
 259 M: object load-gc-root drop %load-gc-root ;
 260
 261 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 262
 263 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 264
 265 M: _gc generate-insn
 266     "no-gc" define-label
 267     {
 268         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 269         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 270         [ data-values>> save-data-regs ]
 271         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 272         [ tagged-values>> length %call-gc ]
 273         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 274         [ data-values>> load-data-regs ]
 275     } cleave
 276     "no-gc" resolve-label ;
 277
 278 M: _loop-entry generate-insn drop %loop-entry ;
 279
 280 M: ##alien-global generate-insn
 281     [ dst>> ] [ symbol>> ] [ library>> ] tri
 282     %alien-global ;
 283
 284 ! ##alien-invoke
 285 GENERIC: next-fastcall-param ( rep -- )
 286
 287 : ?dummy-stack-params ( rep -- )
 288     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 289
 290 : ?dummy-int-params ( rep -- )
 291     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 292
 293 : ?dummy-fp-params ( rep -- )
 294     drop dummy-fp-params? [ float-regs inc ] when ;
 295
 296 M: int-rep next-fastcall-param
 297     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 298
 299 M: single-float-rep next-fastcall-param
 300     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 301
 302 M: double-float-rep next-fastcall-param
 303     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 304
 305 GENERIC: reg-class-full? ( reg-class -- ? )
 306
 307 M: stack-params reg-class-full? drop t ;
 308
 309 M: reg-class reg-class-full?
 310     [ get ] [ param-regs length ] bi >= ;
 311
 312 : alloc-stack-param ( rep -- n reg-class rep )
 313     stack-params get
 314     [ rep-size cell align stack-params +@ ] dip
 315     stack-params dup ;
 316
 317 : alloc-fastcall-param ( rep -- n reg-class rep )
 318     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 319
 320 : alloc-parameter ( parameter -- reg rep )
 321     c-type-rep dup reg-class-of reg-class-full?
 322     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 323     [ param-reg ] dip ;
 324
 325 : (flatten-int-type) ( size -- seq )
 326     cell /i "void*" c-type <repetition> ;
 327
 328 GENERIC: flatten-value-type ( type -- types )
 329
 330 M: object flatten-value-type 1array ;
 331
 332 M: struct-type flatten-value-type ( type -- types )
 333     stack-size cell align (flatten-int-type) ;
 334
 335 M: long-long-type flatten-value-type ( type -- types )
 336     stack-size cell align (flatten-int-type) ;
 337
 338 : flatten-value-types ( params -- params )
 339     #! Convert value type structs to consecutive void*s.
 340     [
 341         0 [
 342             c-type
 343             [ parameter-align (flatten-int-type) % ] keep
 344             [ stack-size cell align + ] keep
 345             flatten-value-type %
 346         ] reduce drop
 347     ] { } make ;
 348
 349 : each-parameter ( parameters quot -- )
 350     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 351
 352 : reverse-each-parameter ( parameters quot -- )
 353     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 354
 355 : reset-fastcall-counts ( -- )
 356     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 357
 358 : with-param-regs ( quot -- )
 359     #! In quot you can call alloc-parameter
 360     [ reset-fastcall-counts call ] with-scope ; inline
 361
 362 : move-parameters ( node word -- )
 363     #! Moves values from C stack to registers (if word is
 364     #! %load-param-reg) and registers to C stack (if word is
 365     #! %save-param-reg).
 366     [ alien-parameters flatten-value-types ]
 367     [ '[ alloc-parameter _ execute ] ]
 368     bi* each-parameter ; inline
 369
 370 : unbox-parameters ( offset node -- )
 371     parameters>> [
 372         %prepare-unbox [ over + ] dip unbox-parameter
 373     ] reverse-each-parameter drop ;
 374
 375 : prepare-box-struct ( node -- offset )
 376     #! Return offset on C stack where to store unboxed
 377     #! parameters. If the C function is returning a structure,
 378     #! the first parameter is an implicit target area pointer,
 379     #! so we need to use a different offset.
 380     return>> large-struct?
 381     [ %prepare-box-struct cell ] [ 0 ] if ;
 382
 383 : objects>registers ( params -- )
 384     #! Generate code for unboxing a list of C types, then
 385     #! generate code for moving these parameters to registers on
 386     #! architectures where parameters are passed in registers.
 387     [
 388         [ prepare-box-struct ] keep
 389         [ unbox-parameters ] keep
 390         \ %load-param-reg move-parameters
 391     ] with-param-regs ;
 392
 393 : box-return* ( node -- )
 394     return>> [ ] [ box-return ] if-void ;
 395
 396 : check-dlsym ( symbols dll -- )
 397     dup dll-valid? [
 398         dupd '[ _ dlsym ] any?
 399         [ drop ] [ compiling-word get no-such-symbol ] if
 400     ] [
 401         dll-path compiling-word get no-such-library drop
 402     ] if ;
 403
 404 : stdcall-mangle ( symbol params -- symbol )
 405     parameters>> parameter-sizes drop number>string "@" glue ;
 406
 407 : alien-invoke-dlsym ( params -- symbols dll )
 408     [ [ function>> dup ] keep stdcall-mangle 2array ]
 409     [ library>> library dup [ dll>> ] when ]
 410     bi 2dup check-dlsym ;
 411
 412 M: ##alien-invoke generate-insn
 413     params>>
 414     ! Save registers for GC
 415     %prepare-alien-invoke
 416     ! Unbox parameters
 417     dup objects>registers
 418     %prepare-var-args
 419     ! Call function
 420     dup alien-invoke-dlsym %alien-invoke
 421     ! Box return value
 422     dup %cleanup
 423     box-return* ;
 424
 425 ! ##alien-indirect
 426 M: ##alien-indirect generate-insn
 427     params>>
 428     ! Save registers for GC
 429     %prepare-alien-invoke
 430     ! Save alien at top of stack to temporary storage
 431     %prepare-alien-indirect
 432     ! Unbox parameters
 433     dup objects>registers
 434     %prepare-var-args
 435     ! Call alien in temporary storage
 436     %alien-indirect
 437     ! Box return value
 438     dup %cleanup
 439     box-return* ;
 440
 441 ! ##alien-callback
 442 : box-parameters ( params -- )
 443     alien-parameters [ box-parameter ] each-parameter ;
 444
 445 : registers>objects ( node -- )
 446     ! Generate code for boxing input parameters in a callback.
 447     [
 448         dup \ %save-param-reg move-parameters
 449         "nest_stacks" f %alien-invoke
 450         box-parameters
 451     ] with-param-regs ;
 452
 453 TUPLE: callback-context ;
 454
 455 : current-callback ( -- id ) 2 getenv ;
 456
 457 : wait-to-return ( token -- )
 458     dup current-callback eq? [
 459         drop
 460     ] [
 461         yield-hook get call( -- ) wait-to-return
 462     ] if ;
 463
 464 : do-callback ( quot token -- )
 465     init-catchstack
 466     [ 2 setenv call ] keep
 467     wait-to-return ; inline
 468
 469 : callback-return-quot ( ctype -- quot )
 470     return>> {
 471         { [ dup "void" = ] [ drop [ ] ] }
 472         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 473         [ c-type c-type-unboxer-quot ]
 474     } cond ;
 475
 476 : callback-prep-quot ( params -- quot )
 477     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 478
 479 : wrap-callback-quot ( params -- quot )
 480     [
 481         [ callback-prep-quot ]
 482         [ quot>> ]
 483         [ callback-return-quot ] tri 3append ,
 484         [ callback-context new do-callback ] %
 485     ] [ ] make ;
 486
 487 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 488
 489 M: ##callback-return generate-insn
 490     #! All the extra book-keeping for %unwind is only for x86.
 491     #! On other platforms its an alias for %return.
 492     params>> %callback-return ;
 493
 494 M: ##alien-callback generate-insn
 495     params>>
 496     [ registers>objects ]
 497     [ wrap-callback-quot %alien-callback ]
 498     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 499     tri ;
 500
 501 M: _prologue generate-insn
 502     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 503
 504 M: _epilogue generate-insn
 505     stack-frame>> total-size>> %epilogue ;
 506
 507 M: _label generate-insn
 508     id>> lookup-label resolve-label ;
 509
 510 M: _branch generate-insn
 511     label>> lookup-label %jump-label ;
 512
 513 : >compare< ( insn -- dst temp cc src1 src2 )
 514     {
 515         [ dst>> ]
 516         [ temp>> ]
 517         [ cc>> ]
 518         [ src1>> ]
 519         [ src2>> ]
 520     } cleave ; inline
 521
 522 M: ##compare generate-insn >compare< %compare ;
 523 M: ##compare-imm generate-insn >compare< %compare-imm ;
 524 M: ##compare-float generate-insn >compare< %compare-float ;
 525
 526 : >binary-branch< ( insn -- label cc src1 src2 )
 527     {
 528         [ label>> lookup-label ]
 529         [ cc>> ]
 530         [ src1>> ]
 531         [ src2>> ]
 532     } cleave ; inline
 533
 534 M: _compare-branch generate-insn
 535     >binary-branch< %compare-branch ;
 536
 537 M: _compare-imm-branch generate-insn
 538     >binary-branch< %compare-imm-branch ;
 539
 540 M: _compare-float-branch generate-insn
 541     >binary-branch< %compare-float-branch ;
 542
 543 M: _spill generate-insn
 544     [ src>> ] [ n>> ] [ rep>> ] tri %spill ;
 545
 546 M: _reload generate-insn
 547     [ dst>> ] [ n>> ] [ rep>> ] tri %reload ;
 548
 549 M: _spill-area-size generate-insn drop ;