basis/constructors/constructors.factor

   1 ! Copyright (C) 2009 Slava Pestov, Doug Coleman.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs classes classes.tuple effects
   4 effects.parser kernel lexer parser sequences
   5 sequences.generalizations sets words ;
   6 IN: constructors
   7
   8 : all-slots-assoc ( class -- slots )
   9     superclasses-of [
  10         [ "slots" word-prop ] keep '[ _ ] { } map>assoc
  11     ] map concat ;
  12
  13 MACRO:: slots>boa ( slots class -- quot )
  14     class all-slots-assoc slots [ '[ first name>> _ = ] find-last nip ] with map :> slot-assoc
  15     class all-slots-assoc [ [ ] [ first initial>> ] bi ] { } map>assoc :> default-params
  16     slots length
  17     default-params length
  18     '[
  19         _ narray slot-assoc swap zip
  20         default-params swap assoc-union values _ firstn class boa
  21     ] ;
  22
  23 ERROR: repeated-constructor-parameters class effect ;
  24
  25 ERROR: unknown-constructor-parameters class effect unknown ;
  26
  27 : ensure-constructor-parameters ( class effect -- class effect )
  28     dup in>> all-unique? [ repeated-constructor-parameters ] unless
  29     2dup [ all-slots [ name>> ] map ] [ in>> ] bi* swap diff
  30     [ unknown-constructor-parameters ] unless-empty ;
  31
  32 : constructor-boa-quot ( constructor-word class effect -- word quot )
  33     in>> swap '[ _ _ slots>boa ] ; inline
  34
  35 : define-constructor ( constructor-word class effect -- )
  36     ensure-constructor-parameters
  37     [ constructor-boa-quot ] keep define-declared ;
  38
  39 : create-reset ( string -- word )
  40     create-word-in dup reset-generic ;
  41
  42 : scan-constructor ( -- word class )
  43     scan-new-word scan-class ;
  44
  45 : parse-constructor ( -- word class effect def )
  46     scan-constructor scan-effect ensure-constructor-parameters
  47     parse-definition ;
  48
  49 SYNTAX: CONSTRUCTOR:
  50     parse-constructor
  51     [ [ constructor-boa-quot ] dip compose ]
  52     [ drop ] 2bi define-declared ;
  53
  54 : scan-rest-input-effect ( -- effect )
  55     ")" parse-effect-tokens nip
  56     { "obj" } <effect> ;
  57
  58 : scan-full-input-effect ( -- effect )
  59     "(" expect scan-rest-input-effect ;
  60
  61 SYNTAX: SLOT-CONSTRUCTOR:
  62     scan-new-word [ name>> "(" append create-reset ] keep
  63     '[ scan-rest-input-effect in>> _ '[ _ _ slots>boa ] append! ] define-syntax ;