basis/compiler/tree/propagation/slots/slots.factor

   1 ! Copyright (C) 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: fry assocs arrays byte-arrays strings accessors sequences
   4 kernel slots classes.algebra classes.tuple classes.tuple.private
   5 words math math.private combinators sequences.private namespaces
   6 slots.private classes compiler.tree.propagation.info ;
   7 IN: compiler.tree.propagation.slots
   8
   9 ! Propagation of immutable slots and array lengths
  10
  11 ! Revisit this code when delegation is removed and when complex
  12 ! numbers become tuples.
  13
  14 UNION: fixed-length-sequence array byte-array string ;
  15
  16 : sequence-constructor? ( word -- ? )
  17     { <array> <byte-array> <string> } memq? ;
  18
  19 : constructor-output-class ( word -- class )
  20     {
  21         { <array> array }
  22         { <byte-array> byte-array }
  23         { <string> string }
  24     } at ;
  25
  26 : propagate-sequence-constructor ( #call word -- infos )
  27     [ in-d>> first <sequence-info> ]
  28     [ constructor-output-class <class-info> ]
  29     bi* value-info-intersect 1array ;
  30
  31 : tuple-constructor? ( word -- ? )
  32     { <tuple-boa> <complex> } memq? ;
  33
  34 : fold-<tuple-boa> ( values class -- info )
  35     [ [ literal>> ] map ] dip prefix >tuple
  36     <literal-info> ;
  37
  38 : (propagate-tuple-constructor) ( values class -- info )
  39     [ [ value-info ] map ] dip [ read-only-slots ] keep
  40     over rest-slice [ dup [ literal?>> ] when ] all? [
  41         [ rest-slice ] dip fold-<tuple-boa>
  42     ] [
  43         <tuple-info>
  44     ] if ;
  45
  46 : propagate-<tuple-boa> ( #call -- info )
  47     in-d>> unclip-last
  48     value-info literal>> class>> (propagate-tuple-constructor) ;
  49
  50 : propagate-<complex> ( #call -- info )
  51     in-d>> [ value-info ] map complex <tuple-info> ;
  52
  53 : propagate-tuple-constructor ( #call word -- infos )
  54     {
  55         { \ <tuple-boa> [ propagate-<tuple-boa> ] }
  56         { \ <complex> [ propagate-<complex> ] }
  57     } case 1array ;
  58
  59 : read-only-slot? ( n class -- ? )
  60     all-slots [ offset>> = ] with find nip
  61     dup [ read-only>> ] when ;
  62
  63 : literal-info-slot ( slot object -- info/f )
  64     2dup class read-only-slot?
  65     [ swap slot <literal-info> ] [ 2drop f ] if ;
  66
  67 : length-accessor? ( slot info -- ? )
  68     [ 1 = ] [ length>> ] bi* and ;
  69
  70 : value-info-slot ( slot info -- info' )
  71     {
  72         { [ over 0 = ] [ 2drop fixnum <class-info> ] }
  73         { [ 2dup length-accessor? ] [ nip length>> ] }
  74         { [ dup literal?>> ] [ literal>> literal-info-slot ] }
  75         [ [ 1- ] [ slots>> ] bi* ?nth ]
  76     } cond [ object-info ] unless* ;