basis/compiler/tree/propagation/slots/slots.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: fry assocs arrays byte-arrays strings accessors sequences
   4 kernel slots classes.algebra classes.tuple classes.tuple.private
   5 words math math.private combinators sequences.private namespaces
   6 slots.private classes compiler.tree.propagation.info ;
   7 IN: compiler.tree.propagation.slots
   8
   9 ! Propagation of immutable slots and array lengths
  10
  11 ! Revisit this code when delegation is removed and when complex
  12 ! numbers become tuples.
  13
  14 UNION: fixed-length-sequence array byte-array string ;
  15
  16 : sequence-constructor? ( word -- ? )
  17     { <array> <byte-array> <string> } memq? ;
  18
  19 : constructor-output-class ( word -- class )
  20     {
  21         { <array> array }
  22         { <byte-array> byte-array }
  23         { <string> string }
  24     } at ;
  25
  26 : propagate-sequence-constructor ( #call word -- infos )
  27     [ in-d>> first <sequence-info> ]
  28     [ constructor-output-class <class-info> ]
  29     bi* value-info-intersect 1array ;
  30
  31 : tuple-constructor? ( word -- ? )
  32     { <tuple-boa> <complex> } memq? ;
  33
  34 : fold-<tuple-boa> ( values class -- info )
  35     [ , f , [ literal>> ] map % ] { } make >tuple
  36     <literal-info> ;
  37
  38 : (propagate-tuple-constructor) ( values class -- info )
  39     [ [ value-info ] map ] dip [ read-only-slots ] keep
  40     over 2 tail-slice [ dup [ literal?>> ] when ] all? [
  41         [ 2 tail-slice ] dip fold-<tuple-boa>
  42     ] [
  43         <tuple-info>
  44     ] if ;
  45
  46 : propagate-<tuple-boa> ( #call -- info )
  47     #! Delegation
  48     in-d>> unclip-last
  49     value-info literal>> class>> (propagate-tuple-constructor) ;
  50
  51 : propagate-<complex> ( #call -- info )
  52     in-d>> [ value-info ] map complex <tuple-info> ;
  53
  54 : propagate-tuple-constructor ( #call word -- infos )
  55     {
  56         { \ <tuple-boa> [ propagate-<tuple-boa> ] }
  57         { \ <complex> [ propagate-<complex> ] }
  58     } case 1array ;
  59
  60 : read-only-slot? ( n class -- ? )
  61     all-slots [ offset>> = ] with find nip
  62     dup [ read-only>> ] when ;
  63
  64 : literal-info-slot ( slot object -- info/f )
  65     2dup class read-only-slot?
  66     [ swap slot <literal-info> ] [ 2drop f ] if ;
  67
  68 : length-accessor? ( slot info -- ? )
  69     [ 1 = ] [ length>> ] bi* and ;
  70
  71 : value-info-slot ( slot info -- info' )
  72     #! Delegation.
  73     {
  74         { [ over 0 = ] [ 2drop fixnum <class-info> ] }
  75         { [ 2dup length-accessor? ] [ nip length>> ] }
  76         { [ dup literal?>> ] [ literal>> literal-info-slot ] }
  77         [ [ 1- ] [ slots>> ] bi* ?nth ]
  78     } cond [ object-info ] unless* ;