basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors slots parser generic.parser
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 ! Special cases
  71 M: ##no-tco generate-insn drop ;
  72
  73 M: ##call generate-insn
  74     word>> dup sub-primitive>>
  75     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  76
  77 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  78
  79 M: _dispatch-label generate-insn
  80     label>> lookup-label
  81     cell 0 <repetition> %
  82     rc-absolute-cell label-fixup ;
  83
  84 M: _prologue generate-insn
  85     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  86
  87 M: _epilogue generate-insn
  88     stack-frame>> total-size>> %epilogue ;
  89
  90 M: _spill-area-size generate-insn drop ;
  91
  92 ! Some meta-programming to generate simple code generators, where
  93 ! the instruction is unpacked and then a %word is called
  94 <<
  95
  96 : insn-slot-quot ( spec -- quot )
  97     name>> [ reader-word ] [ "label" = ] bi
  98     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
  99
 100 : codegen-method-body ( class word -- quot )
 101     [
 102         "insn-slots" word-prop
 103         [ insn-slot-quot ] map
 104     ] dip
 105     '[ _ cleave _ execute ] ;
 106
 107 SYNTAX: CODEGEN:
 108     scan-word [ \ generate-insn create-method-in ] keep scan-word
 109     codegen-method-body define ;
 110 >>
 111
 112 CODEGEN: ##load-immediate %load-immediate
 113 CODEGEN: ##load-reference %load-reference
 114 CODEGEN: ##peek %peek
 115 CODEGEN: ##replace %replace
 116 CODEGEN: ##inc-d %inc-d
 117 CODEGEN: ##inc-r %inc-r
 118 CODEGEN: ##return %return
 119 CODEGEN: ##slot %slot
 120 CODEGEN: ##slot-imm %slot-imm
 121 CODEGEN: ##set-slot %set-slot
 122 CODEGEN: ##set-slot-imm %set-slot-imm
 123 CODEGEN: ##string-nth %string-nth
 124 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 125 CODEGEN: ##add %add
 126 CODEGEN: ##add-imm %add-imm
 127 CODEGEN: ##sub %sub
 128 CODEGEN: ##sub-imm %sub-imm
 129 CODEGEN: ##mul %mul
 130 CODEGEN: ##mul-imm %mul-imm
 131 CODEGEN: ##and %and
 132 CODEGEN: ##and-imm %and-imm
 133 CODEGEN: ##or %or
 134 CODEGEN: ##or-imm %or-imm
 135 CODEGEN: ##xor %xor
 136 CODEGEN: ##xor-imm %xor-imm
 137 CODEGEN: ##shl %shl
 138 CODEGEN: ##shl-imm %shl-imm
 139 CODEGEN: ##shr %shr
 140 CODEGEN: ##shr-imm %shr-imm
 141 CODEGEN: ##sar %sar
 142 CODEGEN: ##sar-imm %sar-imm
 143 CODEGEN: ##min %min
 144 CODEGEN: ##max %max
 145 CODEGEN: ##not %not
 146 CODEGEN: ##log2 %log2
 147 CODEGEN: ##copy %copy
 148 CODEGEN: ##integer>bignum %integer>bignum
 149 CODEGEN: ##bignum>integer %bignum>integer
 150 CODEGEN: ##unbox-float %unbox-float
 151 CODEGEN: ##box-float %box-float
 152 CODEGEN: ##add-float %add-float
 153 CODEGEN: ##sub-float %sub-float
 154 CODEGEN: ##mul-float %mul-float
 155 CODEGEN: ##div-float %div-float
 156 CODEGEN: ##min-float %min-float
 157 CODEGEN: ##max-float %max-float
 158 CODEGEN: ##sqrt %sqrt
 159 CODEGEN: ##unary-float-function %unary-float-function
 160 CODEGEN: ##binary-float-function %binary-float-function
 161 CODEGEN: ##single>double-float %single>double-float
 162 CODEGEN: ##double>single-float %double>single-float
 163 CODEGEN: ##integer>float %integer>float
 164 CODEGEN: ##float>integer %float>integer
 165 CODEGEN: ##unbox-vector %unbox-vector
 166 CODEGEN: ##broadcast-vector %broadcast-vector
 167 CODEGEN: ##gather-vector-2 %gather-vector-2
 168 CODEGEN: ##gather-vector-4 %gather-vector-4
 169 CODEGEN: ##box-vector %box-vector
 170 CODEGEN: ##add-vector %add-vector
 171 CODEGEN: ##sub-vector %sub-vector
 172 CODEGEN: ##mul-vector %mul-vector
 173 CODEGEN: ##div-vector %div-vector
 174 CODEGEN: ##min-vector %min-vector
 175 CODEGEN: ##max-vector %max-vector
 176 CODEGEN: ##sqrt-vector %sqrt-vector
 177 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 178 CODEGEN: ##box-alien %box-alien
 179 CODEGEN: ##box-displaced-alien %box-displaced-alien
 180 CODEGEN: ##unbox-alien %unbox-alien
 181 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 182 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 183 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 184 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 185 CODEGEN: ##alien-signed-1 %alien-signed-1
 186 CODEGEN: ##alien-signed-2 %alien-signed-2
 187 CODEGEN: ##alien-signed-4 %alien-signed-4
 188 CODEGEN: ##alien-cell %alien-cell
 189 CODEGEN: ##alien-float %alien-float
 190 CODEGEN: ##alien-double %alien-double
 191 CODEGEN: ##alien-vector %alien-vector
 192 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 193 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 194 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 195 CODEGEN: ##set-alien-cell %set-alien-cell
 196 CODEGEN: ##set-alien-float %set-alien-float
 197 CODEGEN: ##set-alien-double %set-alien-double
 198 CODEGEN: ##set-alien-vector %set-alien-vector
 199 CODEGEN: ##allot %allot
 200 CODEGEN: ##write-barrier %write-barrier
 201 CODEGEN: ##compare %compare
 202 CODEGEN: ##compare-imm %compare-imm
 203 CODEGEN: ##compare-float %compare-float
 204
 205 CODEGEN: _fixnum-add %fixnum-add
 206 CODEGEN: _fixnum-sub %fixnum-sub
 207 CODEGEN: _fixnum-mul %fixnum-mul
 208 CODEGEN: _label resolve-label
 209 CODEGEN: _branch %jump-label
 210 CODEGEN: _compare-branch %compare-branch
 211 CODEGEN: _compare-imm-branch %compare-imm-branch
 212 CODEGEN: _compare-float-branch %compare-float-branch
 213 CODEGEN: _dispatch %dispatch
 214 CODEGEN: _spill %spill
 215 CODEGEN: _reload %reload
 216
 217 ! ##gc
 218 : wipe-locs ( locs temp -- )
 219     '[
 220         _
 221         [ 0 %load-immediate ]
 222         [ swap [ %replace ] with each ] bi
 223     ] unless-empty ;
 224
 225 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 226
 227 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 228     temp int-rep operand n>> %reload
 229     gc-root temp %save-gc-root ;
 230
 231 M: object save-gc-root drop %save-gc-root ;
 232
 233 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 234
 235 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 236
 237 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 238
 239 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 240     gc-root temp %load-gc-root
 241     temp int-rep operand n>> %spill ;
 242
 243 M: object load-gc-root drop %load-gc-root ;
 244
 245 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 246
 247 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 248
 249 M: _gc generate-insn
 250     "no-gc" define-label
 251     {
 252         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 253         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 254         [ data-values>> save-data-regs ]
 255         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 256         [ tagged-values>> length %call-gc ]
 257         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 258         [ data-values>> load-data-regs ]
 259     } cleave
 260     "no-gc" resolve-label ;
 261
 262 M: _loop-entry generate-insn drop %loop-entry ;
 263
 264 M: ##alien-global generate-insn
 265     [ dst>> ] [ symbol>> ] [ library>> ] tri
 266     %alien-global ;
 267
 268 ! ##alien-invoke
 269 GENERIC: next-fastcall-param ( rep -- )
 270
 271 : ?dummy-stack-params ( rep -- )
 272     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 273
 274 : ?dummy-int-params ( rep -- )
 275     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 276
 277 : ?dummy-fp-params ( rep -- )
 278     drop dummy-fp-params? [ float-regs inc ] when ;
 279
 280 M: int-rep next-fastcall-param
 281     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 282
 283 M: float-rep next-fastcall-param
 284     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 285
 286 M: double-rep next-fastcall-param
 287     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 288
 289 GENERIC: reg-class-full? ( reg-class -- ? )
 290
 291 M: stack-params reg-class-full? drop t ;
 292
 293 M: reg-class reg-class-full?
 294     [ get ] [ param-regs length ] bi >= ;
 295
 296 : alloc-stack-param ( rep -- n reg-class rep )
 297     stack-params get
 298     [ rep-size cell align stack-params +@ ] dip
 299     stack-params dup ;
 300
 301 : alloc-fastcall-param ( rep -- n reg-class rep )
 302     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 303
 304 : alloc-parameter ( parameter -- reg rep )
 305     c-type-rep dup reg-class-of reg-class-full?
 306     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 307     [ param-reg ] dip ;
 308
 309 : (flatten-int-type) ( size -- seq )
 310     cell /i "void*" c-type <repetition> ;
 311
 312 GENERIC: flatten-value-type ( type -- types )
 313
 314 M: object flatten-value-type 1array ;
 315
 316 M: struct-type flatten-value-type ( type -- types )
 317     stack-size cell align (flatten-int-type) ;
 318
 319 M: long-long-type flatten-value-type ( type -- types )
 320     stack-size cell align (flatten-int-type) ;
 321
 322 : flatten-value-types ( params -- params )
 323     #! Convert value type structs to consecutive void*s.
 324     [
 325         0 [
 326             c-type
 327             [ parameter-align (flatten-int-type) % ] keep
 328             [ stack-size cell align + ] keep
 329             flatten-value-type %
 330         ] reduce drop
 331     ] { } make ;
 332
 333 : each-parameter ( parameters quot -- )
 334     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 335
 336 : reverse-each-parameter ( parameters quot -- )
 337     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 338
 339 : reset-fastcall-counts ( -- )
 340     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 341
 342 : with-param-regs ( quot -- )
 343     #! In quot you can call alloc-parameter
 344     [ reset-fastcall-counts call ] with-scope ; inline
 345
 346 : move-parameters ( node word -- )
 347     #! Moves values from C stack to registers (if word is
 348     #! %load-param-reg) and registers to C stack (if word is
 349     #! %save-param-reg).
 350     [ alien-parameters flatten-value-types ]
 351     [ '[ alloc-parameter _ execute ] ]
 352     bi* each-parameter ; inline
 353
 354 : unbox-parameters ( offset node -- )
 355     parameters>> [
 356         %prepare-unbox [ over + ] dip unbox-parameter
 357     ] reverse-each-parameter drop ;
 358
 359 : prepare-box-struct ( node -- offset )
 360     #! Return offset on C stack where to store unboxed
 361     #! parameters. If the C function is returning a structure,
 362     #! the first parameter is an implicit target area pointer,
 363     #! so we need to use a different offset.
 364     return>> large-struct?
 365     [ %prepare-box-struct cell ] [ 0 ] if ;
 366
 367 : objects>registers ( params -- )
 368     #! Generate code for unboxing a list of C types, then
 369     #! generate code for moving these parameters to registers on
 370     #! architectures where parameters are passed in registers.
 371     [
 372         [ prepare-box-struct ] keep
 373         [ unbox-parameters ] keep
 374         \ %load-param-reg move-parameters
 375     ] with-param-regs ;
 376
 377 : box-return* ( node -- )
 378     return>> [ ] [ box-return ] if-void ;
 379
 380 : check-dlsym ( symbols dll -- )
 381     dup dll-valid? [
 382         dupd '[ _ dlsym ] any?
 383         [ drop ] [ compiling-word get no-such-symbol ] if
 384     ] [
 385         dll-path compiling-word get no-such-library drop
 386     ] if ;
 387
 388 : stdcall-mangle ( symbol params -- symbol )
 389     parameters>> parameter-sizes drop number>string "@" glue ;
 390
 391 : alien-invoke-dlsym ( params -- symbols dll )
 392     [ [ function>> dup ] keep stdcall-mangle 2array ]
 393     [ library>> library dup [ dll>> ] when ]
 394     bi 2dup check-dlsym ;
 395
 396 M: ##alien-invoke generate-insn
 397     params>>
 398     ! Save registers for GC
 399     %prepare-alien-invoke
 400     ! Unbox parameters
 401     dup objects>registers
 402     %prepare-var-args
 403     ! Call function
 404     dup alien-invoke-dlsym %alien-invoke
 405     ! Box return value
 406     dup %cleanup
 407     box-return* ;
 408
 409 ! ##alien-indirect
 410 M: ##alien-indirect generate-insn
 411     params>>
 412     ! Save registers for GC
 413     %prepare-alien-invoke
 414     ! Save alien at top of stack to temporary storage
 415     %prepare-alien-indirect
 416     ! Unbox parameters
 417     dup objects>registers
 418     %prepare-var-args
 419     ! Call alien in temporary storage
 420     %alien-indirect
 421     ! Box return value
 422     dup %cleanup
 423     box-return* ;
 424
 425 ! ##alien-callback
 426 : box-parameters ( params -- )
 427     alien-parameters [ box-parameter ] each-parameter ;
 428
 429 : registers>objects ( node -- )
 430     ! Generate code for boxing input parameters in a callback.
 431     [
 432         dup \ %save-param-reg move-parameters
 433         "nest_stacks" f %alien-invoke
 434         box-parameters
 435     ] with-param-regs ;
 436
 437 TUPLE: callback-context ;
 438
 439 : current-callback ( -- id ) 2 getenv ;
 440
 441 : wait-to-return ( token -- )
 442     dup current-callback eq? [
 443         drop
 444     ] [
 445         yield-hook get call( -- ) wait-to-return
 446     ] if ;
 447
 448 : do-callback ( quot token -- )
 449     init-catchstack
 450     [ 2 setenv call ] keep
 451     wait-to-return ; inline
 452
 453 : callback-return-quot ( ctype -- quot )
 454     return>> {
 455         { [ dup "void" = ] [ drop [ ] ] }
 456         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 457         [ c-type c-type-unboxer-quot ]
 458     } cond ;
 459
 460 : callback-prep-quot ( params -- quot )
 461     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 462
 463 : wrap-callback-quot ( params -- quot )
 464     [
 465         [ callback-prep-quot ]
 466         [ quot>> ]
 467         [ callback-return-quot ] tri 3append ,
 468         [ callback-context new do-callback ] %
 469     ] [ ] make ;
 470
 471 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 472
 473 M: ##callback-return generate-insn
 474     #! All the extra book-keeping for %unwind is only for x86.
 475     #! On other platforms its an alias for %return.
 476     params>> %callback-return ;
 477
 478 M: ##alien-callback generate-insn
 479     params>>
 480     [ registers>objects ]
 481     [ wrap-callback-quot %alien-callback ]
 482     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 483     tri ;