basis/cpu/ppc/ppc.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs sequences kernel combinators make math
   4 math.order math.ranges system namespaces locals layouts words
   5 alien alien.c-types cpu.architecture cpu.ppc.assembler
   6 compiler.cfg.registers compiler.cfg.instructions
   7 compiler.constants compiler.codegen compiler.codegen.fixup
   8 compiler.cfg.intrinsics compiler.cfg.stack-frame ;
   9 IN: cpu.ppc
  10
  11 ! PowerPC register assignments:
  12 ! r2-r27: integer vregs
  13 ! r28: integer scratch
  14 ! r29: data stack
  15 ! r30: retain stack
  16 ! f0-f29: float vregs
  17 ! f30, f31: float scratch
  18
  19 enable-float-intrinsics
  20
  21 << \ ##integer>float t frame-required? set-word-prop
  22 \ ##float>integer t frame-required? set-word-prop >>
  23
  24 M: ppc machine-registers
  25     {
  26         { int-regs T{ range f 2 26 1 } }
  27         { double-float-regs T{ range f 0 29 1 } }
  28     } ;
  29
  30 : scratch-reg 28 ; inline
  31 : fp-scratch-reg 30 ; inline
  32
  33 M: ppc two-operand? f ;
  34
  35 M: ppc %load-immediate ( reg n -- ) swap LOAD ;
  36
  37 M: ppc %load-indirect ( reg obj -- )
  38     [ 0 swap LOAD32 ] [ rc-absolute-ppc-2/2 rel-immediate ] bi* ;
  39
  40 M: ppc %alien-global ( register symbol dll -- )
  41     [ 0 swap LOAD32 ] 2dip rc-absolute-ppc-2/2 rel-dlsym ;
  42
  43 : ds-reg 29 ; inline
  44 : rs-reg 30 ; inline
  45
  46 GENERIC: loc-reg ( loc -- reg )
  47
  48 M: ds-loc loc-reg drop ds-reg ;
  49 M: rs-loc loc-reg drop rs-reg ;
  50
  51 : loc>operand ( loc -- reg n )
  52     [ loc-reg ] [ n>> cells neg ] bi ; inline
  53
  54 M: ppc %peek loc>operand LWZ ;
  55 M: ppc %replace loc>operand STW ;
  56
  57 : (%inc) ( n reg -- ) dup rot cells ADDI ; inline
  58
  59 M: ppc %inc-d ( n -- ) ds-reg (%inc) ;
  60 M: ppc %inc-r ( n -- ) rs-reg (%inc) ;
  61
  62 HOOK: reserved-area-size os ( -- n )
  63
  64 ! The start of the stack frame contains the size of this frame
  65 ! as well as the currently executing XT
  66 : factor-area-size ( -- n ) 2 cells ; foldable
  67 : next-save ( n -- i ) cell - ;
  68 : xt-save ( n -- i ) 2 cells - ;
  69
  70 ! Next, we have the spill area as well as the FFI parameter area.
  71 ! They overlap, since basic blocks with FFI calls will never
  72 ! spill.
  73 : param@ ( n -- x ) reserved-area-size + ; inline
  74
  75 : param-save-size ( -- n ) 8 cells ; foldable
  76
  77 : local@ ( n -- x )
  78     reserved-area-size param-save-size + + ; inline
  79
  80 : spill-integer-base ( -- n )
  81     stack-frame get spill-counts>> double-float-regs swap at
  82     double-float-regs reg-size * ;
  83
  84 : spill-integer@ ( n -- offset )
  85     cells spill-integer-base + param@ ;
  86
  87 : spill-float@ ( n -- offset )
  88     double-float-regs reg-size * param@ ;
  89
  90 ! Some FP intrinsics need a temporary scratch area in the stack
  91 ! frame, 8 bytes in size
  92 : scratch@ ( n -- offset )
  93     stack-frame get total-size>>
  94     factor-area-size -
  95     param-save-size -
  96     + ;
  97
  98 ! Finally we have the linkage area
  99 HOOK: lr-save os ( -- n )
 100
 101 M: ppc stack-frame-size ( stack-frame -- i )
 102     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
 103     [ params>> ]
 104     [ return>> ]
 105     tri + +
 106     param-save-size +
 107     reserved-area-size +
 108     factor-area-size +
 109     4 cells align ;
 110
 111 M: ppc %call ( label -- ) BL ;
 112 M: ppc %jump-label ( label -- ) B ;
 113 M: ppc %return ( -- ) BLR ;
 114
 115 M:: ppc %dispatch ( src temp offset -- )
 116     0 temp LOAD32
 117     4 offset + cells rc-absolute-ppc-2/2 rel-here
 118     temp temp src LWZX
 119     temp MTCTR
 120     BCTR ;
 121
 122 M: ppc %dispatch-label ( word -- )
 123     0 , rc-absolute-cell rel-word ;
 124
 125 :: (%slot) ( obj slot tag temp -- reg offset )
 126     temp slot obj ADD
 127     temp tag neg ; inline
 128
 129 : (%slot-imm) ( obj slot tag -- reg offset )
 130     [ cells ] dip - ; inline
 131
 132 M: ppc %slot ( dst obj slot tag temp -- ) (%slot) LWZ ;
 133 M: ppc %slot-imm ( dst obj slot tag -- ) (%slot-imm) LWZ ;
 134 M: ppc %set-slot ( src obj slot tag temp -- ) (%slot) STW ;
 135 M: ppc %set-slot-imm ( src obj slot tag -- ) (%slot-imm) STW ;
 136
 137 M:: ppc %string-nth ( dst src index temp -- )
 138     [
 139         "end" define-label
 140         temp src index ADD
 141         dst temp string-offset LBZ
 142         0 dst HEX: 80 CMPI
 143         "end" get BLT
 144         temp src string-aux-offset LWZ
 145         temp temp index ADD
 146         temp temp index ADD
 147         temp temp byte-array-offset LHZ
 148         temp temp 7 SLWI
 149         dst dst temp XOR
 150         "end" resolve-label
 151     ] with-scope ;
 152
 153 M:: ppc %set-string-nth-fast ( ch obj index temp -- )
 154     temp obj index ADD
 155     ch temp string-offset STB ;
 156
 157 M: ppc %add     ADD ;
 158 M: ppc %add-imm ADDI ;
 159 M: ppc %sub     swap SUBF ;
 160 M: ppc %sub-imm SUBI ;
 161 M: ppc %mul     MULLW ;
 162 M: ppc %mul-imm MULLI ;
 163 M: ppc %and     AND ;
 164 M: ppc %and-imm ANDI ;
 165 M: ppc %or      OR ;
 166 M: ppc %or-imm  ORI ;
 167 M: ppc %xor     XOR ;
 168 M: ppc %xor-imm XORI ;
 169 M: ppc %shl-imm swapd SLWI ;
 170 M: ppc %shr-imm swapd SRWI ;
 171 M: ppc %sar-imm SRAWI ;
 172 M: ppc %not     NOT ;
 173
 174 : %alien-invoke-tail ( func dll -- )
 175     [ scratch-reg ] 2dip %alien-global scratch-reg MTCTR BCTR ;
 176
 177 :: exchange-regs ( r1 r2 -- )
 178     scratch-reg r1 MR
 179     r1 r2 MR
 180     r2 scratch-reg MR ;
 181
 182 : ?MR ( r1 r2 -- ) 2dup = [ 2drop ] [ MR ] if ;
 183
 184 :: move>args ( src1 src2 -- )
 185     {
 186         { [ src1 4 = ] [ 3 src2 ?MR 3 4 exchange-regs ] }
 187         { [ src1 3 = ] [ 4 src2 ?MR ] }
 188         { [ src2 3 = ] [ 4 src1 ?MR 3 4 exchange-regs ] }
 189         { [ src2 4 = ] [ 3 src1 ?MR ] }
 190         [ 3 src1 MR 4 src2 MR ]
 191     } cond ;
 192
 193 : clear-xer ( -- )
 194     0 0 LI
 195     0 MTXER ; inline
 196
 197 :: overflow-template ( src1 src2 insn func -- )
 198     "no-overflow" define-label
 199     clear-xer
 200     scratch-reg src2 src1 insn call
 201     scratch-reg ds-reg 0 STW
 202     "no-overflow" get BNO
 203     src1 src2 move>args
 204     %prepare-alien-invoke
 205     func f %alien-invoke
 206     "no-overflow" resolve-label ; inline
 207
 208 :: overflow-template-tail ( src1 src2 insn func -- )
 209     "overflow" define-label
 210     clear-xer
 211     scratch-reg src2 src1 insn call
 212     "overflow" get BO
 213     scratch-reg ds-reg 0 STW
 214     BLR
 215     "overflow" resolve-label
 216     src1 src2 move>args
 217     %prepare-alien-invoke
 218     func f %alien-invoke-tail ; inline
 219
 220 M: ppc %fixnum-add ( src1 src2 -- )
 221     [ ADDO. ] "overflow_fixnum_add" overflow-template ;
 222
 223 M: ppc %fixnum-add-tail ( src1 src2 -- )
 224     [ ADDO. ] "overflow_fixnum_add" overflow-template-tail ;
 225
 226 M: ppc %fixnum-sub ( src1 src2 -- )
 227     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template ;
 228
 229 M: ppc %fixnum-sub-tail ( src1 src2 -- )
 230     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template-tail ;
 231
 232 M:: ppc %fixnum-mul ( src1 src2 temp1 temp2 -- )
 233     "no-overflow" define-label
 234     clear-xer
 235     temp1 src1 tag-bits get SRAWI
 236     temp2 temp1 src2 MULLWO.
 237     temp2 ds-reg 0 STW
 238     "no-overflow" get BNO
 239     src2 src2 tag-bits get SRAWI
 240     temp1 src2 move>args
 241     %prepare-alien-invoke
 242     "overflow_fixnum_multiply" f %alien-invoke
 243     "no-overflow" resolve-label ;
 244
 245 M:: ppc %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 246     "overflow" define-label
 247     clear-xer
 248     temp1 src1 tag-bits get SRAWI
 249     temp2 temp1 src2 MULLWO.
 250     "overflow" get BO
 251     temp2 ds-reg 0 STW
 252     BLR
 253     "overflow" resolve-label
 254     src2 src2 tag-bits get SRAWI
 255     temp1 src2 move>args
 256     %prepare-alien-invoke
 257     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 258
 259 : bignum@ ( n -- offset ) cells bignum tag-number - ; inline
 260
 261 M:: ppc %integer>bignum ( dst src temp -- )
 262     [
 263         "end" define-label
 264         dst 0 >bignum %load-indirect
 265         ! Is it zero? Then just go to the end and return this zero
 266         0 src 0 CMPI
 267         "end" get BEQ
 268         ! Allocate a bignum
 269         dst 4 cells bignum temp %allot
 270         ! Write length
 271         2 tag-fixnum temp LI
 272         temp dst 1 bignum@ STW
 273         ! Compute sign
 274         temp src MR
 275         temp temp cell-bits 1- SRAWI
 276         temp temp 1 ANDI
 277         ! Store sign
 278         temp dst 2 bignum@ STW
 279         ! Make negative value positive
 280         temp temp temp ADD
 281         temp temp NEG
 282         temp temp 1 ADDI
 283         temp src temp MULLW
 284         ! Store the bignum
 285         temp dst 3 bignum@ STW
 286         "end" resolve-label
 287     ] with-scope ;
 288
 289 M:: ppc %bignum>integer ( dst src temp -- )
 290     [
 291         "end" define-label
 292         temp src 1 bignum@ LWZ
 293         ! if the length is 1, its just the sign and nothing else,
 294         ! so output 0
 295         0 dst LI
 296         0 temp 1 tag-fixnum CMPI
 297         "end" get BEQ
 298         ! load the value
 299         dst src 3 bignum@ LWZ
 300         ! load the sign
 301         temp src 2 bignum@ LWZ
 302         ! branchless arithmetic: we want to turn 0 into 1,
 303         ! and 1 into -1
 304         temp temp temp ADD
 305         temp temp 1 SUBI
 306         temp temp NEG
 307         ! multiply value by sign
 308         dst dst temp MULLW
 309         "end" resolve-label
 310     ] with-scope ;
 311
 312 M: ppc %add-float FADD ;
 313 M: ppc %sub-float FSUB ;
 314 M: ppc %mul-float FMUL ;
 315 M: ppc %div-float FDIV ;
 316
 317 M:: ppc %integer>float ( dst src -- )
 318     HEX: 4330 scratch-reg LIS
 319     scratch-reg 1 0 scratch@ STW
 320     scratch-reg src MR
 321     scratch-reg dup HEX: 8000 XORIS
 322     scratch-reg 1 4 scratch@ STW
 323     dst 1 0 scratch@ LFD
 324     scratch-reg 4503601774854144.0 %load-indirect
 325     fp-scratch-reg scratch-reg float-offset LFD
 326     dst dst fp-scratch-reg FSUB ;
 327
 328 M:: ppc %float>integer ( dst src -- )
 329     fp-scratch-reg src FCTIWZ
 330     fp-scratch-reg 1 0 scratch@ STFD
 331     dst 1 4 scratch@ LWZ ;
 332
 333 M: ppc %copy ( dst src -- ) MR ;
 334
 335 M: ppc %copy-float ( dst src -- ) FMR ;
 336
 337 M: ppc %unbox-float ( dst src -- ) float-offset LFD ;
 338
 339 M:: ppc %box-float ( dst src temp -- )
 340     dst 16 float temp %allot
 341     src dst float-offset STFD ;
 342
 343 M:: ppc %unbox-any-c-ptr ( dst src temp -- )
 344     [
 345         { "is-byte-array" "end" "start" } [ define-label ] each
 346         ! Address is computed in dst
 347         0 dst LI
 348         ! Load object into scratch-reg
 349         scratch-reg src MR
 350         ! We come back here with displaced aliens
 351         "start" resolve-label
 352         ! Is the object f?
 353         0 scratch-reg \ f tag-number CMPI
 354         ! If so, done
 355         "end" get BEQ
 356         ! Is the object an alien?
 357         0 scratch-reg header-offset LWZ
 358         0 0 alien type-number tag-fixnum CMPI
 359         "is-byte-array" get BNE
 360         ! If so, load the offset
 361         0 scratch-reg alien-offset LWZ
 362         ! Add it to address being computed
 363         dst dst 0 ADD
 364         ! Now recurse on the underlying alien
 365         scratch-reg scratch-reg underlying-alien-offset LWZ
 366         "start" get B
 367         "is-byte-array" resolve-label
 368         ! Add byte array address to address being computed
 369         dst dst scratch-reg ADD
 370         ! Add an offset to start of byte array's data area
 371         dst dst byte-array-offset ADDI
 372         "end" resolve-label
 373     ] with-scope ;
 374
 375 : alien@ ( n -- n' ) cells object tag-number - ;
 376
 377 M:: ppc %box-alien ( dst src temp -- )
 378     [
 379         "f" define-label
 380         dst \ f tag-number %load-immediate
 381         0 src 0 CMPI
 382         "f" get BEQ
 383         dst 4 cells alien temp %allot
 384         ! Store offset
 385         src dst 3 alien@ STW
 386         ! Store expired slot
 387         temp \ f tag-number %load-immediate
 388         temp dst 1 alien@ STW
 389         ! Store underlying-alien slot
 390         temp dst 2 alien@ STW
 391         "f" resolve-label
 392     ] with-scope ;
 393
 394 M: ppc %alien-unsigned-1 0 LBZ ;
 395 M: ppc %alien-unsigned-2 0 LHZ ;
 396
 397 M: ppc %alien-signed-1 dupd 0 LBZ dup EXTSB ;
 398 M: ppc %alien-signed-2 0 LHA ;
 399
 400 M: ppc %alien-cell 0 LWZ ;
 401
 402 M: ppc %alien-float 0 LFS ;
 403 M: ppc %alien-double 0 LFD ;
 404
 405 M: ppc %set-alien-integer-1 swap 0 STB ;
 406 M: ppc %set-alien-integer-2 swap 0 STH ;
 407
 408 M: ppc %set-alien-cell swap 0 STW ;
 409
 410 M: ppc %set-alien-float swap 0 STFS ;
 411 M: ppc %set-alien-double swap 0 STFD ;
 412
 413 : load-zone-ptr ( reg -- )
 414     "nursery" f %alien-global ;
 415
 416 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 417     [ drop load-zone-ptr ] [ swap 4 LWZ ] 2bi ;
 418
 419 :: inc-allot-ptr ( nursery-ptr allot-ptr n -- )
 420     scratch-reg allot-ptr n 8 align ADDI
 421     scratch-reg nursery-ptr 4 STW ;
 422
 423 :: store-header ( dst class -- )
 424     class type-number tag-fixnum scratch-reg LI
 425     scratch-reg dst 0 STW ;
 426
 427 : store-tagged ( dst tag -- )
 428     dupd tag-number ORI ;
 429
 430 M:: ppc %allot ( dst size class nursery-ptr -- )
 431     nursery-ptr dst load-allot-ptr
 432     nursery-ptr dst size inc-allot-ptr
 433     dst class store-header
 434     dst class store-tagged ;
 435
 436 : load-cards-offset ( dst -- )
 437     [ "cards_offset" f %alien-global ] [ dup 0 LWZ ] bi ;
 438
 439 : load-decks-offset ( dst -- )
 440     [ "decks_offset" f %alien-global ] [ dup 0 LWZ ] bi  ;
 441
 442 M:: ppc %write-barrier ( src card# table -- )
 443     card-mark scratch-reg LI
 444
 445     ! Mark the card
 446     table load-cards-offset
 447     src card# card-bits SRWI
 448     table scratch-reg card# STBX
 449
 450     ! Mark the card deck
 451     table load-decks-offset
 452     src card# deck-bits SRWI
 453     table scratch-reg card# STBX ;
 454
 455 M: ppc %gc
 456     "end" define-label
 457     12 load-zone-ptr
 458     11 12 cell LWZ ! nursery.here -> r11
 459     12 12 3 cells LWZ ! nursery.end -> r12
 460     11 11 1024 ADDI ! add ALLOT_BUFFER_ZONE to here
 461     11 0 12 CMP ! is here >= end?
 462     "end" get BLE
 463     %prepare-alien-invoke
 464     "minor_gc" f %alien-invoke
 465     "end" resolve-label ;
 466
 467 M: ppc %prologue ( n -- )
 468     0 11 LOAD32 rc-absolute-ppc-2/2 rel-this
 469     0 MFLR
 470     1 1 pick neg ADDI
 471     11 1 pick xt-save STW
 472     dup 11 LI
 473     11 1 pick next-save STW
 474     0 1 rot lr-save + STW ;
 475
 476 M: ppc %epilogue ( n -- )
 477     #! At the end of each word that calls a subroutine, we store
 478     #! the previous link register value in r0 by popping it off
 479     #! the stack, set the link register to the contents of r0,
 480     #! and jump to the link register.
 481     0 1 pick lr-save + LWZ
 482     1 1 rot ADDI
 483     0 MTLR ;
 484
 485 :: (%boolean) ( dst temp word -- )
 486     "end" define-label
 487     dst \ f tag-number %load-immediate
 488     "end" get word execute
 489     dst \ t %load-indirect
 490     "end" get resolve-label ; inline
 491
 492 : %boolean ( dst temp cc -- )
 493     negate-cc {
 494         { cc< [ \ BLT (%boolean) ] }
 495         { cc<= [ \ BLE (%boolean) ] }
 496         { cc> [ \ BGT (%boolean) ] }
 497         { cc>= [ \ BGE (%boolean) ] }
 498         { cc= [ \ BEQ (%boolean) ] }
 499         { cc/= [ \ BNE (%boolean) ] }
 500     } case ;
 501
 502 : (%compare) ( src1 src2 -- ) [ 0 ] dip CMP ; inline
 503 : (%compare-imm) ( src1 src2 -- ) [ 0 ] 2dip CMPI ; inline
 504 : (%compare-float) ( src1 src2 -- ) [ 0 ] dip FCMPU ; inline
 505
 506 M: ppc %compare (%compare) %boolean ;
 507 M: ppc %compare-imm (%compare-imm) %boolean ;
 508 M: ppc %compare-float (%compare-float) %boolean ;
 509
 510 : %branch ( label cc -- )
 511     {
 512         { cc< [ BLT ] }
 513         { cc<= [ BLE ] }
 514         { cc> [ BGT ] }
 515         { cc>= [ BGE ] }
 516         { cc= [ BEQ ] }
 517         { cc/= [ BNE ] }
 518     } case ;
 519
 520 M: ppc %compare-branch (%compare) %branch ;
 521 M: ppc %compare-imm-branch (%compare-imm) %branch ;
 522 M: ppc %compare-float-branch (%compare-float) %branch ;
 523
 524 M: ppc %spill-integer ( src n -- ) spill-integer@ 1 swap STW ;
 525 M: ppc %reload-integer ( dst n -- ) spill-integer@ 1 swap LWZ ;
 526
 527 M: ppc %spill-float ( src n -- ) spill-float@ 1 swap STFD ;
 528 M: ppc %reload-float ( dst n -- ) spill-float@ 1 swap LFD ;
 529
 530 M: ppc %loop-entry ;
 531
 532 M: int-regs return-reg drop 3 ;
 533 M: int-regs param-regs drop { 3 4 5 6 7 8 9 10 } ;
 534 M: float-regs return-reg drop 1 ;
 535
 536 M: int-regs %save-param-reg drop 1 rot local@ STW ;
 537 M: int-regs %load-param-reg drop 1 rot local@ LWZ ;
 538
 539 GENERIC: STF ( src dst off reg-class -- )
 540
 541 M: single-float-regs STF drop STFS ;
 542 M: double-float-regs STF drop STFD ;
 543
 544 M: float-regs %save-param-reg >r 1 rot local@ r> STF ;
 545
 546 GENERIC: LF ( dst src off reg-class -- )
 547
 548 M: single-float-regs LF drop LFS ;
 549 M: double-float-regs LF drop LFD ;
 550
 551 M: float-regs %load-param-reg >r 1 rot local@ r> LF ;
 552
 553 M: stack-params %load-param-reg ( stack reg reg-class -- )
 554     drop >r 0 1 rot local@ LWZ 0 1 r> param@ STW ;
 555
 556 : next-param@ ( n -- x ) param@ stack-frame get total-size>> + ;
 557
 558 M: stack-params %save-param-reg ( stack reg reg-class -- )
 559     #! Funky. Read the parameter from the caller's stack frame.
 560     #! This word is used in callbacks
 561     drop
 562     0 1 rot next-param@ LWZ
 563     0 1 rot local@ STW ;
 564
 565 M: ppc %prepare-unbox ( -- )
 566     ! First parameter is top of stack
 567     3 ds-reg 0 LWZ
 568     ds-reg dup cell SUBI ;
 569
 570 M: ppc %unbox ( n reg-class func -- )
 571     ! Value must be in r3
 572     ! Call the unboxer
 573     f %alien-invoke
 574     ! Store the return value on the C stack
 575     over [ [ return-reg ] keep %save-param-reg ] [ 2drop ] if ;
 576
 577 M: ppc %unbox-long-long ( n func -- )
 578     ! Value must be in r3:r4
 579     ! Call the unboxer
 580     f %alien-invoke
 581     ! Store the return value on the C stack
 582     [
 583         3 1 pick local@ STW
 584         4 1 rot cell + local@ STW
 585     ] when* ;
 586
 587 M: ppc %unbox-large-struct ( n c-type -- )
 588     ! Value must be in r3
 589     ! Compute destination address and load struct size
 590     [ 4 1 rot local@ ADDI ] [ heap-size 5 LI ] bi*
 591     ! Call the function
 592     "to_value_struct" f %alien-invoke ;
 593
 594 M: ppc %box ( n reg-class func -- )
 595     ! If the source is a stack location, load it into freg #0.
 596     ! If the source is f, then we assume the value is already in
 597     ! freg #0.
 598     >r
 599     over [ 0 over param-reg swap %load-param-reg ] [ 2drop ] if
 600     r> f %alien-invoke ;
 601
 602 M: ppc %box-long-long ( n func -- )
 603     >r [
 604         3 1 pick local@ LWZ
 605         4 1 rot cell + local@ LWZ
 606     ] when* r> f %alien-invoke ;
 607
 608 : struct-return@ ( n -- n )
 609     [ stack-frame get params>> ] unless* local@ ;
 610
 611 M: ppc %prepare-box-struct ( -- )
 612     #! Compute target address for value struct return
 613     3 1 f struct-return@ ADDI
 614     3 1 0 local@ STW ;
 615
 616 M: ppc %box-large-struct ( n c-type -- )
 617     ! If n = f, then we're boxing a returned struct
 618     ! Compute destination address and load struct size
 619     [ 3 1 rot struct-return@ ADDI ] [ heap-size 4 LI ] bi*
 620     ! Call the function
 621     "box_value_struct" f %alien-invoke ;
 622
 623 M: ppc %prepare-alien-invoke
 624     #! Save Factor stack pointers in case the C code calls a
 625     #! callback which does a GC, which must reliably trace
 626     #! all roots.
 627     scratch-reg "stack_chain" f %alien-global
 628     scratch-reg scratch-reg 0 LWZ
 629     1 scratch-reg 0 STW
 630     ds-reg scratch-reg 8 STW
 631     rs-reg scratch-reg 12 STW ;
 632
 633 M: ppc %alien-invoke ( symbol dll -- )
 634     [ 11 ] 2dip %alien-global 11 MTLR BLRL ;
 635
 636 M: ppc %alien-callback ( quot -- )
 637     3 swap %load-indirect "c_to_factor" f %alien-invoke ;
 638
 639 M: ppc %prepare-alien-indirect ( -- )
 640     "unbox_alien" f %alien-invoke
 641     13 3 MR ;
 642
 643 M: ppc %alien-indirect ( -- )
 644     13 MTLR BLRL ;
 645
 646 M: ppc %callback-value ( ctype -- )
 647     ! Save top of data stack
 648     3 ds-reg 0 LWZ
 649     3 1 0 local@ STW
 650     ! Restore data/call/retain stacks
 651     "unnest_stacks" f %alien-invoke
 652     ! Restore top of data stack
 653     3 1 0 local@ LWZ
 654     ! Unbox former top of data stack to return registers
 655     unbox-return ;
 656
 657 M: ppc small-enough? ( n -- ? ) -32768 32767 between? ;
 658
 659 M: ppc struct-small-enough? ( size -- ? ) drop f ;
 660
 661 M: ppc %box-small-struct
 662     drop "No small structs" throw ;
 663
 664 M: ppc %unbox-small-struct
 665     drop "No small structs" throw ;
 666
 667 USE: vocabs.loader
 668
 669 {
 670     { [ os macosx? ] [ "cpu.ppc.macosx" require ] }
 671     { [ os linux? ] [ "cpu.ppc.linux" require ] }
 672 } cond