basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> ] [ temp>> ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     { [ dst>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 106
 107 M: ##slot generate-insn
 108     [ >slot< ] [ temp>> ] bi %slot ;
 109
 110 M: ##slot-imm generate-insn
 111     >slot< %slot-imm ;
 112
 113 : >set-slot< ( insn -- src obj slot tag )
 114     { [ src>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 115
 116 M: ##set-slot generate-insn
 117     [ >set-slot< ] [ temp>> ] bi %set-slot ;
 118
 119 M: ##set-slot-imm generate-insn
 120     >set-slot< %set-slot-imm ;
 121
 122 M: ##string-nth generate-insn
 123     { [ dst>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %string-nth ;
 124
 125 M: ##set-string-nth-fast generate-insn
 126     { [ src>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %set-string-nth-fast ;
 127
 128 : dst/src ( insn -- dst src )
 129     [ dst>> ] [ src>> ] bi ; inline
 130
 131 : dst/src1/src2 ( insn -- dst src1 src2 )
 132     [ dst>> ] [ src1>> ] [ src2>> ] tri ; inline
 133
 134 M: ##add     generate-insn dst/src1/src2 %add     ;
 135 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 136 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 137 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 138 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 139 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 140 M: ##and     generate-insn dst/src1/src2 %and     ;
 141 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 142 M: ##or      generate-insn dst/src1/src2 %or      ;
 143 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 144 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 145 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 146 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 147 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 148 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 149 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 150 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 151 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 152 M: ##not     generate-insn dst/src       %not     ;
 153 M: ##log2    generate-insn dst/src       %log2    ;
 154
 155 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 156     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 157
 158 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 159 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 160 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 161
 162 : dst/src/temp ( insn -- dst src temp )
 163     [ dst/src ] [ temp>> ] bi ; inline
 164
 165 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 166 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 167
 168 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 169 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 170 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 171 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 172
 173 M: ##integer>float generate-insn dst/src %integer>float ;
 174 M: ##float>integer generate-insn dst/src %float>integer ;
 175
 176 M: ##copy generate-insn [ dst/src ] [ rep>> ] bi %copy ;
 177
 178 M: ##unbox-float     generate-insn dst/src %unbox-float ;
 179 M: ##unbox-any-c-ptr generate-insn dst/src/temp %unbox-any-c-ptr ;
 180 M: ##box-float       generate-insn dst/src/temp %box-float ;
 181 M: ##box-alien       generate-insn dst/src/temp %box-alien ;
 182
 183 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 184 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 185 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 186 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 187 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 188 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 189 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 190 M: ##alien-float      generate-insn dst/src %alien-float      ;
 191 M: ##alien-double     generate-insn dst/src %alien-double     ;
 192
 193 : >alien-setter< ( insn -- src value )
 194     [ src>> ] [ value>> ] bi ; inline
 195
 196 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 197 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 198 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 199 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 200 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 201 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 202
 203 M: ##allot generate-insn
 204     {
 205         [ dst>> ]
 206         [ size>> ]
 207         [ class>> ]
 208         [ temp>> ]
 209     } cleave
 210     %allot ;
 211
 212 M: ##write-barrier generate-insn
 213     [ src>> ]
 214     [ card#>> ]
 215     [ table>> ]
 216     tri %write-barrier ;
 217
 218 ! GC checks
 219 : wipe-locs ( locs temp -- )
 220     '[
 221         _
 222         [ 0 %load-immediate ]
 223         [ swap [ %replace ] with each ] bi
 224     ] unless-empty ;
 225
 226 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 227
 228 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 229     temp operand n>> int-rep %reload
 230     gc-root temp %save-gc-root ;
 231
 232 M: object save-gc-root drop %save-gc-root ;
 233
 234 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 235
 236 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 237
 238 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 239
 240 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 241     gc-root temp %load-gc-root
 242     temp operand n>> int-rep %spill ;
 243
 244 M: object load-gc-root drop %load-gc-root ;
 245
 246 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 247
 248 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 249
 250 M: _gc generate-insn
 251     "no-gc" define-label
 252     {
 253         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 254         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 255         [ data-values>> save-data-regs ]
 256         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 257         [ tagged-values>> length %call-gc ]
 258         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 259         [ data-values>> load-data-regs ]
 260     } cleave
 261     "no-gc" resolve-label ;
 262
 263 M: _loop-entry generate-insn drop %loop-entry ;
 264
 265 M: ##alien-global generate-insn
 266     [ dst>> ] [ symbol>> ] [ library>> ] tri
 267     %alien-global ;
 268
 269 ! ##alien-invoke
 270 GENERIC: next-fastcall-param ( rep -- )
 271
 272 : ?dummy-stack-params ( rep -- )
 273     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 274
 275 : ?dummy-int-params ( rep -- )
 276     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 277
 278 : ?dummy-fp-params ( rep -- )
 279     drop dummy-fp-params? [ float-regs inc ] when ;
 280
 281 M: int-rep next-fastcall-param
 282     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 283
 284 M: single-float-rep next-fastcall-param
 285     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 286
 287 M: double-float-rep next-fastcall-param
 288     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 289
 290 GENERIC: reg-class-full? ( reg-class -- ? )
 291
 292 M: stack-params reg-class-full? drop t ;
 293
 294 M: reg-class reg-class-full?
 295     [ get ] [ param-regs length ] bi >= ;
 296
 297 : alloc-stack-param ( rep -- n reg-class rep )
 298     stack-params get
 299     [ rep-size cell align stack-params +@ ] dip
 300     stack-params dup ;
 301
 302 : alloc-fastcall-param ( rep -- n reg-class rep )
 303     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 304
 305 : alloc-parameter ( parameter -- reg rep )
 306     c-type-rep dup reg-class-of reg-class-full?
 307     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 308     [ param-reg ] dip ;
 309
 310 : (flatten-int-type) ( size -- seq )
 311     cell /i "void*" c-type <repetition> ;
 312
 313 GENERIC: flatten-value-type ( type -- types )
 314
 315 M: object flatten-value-type 1array ;
 316
 317 M: struct-type flatten-value-type ( type -- types )
 318     stack-size cell align (flatten-int-type) ;
 319
 320 M: long-long-type flatten-value-type ( type -- types )
 321     stack-size cell align (flatten-int-type) ;
 322
 323 : flatten-value-types ( params -- params )
 324     #! Convert value type structs to consecutive void*s.
 325     [
 326         0 [
 327             c-type
 328             [ parameter-align (flatten-int-type) % ] keep
 329             [ stack-size cell align + ] keep
 330             flatten-value-type %
 331         ] reduce drop
 332     ] { } make ;
 333
 334 : each-parameter ( parameters quot -- )
 335     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 336
 337 : reverse-each-parameter ( parameters quot -- )
 338     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 339
 340 : reset-fastcall-counts ( -- )
 341     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 342
 343 : with-param-regs ( quot -- )
 344     #! In quot you can call alloc-parameter
 345     [ reset-fastcall-counts call ] with-scope ; inline
 346
 347 : move-parameters ( node word -- )
 348     #! Moves values from C stack to registers (if word is
 349     #! %load-param-reg) and registers to C stack (if word is
 350     #! %save-param-reg).
 351     [ alien-parameters flatten-value-types ]
 352     [ '[ alloc-parameter _ execute ] ]
 353     bi* each-parameter ; inline
 354
 355 : unbox-parameters ( offset node -- )
 356     parameters>> [
 357         %prepare-unbox [ over + ] dip unbox-parameter
 358     ] reverse-each-parameter drop ;
 359
 360 : prepare-box-struct ( node -- offset )
 361     #! Return offset on C stack where to store unboxed
 362     #! parameters. If the C function is returning a structure,
 363     #! the first parameter is an implicit target area pointer,
 364     #! so we need to use a different offset.
 365     return>> large-struct?
 366     [ %prepare-box-struct cell ] [ 0 ] if ;
 367
 368 : objects>registers ( params -- )
 369     #! Generate code for unboxing a list of C types, then
 370     #! generate code for moving these parameters to registers on
 371     #! architectures where parameters are passed in registers.
 372     [
 373         [ prepare-box-struct ] keep
 374         [ unbox-parameters ] keep
 375         \ %load-param-reg move-parameters
 376     ] with-param-regs ;
 377
 378 : box-return* ( node -- )
 379     return>> [ ] [ box-return ] if-void ;
 380
 381 : check-dlsym ( symbols dll -- )
 382     dup dll-valid? [
 383         dupd '[ _ dlsym ] any?
 384         [ drop ] [ compiling-word get no-such-symbol ] if
 385     ] [
 386         dll-path compiling-word get no-such-library drop
 387     ] if ;
 388
 389 : stdcall-mangle ( symbol params -- symbol )
 390     parameters>> parameter-sizes drop number>string "@" glue ;
 391
 392 : alien-invoke-dlsym ( params -- symbols dll )
 393     [ [ function>> dup ] keep stdcall-mangle 2array ]
 394     [ library>> library dup [ dll>> ] when ]
 395     bi 2dup check-dlsym ;
 396
 397 M: ##alien-invoke generate-insn
 398     params>>
 399     ! Save registers for GC
 400     %prepare-alien-invoke
 401     ! Unbox parameters
 402     dup objects>registers
 403     %prepare-var-args
 404     ! Call function
 405     dup alien-invoke-dlsym %alien-invoke
 406     ! Box return value
 407     dup %cleanup
 408     box-return* ;
 409
 410 ! ##alien-indirect
 411 M: ##alien-indirect generate-insn
 412     params>>
 413     ! Save registers for GC
 414     %prepare-alien-invoke
 415     ! Save alien at top of stack to temporary storage
 416     %prepare-alien-indirect
 417     ! Unbox parameters
 418     dup objects>registers
 419     %prepare-var-args
 420     ! Call alien in temporary storage
 421     %alien-indirect
 422     ! Box return value
 423     dup %cleanup
 424     box-return* ;
 425
 426 ! ##alien-callback
 427 : box-parameters ( params -- )
 428     alien-parameters [ box-parameter ] each-parameter ;
 429
 430 : registers>objects ( node -- )
 431     ! Generate code for boxing input parameters in a callback.
 432     [
 433         dup \ %save-param-reg move-parameters
 434         "nest_stacks" f %alien-invoke
 435         box-parameters
 436     ] with-param-regs ;
 437
 438 TUPLE: callback-context ;
 439
 440 : current-callback ( -- id ) 2 getenv ;
 441
 442 : wait-to-return ( token -- )
 443     dup current-callback eq? [
 444         drop
 445     ] [
 446         yield-hook get call( -- ) wait-to-return
 447     ] if ;
 448
 449 : do-callback ( quot token -- )
 450     init-catchstack
 451     [ 2 setenv call ] keep
 452     wait-to-return ; inline
 453
 454 : callback-return-quot ( ctype -- quot )
 455     return>> {
 456         { [ dup "void" = ] [ drop [ ] ] }
 457         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 458         [ c-type c-type-unboxer-quot ]
 459     } cond ;
 460
 461 : callback-prep-quot ( params -- quot )
 462     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 463
 464 : wrap-callback-quot ( params -- quot )
 465     [
 466         [ callback-prep-quot ]
 467         [ quot>> ]
 468         [ callback-return-quot ] tri 3append ,
 469         [ callback-context new do-callback ] %
 470     ] [ ] make ;
 471
 472 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 473
 474 M: ##callback-return generate-insn
 475     #! All the extra book-keeping for %unwind is only for x86.
 476     #! On other platforms its an alias for %return.
 477     params>> %callback-return ;
 478
 479 M: ##alien-callback generate-insn
 480     params>>
 481     [ registers>objects ]
 482     [ wrap-callback-quot %alien-callback ]
 483     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 484     tri ;
 485
 486 M: _prologue generate-insn
 487     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 488
 489 M: _epilogue generate-insn
 490     stack-frame>> total-size>> %epilogue ;
 491
 492 M: _label generate-insn
 493     id>> lookup-label resolve-label ;
 494
 495 M: _branch generate-insn
 496     label>> lookup-label %jump-label ;
 497
 498 : >compare< ( insn -- dst temp cc src1 src2 )
 499     {
 500         [ dst>> ]
 501         [ temp>> ]
 502         [ cc>> ]
 503         [ src1>> ]
 504         [ src2>> ]
 505     } cleave ; inline
 506
 507 M: ##compare generate-insn >compare< %compare ;
 508 M: ##compare-imm generate-insn >compare< %compare-imm ;
 509 M: ##compare-float generate-insn >compare< %compare-float ;
 510
 511 : >binary-branch< ( insn -- label cc src1 src2 )
 512     {
 513         [ label>> lookup-label ]
 514         [ cc>> ]
 515         [ src1>> ]
 516         [ src2>> ]
 517     } cleave ; inline
 518
 519 M: _compare-branch generate-insn
 520     >binary-branch< %compare-branch ;
 521
 522 M: _compare-imm-branch generate-insn
 523     >binary-branch< %compare-imm-branch ;
 524
 525 M: _compare-float-branch generate-insn
 526     >binary-branch< %compare-float-branch ;
 527
 528 M: _spill generate-insn
 529     [ src>> ] [ n>> ] [ rep>> ] tri %spill ;
 530
 531 M: _reload generate-insn
 532     [ dst>> ] [ n>> ] [ rep>> ] tri %reload ;
 533
 534 M: _spill-area-size generate-insn drop ;