basis/cpu/ppc/ppc.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs sequences kernel combinators make math
   4 math.order math.ranges system namespaces locals layouts words
   5 alien alien.accessors alien.c-types literals cpu.architecture
   6 cpu.ppc.assembler cpu.ppc.assembler.backend compiler.cfg.registers
   7 compiler.cfg.instructions compiler.cfg.comparisons
   8 compiler.codegen.fixup compiler.cfg.intrinsics
   9 compiler.cfg.stack-frame compiler.cfg.build-stack-frame
  10 compiler.units compiler.constants compiler.codegen ;
  11 FROM: cpu.ppc.assembler => B ;
  12 IN: cpu.ppc
  13
  14 ! PowerPC register assignments:
  15 ! r2-r12: integer vregs
  16 ! r15-r29
  17 ! r30: integer scratch
  18 ! f0-f29: float vregs
  19 ! f30: float scratch
  20
  21 ! Add some methods to the assembler that are useful to us
  22 M: label (B) [ 0 ] 2dip (B) rc-relative-ppc-3 label-fixup ;
  23 M: label BC [ 0 BC ] dip rc-relative-ppc-2 label-fixup ;
  24
  25 enable-float-intrinsics
  26
  27 <<
  28 \ ##integer>float t frame-required? set-word-prop
  29 \ ##float>integer t frame-required? set-word-prop
  30 >>
  31
  32 M: ppc machine-registers
  33     {
  34         { int-regs $[ 2 12 [a,b] 15 29 [a,b] append ] }
  35         { float-regs $[ 0 29 [a,b] ] }
  36     } ;
  37
  38 CONSTANT: scratch-reg 30
  39 CONSTANT: fp-scratch-reg 30
  40
  41 M: ppc two-operand? f ;
  42
  43 M: ppc %load-immediate ( reg n -- ) swap LOAD ;
  44
  45 M: ppc %load-reference ( reg obj -- )
  46     [ 0 swap LOAD32 ] [ rc-absolute-ppc-2/2 rel-immediate ] bi* ;
  47
  48 M: ppc %alien-global ( register symbol dll -- )
  49     [ 0 swap LOAD32 ] 2dip rc-absolute-ppc-2/2 rel-dlsym ;
  50
  51 CONSTANT: ds-reg 13
  52 CONSTANT: rs-reg 14
  53
  54 GENERIC: loc-reg ( loc -- reg )
  55
  56 M: ds-loc loc-reg drop ds-reg ;
  57 M: rs-loc loc-reg drop rs-reg ;
  58
  59 : loc>operand ( loc -- reg n )
  60     [ loc-reg ] [ n>> cells neg ] bi ; inline
  61
  62 M: ppc %peek loc>operand LWZ ;
  63 M: ppc %replace loc>operand STW ;
  64
  65 :: (%inc) ( n reg -- ) reg reg n cells ADDI ; inline
  66
  67 M: ppc %inc-d ( n -- ) ds-reg (%inc) ;
  68 M: ppc %inc-r ( n -- ) rs-reg (%inc) ;
  69
  70 HOOK: reserved-area-size os ( -- n )
  71
  72 ! The start of the stack frame contains the size of this frame
  73 ! as well as the currently executing XT
  74 : factor-area-size ( -- n ) 2 cells ; foldable
  75 : next-save ( n -- i ) cell - ;
  76 : xt-save ( n -- i ) 2 cells - ;
  77
  78 ! Next, we have the spill area as well as the FFI parameter area.
  79 ! It is safe for them to overlap, since basic blocks with FFI calls
  80 ! will never spill -- indeed, basic blocks with FFI calls do not
  81 ! use vregs at all, and the FFI call is a stack analysis sync point.
  82 ! In the future this will change and the stack frame logic will
  83 ! need to be untangled somewhat.
  84
  85 : param@ ( n -- x ) reserved-area-size + ; inline
  86
  87 : param-save-size ( -- n ) 8 cells ; foldable
  88
  89 : local@ ( n -- x )
  90     reserved-area-size param-save-size + + ; inline
  91
  92 : spill@ ( n -- offset )
  93     spill-offset local@ ;
  94
  95 ! Some FP intrinsics need a temporary scratch area in the stack
  96 ! frame, 8 bytes in size. This is in the param-save area so it
  97 ! does not overlap with spill slots.
  98 : scratch@ ( n -- offset )
  99     factor-area-size + ;
 100
 101 ! GC root area
 102 : gc-root@ ( n -- offset )
 103     gc-root-offset local@ ;
 104
 105 ! Finally we have the linkage area
 106 HOOK: lr-save os ( -- n )
 107
 108 M: ppc stack-frame-size ( stack-frame -- i )
 109     (stack-frame-size)
 110     param-save-size +
 111     reserved-area-size +
 112     factor-area-size +
 113     4 cells align ;
 114
 115 M: ppc %call ( word -- ) 0 BL rc-relative-ppc-3 rel-word-pic ;
 116
 117 M: ppc %jump ( word -- )
 118     0 6 LOAD32 8 rc-absolute-ppc-2/2 rel-here
 119     0 B rc-relative-ppc-3 rel-word-pic-tail ;
 120
 121 M: ppc %jump-label ( label -- ) B ;
 122 M: ppc %return ( -- ) BLR ;
 123
 124 M:: ppc %dispatch ( src temp -- )
 125     0 temp LOAD32
 126     4 cells rc-absolute-ppc-2/2 rel-here
 127     temp temp src LWZX
 128     temp MTCTR
 129     BCTR ;
 130
 131 :: (%slot) ( obj slot tag temp -- reg offset )
 132     temp slot obj ADD
 133     temp tag neg ; inline
 134
 135 : (%slot-imm) ( obj slot tag -- reg offset )
 136     [ cells ] dip - ; inline
 137
 138 M: ppc %slot ( dst obj slot tag temp -- ) (%slot) LWZ ;
 139 M: ppc %slot-imm ( dst obj slot tag -- ) (%slot-imm) LWZ ;
 140 M: ppc %set-slot ( src obj slot tag temp -- ) (%slot) STW ;
 141 M: ppc %set-slot-imm ( src obj slot tag -- ) (%slot-imm) STW ;
 142
 143 M:: ppc %string-nth ( dst src index temp -- )
 144     [
 145         "end" define-label
 146         temp src index ADD
 147         dst temp string-offset LBZ
 148         0 dst HEX: 80 CMPI
 149         "end" get BLT
 150         temp src string-aux-offset LWZ
 151         temp temp index ADD
 152         temp temp index ADD
 153         temp temp byte-array-offset LHZ
 154         temp temp 7 SLWI
 155         dst dst temp XOR
 156         "end" resolve-label
 157     ] with-scope ;
 158
 159 M:: ppc %set-string-nth-fast ( ch obj index temp -- )
 160     temp obj index ADD
 161     ch temp string-offset STB ;
 162
 163 M: ppc %add     ADD ;
 164 M: ppc %add-imm ADDI ;
 165 M: ppc %sub     swap SUBF ;
 166 M: ppc %sub-imm SUBI ;
 167 M: ppc %mul     MULLW ;
 168 M: ppc %mul-imm MULLI ;
 169 M: ppc %and     AND ;
 170 M: ppc %and-imm ANDI ;
 171 M: ppc %or      OR ;
 172 M: ppc %or-imm  ORI ;
 173 M: ppc %xor     XOR ;
 174 M: ppc %xor-imm XORI ;
 175 M: ppc %shl     SLW ;
 176 M: ppc %shl-imm swapd SLWI ;
 177 M: ppc %shr     SRW ;
 178 M: ppc %shr-imm swapd SRWI ;
 179 M: ppc %sar     SRAW ;
 180 M: ppc %sar-imm SRAWI ;
 181 M: ppc %not     NOT ;
 182
 183 :: overflow-template ( label dst src1 src2 insn -- )
 184     0 0 LI
 185     0 MTXER
 186     dst src2 src1 insn call
 187     label BO ; inline
 188
 189 M: ppc %fixnum-add ( label dst src1 src2 -- )
 190     [ ADDO. ] overflow-template ;
 191
 192 M: ppc %fixnum-sub ( label dst src1 src2 -- )
 193     [ SUBFO. ] overflow-template ;
 194
 195 M: ppc %fixnum-mul ( label dst src1 src2 -- )
 196     [ MULLWO. ] overflow-template ;
 197
 198 : bignum@ ( n -- offset ) cells bignum tag-number - ; inline
 199
 200 M:: ppc %integer>bignum ( dst src temp -- )
 201     [
 202         "end" define-label
 203         dst 0 >bignum %load-reference
 204         ! Is it zero? Then just go to the end and return this zero
 205         0 src 0 CMPI
 206         "end" get BEQ
 207         ! Allocate a bignum
 208         dst 4 cells bignum temp %allot
 209         ! Write length
 210         2 tag-fixnum temp LI
 211         temp dst 1 bignum@ STW
 212         ! Compute sign
 213         temp src MR
 214         temp temp cell-bits 1 - SRAWI
 215         temp temp 1 ANDI
 216         ! Store sign
 217         temp dst 2 bignum@ STW
 218         ! Make negative value positive
 219         temp temp temp ADD
 220         temp temp NEG
 221         temp temp 1 ADDI
 222         temp src temp MULLW
 223         ! Store the bignum
 224         temp dst 3 bignum@ STW
 225         "end" resolve-label
 226     ] with-scope ;
 227
 228 M:: ppc %bignum>integer ( dst src temp -- )
 229     [
 230         "end" define-label
 231         temp src 1 bignum@ LWZ
 232         ! if the length is 1, its just the sign and nothing else,
 233         ! so output 0
 234         0 dst LI
 235         0 temp 1 tag-fixnum CMPI
 236         "end" get BEQ
 237         ! load the value
 238         dst src 3 bignum@ LWZ
 239         ! load the sign
 240         temp src 2 bignum@ LWZ
 241         ! branchless arithmetic: we want to turn 0 into 1,
 242         ! and 1 into -1
 243         temp temp temp ADD
 244         temp temp 1 SUBI
 245         temp temp NEG
 246         ! multiply value by sign
 247         dst dst temp MULLW
 248         "end" resolve-label
 249     ] with-scope ;
 250
 251 M: ppc %add-float FADD ;
 252 M: ppc %sub-float FSUB ;
 253 M: ppc %mul-float FMUL ;
 254 M: ppc %div-float FDIV ;
 255
 256 M:: ppc %integer>float ( dst src -- )
 257     HEX: 4330 scratch-reg LIS
 258     scratch-reg 1 0 scratch@ STW
 259     scratch-reg src MR
 260     scratch-reg dup HEX: 8000 XORIS
 261     scratch-reg 1 4 scratch@ STW
 262     dst 1 0 scratch@ LFD
 263     scratch-reg 4503601774854144.0 %load-reference
 264     fp-scratch-reg scratch-reg float-offset LFD
 265     dst dst fp-scratch-reg FSUB ;
 266
 267 M:: ppc %float>integer ( dst src -- )
 268     fp-scratch-reg src FCTIWZ
 269     fp-scratch-reg 1 0 scratch@ STFD
 270     dst 1 4 scratch@ LWZ ;
 271
 272 M: ppc %copy ( dst src rep -- )
 273     {
 274         { int-rep [ MR ] }
 275         { double-rep [ FMR ] }
 276     } case ;
 277
 278 M: ppc %unbox-float ( dst src -- ) float-offset LFD ;
 279
 280 M:: ppc %box-float ( dst src temp -- )
 281     dst 16 float temp %allot
 282     src dst float-offset STFD ;
 283
 284 : float-function-param ( i spill-slot -- )
 285     [ float-regs param-regs nth 1 ] [ n>> spill@ ] bi* LFD ;
 286
 287 : float-function-return ( reg -- )
 288     float-regs return-reg 2dup = [ 2drop ] [ FMR ] if ;
 289
 290 M:: ppc %unary-float-function ( dst src func -- )
 291     0 src float-function-param
 292     func f %alien-invoke
 293     dst float-function-return ;
 294
 295 M:: ppc %binary-float-function ( dst src1 src2 func -- )
 296     0 src1 float-function-param
 297     1 src2 float-function-param
 298     func f %alien-invoke
 299     dst float-function-return ;
 300
 301 M:: ppc %unbox-any-c-ptr ( dst src temp -- )
 302     [
 303         { "is-byte-array" "end" "start" } [ define-label ] each
 304         ! Address is computed in dst
 305         0 dst LI
 306         ! Load object into scratch-reg
 307         scratch-reg src MR
 308         ! We come back here with displaced aliens
 309         "start" resolve-label
 310         ! Is the object f?
 311         0 scratch-reg \ f tag-number CMPI
 312         ! If so, done
 313         "end" get BEQ
 314         ! Is the object an alien?
 315         0 scratch-reg header-offset LWZ
 316         0 0 alien type-number tag-fixnum CMPI
 317         "is-byte-array" get BNE
 318         ! If so, load the offset
 319         0 scratch-reg alien-offset LWZ
 320         ! Add it to address being computed
 321         dst dst 0 ADD
 322         ! Now recurse on the underlying alien
 323         scratch-reg scratch-reg underlying-alien-offset LWZ
 324         "start" get B
 325         "is-byte-array" resolve-label
 326         ! Add byte array address to address being computed
 327         dst dst scratch-reg ADD
 328         ! Add an offset to start of byte array's data area
 329         dst dst byte-array-offset ADDI
 330         "end" resolve-label
 331     ] with-scope ;
 332
 333 : alien@ ( n -- n' ) cells object tag-number - ;
 334
 335 :: %allot-alien ( dst displacement base temp -- )
 336     dst 4 cells alien temp %allot
 337     temp \ f tag-number %load-immediate
 338     ! Store underlying-alien slot
 339     base dst 1 alien@ STW
 340     ! Store expired slot
 341     temp dst 2 alien@ STW
 342     ! Store offset
 343     displacement dst 3 alien@ STW ;
 344
 345 M:: ppc %box-alien ( dst src temp -- )
 346     [
 347         "f" define-label
 348         dst \ f tag-number %load-immediate
 349         0 src 0 CMPI
 350         "f" get BEQ
 351         dst src temp temp %allot-alien
 352         "f" resolve-label
 353     ] with-scope ;
 354
 355 M:: ppc %box-displaced-alien ( dst displacement base displacement' base' base-class -- )
 356     [
 357         "end" define-label
 358         "alloc" define-label
 359         "simple-case" define-label
 360         ! If displacement is zero, return the base
 361         dst base MR
 362         0 displacement 0 CMPI
 363         "end" get BEQ
 364         ! Quickly use displacement' before its needed for real, as allot temporary
 365         displacement' :> temp
 366         dst 4 cells alien temp %allot
 367         ! If base is already a displaced alien, unpack it
 368         0 base \ f tag-number CMPI
 369         "simple-case" get BEQ
 370         temp base header-offset LWZ
 371         0 temp alien type-number tag-fixnum CMPI
 372         "simple-case" get BNE
 373         ! displacement += base.displacement
 374         temp base 3 alien@ LWZ
 375         displacement' displacement temp ADD
 376         ! base = base.base
 377         base' base 1 alien@ LWZ
 378         "alloc" get B
 379         "simple-case" resolve-label
 380         displacement' displacement MR
 381         base' base MR
 382         "alloc" resolve-label
 383         ! Store underlying-alien slot
 384         base' dst 1 alien@ STW
 385         ! Store offset
 386         displacement' dst 3 alien@ STW
 387         ! Store expired slot (its ok to clobber displacement')
 388         temp \ f tag-number %load-immediate
 389         temp dst 2 alien@ STW
 390         "end" resolve-label
 391     ] with-scope ;
 392
 393 M: ppc %alien-unsigned-1 0 LBZ ;
 394 M: ppc %alien-unsigned-2 0 LHZ ;
 395
 396 M: ppc %alien-signed-1 dupd 0 LBZ dup EXTSB ;
 397 M: ppc %alien-signed-2 0 LHA ;
 398
 399 M: ppc %alien-cell 0 LWZ ;
 400
 401 M: ppc %alien-float 0 LFS ;
 402 M: ppc %alien-double 0 LFD ;
 403
 404 M: ppc %set-alien-integer-1 swap 0 STB ;
 405 M: ppc %set-alien-integer-2 swap 0 STH ;
 406
 407 M: ppc %set-alien-cell swap 0 STW ;
 408
 409 M: ppc %set-alien-float swap 0 STFS ;
 410 M: ppc %set-alien-double swap 0 STFD ;
 411
 412 : load-zone-ptr ( reg -- )
 413     "nursery" f %alien-global ;
 414
 415 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 416     [ drop load-zone-ptr ] [ swap 4 LWZ ] 2bi ;
 417
 418 :: inc-allot-ptr ( nursery-ptr allot-ptr n -- )
 419     scratch-reg allot-ptr n 8 align ADDI
 420     scratch-reg nursery-ptr 4 STW ;
 421
 422 :: store-header ( dst class -- )
 423     class type-number tag-fixnum scratch-reg LI
 424     scratch-reg dst 0 STW ;
 425
 426 : store-tagged ( dst tag -- )
 427     dupd tag-number ORI ;
 428
 429 M:: ppc %allot ( dst size class nursery-ptr -- )
 430     nursery-ptr dst load-allot-ptr
 431     nursery-ptr dst size inc-allot-ptr
 432     dst class store-header
 433     dst class store-tagged ;
 434
 435 : load-cards-offset ( dst -- )
 436     [ "cards_offset" f %alien-global ] [ dup 0 LWZ ] bi ;
 437
 438 : load-decks-offset ( dst -- )
 439     [ "decks_offset" f %alien-global ] [ dup 0 LWZ ] bi  ;
 440
 441 M:: ppc %write-barrier ( src card# table -- )
 442     card-mark scratch-reg LI
 443
 444     ! Mark the card
 445     table load-cards-offset
 446     src card# card-bits SRWI
 447     table scratch-reg card# STBX
 448
 449     ! Mark the card deck
 450     table load-decks-offset
 451     src card# deck-bits SRWI
 452     table scratch-reg card# STBX ;
 453
 454 M:: ppc %check-nursery ( label temp1 temp2 -- )
 455     temp2 load-zone-ptr
 456     temp1 temp2 cell LWZ
 457     temp2 temp2 3 cells LWZ
 458     ! add ALLOT_BUFFER_ZONE to here
 459     temp1 temp1 1024 ADDI
 460     ! is here >= end?
 461     temp1 0 temp2 CMP
 462     label BLE ;
 463
 464 M:: ppc %save-gc-root ( gc-root register -- )
 465     register 1 gc-root gc-root@ STW ;
 466
 467 M:: ppc %load-gc-root ( gc-root register -- )
 468     register 1 gc-root gc-root@ LWZ ;
 469
 470 M:: ppc %call-gc ( gc-root-count -- )
 471     %prepare-alien-invoke
 472     3 1 gc-root-base local@ ADDI
 473     gc-root-count 4 LI
 474     "inline_gc" f %alien-invoke ;
 475
 476 M: ppc %prologue ( n -- )
 477     0 11 LOAD32 rc-absolute-ppc-2/2 rel-this
 478     0 MFLR
 479     {
 480         [ [ 1 1 ] dip neg ADDI ]
 481         [ [ 11 1 ] dip xt-save STW ]
 482         [ 11 LI ]
 483         [ [ 11 1 ] dip next-save STW ]
 484         [ [ 0 1 ] dip lr-save + STW ]
 485     } cleave ;
 486
 487 M: ppc %epilogue ( n -- )
 488     #! At the end of each word that calls a subroutine, we store
 489     #! the previous link register value in r0 by popping it off
 490     #! the stack, set the link register to the contents of r0,
 491     #! and jump to the link register.
 492     [ [ 0 1 ] dip lr-save + LWZ ]
 493     [ [ 1 1 ] dip ADDI ] bi
 494     0 MTLR ;
 495
 496 :: (%boolean) ( dst temp branch1 branch2 -- )
 497     "end" define-label
 498     dst \ f tag-number %load-immediate
 499     "end" get branch1 execute( label -- )
 500     branch2 [ "end" get branch2 execute( label -- ) ] when
 501     dst \ t %load-reference
 502     "end" get resolve-label ; inline
 503
 504 :: %boolean ( dst cc temp -- )
 505     cc negate-cc order-cc {
 506         { cc<  [ dst temp \ BLT f (%boolean) ] }
 507         { cc<= [ dst temp \ BLE f (%boolean) ] }
 508         { cc>  [ dst temp \ BGT f (%boolean) ] }
 509         { cc>= [ dst temp \ BGE f (%boolean) ] }
 510         { cc=  [ dst temp \ BEQ f (%boolean) ] }
 511         { cc/= [ dst temp \ BNE f (%boolean) ] }
 512     } case ;
 513
 514 : (%compare) ( src1 src2 -- ) [ 0 ] dip CMP ; inline
 515 : (%compare-imm) ( src1 src2 -- ) [ 0 ] 2dip CMPI ; inline
 516 : (%compare-float-unordered) ( src1 src2 -- ) [ 0 ] dip FCMPU ; inline
 517 : (%compare-float-ordered) ( src1 src2 -- ) [ 0 ] dip FCMPO ; inline
 518
 519 :: (%compare-float) ( src1 src2 cc -- branch1 branch2 )
 520     cc {
 521         { cc<    [ src1 src2 (%compare-float-ordered)   \ BLT f     ] }
 522         { cc<=   [ src1 src2 (%compare-float-ordered)   \ BLT \ BEQ ] }
 523         { cc>    [ src1 src2 (%compare-float-ordered)   \ BGT f     ] }
 524         { cc>=   [ src1 src2 (%compare-float-ordered)   \ BGT \ BEQ ] }
 525         { cc=    [ src1 src2 (%compare-float-unordered) \ BEQ f     ] }
 526         { cc<>   [ src1 src2 (%compare-float-ordered)   \ BLT \ BGT ] }
 527         { cc<>=  [ src1 src2 (%compare-float-ordered)   \ BNO f     ] }
 528         { cc/<   [ src1 src2 (%compare-float-unordered) \ BGE f     ] }
 529         { cc/<=  [ src1 src2 (%compare-float-unordered) \ BGT \ BO  ] }
 530         { cc/>   [ src1 src2 (%compare-float-unordered) \ BLE f     ] }
 531         { cc/>=  [ src1 src2 (%compare-float-unordered) \ BLT \ BO  ] }
 532         { cc/=   [ src1 src2 (%compare-float-unordered) \ BNE f     ] }
 533         { cc/<>  [ src1 src2 (%compare-float-unordered) \ BEQ \ BO  ] }
 534         { cc/<>= [ src1 src2 (%compare-float-unordered) \ BO  f     ] }
 535     } case ; inline
 536
 537 M: ppc %compare [ (%compare) ] 2dip %boolean ;
 538
 539 M: ppc %compare-imm [ (%compare-imm) ] 2dip %boolean ;
 540
 541 M:: ppc %compare-float ( dst src1 src2 cc temp -- )
 542     cc negate-cc src1 src2 (%compare-float) :> branch2 :> branch1
 543     dst temp branch1 branch2 (%boolean) ;
 544
 545 :: %branch ( label cc -- )
 546     cc order-cc {
 547         { cc<  [ label BLT ] }
 548         { cc<= [ label BLE ] }
 549         { cc>  [ label BGT ] }
 550         { cc>= [ label BGE ] }
 551         { cc=  [ label BEQ ] }
 552         { cc/= [ label BNE ] }
 553     } case ;
 554
 555 M: ppc %compare-branch [ (%compare) ] 2dip %branch ;
 556
 557 M: ppc %compare-imm-branch [ (%compare-imm) ] 2dip %branch ;
 558
 559 M:: ppc %compare-float-branch ( label src1 src2 cc -- )
 560     cc src1 src2 (%compare-float) :> branch2 :> branch1
 561     label branch1 execute( label -- )
 562     branch2 [ label branch2 execute( label -- ) ] when ;
 563
 564 : load-from-frame ( dst n rep -- )
 565     {
 566         { int-rep [ [ 1 ] dip LWZ ] }
 567         { float-rep [ [ 1 ] dip LFS ] }
 568         { double-rep [ [ 1 ] dip LFD ] }
 569         { stack-params [ [ 0 1 ] dip LWZ [ 0 1 ] dip param@ STW ] }
 570     } case ;
 571
 572 : next-param@ ( n -- x ) param@ stack-frame get total-size>> + ;
 573
 574 : store-to-frame ( src n rep -- )
 575     {
 576         { int-rep [ [ 1 ] dip STW ] }
 577         { float-rep [ [ 1 ] dip STFS ] }
 578         { double-rep [ [ 1 ] dip STFD ] }
 579         { stack-params [ [ [ 0 1 ] dip next-param@ LWZ 0 1 ] dip STW ] }
 580     } case ;
 581
 582 M: ppc %spill ( src rep n -- )
 583     swap [ spill@ ] dip store-to-frame ;
 584
 585 M: ppc %reload ( dst rep n -- )
 586     swap [ spill@ ] dip load-from-frame ;
 587
 588 M: ppc %loop-entry ;
 589
 590 M: int-regs return-reg drop 3 ;
 591 M: int-regs param-regs drop { 3 4 5 6 7 8 9 10 } ;
 592 M: float-regs return-reg drop 1 ;
 593
 594 M:: ppc %save-param-reg ( stack reg rep -- )
 595     reg stack local@ rep store-to-frame ;
 596
 597 M:: ppc %load-param-reg ( stack reg rep -- )
 598     reg stack local@ rep load-from-frame ;
 599
 600 M: ppc %prepare-unbox ( -- )
 601     ! First parameter is top of stack
 602     3 ds-reg 0 LWZ
 603     ds-reg dup cell SUBI ;
 604
 605 M: ppc %unbox ( n rep func -- )
 606     ! Value must be in r3
 607     ! Call the unboxer
 608     f %alien-invoke
 609     ! Store the return value on the C stack
 610     over [ [ reg-class-of return-reg ] keep %save-param-reg ] [ 2drop ] if ;
 611
 612 M: ppc %unbox-long-long ( n func -- )
 613     ! Value must be in r3:r4
 614     ! Call the unboxer
 615     f %alien-invoke
 616     ! Store the return value on the C stack
 617     [
 618         [ [ 3 1 ] dip local@ STW ]
 619         [ [ 4 1 ] dip cell + local@ STW ] bi
 620     ] when* ;
 621
 622 M: ppc %unbox-large-struct ( n c-type -- )
 623     ! Value must be in r3
 624     ! Compute destination address and load struct size
 625     [ [ 4 1 ] dip local@ ADDI ] [ heap-size 5 LI ] bi*
 626     ! Call the function
 627     "to_value_struct" f %alien-invoke ;
 628
 629 M: ppc %box ( n rep func -- )
 630     ! If the source is a stack location, load it into freg #0.
 631     ! If the source is f, then we assume the value is already in
 632     ! freg #0.
 633     [ over [ 0 over reg-class-of param-reg swap %load-param-reg ] [ 2drop ] if ] dip
 634     f %alien-invoke ;
 635
 636 M: ppc %box-long-long ( n func -- )
 637     [
 638         [
 639             [ [ 3 1 ] dip local@ LWZ ]
 640             [ [ 4 1 ] dip cell + local@ LWZ ] bi
 641         ] when*
 642     ] dip f %alien-invoke ;
 643
 644 : struct-return@ ( n -- n )
 645     [ stack-frame get params>> ] unless* local@ ;
 646
 647 M: ppc %prepare-box-struct ( -- )
 648     #! Compute target address for value struct return
 649     3 1 f struct-return@ ADDI
 650     3 1 0 local@ STW ;
 651
 652 M: ppc %box-large-struct ( n c-type -- )
 653     ! If n = f, then we're boxing a returned struct
 654     ! Compute destination address and load struct size
 655     [ [ 3 1 ] dip struct-return@ ADDI ] [ heap-size 4 LI ] bi*
 656     ! Call the function
 657     "box_value_struct" f %alien-invoke ;
 658
 659 M: ppc %prepare-alien-invoke
 660     #! Save Factor stack pointers in case the C code calls a
 661     #! callback which does a GC, which must reliably trace
 662     #! all roots.
 663     scratch-reg "stack_chain" f %alien-global
 664     scratch-reg scratch-reg 0 LWZ
 665     1 scratch-reg 0 STW
 666     ds-reg scratch-reg 8 STW
 667     rs-reg scratch-reg 12 STW ;
 668
 669 M: ppc %alien-invoke ( symbol dll -- )
 670     [ 11 ] 2dip %alien-global 11 MTLR BLRL ;
 671
 672 M: ppc %alien-callback ( quot -- )
 673     3 swap %load-reference "c_to_factor" f %alien-invoke ;
 674
 675 M: ppc %prepare-alien-indirect ( -- )
 676     "unbox_alien" f %alien-invoke
 677     15 3 MR ;
 678
 679 M: ppc %alien-indirect ( -- )
 680     15 MTLR BLRL ;
 681
 682 M: ppc %callback-value ( ctype -- )
 683     ! Save top of data stack
 684     3 ds-reg 0 LWZ
 685     3 1 0 local@ STW
 686     ! Restore data/call/retain stacks
 687     "unnest_stacks" f %alien-invoke
 688     ! Restore top of data stack
 689     3 1 0 local@ LWZ
 690     ! Unbox former top of data stack to return registers
 691     unbox-return ;
 692
 693 M: ppc small-enough? ( n -- ? ) -32768 32767 between? ;
 694
 695 M: ppc return-struct-in-registers? ( c-type -- ? )
 696     c-type return-in-registers?>> ;
 697
 698 M: ppc %box-small-struct ( c-type -- )
 699     #! Box a <= 16-byte struct returned in r3:r4:r5:r6
 700     heap-size 7 LI
 701     "box_medium_struct" f %alien-invoke ;
 702
 703 : %unbox-struct-1 ( -- )
 704     ! Alien must be in r3.
 705     "alien_offset" f %alien-invoke
 706     3 3 0 LWZ ;
 707
 708 : %unbox-struct-2 ( -- )
 709     ! Alien must be in r3.
 710     "alien_offset" f %alien-invoke
 711     4 3 4 LWZ
 712     3 3 0 LWZ ;
 713
 714 : %unbox-struct-4 ( -- )
 715     ! Alien must be in r3.
 716     "alien_offset" f %alien-invoke
 717     6 3 12 LWZ
 718     5 3 8 LWZ
 719     4 3 4 LWZ
 720     3 3 0 LWZ ;
 721
 722 M: ppc %unbox-small-struct ( size -- )
 723     #! Alien must be in EAX.
 724     heap-size cell align cell /i {
 725         { 1 [ %unbox-struct-1 ] }
 726         { 2 [ %unbox-struct-2 ] }
 727         { 4 [ %unbox-struct-4 ] }
 728     } case ;
 729
 730 enable-float-functions
 731
 732 USE: vocabs.loader
 733
 734 {
 735     { [ os macosx? ] [ "cpu.ppc.macosx" require ] }
 736     { [ os linux? ] [ "cpu.ppc.linux" require ] }
 737 } cond
 738
 739 "complex-double" c-type t >>return-in-registers? drop
 740
 741 [
 742     <c-type>
 743         [ alien-unsigned-4 c-bool> ] >>getter
 744         [ [ >c-bool ] 2dip set-alien-unsigned-4 ] >>setter
 745         4 >>size
 746         4 >>align
 747         "box_boolean" >>boxer
 748         "to_boolean" >>unboxer
 749     "bool" define-primitive-type
 750 ] with-compilation-unit