basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types alien.structs
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 IN: compiler.codegen
  20
  21 SYMBOL: insn-counts
  22
  23 H{ } clone insn-counts set-global
  24
  25 GENERIC: generate-insn ( insn -- )
  26
  27 TUPLE: asm label code calls ;
  28
  29 SYMBOL: calls
  30
  31 : add-call ( word -- )
  32     #! Compile this word later.
  33     calls get push ;
  34
  35 SYMBOL: compiling-word
  36
  37 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  38
  39 ! Mapping _label IDs to label instances
  40 SYMBOL: labels
  41
  42 : init-generator ( word -- )
  43     H{ } clone labels set
  44     V{ } clone calls set
  45     compiling-word set
  46     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  47
  48 : generate-insns ( asm -- code )
  49     [
  50         [ word>> init-generator ]
  51         [
  52             instructions>>
  53             [
  54                 [ class insn-counts get inc-at ]
  55                 [ generate-insn ]
  56                 bi
  57             ] each
  58         ] bi
  59     ] with-fixup ;
  60
  61 : generate ( mr -- asm )
  62     [
  63         [ label>> ] [ generate-insns ] bi calls get
  64         asm boa
  65     ] with-scope ;
  66
  67 : lookup-label ( id -- label )
  68     labels get [ drop <label> ] cache ;
  69
  70 M: ##no-tco generate-insn drop ;
  71
  72 M: ##load-immediate generate-insn
  73     [ dst>> ] [ val>> ] bi %load-immediate ;
  74
  75 M: ##load-reference generate-insn
  76     [ dst>> ] [ obj>> ] bi %load-reference ;
  77
  78 M: ##peek generate-insn
  79     [ dst>> ] [ loc>> ] bi %peek ;
  80
  81 M: ##replace generate-insn
  82     [ src>> ] [ loc>> ] bi %replace ;
  83
  84 M: ##inc-d generate-insn n>> %inc-d ;
  85
  86 M: ##inc-r generate-insn n>> %inc-r ;
  87
  88 M: ##call generate-insn
  89     word>> dup sub-primitive>>
  90     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  91
  92 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  93
  94 M: ##return generate-insn drop %return ;
  95
  96 M: _dispatch generate-insn
  97     [ src>> ] [ temp>> ] bi %dispatch ;
  98
  99 M: _dispatch-label generate-insn
 100     label>> lookup-label
 101     cell 0 <repetition> %
 102     rc-absolute-cell label-fixup ;
 103
 104 : >slot< ( insn -- dst obj slot tag )
 105     { [ dst>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 106
 107 M: ##slot generate-insn
 108     [ >slot< ] [ temp>> ] bi %slot ;
 109
 110 M: ##slot-imm generate-insn
 111     >slot< %slot-imm ;
 112
 113 : >set-slot< ( insn -- src obj slot tag )
 114     { [ src>> ] [ obj>> ] [ slot>> ] [ tag>> ] } cleave ; inline
 115
 116 M: ##set-slot generate-insn
 117     [ >set-slot< ] [ temp>> ] bi %set-slot ;
 118
 119 M: ##set-slot-imm generate-insn
 120     >set-slot< %set-slot-imm ;
 121
 122 M: ##string-nth generate-insn
 123     { [ dst>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %string-nth ;
 124
 125 M: ##set-string-nth-fast generate-insn
 126     { [ src>> ] [ obj>> ] [ index>> ] [ temp>> ] } cleave %set-string-nth-fast ;
 127
 128 : dst/src ( insn -- dst src )
 129     [ dst>> ] [ src>> ] bi ; inline
 130
 131 : dst/src1/src2 ( insn -- dst src1 src2 )
 132     [ dst>> ] [ src1>> ] [ src2>> ] tri ; inline
 133
 134 M: ##add     generate-insn dst/src1/src2 %add     ;
 135 M: ##add-imm generate-insn dst/src1/src2 %add-imm ;
 136 M: ##sub     generate-insn dst/src1/src2 %sub     ;
 137 M: ##sub-imm generate-insn dst/src1/src2 %sub-imm ;
 138 M: ##mul     generate-insn dst/src1/src2 %mul     ;
 139 M: ##mul-imm generate-insn dst/src1/src2 %mul-imm ;
 140 M: ##and     generate-insn dst/src1/src2 %and     ;
 141 M: ##and-imm generate-insn dst/src1/src2 %and-imm ;
 142 M: ##or      generate-insn dst/src1/src2 %or      ;
 143 M: ##or-imm  generate-insn dst/src1/src2 %or-imm  ;
 144 M: ##xor     generate-insn dst/src1/src2 %xor     ;
 145 M: ##xor-imm generate-insn dst/src1/src2 %xor-imm ;
 146 M: ##shl     generate-insn dst/src1/src2 %shl     ;
 147 M: ##shl-imm generate-insn dst/src1/src2 %shl-imm ;
 148 M: ##shr     generate-insn dst/src1/src2 %shr     ;
 149 M: ##shr-imm generate-insn dst/src1/src2 %shr-imm ;
 150 M: ##sar     generate-insn dst/src1/src2 %sar     ;
 151 M: ##sar-imm generate-insn dst/src1/src2 %sar-imm ;
 152 M: ##not     generate-insn dst/src       %not     ;
 153 M: ##log2    generate-insn dst/src       %log2    ;
 154
 155 : label/dst/src1/src2 ( insn -- label dst src1 src2 )
 156     [ label>> lookup-label ] [ dst/src1/src2 ] bi ; inline
 157
 158 M: _fixnum-add generate-insn label/dst/src1/src2 %fixnum-add ;
 159 M: _fixnum-sub generate-insn label/dst/src1/src2 %fixnum-sub ;
 160 M: _fixnum-mul generate-insn label/dst/src1/src2 %fixnum-mul ;
 161
 162 : dst/src/temp ( insn -- dst src temp )
 163     [ dst/src ] [ temp>> ] bi ; inline
 164
 165 M: ##integer>bignum generate-insn dst/src/temp %integer>bignum ;
 166 M: ##bignum>integer generate-insn dst/src/temp %bignum>integer ;
 167
 168 M: ##add-float generate-insn dst/src1/src2 %add-float ;
 169 M: ##sub-float generate-insn dst/src1/src2 %sub-float ;
 170 M: ##mul-float generate-insn dst/src1/src2 %mul-float ;
 171 M: ##div-float generate-insn dst/src1/src2 %div-float ;
 172
 173 M: ##sqrt generate-insn dst/src %sqrt ;
 174
 175 M: ##integer>float generate-insn dst/src %integer>float ;
 176 M: ##float>integer generate-insn dst/src %float>integer ;
 177
 178 M: ##copy generate-insn [ dst/src ] [ rep>> ] bi %copy ;
 179
 180 M: ##unbox-float generate-insn dst/src %unbox-float ;
 181 M: ##unbox-any-c-ptr generate-insn dst/src/temp %unbox-any-c-ptr ;
 182 M: ##box-float generate-insn dst/src/temp %box-float ;
 183 M: ##box-alien generate-insn dst/src/temp %box-alien ;
 184
 185 M: ##box-displaced-alien generate-insn
 186     [ dst/src1/src2 ] [ temp>> ] bi %box-displaced-alien ;
 187
 188 M: ##alien-unsigned-1 generate-insn dst/src %alien-unsigned-1 ;
 189 M: ##alien-unsigned-2 generate-insn dst/src %alien-unsigned-2 ;
 190 M: ##alien-unsigned-4 generate-insn dst/src %alien-unsigned-4 ;
 191 M: ##alien-signed-1   generate-insn dst/src %alien-signed-1   ;
 192 M: ##alien-signed-2   generate-insn dst/src %alien-signed-2   ;
 193 M: ##alien-signed-4   generate-insn dst/src %alien-signed-4   ;
 194 M: ##alien-cell       generate-insn dst/src %alien-cell       ;
 195 M: ##alien-float      generate-insn dst/src %alien-float      ;
 196 M: ##alien-double     generate-insn dst/src %alien-double     ;
 197
 198 : >alien-setter< ( insn -- src value )
 199     [ src>> ] [ value>> ] bi ; inline
 200
 201 M: ##set-alien-integer-1 generate-insn >alien-setter< %set-alien-integer-1 ;
 202 M: ##set-alien-integer-2 generate-insn >alien-setter< %set-alien-integer-2 ;
 203 M: ##set-alien-integer-4 generate-insn >alien-setter< %set-alien-integer-4 ;
 204 M: ##set-alien-cell      generate-insn >alien-setter< %set-alien-cell      ;
 205 M: ##set-alien-float     generate-insn >alien-setter< %set-alien-float     ;
 206 M: ##set-alien-double    generate-insn >alien-setter< %set-alien-double    ;
 207
 208 M: ##allot generate-insn
 209     {
 210         [ dst>> ]
 211         [ size>> ]
 212         [ class>> ]
 213         [ temp>> ]
 214     } cleave
 215     %allot ;
 216
 217 M: ##write-barrier generate-insn
 218     [ src>> ]
 219     [ card#>> ]
 220     [ table>> ]
 221     tri %write-barrier ;
 222
 223 ! GC checks
 224 : wipe-locs ( locs temp -- )
 225     '[
 226         _
 227         [ 0 %load-immediate ]
 228         [ swap [ %replace ] with each ] bi
 229     ] unless-empty ;
 230
 231 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 232
 233 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 234     temp operand n>> int-rep %reload
 235     gc-root temp %save-gc-root ;
 236
 237 M: object save-gc-root drop %save-gc-root ;
 238
 239 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 240
 241 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 242
 243 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 244
 245 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 246     gc-root temp %load-gc-root
 247     temp operand n>> int-rep %spill ;
 248
 249 M: object load-gc-root drop %load-gc-root ;
 250
 251 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 252
 253 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 254
 255 M: _gc generate-insn
 256     "no-gc" define-label
 257     {
 258         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 259         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 260         [ data-values>> save-data-regs ]
 261         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 262         [ tagged-values>> length %call-gc ]
 263         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 264         [ data-values>> load-data-regs ]
 265     } cleave
 266     "no-gc" resolve-label ;
 267
 268 M: _loop-entry generate-insn drop %loop-entry ;
 269
 270 M: ##alien-global generate-insn
 271     [ dst>> ] [ symbol>> ] [ library>> ] tri
 272     %alien-global ;
 273
 274 ! ##alien-invoke
 275 GENERIC: next-fastcall-param ( rep -- )
 276
 277 : ?dummy-stack-params ( rep -- )
 278     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 279
 280 : ?dummy-int-params ( rep -- )
 281     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 282
 283 : ?dummy-fp-params ( rep -- )
 284     drop dummy-fp-params? [ float-regs inc ] when ;
 285
 286 M: int-rep next-fastcall-param
 287     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 288
 289 M: single-float-rep next-fastcall-param
 290     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 291
 292 M: double-float-rep next-fastcall-param
 293     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 294
 295 GENERIC: reg-class-full? ( reg-class -- ? )
 296
 297 M: stack-params reg-class-full? drop t ;
 298
 299 M: reg-class reg-class-full?
 300     [ get ] [ param-regs length ] bi >= ;
 301
 302 : alloc-stack-param ( rep -- n reg-class rep )
 303     stack-params get
 304     [ rep-size cell align stack-params +@ ] dip
 305     stack-params dup ;
 306
 307 : alloc-fastcall-param ( rep -- n reg-class rep )
 308     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 309
 310 : alloc-parameter ( parameter -- reg rep )
 311     c-type-rep dup reg-class-of reg-class-full?
 312     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 313     [ param-reg ] dip ;
 314
 315 : (flatten-int-type) ( size -- seq )
 316     cell /i "void*" c-type <repetition> ;
 317
 318 GENERIC: flatten-value-type ( type -- types )
 319
 320 M: object flatten-value-type 1array ;
 321
 322 M: struct-type flatten-value-type ( type -- types )
 323     stack-size cell align (flatten-int-type) ;
 324
 325 M: long-long-type flatten-value-type ( type -- types )
 326     stack-size cell align (flatten-int-type) ;
 327
 328 : flatten-value-types ( params -- params )
 329     #! Convert value type structs to consecutive void*s.
 330     [
 331         0 [
 332             c-type
 333             [ parameter-align (flatten-int-type) % ] keep
 334             [ stack-size cell align + ] keep
 335             flatten-value-type %
 336         ] reduce drop
 337     ] { } make ;
 338
 339 : each-parameter ( parameters quot -- )
 340     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 341
 342 : reverse-each-parameter ( parameters quot -- )
 343     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 344
 345 : reset-fastcall-counts ( -- )
 346     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 347
 348 : with-param-regs ( quot -- )
 349     #! In quot you can call alloc-parameter
 350     [ reset-fastcall-counts call ] with-scope ; inline
 351
 352 : move-parameters ( node word -- )
 353     #! Moves values from C stack to registers (if word is
 354     #! %load-param-reg) and registers to C stack (if word is
 355     #! %save-param-reg).
 356     [ alien-parameters flatten-value-types ]
 357     [ '[ alloc-parameter _ execute ] ]
 358     bi* each-parameter ; inline
 359
 360 : unbox-parameters ( offset node -- )
 361     parameters>> [
 362         %prepare-unbox [ over + ] dip unbox-parameter
 363     ] reverse-each-parameter drop ;
 364
 365 : prepare-box-struct ( node -- offset )
 366     #! Return offset on C stack where to store unboxed
 367     #! parameters. If the C function is returning a structure,
 368     #! the first parameter is an implicit target area pointer,
 369     #! so we need to use a different offset.
 370     return>> large-struct?
 371     [ %prepare-box-struct cell ] [ 0 ] if ;
 372
 373 : objects>registers ( params -- )
 374     #! Generate code for unboxing a list of C types, then
 375     #! generate code for moving these parameters to registers on
 376     #! architectures where parameters are passed in registers.
 377     [
 378         [ prepare-box-struct ] keep
 379         [ unbox-parameters ] keep
 380         \ %load-param-reg move-parameters
 381     ] with-param-regs ;
 382
 383 : box-return* ( node -- )
 384     return>> [ ] [ box-return ] if-void ;
 385
 386 : check-dlsym ( symbols dll -- )
 387     dup dll-valid? [
 388         dupd '[ _ dlsym ] any?
 389         [ drop ] [ compiling-word get no-such-symbol ] if
 390     ] [
 391         dll-path compiling-word get no-such-library drop
 392     ] if ;
 393
 394 : stdcall-mangle ( symbol params -- symbol )
 395     parameters>> parameter-sizes drop number>string "@" glue ;
 396
 397 : alien-invoke-dlsym ( params -- symbols dll )
 398     [ [ function>> dup ] keep stdcall-mangle 2array ]
 399     [ library>> library dup [ dll>> ] when ]
 400     bi 2dup check-dlsym ;
 401
 402 M: ##alien-invoke generate-insn
 403     params>>
 404     ! Save registers for GC
 405     %prepare-alien-invoke
 406     ! Unbox parameters
 407     dup objects>registers
 408     %prepare-var-args
 409     ! Call function
 410     dup alien-invoke-dlsym %alien-invoke
 411     ! Box return value
 412     dup %cleanup
 413     box-return* ;
 414
 415 ! ##alien-indirect
 416 M: ##alien-indirect generate-insn
 417     params>>
 418     ! Save registers for GC
 419     %prepare-alien-invoke
 420     ! Save alien at top of stack to temporary storage
 421     %prepare-alien-indirect
 422     ! Unbox parameters
 423     dup objects>registers
 424     %prepare-var-args
 425     ! Call alien in temporary storage
 426     %alien-indirect
 427     ! Box return value
 428     dup %cleanup
 429     box-return* ;
 430
 431 ! ##alien-callback
 432 : box-parameters ( params -- )
 433     alien-parameters [ box-parameter ] each-parameter ;
 434
 435 : registers>objects ( node -- )
 436     ! Generate code for boxing input parameters in a callback.
 437     [
 438         dup \ %save-param-reg move-parameters
 439         "nest_stacks" f %alien-invoke
 440         box-parameters
 441     ] with-param-regs ;
 442
 443 TUPLE: callback-context ;
 444
 445 : current-callback ( -- id ) 2 getenv ;
 446
 447 : wait-to-return ( token -- )
 448     dup current-callback eq? [
 449         drop
 450     ] [
 451         yield-hook get call( -- ) wait-to-return
 452     ] if ;
 453
 454 : do-callback ( quot token -- )
 455     init-catchstack
 456     [ 2 setenv call ] keep
 457     wait-to-return ; inline
 458
 459 : callback-return-quot ( ctype -- quot )
 460     return>> {
 461         { [ dup "void" = ] [ drop [ ] ] }
 462         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 463         [ c-type c-type-unboxer-quot ]
 464     } cond ;
 465
 466 : callback-prep-quot ( params -- quot )
 467     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 468
 469 : wrap-callback-quot ( params -- quot )
 470     [
 471         [ callback-prep-quot ]
 472         [ quot>> ]
 473         [ callback-return-quot ] tri 3append ,
 474         [ callback-context new do-callback ] %
 475     ] [ ] make ;
 476
 477 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 478
 479 M: ##callback-return generate-insn
 480     #! All the extra book-keeping for %unwind is only for x86.
 481     #! On other platforms its an alias for %return.
 482     params>> %callback-return ;
 483
 484 M: ##alien-callback generate-insn
 485     params>>
 486     [ registers>objects ]
 487     [ wrap-callback-quot %alien-callback ]
 488     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 489     tri ;
 490
 491 M: _prologue generate-insn
 492     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
 493
 494 M: _epilogue generate-insn
 495     stack-frame>> total-size>> %epilogue ;
 496
 497 M: _label generate-insn
 498     id>> lookup-label resolve-label ;
 499
 500 M: _branch generate-insn
 501     label>> lookup-label %jump-label ;
 502
 503 : >compare< ( insn -- dst temp cc src1 src2 )
 504     {
 505         [ dst>> ]
 506         [ temp>> ]
 507         [ cc>> ]
 508         [ src1>> ]
 509         [ src2>> ]
 510     } cleave ; inline
 511
 512 M: ##compare generate-insn >compare< %compare ;
 513 M: ##compare-imm generate-insn >compare< %compare-imm ;
 514 M: ##compare-float generate-insn >compare< %compare-float ;
 515
 516 : >binary-branch< ( insn -- label cc src1 src2 )
 517     {
 518         [ label>> lookup-label ]
 519         [ cc>> ]
 520         [ src1>> ]
 521         [ src2>> ]
 522     } cleave ; inline
 523
 524 M: _compare-branch generate-insn
 525     >binary-branch< %compare-branch ;
 526
 527 M: _compare-imm-branch generate-insn
 528     >binary-branch< %compare-imm-branch ;
 529
 530 M: _compare-float-branch generate-insn
 531     >binary-branch< %compare-float-branch ;
 532
 533 M: _spill generate-insn
 534     [ src>> ] [ n>> ] [ rep>> ] tri %spill ;
 535
 536 M: _reload generate-insn
 537     [ dst>> ] [ n>> ] [ rep>> ] tri %reload ;
 538
 539 M: _spill-area-size generate-insn drop ;