basis/core-foundation/strings/strings.factor

   1 ! Copyright (C) 2008, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.c-types alien.data alien.syntax alien.strings
   4 io.encodings.string kernel sequences byte-arrays
   5 io.encodings.utf8 math core-foundation core-foundation.arrays
   6 destructors parser fry alien words ;
   7 IN: core-foundation.strings
   8
   9 TYPEDEF: void* CFStringRef
  10
  11 TYPEDEF: int CFStringEncoding
  12 CONSTANT: kCFStringEncodingMacRoman HEX: 0
  13 CONSTANT: kCFStringEncodingWindowsLatin1 HEX: 0500
  14 CONSTANT: kCFStringEncodingISOLatin1 HEX: 0201
  15 CONSTANT: kCFStringEncodingNextStepLatin HEX: 0B01
  16 CONSTANT: kCFStringEncodingASCII HEX: 0600
  17 CONSTANT: kCFStringEncodingUnicode HEX: 0100
  18 CONSTANT: kCFStringEncodingUTF8 HEX: 08000100
  19 CONSTANT: kCFStringEncodingNonLossyASCII HEX: 0BFF
  20 CONSTANT: kCFStringEncodingUTF16 HEX: 0100
  21 CONSTANT: kCFStringEncodingUTF16BE HEX: 10000100
  22 CONSTANT: kCFStringEncodingUTF16LE HEX: 14000100
  23 CONSTANT: kCFStringEncodingUTF32 HEX: 0c000100
  24 CONSTANT: kCFStringEncodingUTF32BE HEX: 18000100
  25 CONSTANT: kCFStringEncodingUTF32LE HEX: 1c000100
  26
  27 FUNCTION: CFStringRef CFStringCreateWithBytes (
  28     CFAllocatorRef alloc,
  29     UInt8* bytes,
  30     CFIndex numBytes,
  31     CFStringEncoding encoding,
  32     Boolean isExternalRepresentation
  33 ) ;
  34
  35 FUNCTION: CFIndex CFStringGetLength ( CFStringRef theString ) ;
  36
  37 FUNCTION: void CFStringGetCharacters ( void* theString, CFIndex start, CFIndex length, void* buffer ) ;
  38
  39 FUNCTION: Boolean CFStringGetCString (
  40     CFStringRef theString,
  41     UInt8* buffer,
  42     CFIndex bufferSize,
  43     CFStringEncoding encoding
  44 ) ;
  45
  46 FUNCTION: CFIndex CFStringGetBytes (
  47    CFStringRef theString,
  48    CFRange range,
  49    CFStringEncoding encoding,
  50    UInt8 lossByte,
  51    Boolean isExternalRepresentation,
  52    UInt8* buffer,
  53    CFIndex maxBufLen,
  54    CFIndex* usedBufLen
  55 ) ;
  56
  57 FUNCTION: CFStringRef CFStringCreateWithCString (
  58     CFAllocatorRef alloc,
  59     UInt8* cStr,
  60     CFStringEncoding encoding
  61 ) ;
  62
  63 : prepare-CFString ( string -- byte-array )
  64     [
  65         dup HEX: 10ffff >
  66         [ drop HEX: fffd ] when
  67     ] map utf8 encode ;
  68
  69 : <CFString> ( string -- alien )
  70     [ f ] dip
  71     prepare-CFString dup length
  72     kCFStringEncodingUTF8 f
  73     CFStringCreateWithBytes
  74     [ "CFStringCreateWithBytes failed" throw ] unless* ;
  75
  76 : CF>string ( alien -- string )
  77     dup CFStringGetLength
  78     [ 0 swap <CFRange> kCFStringEncodingUTF8 0 f ] keep
  79     4 * 1 + <byte-array> [
  80         dup length
  81         { CFIndex } [ CFStringGetBytes drop ] [ ]
  82         with-out-parameters
  83     ] keep
  84     swap head-slice utf8 decode ;
  85
  86 : CF>string-array ( alien -- seq )
  87     CF>array [ CF>string ] map ;
  88
  89 : <CFStringArray> ( seq -- alien )
  90     [ [ <CFString> &CFRelease ] map <CFArray> ] with-destructors ;
  91
  92 SYNTAX: CFSTRING:
  93     CREATE scan-object
  94     [ drop ] [ '[ _ [ _ <CFString> ] initialize-alien ] ] 2bi
  95     (( -- alien )) define-declared ;