basis/compiler/tree/debugger/debugger.factor

   1 ! Copyright (C) 2006, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel assocs match fry accessors namespaces make effects
   4 sequences sequences.private quotations generic macros arrays
   5 prettyprint prettyprint.backend prettyprint.custom
   6 prettyprint.sections math words combinators
   7 combinators.short-circuit io sorting hints
   8 compiler.tree
   9 compiler.tree.recursive
  10 compiler.tree.normalization
  11 compiler.tree.cleanup
  12 compiler.tree.propagation
  13 compiler.tree.propagation.info
  14 compiler.tree.escape-analysis
  15 compiler.tree.tuple-unboxing
  16 compiler.tree.def-use
  17 compiler.tree.builder
  18 compiler.tree.optimizer
  19 compiler.tree.combinators
  20 compiler.tree.checker
  21 compiler.tree.identities
  22 compiler.tree.dead-code
  23 compiler.tree.modular-arithmetic ;
  24 FROM: fry => _ ;
  25 RENAME: _ match => __
  26 IN: compiler.tree.debugger
  27
  28 ! A simple tool for turning tree IR into quotations and
  29 ! printing reports, for debugging purposes.
  30
  31 GENERIC: node>quot ( node -- )
  32
  33 MACRO: match-choose ( alist -- )
  34     [ '[ _ ] ] assoc-map '[ _ match-cond ] ;
  35
  36 MATCH-VARS: ?a ?b ?c ;
  37
  38 : pretty-shuffle ( effect -- word/f )
  39     [ in>> ] [ out>> ] bi 2array {
  40         { { { } { } } [ ] }
  41         { { { ?a } { ?a } } [ ] }
  42         { { { ?a ?b } { ?a ?b } } [ ] }
  43         { { { ?a ?b ?c } { ?a ?b ?c } } [ ] }
  44         { { { ?a } { } } [ drop ] }
  45         { { { ?a ?b } { } } [ 2drop ] }
  46         { { { ?a ?b ?c } { } } [ 3drop ] }
  47         { { { ?a } { ?a ?a } } [ dup ] }
  48         { { { ?a ?b } { ?a ?b ?a ?b } } [ 2dup ] }
  49         { { { ?a ?b ?c } { ?a ?b ?c ?a ?b ?c } } [ 3dup ] }
  50         { { { ?a ?b } { ?a ?b ?a } } [ over ] }
  51         { { { ?b ?a } { ?a ?b } } [ swap ] }
  52         { { { ?b ?a ?c } { ?a ?b ?c } } [ swapd ] }
  53         { { { ?a ?b } { ?a ?a ?b } } [ dupd ] }
  54         { { { ?a ?b ?c } { ?a ?b ?c ?a } } [ pick ] }
  55         { { { ?a ?b ?c } { ?c ?a ?b } } [ -rot ] }
  56         { { { ?a ?b ?c } { ?b ?c ?a } } [ rot ] }
  57         { { { ?a ?b } { ?b } } [ nip ] }
  58         { { { ?a ?b ?c } { ?c } } [ 2nip ] }
  59         { __ f }
  60     } match-choose ;
  61
  62 TUPLE: shuffle-node { effect effect } ;
  63
  64 M: shuffle-node pprint* effect>> effect>string text ;
  65
  66 : (shuffle-effect) ( in out #shuffle -- effect )
  67     mapping>> '[ _ at ] map <effect> ;
  68
  69 : shuffle-effect ( #shuffle -- effect )
  70     [ in-d>> ] [ out-d>> ] [ ] tri (shuffle-effect) ;
  71
  72 : #>r? ( #shuffle -- ? )
  73     {
  74         [ in-d>> length 1 = ]
  75         [ out-r>> length 1 = ]
  76         [ in-r>> empty? ]
  77         [ out-d>> empty? ]
  78     } 1&& ;
  79
  80 : #r>? ( #shuffle -- ? )
  81     {
  82         [ in-d>> empty? ]
  83         [ out-r>> empty? ]
  84         [ in-r>> length 1 = ]
  85         [ out-d>> length 1 = ]
  86     } 1&& ;
  87
  88 SYMBOLS: >R R> ;
  89
  90 M: #shuffle node>quot
  91     {
  92         { [ dup #>r? ] [ drop \ >R , ] }
  93         { [ dup #r>? ] [ drop \ R> , ] }
  94         {
  95             [ dup [ in-r>> empty? ] [ out-r>> empty? ] bi and ]
  96             [
  97                 shuffle-effect dup pretty-shuffle
  98                 [ % ] [ shuffle-node boa , ] ?if
  99             ]
 100         }
 101         [ drop "COMPLEX SHUFFLE" , ]
 102     } cond ;
 103
 104 M: #push node>quot literal>> literalize , ;
 105
 106 M: #call node>quot word>> , ;
 107
 108 M: #call-recursive node>quot label>> id>> , ;
 109
 110 DEFER: nodes>quot
 111
 112 DEFER: label
 113
 114 M: #recursive node>quot
 115     [ label>> id>> literalize , ]
 116     [ child>> nodes>quot , \ label , ]
 117     bi ;
 118
 119 M: #if node>quot
 120     children>> [ nodes>quot ] map % \ if , ;
 121
 122 M: #dispatch node>quot
 123     children>> [ nodes>quot ] map , \ dispatch , ;
 124
 125 M: #alien-invoke node>quot params>> , \ #alien-invoke , ;
 126
 127 M: #alien-indirect node>quot params>> , \ #alien-indirect , ;
 128
 129 M: #alien-callback node>quot params>> , \ #alien-callback , ;
 130
 131 M: node node>quot drop ;
 132
 133 : nodes>quot ( node -- quot )
 134     [ [ node>quot ] each ] [ ] make ;
 135
 136 GENERIC: optimized. ( quot/word -- )
 137
 138 M: word optimized. specialized-def optimized. ;
 139
 140 M: callable optimized. build-tree optimize-tree nodes>quot . ;
 141
 142 SYMBOL: words-called
 143 SYMBOL: generics-called
 144 SYMBOL: methods-called
 145 SYMBOL: intrinsics-called
 146 SYMBOL: node-count
 147
 148 : make-report ( word/quot -- assoc )
 149     [
 150         build-tree optimize-tree
 151
 152         H{ } clone words-called set
 153         H{ } clone generics-called set
 154         H{ } clone methods-called set
 155         H{ } clone intrinsics-called set
 156
 157         0 swap [
 158             [ 1 + ] dip
 159             dup #call? [
 160                 word>> {
 161                     { [ dup "intrinsic" word-prop ] [ intrinsics-called ] }
 162                     { [ dup generic? ] [ generics-called ] }
 163                     { [ dup method-body? ] [ methods-called ] }
 164                     [ words-called ]
 165                 } cond get inc-at
 166             ] [ drop ] if
 167         ] each-node
 168         node-count set
 169     ] H{ } make-assoc ;
 170
 171 : report. ( report -- )
 172     [
 173         "==== Total number of IR nodes:" print
 174         node-count get .
 175
 176         {
 177             { generics-called "==== Generic word calls:" }
 178             { words-called "==== Ordinary word calls:" }
 179             { methods-called "==== Non-inlined method calls:" }
 180             { intrinsics-called "==== Open-coded intrinsic calls:" }
 181         } [
 182             nl print get keys natural-sort stack.
 183         ] assoc-each
 184     ] bind ;
 185
 186 : optimizer-report. ( word -- )
 187     make-report report. ;
 188
 189 ! More utilities
 190
 191 : final-info ( quot -- seq )
 192     build-tree
 193     analyze-recursive
 194     normalize
 195     propagate
 196     compute-def-use
 197     dup check-nodes
 198     last node-input-infos ;
 199
 200 : final-classes ( quot -- seq )
 201     final-info [ class>> ] map ;
 202
 203 : final-literals ( quot -- seq )
 204     final-info [ literal>> ] map ;
 205
 206 : cleaned-up-tree ( quot -- nodes )
 207     [
 208         build-tree
 209         analyze-recursive
 210         normalize
 211         propagate
 212         cleanup
 213         escape-analysis
 214         unbox-tuples
 215         apply-identities
 216         compute-def-use
 217         remove-dead-code
 218         compute-def-use
 219         optimize-modular-arithmetic
 220     ] with-scope ;
 221
 222 : inlined? ( quot seq/word -- ? )
 223     [ cleaned-up-tree ] dip
 224     dup word? [ 1array ] when
 225     '[ dup #call? [ word>> _ member? ] [ drop f ] if ]
 226     contains-node? not ;