basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make math math.order math.parser sequences accessors
   4 kernel kernel.private layouts assocs words summary arrays
   5 combinators classes.algebra alien alien.c-types
   6 alien.strings alien.arrays alien.complex alien.libraries sets libc
   7 continuations.private fry cpu.architecture classes locals
   8 source-files.errors slots parser generic.parser
   9 compiler.errors
  10 compiler.alien
  11 compiler.constants
  12 compiler.cfg
  13 compiler.cfg.instructions
  14 compiler.cfg.stack-frame
  15 compiler.cfg.registers
  16 compiler.cfg.builder
  17 compiler.codegen.fixup
  18 compiler.utilities ;
  19 QUALIFIED: classes.struct
  20 QUALIFIED: alien.structs
  21 IN: compiler.codegen
  22
  23 SYMBOL: insn-counts
  24
  25 H{ } clone insn-counts set-global
  26
  27 GENERIC: generate-insn ( insn -- )
  28
  29 TUPLE: asm label code calls ;
  30
  31 SYMBOL: calls
  32
  33 : add-call ( word -- )
  34     #! Compile this word later.
  35     calls get push ;
  36
  37 SYMBOL: compiling-word
  38
  39 : compiled-stack-traces? ( -- ? ) 67 getenv ;
  40
  41 ! Mapping _label IDs to label instances
  42 SYMBOL: labels
  43
  44 : init-generator ( word -- )
  45     H{ } clone labels set
  46     V{ } clone calls set
  47     compiling-word set
  48     compiled-stack-traces? [ compiling-word get add-literal ] when ;
  49
  50 : generate-insns ( asm -- code )
  51     [
  52         [ word>> init-generator ]
  53         [
  54             instructions>>
  55             [
  56                 [ class insn-counts get inc-at ]
  57                 [ generate-insn ]
  58                 bi
  59             ] each
  60         ] bi
  61     ] with-fixup ;
  62
  63 : generate ( mr -- asm )
  64     [
  65         [ label>> ] [ generate-insns ] bi calls get
  66         asm boa
  67     ] with-scope ;
  68
  69 : lookup-label ( id -- label )
  70     labels get [ drop <label> ] cache ;
  71
  72 ! Special cases
  73 M: ##no-tco generate-insn drop ;
  74
  75 M: ##call generate-insn
  76     word>> dup sub-primitive>>
  77     [ first % ] [ [ add-call ] [ %call ] bi ] ?if ;
  78
  79 M: ##jump generate-insn word>> [ add-call ] [ %jump ] bi ;
  80
  81 M: _dispatch-label generate-insn
  82     label>> lookup-label
  83     cell 0 <repetition> %
  84     rc-absolute-cell label-fixup ;
  85
  86 M: _prologue generate-insn
  87     stack-frame>> [ stack-frame set ] [ total-size>> %prologue ] bi ;
  88
  89 M: _epilogue generate-insn
  90     stack-frame>> total-size>> %epilogue ;
  91
  92 M: _spill-area-size generate-insn drop ;
  93
  94 ! Some meta-programming to generate simple code generators, where
  95 ! the instruction is unpacked and then a %word is called
  96 <<
  97
  98 : insn-slot-quot ( spec -- quot )
  99     name>> [ reader-word ] [ "label" = ] bi
 100     [ \ lookup-label [ ] 2sequence ] [ [ ] 1sequence ] if ;
 101
 102 : codegen-method-body ( class word -- quot )
 103     [
 104         "insn-slots" word-prop
 105         [ insn-slot-quot ] map cleave>quot
 106     ] dip suffix ;
 107
 108 SYNTAX: CODEGEN:
 109     scan-word [ \ generate-insn create-method-in ] keep scan-word
 110     codegen-method-body define ;
 111 >>
 112
 113 CODEGEN: ##load-immediate %load-immediate
 114 CODEGEN: ##load-reference %load-reference
 115 CODEGEN: ##peek %peek
 116 CODEGEN: ##replace %replace
 117 CODEGEN: ##inc-d %inc-d
 118 CODEGEN: ##inc-r %inc-r
 119 CODEGEN: ##return %return
 120 CODEGEN: ##slot %slot
 121 CODEGEN: ##slot-imm %slot-imm
 122 CODEGEN: ##set-slot %set-slot
 123 CODEGEN: ##set-slot-imm %set-slot-imm
 124 CODEGEN: ##string-nth %string-nth
 125 CODEGEN: ##set-string-nth-fast %set-string-nth-fast
 126 CODEGEN: ##add %add
 127 CODEGEN: ##add-imm %add-imm
 128 CODEGEN: ##sub %sub
 129 CODEGEN: ##sub-imm %sub-imm
 130 CODEGEN: ##mul %mul
 131 CODEGEN: ##mul-imm %mul-imm
 132 CODEGEN: ##and %and
 133 CODEGEN: ##and-imm %and-imm
 134 CODEGEN: ##or %or
 135 CODEGEN: ##or-imm %or-imm
 136 CODEGEN: ##xor %xor
 137 CODEGEN: ##xor-imm %xor-imm
 138 CODEGEN: ##shl %shl
 139 CODEGEN: ##shl-imm %shl-imm
 140 CODEGEN: ##shr %shr
 141 CODEGEN: ##shr-imm %shr-imm
 142 CODEGEN: ##sar %sar
 143 CODEGEN: ##sar-imm %sar-imm
 144 CODEGEN: ##min %min
 145 CODEGEN: ##max %max
 146 CODEGEN: ##not %not
 147 CODEGEN: ##log2 %log2
 148 CODEGEN: ##copy %copy
 149 CODEGEN: ##integer>bignum %integer>bignum
 150 CODEGEN: ##bignum>integer %bignum>integer
 151 CODEGEN: ##unbox-float %unbox-float
 152 CODEGEN: ##box-float %box-float
 153 CODEGEN: ##add-float %add-float
 154 CODEGEN: ##sub-float %sub-float
 155 CODEGEN: ##mul-float %mul-float
 156 CODEGEN: ##div-float %div-float
 157 CODEGEN: ##min-float %min-float
 158 CODEGEN: ##max-float %max-float
 159 CODEGEN: ##sqrt %sqrt
 160 CODEGEN: ##unary-float-function %unary-float-function
 161 CODEGEN: ##binary-float-function %binary-float-function
 162 CODEGEN: ##single>double-float %single>double-float
 163 CODEGEN: ##double>single-float %double>single-float
 164 CODEGEN: ##integer>float %integer>float
 165 CODEGEN: ##float>integer %float>integer
 166 CODEGEN: ##unbox-vector %unbox-vector
 167 CODEGEN: ##broadcast-vector %broadcast-vector
 168 CODEGEN: ##gather-vector-2 %gather-vector-2
 169 CODEGEN: ##gather-vector-4 %gather-vector-4
 170 CODEGEN: ##box-vector %box-vector
 171 CODEGEN: ##add-vector %add-vector
 172 CODEGEN: ##sub-vector %sub-vector
 173 CODEGEN: ##mul-vector %mul-vector
 174 CODEGEN: ##div-vector %div-vector
 175 CODEGEN: ##min-vector %min-vector
 176 CODEGEN: ##max-vector %max-vector
 177 CODEGEN: ##sqrt-vector %sqrt-vector
 178 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 179 CODEGEN: ##box-alien %box-alien
 180 CODEGEN: ##box-displaced-alien %box-displaced-alien
 181 CODEGEN: ##unbox-alien %unbox-alien
 182 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 183 CODEGEN: ##alien-unsigned-1 %alien-unsigned-1
 184 CODEGEN: ##alien-unsigned-2 %alien-unsigned-2
 185 CODEGEN: ##alien-unsigned-4 %alien-unsigned-4
 186 CODEGEN: ##alien-signed-1 %alien-signed-1
 187 CODEGEN: ##alien-signed-2 %alien-signed-2
 188 CODEGEN: ##alien-signed-4 %alien-signed-4
 189 CODEGEN: ##alien-cell %alien-cell
 190 CODEGEN: ##alien-float %alien-float
 191 CODEGEN: ##alien-double %alien-double
 192 CODEGEN: ##alien-vector %alien-vector
 193 CODEGEN: ##set-alien-integer-1 %set-alien-integer-1
 194 CODEGEN: ##set-alien-integer-2 %set-alien-integer-2
 195 CODEGEN: ##set-alien-integer-4 %set-alien-integer-4
 196 CODEGEN: ##set-alien-cell %set-alien-cell
 197 CODEGEN: ##set-alien-float %set-alien-float
 198 CODEGEN: ##set-alien-double %set-alien-double
 199 CODEGEN: ##set-alien-vector %set-alien-vector
 200 CODEGEN: ##allot %allot
 201 CODEGEN: ##write-barrier %write-barrier
 202 CODEGEN: ##compare %compare
 203 CODEGEN: ##compare-imm %compare-imm
 204 CODEGEN: ##compare-float-ordered %compare-float-ordered
 205 CODEGEN: ##compare-float-unordered %compare-float-unordered
 206 CODEGEN: ##save-context %save-context
 207
 208 CODEGEN: _fixnum-add %fixnum-add
 209 CODEGEN: _fixnum-sub %fixnum-sub
 210 CODEGEN: _fixnum-mul %fixnum-mul
 211 CODEGEN: _label resolve-label
 212 CODEGEN: _branch %jump-label
 213 CODEGEN: _compare-branch %compare-branch
 214 CODEGEN: _compare-imm-branch %compare-imm-branch
 215 CODEGEN: _compare-float-ordered-branch %compare-float-ordered-branch
 216 CODEGEN: _compare-float-unordered-branch %compare-float-unordered-branch
 217 CODEGEN: _dispatch %dispatch
 218 CODEGEN: _spill %spill
 219 CODEGEN: _reload %reload
 220
 221 ! ##gc
 222 : wipe-locs ( locs temp -- )
 223     '[
 224         _
 225         [ 0 %load-immediate ]
 226         [ swap [ %replace ] with each ] bi
 227     ] unless-empty ;
 228
 229 GENERIC# save-gc-root 1 ( gc-root operand temp -- )
 230
 231 M:: spill-slot save-gc-root ( gc-root operand temp -- )
 232     temp int-rep operand n>> %reload
 233     gc-root temp %save-gc-root ;
 234
 235 M: object save-gc-root drop %save-gc-root ;
 236
 237 : save-gc-roots ( gc-roots temp -- ) '[ _ save-gc-root ] assoc-each ;
 238
 239 : save-data-regs ( data-regs -- ) [ first3 %spill ] each ;
 240
 241 GENERIC# load-gc-root 1 ( gc-root operand temp -- )
 242
 243 M:: spill-slot load-gc-root ( gc-root operand temp -- )
 244     gc-root temp %load-gc-root
 245     temp int-rep operand n>> %spill ;
 246
 247 M: object load-gc-root drop %load-gc-root ;
 248
 249 : load-gc-roots ( gc-roots temp -- ) '[ _ load-gc-root ] assoc-each ;
 250
 251 : load-data-regs ( data-regs -- ) [ first3 %reload ] each ;
 252
 253 M: _gc generate-insn
 254     "no-gc" define-label
 255     {
 256         [ [ "no-gc" get ] dip [ temp1>> ] [ temp2>> ] bi %check-nursery ]
 257         [ [ uninitialized-locs>> ] [ temp1>> ] bi wipe-locs ]
 258         [ data-values>> save-data-regs ]
 259         [ [ tagged-values>> ] [ temp1>> ] bi save-gc-roots ]
 260         [ [ temp1>> ] [ temp2>> ] bi t %save-context ]
 261         [ tagged-values>> length %call-gc ]
 262         [ [ tagged-values>> ] [ temp1>> ] bi load-gc-roots ]
 263         [ data-values>> load-data-regs ]
 264     } cleave
 265     "no-gc" resolve-label ;
 266
 267 M: _loop-entry generate-insn drop %loop-entry ;
 268
 269 M: ##alien-global generate-insn
 270     [ dst>> ] [ symbol>> ] [ library>> ] tri
 271     %alien-global ;
 272
 273 ! ##alien-invoke
 274 GENERIC: next-fastcall-param ( rep -- )
 275
 276 : ?dummy-stack-params ( rep -- )
 277     dummy-stack-params? [ rep-size cell align stack-params +@ ] [ drop ] if ;
 278
 279 : ?dummy-int-params ( rep -- )
 280     dummy-int-params? [ rep-size cell /i 1 max int-regs +@ ] [ drop ] if ;
 281
 282 : ?dummy-fp-params ( rep -- )
 283     drop dummy-fp-params? [ float-regs inc ] when ;
 284
 285 M: int-rep next-fastcall-param
 286     int-regs inc [ ?dummy-stack-params ] [ ?dummy-fp-params ] bi ;
 287
 288 M: float-rep next-fastcall-param
 289     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 290
 291 M: double-rep next-fastcall-param
 292     float-regs inc [ ?dummy-stack-params ] [ ?dummy-int-params ] bi ;
 293
 294 GENERIC: reg-class-full? ( reg-class -- ? )
 295
 296 M: stack-params reg-class-full? drop t ;
 297
 298 M: reg-class reg-class-full?
 299     [ get ] [ param-regs length ] bi >= ;
 300
 301 : alloc-stack-param ( rep -- n reg-class rep )
 302     stack-params get
 303     [ rep-size cell align stack-params +@ ] dip
 304     stack-params dup ;
 305
 306 : alloc-fastcall-param ( rep -- n reg-class rep )
 307     [ [ reg-class-of get ] [ reg-class-of ] [ next-fastcall-param ] tri ] keep ;
 308
 309 : alloc-parameter ( parameter -- reg rep )
 310     c-type-rep dup reg-class-of reg-class-full?
 311     [ alloc-stack-param ] [ alloc-fastcall-param ] if
 312     [ param-reg ] dip ;
 313
 314 : (flatten-int-type) ( size -- seq )
 315     cell /i "void*" c-type <repetition> ;
 316
 317 GENERIC: flatten-value-type ( type -- types )
 318
 319 M: object flatten-value-type 1array ;
 320
 321 M: alien.structs:struct-type flatten-value-type ( type -- types )
 322     stack-size cell align (flatten-int-type) ;
 323
 324 M: classes.struct:struct-c-type flatten-value-type ( type -- types )
 325     stack-size cell align (flatten-int-type) ;
 326
 327 M: long-long-type flatten-value-type ( type -- types )
 328     stack-size cell align (flatten-int-type) ;
 329
 330 : flatten-value-types ( params -- params )
 331     #! Convert value type structs to consecutive void*s.
 332     [
 333         0 [
 334             c-type
 335             [ parameter-align (flatten-int-type) % ] keep
 336             [ stack-size cell align + ] keep
 337             flatten-value-type %
 338         ] reduce drop
 339     ] { } make ;
 340
 341 : each-parameter ( parameters quot -- )
 342     [ [ parameter-sizes nip ] keep ] dip 2each ; inline
 343
 344 : reverse-each-parameter ( parameters quot -- )
 345     [ [ parameter-sizes nip ] keep ] dip 2reverse-each ; inline
 346
 347 : reset-fastcall-counts ( -- )
 348     { int-regs float-regs stack-params } [ 0 swap set ] each ;
 349
 350 : with-param-regs ( quot -- )
 351     #! In quot you can call alloc-parameter
 352     [ reset-fastcall-counts call ] with-scope ; inline
 353
 354 : move-parameters ( node word -- )
 355     #! Moves values from C stack to registers (if word is
 356     #! %load-param-reg) and registers to C stack (if word is
 357     #! %save-param-reg).
 358     [ alien-parameters flatten-value-types ]
 359     [ '[ alloc-parameter _ execute ] ]
 360     bi* each-parameter ; inline
 361
 362 : unbox-parameters ( offset node -- )
 363     parameters>> [
 364         %prepare-unbox [ over + ] dip unbox-parameter
 365     ] reverse-each-parameter drop ;
 366
 367 : prepare-box-struct ( node -- offset )
 368     #! Return offset on C stack where to store unboxed
 369     #! parameters. If the C function is returning a structure,
 370     #! the first parameter is an implicit target area pointer,
 371     #! so we need to use a different offset.
 372     return>> large-struct?
 373     [ %prepare-box-struct cell ] [ 0 ] if ;
 374
 375 : objects>registers ( params -- )
 376     #! Generate code for unboxing a list of C types, then
 377     #! generate code for moving these parameters to registers on
 378     #! architectures where parameters are passed in registers.
 379     [
 380         [ prepare-box-struct ] keep
 381         [ unbox-parameters ] keep
 382         \ %load-param-reg move-parameters
 383     ] with-param-regs ;
 384
 385 : box-return* ( node -- )
 386     return>> [ ] [ box-return ] if-void ;
 387
 388 : check-dlsym ( symbols dll -- )
 389     dup dll-valid? [
 390         dupd '[ _ dlsym ] any?
 391         [ drop ] [ compiling-word get no-such-symbol ] if
 392     ] [
 393         dll-path compiling-word get no-such-library drop
 394     ] if ;
 395
 396 : stdcall-mangle ( symbol params -- symbol )
 397     parameters>> parameter-sizes drop number>string "@" glue ;
 398
 399 : alien-invoke-dlsym ( params -- symbols dll )
 400     [ [ function>> dup ] keep stdcall-mangle 2array ]
 401     [ library>> library dup [ dll>> ] when ]
 402     bi 2dup check-dlsym ;
 403
 404 M: ##alien-invoke generate-insn
 405     params>>
 406     ! Unbox parameters
 407     dup objects>registers
 408     %prepare-var-args
 409     ! Call function
 410     dup alien-invoke-dlsym %alien-invoke
 411     ! Box return value
 412     dup %cleanup
 413     box-return* ;
 414
 415 ! ##alien-indirect
 416 M: ##alien-indirect generate-insn
 417     params>>
 418     ! Save alien at top of stack to temporary storage
 419     %prepare-alien-indirect
 420     ! Unbox parameters
 421     dup objects>registers
 422     %prepare-var-args
 423     ! Call alien in temporary storage
 424     %alien-indirect
 425     ! Box return value
 426     dup %cleanup
 427     box-return* ;
 428
 429 ! ##alien-callback
 430 : box-parameters ( params -- )
 431     alien-parameters [ box-parameter ] each-parameter ;
 432
 433 : registers>objects ( node -- )
 434     ! Generate code for boxing input parameters in a callback.
 435     [
 436         dup \ %save-param-reg move-parameters
 437         "nest_stacks" f %alien-invoke
 438         box-parameters
 439     ] with-param-regs ;
 440
 441 TUPLE: callback-context ;
 442
 443 : current-callback ( -- id ) 2 getenv ;
 444
 445 : wait-to-return ( token -- )
 446     dup current-callback eq? [
 447         drop
 448     ] [
 449         yield-hook get call( -- ) wait-to-return
 450     ] if ;
 451
 452 : do-callback ( quot token -- )
 453     init-catchstack
 454     [ 2 setenv call ] keep
 455     wait-to-return ; inline
 456
 457 : callback-return-quot ( ctype -- quot )
 458     return>> {
 459         { [ dup void? ] [ drop [ ] ] }
 460         { [ dup large-struct? ] [ heap-size '[ _ memcpy ] ] }
 461         [ c-type c-type-unboxer-quot ]
 462     } cond ;
 463
 464 : callback-prep-quot ( params -- quot )
 465     parameters>> [ c-type c-type-boxer-quot ] map spread>quot ;
 466
 467 : wrap-callback-quot ( params -- quot )
 468     [
 469         [ callback-prep-quot ]
 470         [ quot>> ]
 471         [ callback-return-quot ] tri 3append ,
 472         [ callback-context new do-callback ] %
 473     ] [ ] make ;
 474
 475 : %unnest-stacks ( -- ) "unnest_stacks" f %alien-invoke ;
 476
 477 M: ##callback-return generate-insn
 478     #! All the extra book-keeping for %unwind is only for x86.
 479     #! On other platforms its an alias for %return.
 480     params>> %callback-return ;
 481
 482 M: ##alien-callback generate-insn
 483     params>>
 484     [ registers>objects ]
 485     [ wrap-callback-quot %alien-callback ]
 486     [ alien-return [ %unnest-stacks ] [ %callback-value ] if-void ]
 487     tri ;