basis/core-text/core-text.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.c-types alien.data alien.syntax arrays
   4 assocs cache classes colors combinators core-foundation
   5 core-foundation.attributed-strings core-foundation.strings
   6 core-graphics core-graphics.types core-text.fonts destructors
   7 fonts init kernel locals make math math.functions math.order
   8 math.vectors memoize namespaces sequences strings
   9 io.encodings.utf16n io.encodings.string ;
  10 IN: core-text
  11
  12 TYPEDEF: void* CTLineRef
  13
  14 C-GLOBAL: CFStringRef kCTFontAttributeName
  15 C-GLOBAL: CFStringRef kCTKernAttributeName
  16 C-GLOBAL: CFStringRef kCTLigatureAttributeName
  17 C-GLOBAL: CFStringRef kCTForegroundColorAttributeName
  18 C-GLOBAL: CFStringRef kCTParagraphStyleAttributeName
  19 C-GLOBAL: CFStringRef kCTUnderlineStyleAttributeName
  20 C-GLOBAL: CFStringRef kCTVerticalFormsAttributeName
  21 C-GLOBAL: CFStringRef kCTGlyphInfoAttributeName
  22
  23 FUNCTION: CTLineRef CTLineCreateWithAttributedString ( CFAttributedStringRef string )
  24
  25 FUNCTION: void CTLineDraw ( CTLineRef line, CGContextRef context )
  26
  27 FUNCTION: CGFloat CTLineGetOffsetForStringIndex ( CTLineRef line, CFIndex charIndex, CGFloat* secondaryOffset )
  28
  29 FUNCTION: CFIndex CTLineGetStringIndexForPosition ( CTLineRef line, CGPoint position )
  30
  31 FUNCTION: double CTLineGetTypographicBounds ( CTLineRef line, CGFloat* ascent, CGFloat* descent, CGFloat* leading )
  32
  33 FUNCTION: CGRect CTLineGetImageBounds ( CTLineRef line, CGContextRef context )
  34
  35 SYMBOL: retina?
  36
  37 MEMO: make-attributes ( open-font color -- hashtable )
  38     [
  39         kCTForegroundColorAttributeName ,,
  40         kCTFontAttributeName ,,
  41     ] H{ } make ;
  42
  43 : <CTLine> ( string open-font color -- line )
  44     [
  45         [
  46             dup selection? [ string>> ] when
  47             string check-instance
  48         ] 2dip
  49         make-attributes <CFAttributedString> &CFRelease
  50         CTLineCreateWithAttributedString
  51     ] with-destructors ;
  52
  53 TUPLE: line < disposable font string line metrics image loc dim
  54 render-loc render-dim ;
  55
  56 : typographic-bounds ( line -- width ascent descent leading )
  57     { CGFloat CGFloat CGFloat }
  58     [ CTLineGetTypographicBounds ] with-out-parameters ; inline
  59
  60 : store-typographic-bounds ( metrics width ascent descent leading -- metrics )
  61     {
  62         [ >>width ]
  63         [ >>ascent ]
  64         [ >>descent ]
  65         [ >>leading ]
  66     } spread ; inline
  67
  68 : compute-font-metrics ( metrics font -- metrics )
  69     [ CTFontGetCapHeight >>cap-height ]
  70     [ CTFontGetXHeight >>x-height ]
  71     bi ; inline
  72
  73 : compute-line-metrics ( open-font line -- line-metrics )
  74     [ metrics new ] 2dip
  75     [ compute-font-metrics ]
  76     [ typographic-bounds store-typographic-bounds ] bi*
  77     compute-height ;
  78
  79 : metrics>dim ( bounds -- dim )
  80     [ width>> ] [ [ ascent>> ] [ descent>> ] bi + ] bi
  81     [ ceiling >integer ]
  82     bi@ 2array ;
  83
  84 : fill-background ( context font dim -- )
  85     [ background>> >rgba-components CGContextSetRGBFillColor ]
  86     [ [ 0 0 ] dip first2 <CGRect> CGContextFillRect ]
  87     bi-curry* bi ;
  88
  89 : selection-rect ( dim line selection -- rect )
  90     [let [ start>> ] [ end>> ] [ string>> ] tri :> ( start end string )
  91      start end [ 0 swap string subseq utf16n encode length 2 / >integer ] bi@
  92     ]
  93     [ f CTLineGetOffsetForStringIndex round ] bi-curry@ bi
  94     [ drop nip 0 ] [ swap - swap second ] 3bi <CGRect> ;
  95
  96 : CGRect-translate-x ( CGRect x -- CGRect' )
  97     [ dup CGRect-x ] dip - over set-CGRect-x ;
  98
  99 :: fill-selection-background ( context loc dim line string -- )
 100     string selection? [
 101         context string color>> >rgba-components CGContextSetRGBFillColor
 102         context dim line string selection-rect
 103         loc first CGRect-translate-x
 104         CGContextFillRect
 105     ] when ;
 106
 107 : line-rect ( line -- rect )
 108     dummy-context CTLineGetImageBounds ;
 109
 110 : set-text-position ( context loc -- )
 111     first2 [ neg ] bi@ CGContextSetTextPosition ;
 112
 113 :: line-loc ( metrics loc dim -- loc )
 114     loc first
 115     metrics ascent>> ceiling dim second loc second + - 2array ;
 116
 117 :: <line> ( font string -- line )
 118     [
 119         line new-disposable
 120         font retina? get-global [ cache-font@2x ] [ cache-font ] if :> open-font
 121         string open-font font foreground>> <CTLine> |CFRelease :> line
 122         open-font line compute-line-metrics
 123         [ >>metrics ] [ metrics>dim >>dim ] bi
 124         font >>font
 125         string >>string
 126         line >>line
 127     ] with-destructors ;
 128
 129 :: render ( line -- line image )
 130     line line>> :> ctline
 131     line string>> :> string
 132     line font>> :> font
 133
 134     line render-loc>> [
 135
 136         ctline line-rect :> rect
 137         rect origin>> CGPoint>loc :> (loc)
 138         rect size>> CGSize>dim :> (dim)
 139         (loc) vfloor :> loc
 140         (loc) (dim) v+ vceiling :> ext
 141         ext loc [ - >integer 1 max ] 2map :> dim
 142
 143         loc line render-loc<<
 144         dim line render-dim<<
 145
 146         line metrics>> loc dim line-loc line loc<<
 147
 148     ] unless
 149
 150     line render-loc>> :> loc
 151     line render-dim>> :> dim
 152
 153     line dim [
 154         {
 155             [ font dim fill-background ]
 156             [ loc dim ctline string fill-selection-background ]
 157             [ loc set-text-position ]
 158             [ [ ctline ] dip CTLineDraw ]
 159         } cleave
 160     ] make-bitmap-image retina? get-global >>2x? ;
 161
 162 : line>image ( line -- image )
 163     dup image>> [ render >>image ] unless image>> ;
 164
 165 M: line dispose* line>> CFRelease ;
 166
 167 SYMBOL: cached-lines
 168
 169 : cached-line ( font string -- line )
 170     cached-lines get-global [ <line> ] 2cache ;
 171
 172 [ <cache-assoc> cached-lines set-global f retina? set-global ] "core-text" add-startup-hook