basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> ] [ temp>> ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     { [ dst>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 106
 107 M: ##slot generate-insn
 108     [ >slot< ] [ temp>> ] bi %slot ;
 109
 110 M: ##slot-imm generate-insn
 111     >slot< %slot-imm ;
 112
 113 : >set-slot< ( insn -- src obj slot tag )
 114     { [ src>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 115
 116 M: ##set-slot generate-insn
 117     [ >set-slot< ] [ temp>> ] bi %set-slot ;
 118
 119 M: ##set-slot-imm generate-insn
 120     >set-slot< %set-slot-imm ;
 121
 122 M: ##string-nth generate-insn
 123     { [ dst>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %string-nth ;
 124
 125 M: ##set-string-nth-fast generate-insn
 126     { [ src>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %set-string-nth-fast ;
 127
 128 : dst/src ( insn -- dst src )
 129     [ dst>> ] [ src>> ] bi ; inline
 130
 131 : dst/src1/src2 ( insn -- dst src1 src2 )
 132     [ dst>> ] [ src1>> ] [ src2>> ] tri ; inline
 133
 134 M: ##add     generate-insn dst/src1/src2 %add     ;
 135 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 136 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 137 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 138 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 139 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 140 M: ##and     generate-insn dst/src1/src2 %and     ;
 141 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 142 M: ##or      generate-insn dst/src1/src2 %or      ;
 143 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 144 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 145 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 146 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 147 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 148 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 149 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 150 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 151 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 152 M: ##min     generate-insn dst/src1/src2 %min     ;
 153 M: ##max     generate-insn dst/src1/src2 %max     ;
 154 M: ##not     generate-insn dst/src       %not     ;
 155 M: ##log2    generate-insn dst/src       %log2    ;
 156
 157 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 158     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 159
 160 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 161 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 162 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 163
 164 : dst/src/temp ( insn -- dst src temp )
 165     [ dst/src ] [ temp>> ] bi ; inline
 166
 167 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 168 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 169
 170 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 171 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 172 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 173 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 174 M: ##min-float generate-insn dst/src1/src2 %min-float ;
 175 M: ##max-float generate-insn dst/src1/src2 %max-float ;
 176
 177 M: ##sqrt generate-insn dst/src %sqrt ;
 178
 179 M: ##integer>float generate-insn dst/src %integer>float ;
 180 M: ##float>integer generate-insn dst/src %float>integer ;
 181
 182 M: ##copy generate-insn [ dst/src ] [ rep>> ] bi %copy ;
 183
 184 M: ##unbox-float generate-insn dst/src %unbox-float ;
 185 M: ##unbox-any-c-ptr generate-insn dst/src/temp %unbox-any-c-ptr ;
 186 M: ##box-float generate-insn dst/src/temp %box-float ;
 187 M: ##box-alien generate-insn dst/src/temp %box-alien ;
 188
 189 M: ##box-displaced-alien generate-insn
 190     [ dst/src1/src2 ] [ temp>> ] bi %box-displaced-alien ;
 191
 192 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 193 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 194 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 195 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 196 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 197 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 198 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 199 M: ##alien-float      generate-insn dst/src %alien-float      ;
 200 M: ##alien-double     generate-insn dst/src %alien-double     ;
 201
 202 : >alien-setter< ( insn -- src value )
 203     [ src>> ] [ value>> ] bi ; inline
 204
 205 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 206 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 207 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 208 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 209 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 210 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 211
 212 M: ##allot generate-insn
 213     {
 214         [ dst>> ]
 215         [ size>> ]
 216         [ class>> ]
 217         [ temp>> ]
 218     } cleave
 219     %allot ;
 220
 221 M: ##write-barrier generate-insn
 222     [ src>> ]
 223     [ card#>> ]
 224     [ table>> ]
 225     tri %write-barrier ;
 226
 227 ! GC checks
 228 : wipe-locs ( locs temp -- )
 229     '[
 230         _
 231         [ 0 %load-immediate ]
 232         [ swap [ %replace ] with each ] bi
 233     ] unless-empty ;
 234
 235 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 236
 237 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 238     temp operand n>> int-rep %reload
 239     gc-root temp %save-gc-root ;
 240
 241 M: object save-gc-root drop %save-gc-root ;
 242
 243 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 244
 245 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 246
 247 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 248
 249 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 250     gc-root temp %load-gc-root
 251     temp operand n>> int-rep %spill ;
 252
 253 M: object load-gc-root drop %load-gc-root ;
 254
 255 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 256
 257 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 258
 259 M: _gc generate-insn
 260     "no-gc" define-label
 261     {
 262         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 263         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 264         [ data-values>> save-data-regs ]
 265         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 266         [ tagged-values>> length %call-gc ]
 267         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 268         [ data-values>> load-data-regs ]
 269     } cleave
 270     "no-gc" resolve-label ;
 271
 272 M: _loop-entry generate-insn drop %loop-entry ;
 273
 274 M: ##alien-global generate-insn
 275     [ dst>> ] [ symbol>> ] [ library>> ] tri
 276     %alien-global ;
 277
 278 ! ##alien-invoke
 279 GENERIC: next-fastcall-param ( rep -- )
 280
 281 : ?dummy-stack-params ( rep -- )
 282     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 283
 284 : ?dummy-int-params ( rep -- )
 285     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 286
 287 : ?dummy-fp-params ( rep -- )
 288     drop dummy-fp-params? [ float-regs inc ] when ;
 289
 290 M: int-rep next-fastcall-param
 291     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 292
 293 M: single-float-rep next-fastcall-param
 294     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 295
 296 M: double-float-rep next-fastcall-param
 297     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 298
 299 GENERIC: reg-class-full? ( reg-class -- ? )
 300
 301 M: stack-params reg-class-full? drop t ;
 302
 303 M: reg-class reg-class-full?
 304     [ get ] [ param-regs length ] bi >= ;
 305
 306 : alloc-stack-param ( rep -- n reg-class rep )
 307     stack-params get
 308     [ rep-size cell align stack-params +@ ] dip
 309     stack-params dup ;
 310
 311 : alloc-fastcall-param ( rep -- n reg-class rep )
 312     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 313
 314 : alloc-parameter ( parameter -- reg rep )
 315     c-type-rep dup reg-class-of reg-class-full?
 316     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 317     [ param-reg ] dip ;
 318
 319 : (flatten-int-type) ( size -- seq )
 320     cell /i "void*" c-type <repetition> ;
 321
 322 GENERIC: flatten-value-type ( type -- types )
 323
 324 M: object flatten-value-type 1array ;
 325
 326 M: struct-type flatten-value-type ( type -- types )
 327     stack-size cell align (flatten-int-type) ;
 328
 329 M: long-long-type flatten-value-type ( type -- types )
 330     stack-size cell align (flatten-int-type) ;
 331
 332 : flatten-value-types ( params -- params )
 333     #! Convert value type structs to consecutive void*s.
 334     [
 335         0 [
 336             c-type
 337             [ parameter-align (flatten-int-type) % ] keep
 338             [ stack-size cell align + ] keep
 339             flatten-value-type %
 340         ] reduce drop
 341     ] { } make ;
 342
 343 : each-parameter ( parameters quot -- )
 344     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 345
 346 : reverse-each-parameter ( parameters quot -- )
 347     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 348
 349 : reset-fastcall-counts ( -- )
 350     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 351
 352 : with-param-regs ( quot -- )
 353     #! In quot you can call alloc-parameter
 354     [ reset-fastcall-counts call ] with-scope ; inline
 355
 356 : move-parameters ( node word -- )
 357     #! Moves values from C stack to registers (if word is
 358     #! %load-param-reg) and registers to C stack (if word is
 359     #! %save-param-reg).
 360     [ alien-parameters flatten-value-types ]
 361     [ '[ alloc-parameter _ execute ] ]
 362     bi* each-parameter ; inline
 363
 364 : unbox-parameters ( offset node -- )
 365     parameters>> [
 366         %prepare-unbox [ over + ] dip unbox-parameter
 367     ] reverse-each-parameter drop ;
 368
 369 : prepare-box-struct ( node -- offset )
 370     #! Return offset on C stack where to store unboxed
 371     #! parameters. If the C function is returning a structure,
 372     #! the first parameter is an implicit target area pointer,
 373     #! so we need to use a different offset.
 374     return>> large-struct?
 375     [ %prepare-box-struct cell ] [ 0 ] if ;
 376
 377 : objects>registers ( params -- )
 378     #! Generate code for unboxing a list of C types, then
 379     #! generate code for moving these parameters to registers on
 380     #! architectures where parameters are passed in registers.
 381     [
 382         [ prepare-box-struct ] keep
 383         [ unbox-parameters ] keep
 384         \ %load-param-reg move-parameters
 385     ] with-param-regs ;
 386
 387 : box-return* ( node -- )
 388     return>> [ ] [ box-return ] if-void ;
 389
 390 : check-dlsym ( symbols dll -- )
 391     dup dll-valid? [
 392         dupd '[ _ dlsym ] any?
 393         [ drop ] [ compiling-word get no-such-symbol ] if
 394     ] [
 395         dll-path compiling-word get no-such-library drop
 396     ] if ;
 397
 398 : stdcall-mangle ( symbol params -- symbol )
 399     parameters>> parameter-sizes drop number>string "@" glue ;
 400
 401 : alien-invoke-dlsym ( params -- symbols dll )
 402     [ [ function>> dup ] keep stdcall-mangle 2array ]
 403     [ library>> library dup [ dll>> ] when ]
 404     bi 2dup check-dlsym ;
 405
 406 M: ##alien-invoke generate-insn
 407     params>>
 408     ! Save registers for GC
 409     %prepare-alien-invoke
 410     ! Unbox parameters
 411     dup objects>registers
 412     %prepare-var-args
 413     ! Call function
 414     dup alien-invoke-dlsym %alien-invoke
 415     ! Box return value
 416     dup %cleanup
 417     box-return* ;
 418
 419 ! ##alien-indirect
 420 M: ##alien-indirect generate-insn
 421     params>>
 422     ! Save registers for GC
 423     %prepare-alien-invoke
 424     ! Save alien at top of stack to temporary storage
 425     %prepare-alien-indirect
 426     ! Unbox parameters
 427     dup objects>registers
 428     %prepare-var-args
 429     ! Call alien in temporary storage
 430     %alien-indirect
 431     ! Box return value
 432     dup %cleanup
 433     box-return* ;
 434
 435 ! ##alien-callback
 436 : box-parameters ( params -- )
 437     alien-parameters [ box-parameter ] each-parameter ;
 438
 439 : registers>objects ( node -- )
 440     ! Generate code for boxing input parameters in a callback.
 441     [
 442         dup \ %save-param-reg move-parameters
 443         "nest_stacks" f %alien-invoke
 444         box-parameters
 445     ] with-param-regs ;
 446
 447 TUPLE: callback-context ;
 448
 449 : current-callback ( -- id ) 2 getenv ;
 450
 451 : wait-to-return ( token -- )
 452     dup current-callback eq? [
 453         drop
 454     ] [
 455         yield-hook get call( -- ) wait-to-return
 456     ] if ;
 457
 458 : do-callback ( quot token -- )
 459     init-catchstack
 460     [ 2 setenv call ] keep
 461     wait-to-return ; inline
 462
 463 : callback-return-quot ( ctype -- quot )
 464     return>> {
 465         { [ dup "void" = ] [ drop [ ] ] }
 466         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 467         [ c-type c-type-unboxer-quot ]
 468     } cond ;
 469
 470 : callback-prep-quot ( params -- quot )
 471     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 472
 473 : wrap-callback-quot ( params -- quot )
 474     [
 475         [ callback-prep-quot ]
 476         [ quot>> ]
 477         [ callback-return-quot ] tri 3append ,
 478         [ callback-context new do-callback ] %
 479     ] [ ] make ;
 480
 481 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 482
 483 M: ##callback-return generate-insn
 484     #! All the extra book-keeping for %unwind is only for x86.
 485     #! On other platforms its an alias for %return.
 486     params>> %callback-return ;
 487
 488 M: ##alien-callback generate-insn
 489     params>>
 490     [ registers>objects ]
 491     [ wrap-callback-quot %alien-callback ]
 492     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 493     tri ;
 494
 495 M: _prologue generate-insn
 496     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 497
 498 M: _epilogue generate-insn
 499     stack-frame>> total-size>> %epilogue ;
 500
 501 M: _label generate-insn
 502     id>> lookup-label resolve-label ;
 503
 504 M: _branch generate-insn
 505     label>> lookup-label %jump-label ;
 506
 507 : >compare< ( insn -- dst temp cc src1 src2 )
 508     {
 509         [ dst>> ]
 510         [ temp>> ]
 511         [ cc>> ]
 512         [ src1>> ]
 513         [ src2>> ]
 514     } cleave ; inline
 515
 516 M: ##compare generate-insn >compare< %compare ;
 517 M: ##compare-imm generate-insn >compare< %compare-imm ;
 518 M: ##compare-float generate-insn >compare< %compare-float ;
 519
 520 : >binary-branch< ( insn -- label cc src1 src2 )
 521     {
 522         [ label>> lookup-label ]
 523         [ cc>> ]
 524         [ src1>> ]
 525         [ src2>> ]
 526     } cleave ; inline
 527
 528 M: _compare-branch generate-insn
 529     >binary-branch< %compare-branch ;
 530
 531 M: _compare-imm-branch generate-insn
 532     >binary-branch< %compare-imm-branch ;
 533
 534 M: _compare-float-branch generate-insn
 535     >binary-branch< %compare-float-branch ;
 536
 537 M: _spill generate-insn
 538     [ src>> ] [ n>> ] [ rep>> ] tri %spill ;
 539
 540 M: _reload generate-insn
 541     [ dst>> ] [ n>> ] [ rep>> ] tri %reload ;
 542
 543 M: _spill-area-size generate-insn drop ;