basis/compiler/tree/propagation/simd/simd.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs byte-arrays combinators compiler.cfg.builder
   4 continuations fry sequences compiler.tree.propagation.info
   5 compiler.tree.propagation.nodes cpu.architecture kernel layouts words
   6 make math math.intervals math.vectors.simd.intrinsics namespaces ;
   7 IN: compiler.tree.propagation.simd
   8
   9 CONSTANT: vector>vector-intrinsics
  10     {
  11         (simd-v+)
  12         (simd-v-)
  13         (simd-vneg)
  14         (simd-v+-)
  15         (simd-vs+)
  16         (simd-vs-)
  17         (simd-vs*)
  18         (simd-v*)
  19         (simd-v*high)
  20         (simd-v*hs+)
  21         (simd-v/)
  22         (simd-vmin)
  23         (simd-vmax)
  24         (simd-vavg)
  25         (simd-vsqrt)
  26         (simd-vabs)
  27         (simd-vbitand)
  28         (simd-vbitandn)
  29         (simd-vbitor)
  30         (simd-vbitxor)
  31         (simd-vbitnot)
  32         (simd-vand)
  33         (simd-vandn)
  34         (simd-vor)
  35         (simd-vxor)
  36         (simd-vnot)
  37         (simd-vlshift)
  38         (simd-vrshift)
  39         (simd-hlshift)
  40         (simd-hrshift)
  41         (simd-vshuffle-elements)
  42         (simd-vshuffle2-elements)
  43         (simd-vshuffle-bytes)
  44         (simd-vmerge-head)
  45         (simd-vmerge-tail)
  46         (simd-v<=)
  47         (simd-v<)
  48         (simd-v=)
  49         (simd-v>)
  50         (simd-v>=)
  51         (simd-vunordered?)
  52         (simd-v>float)
  53         (simd-v>integer)
  54         (simd-vpack-signed)
  55         (simd-vpack-unsigned)
  56         (simd-vunpack-head)
  57         (simd-vunpack-tail)
  58         (simd-with)
  59         (simd-gather-2)
  60         (simd-gather-4)
  61         alien-vector
  62     }
  63
  64 CONSTANT: vector-other-intrinsics
  65     {
  66         (simd-v.)
  67         (simd-vsad)
  68         (simd-sum)
  69         (simd-vany?)
  70         (simd-vall?)
  71         (simd-vnone?)
  72         (simd-vgetmask)
  73         (simd-select)
  74         set-alien-vector
  75     }
  76
  77 : vector-intrinsics ( -- x )
  78     vector>vector-intrinsics vector-other-intrinsics append ;
  79
  80 vector>vector-intrinsics [ { byte-array } "default-output-classes" set-word-prop ] each
  81
  82 : scalar-output-class ( rep -- class )
  83     dup literal?>> [
  84         literal>> scalar-rep-of {
  85             { float-rep [ float ] }
  86             { double-rep [ float ] }
  87             { longlong-scalar-rep [ integer ] }
  88             { ulonglong-scalar-rep [ integer ] }
  89             { int-scalar-rep [ cell 8 = [ fixnum ] [ integer ] if ] }
  90             { uint-scalar-rep [ cell 8 = [ fixnum ] [ integer ] if ] }
  91             [ drop fixnum ]
  92         } case
  93     ] [ drop real ] if
  94     <class-info> ;
  95
  96 \ (simd-sum) [ nip scalar-output-class ] "outputs" set-word-prop
  97
  98 \ (simd-v.) [ 2nip scalar-output-class ] "outputs" set-word-prop
  99
 100 {
 101     (simd-vany?)
 102     (simd-vall?)
 103     (simd-vnone?)
 104 } [ { boolean } "default-output-classes" set-word-prop ] each
 105
 106 \ (simd-select) [ 2nip scalar-output-class ] "outputs" set-word-prop
 107
 108 \ assert-positive [
 109     real [0,inf] <class/interval-info> value-info-intersect
 110 ] "outputs" set-word-prop
 111
 112 \ (simd-vgetmask) { fixnum } "default-output-classes" set-word-prop
 113
 114 : clone-with-value-infos ( node -- node' )
 115     clone dup in-d>> extract-value-info >>info ;
 116
 117 : try-intrinsic ( node intrinsic-quot -- ? )
 118     '[
 119         _ clone-with-value-infos
 120         _ with-dummy-cfg-builder
 121         t
 122     ] [ drop f ] recover ;
 123
 124 : inline-unless-intrinsic ( word -- )
 125     dup '[
 126         _ swap over "intrinsic" word-prop
 127         "always-inline-simd-intrinsics" get not swap and
 128         ! word node intrinsic
 129         [ try-intrinsic [ drop f ] [ def>> ] if ]
 130         [ drop def>> ] if*
 131     ]
 132     "custom-inlining" set-word-prop ;
 133
 134 vector-intrinsics [ inline-unless-intrinsic ] each