basis/compression/lzw/lzw.factor

   1 ! Copyright (C) 2009 Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors combinators io kernel math namespaces
   4 prettyprint sequences vectors ;
   5 QUALIFIED-WITH: bitstreams bs
   6 IN: compression.lzw
   7
   8 TUPLE: lzw
   9 input
  10 output
  11 table
  12 code
  13 old-code
  14 initial-code-size
  15 code-size
  16 clear-code
  17 end-of-information-code ;
  18
  19 TUPLE: tiff-lzw < lzw ;
  20 TUPLE: gif-lzw < lzw ;
  21
  22 : initial-uncompress-table ( size -- seq )
  23     iota [ 1vector ] V{ } map-as ;
  24
  25 : reset-lzw-uncompress ( lzw -- lzw )
  26     dup end-of-information-code>> 1 + initial-uncompress-table >>table
  27     dup initial-code-size>> >>code-size ;
  28
  29 : <lzw-uncompress> ( input code-size class -- obj )
  30     new
  31         swap >>code-size
  32         dup code-size>> >>initial-code-size
  33         dup code-size>> 1 - 2^ >>clear-code
  34         dup clear-code>> 1 + >>end-of-information-code
  35         swap >>input
  36         BV{ } clone >>output
  37         reset-lzw-uncompress ;
  38
  39 ERROR: not-in-table value ;
  40
  41 : lookup-old-code ( lzw -- vector )
  42     [ old-code>> ] [ table>> ] bi nth ;
  43
  44 : lookup-code ( lzw -- vector )
  45     [ code>> ] [ table>> ] bi nth ;
  46
  47 : code-in-table? ( lzw -- ? )
  48     [ code>> ] [ table>> length ] bi < ;
  49
  50 : code>old-code ( lzw -- lzw )
  51     dup code>> >>old-code ;
  52
  53 : write-code ( lzw -- )
  54     [ lookup-code ] [ output>> ] bi push-all ;
  55
  56 GENERIC: code-space-full? ( lzw -- ? )
  57
  58 M: tiff-lzw code-space-full?
  59     [ table>> length ] [ code-size>> 2^ 1 - ] bi = ;
  60
  61 M: gif-lzw code-space-full?
  62     [ table>> length ] [ code-size>> 2^ ] bi = ;
  63
  64 : maybe-increment-code-size ( lzw -- lzw )
  65     dup code-space-full? [ [ 1 + ] change-code-size ] when ;
  66
  67 : add-to-table ( seq lzw -- )
  68     [ table>> push ]
  69     [ maybe-increment-code-size 2drop ] 2bi ;
  70
  71 : lzw-read ( lzw -- lzw n )
  72     [ ] [ code-size>> ] [ input>> ] tri bs:read ;
  73
  74 : end-of-information? ( lzw code -- ? ) swap end-of-information-code>> = ;
  75 : clear-code? ( lzw code -- ? ) swap clear-code>> = ;
  76
  77 DEFER: handle-clear-code
  78 : lzw-process-next-code ( lzw quot: ( lzw code -- ) -- )
  79     [ lzw-read ] dip {
  80         { [ 3dup drop end-of-information? ] [ 3drop ] }
  81         { [ 3dup drop clear-code? ] [ 2drop handle-clear-code ] }
  82         [ call( lzw code -- ) ]
  83     } cond ; inline
  84
  85 DEFER: lzw-uncompress-char
  86 : handle-clear-code ( lzw -- )
  87     reset-lzw-uncompress
  88     [
  89         >>code
  90         [ write-code ]
  91         [ code>old-code ] bi
  92         lzw-uncompress-char
  93     ] lzw-process-next-code ;
  94
  95 : handle-uncompress-code ( lzw -- lzw )
  96     dup code-in-table? [
  97         [ write-code ]
  98         [
  99             [
 100                 [ lookup-old-code ]
 101                 [ lookup-code first ] bi suffix
 102             ] [ add-to-table ] bi
 103         ] [ code>old-code ] tri
 104     ] [
 105         [
 106             [ lookup-old-code dup first suffix ] keep
 107             [ output>> push-all ] [ add-to-table ] 2bi
 108         ] [ code>old-code ] bi
 109     ] if ;
 110
 111 : lzw-uncompress-char ( lzw -- )
 112     [ >>code handle-uncompress-code lzw-uncompress-char ]
 113     lzw-process-next-code ;
 114
 115 : lzw-uncompress ( bitstream code-size class -- byte-array )
 116     <lzw-uncompress>
 117     [ lzw-uncompress-char ] [ output>> ] bi ;
 118
 119 : tiff-lzw-uncompress ( seq -- byte-array )
 120     bs:<msb0-bit-reader> 9 tiff-lzw lzw-uncompress ;
 121
 122 : gif-lzw-uncompress ( seq code-size -- byte-array )
 123     [ bs:<lsb0-bit-reader> ] dip gif-lzw lzw-uncompress ;