basis/cpu/ppc/ppc.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs sequences kernel combinators make math
   4 math.order math.ranges system namespaces locals layouts words
   5 alien alien.accessors alien.c-types literals cpu.architecture
   6 cpu.ppc.assembler cpu.ppc.assembler.backend literals compiler.cfg.registers
   7 compiler.cfg.instructions compiler.constants compiler.codegen
   8 compiler.codegen.fixup compiler.cfg.intrinsics
   9 compiler.cfg.stack-frame compiler.units ;
  10 FROM: cpu.ppc.assembler => B ;
  11 IN: cpu.ppc
  12
  13 ! PowerPC register assignments:
  14 ! r2-r12: integer vregs
  15 ! r15-r29
  16 ! r30: integer scratch
  17 ! f0-f29: float vregs
  18 ! f30: float scratch
  19
  20 ! Add some methods to the assembler that are useful to us
  21 M: label (B) [ 0 ] 2dip (B) rc-relative-ppc-3 label-fixup ;
  22 M: label BC [ 0 BC ] dip rc-relative-ppc-2 label-fixup ;
  23
  24 enable-float-intrinsics
  25
  26 <<
  27 \ ##integer>float t frame-required? set-word-prop
  28 \ ##float>integer t frame-required? set-word-prop
  29 >>
  30
  31 M: ppc machine-registers
  32     {
  33         { int-regs $[ 2 12 [a,b] 15 29 [a,b] append ] }
  34         { double-float-regs $[ 0 29 [a,b] ] }
  35     } ;
  36
  37 CONSTANT: scratch-reg 30
  38 CONSTANT: fp-scratch-reg 30
  39
  40 M: ppc two-operand? f ;
  41
  42 M: ppc %load-immediate ( reg n -- ) swap LOAD ;
  43
  44 M: ppc %load-reference ( reg obj -- )
  45     [ 0 swap LOAD32 ] [ rc-absolute-ppc-2/2 rel-immediate ] bi* ;
  46
  47 M: ppc %alien-global ( register symbol dll -- )
  48     [ 0 swap LOAD32 ] 2dip rc-absolute-ppc-2/2 rel-dlsym ;
  49
  50 CONSTANT: ds-reg 13
  51 CONSTANT: rs-reg 14
  52
  53 GENERIC: loc-reg ( loc -- reg )
  54
  55 M: ds-loc loc-reg drop ds-reg ;
  56 M: rs-loc loc-reg drop rs-reg ;
  57
  58 : loc>operand ( loc -- reg n )
  59     [ loc-reg ] [ n>> cells neg ] bi ; inline
  60
  61 M: ppc %peek loc>operand LWZ ;
  62 M: ppc %replace loc>operand STW ;
  63
  64 : (%inc) ( n reg -- ) dup rot cells ADDI ; inline
  65
  66 M: ppc %inc-d ( n -- ) ds-reg (%inc) ;
  67 M: ppc %inc-r ( n -- ) rs-reg (%inc) ;
  68
  69 HOOK: reserved-area-size os ( -- n )
  70
  71 ! The start of the stack frame contains the size of this frame
  72 ! as well as the currently executing XT
  73 : factor-area-size ( -- n ) 2 cells ; foldable
  74 : next-save ( n -- i ) cell - ;
  75 : xt-save ( n -- i ) 2 cells - ;
  76
  77 ! Next, we have the spill area as well as the FFI parameter area.
  78 ! They overlap, since basic blocks with FFI calls will never
  79 ! spill.
  80 : param@ ( n -- x ) reserved-area-size + ; inline
  81
  82 : param-save-size ( -- n ) 8 cells ; foldable
  83
  84 : local@ ( n -- x )
  85     reserved-area-size param-save-size + + ; inline
  86
  87 : spill-integer-base ( -- n )
  88     stack-frame get spill-counts>> double-float-regs swap at
  89     double-float-regs reg-size * ;
  90
  91 : spill-integer@ ( n -- offset )
  92     cells spill-integer-base + param@ ;
  93
  94 : spill-float@ ( n -- offset )
  95     double-float-regs reg-size * param@ ;
  96
  97 ! Some FP intrinsics need a temporary scratch area in the stack
  98 ! frame, 8 bytes in size
  99 : scratch@ ( n -- offset )
 100     stack-frame get total-size>>
 101     factor-area-size -
 102     param-save-size -
 103     + ;
 104
 105 ! Finally we have the linkage area
 106 HOOK: lr-save os ( -- n )
 107
 108 M: ppc stack-frame-size ( stack-frame -- i )
 109     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
 110     [ params>> ]
 111     [ return>> ]
 112     tri + +
 113     param-save-size +
 114     reserved-area-size +
 115     factor-area-size +
 116     4 cells align ;
 117
 118 M: ppc %call ( word -- ) 0 BL rc-relative-ppc-3 rel-word-pic ;
 119
 120 M: ppc %jump ( word -- )
 121     0 6 LOAD32 8 rc-absolute-ppc-2/2 rel-here
 122     0 B rc-relative-ppc-3 rel-word-pic-tail ;
 123
 124 M: ppc %jump-label ( label -- ) B ;
 125 M: ppc %return ( -- ) BLR ;
 126
 127 M:: ppc %dispatch ( src temp -- )
 128     0 temp LOAD32
 129     4 cells rc-absolute-ppc-2/2 rel-here
 130     temp temp src LWZX
 131     temp MTCTR
 132     BCTR ;
 133
 134 :: (%slot) ( obj slot tag temp -- reg offset )
 135     temp slot obj ADD
 136     temp tag neg ; inline
 137
 138 : (%slot-imm) ( obj slot tag -- reg offset )
 139     [ cells ] dip - ; inline
 140
 141 M: ppc %slot ( dst obj slot tag temp -- ) (%slot) LWZ ;
 142 M: ppc %slot-imm ( dst obj slot tag -- ) (%slot-imm) LWZ ;
 143 M: ppc %set-slot ( src obj slot tag temp -- ) (%slot) STW ;
 144 M: ppc %set-slot-imm ( src obj slot tag -- ) (%slot-imm) STW ;
 145
 146 M:: ppc %string-nth ( dst src index temp -- )
 147     [
 148         "end" define-label
 149         temp src index ADD
 150         dst temp string-offset LBZ
 151         0 dst HEX: 80 CMPI
 152         "end" get BLT
 153         temp src string-aux-offset LWZ
 154         temp temp index ADD
 155         temp temp index ADD
 156         temp temp byte-array-offset LHZ
 157         temp temp 7 SLWI
 158         dst dst temp XOR
 159         "end" resolve-label
 160     ] with-scope ;
 161
 162 M:: ppc %set-string-nth-fast ( ch obj index temp -- )
 163     temp obj index ADD
 164     ch temp string-offset STB ;
 165
 166 M: ppc %add     ADD ;
 167 M: ppc %add-imm ADDI ;
 168 M: ppc %sub     swap SUBF ;
 169 M: ppc %sub-imm SUBI ;
 170 M: ppc %mul     MULLW ;
 171 M: ppc %mul-imm MULLI ;
 172 M: ppc %and     AND ;
 173 M: ppc %and-imm ANDI ;
 174 M: ppc %or      OR ;
 175 M: ppc %or-imm  ORI ;
 176 M: ppc %xor     XOR ;
 177 M: ppc %xor-imm XORI ;
 178 M: ppc %shl-imm swapd SLWI ;
 179 M: ppc %shr-imm swapd SRWI ;
 180 M: ppc %sar-imm SRAWI ;
 181 M: ppc %not     NOT ;
 182
 183 : %alien-invoke-tail ( func dll -- )
 184     [ scratch-reg ] 2dip %alien-global scratch-reg MTCTR BCTR ;
 185
 186 :: exchange-regs ( r1 r2 -- )
 187     scratch-reg r1 MR
 188     r1 r2 MR
 189     r2 scratch-reg MR ;
 190
 191 : ?MR ( r1 r2 -- ) 2dup = [ 2drop ] [ MR ] if ;
 192
 193 :: move>args ( src1 src2 -- )
 194     {
 195         { [ src1 4 = ] [ 3 src2 ?MR 3 4 exchange-regs ] }
 196         { [ src1 3 = ] [ 4 src2 ?MR ] }
 197         { [ src2 3 = ] [ 4 src1 ?MR 3 4 exchange-regs ] }
 198         { [ src2 4 = ] [ 3 src1 ?MR ] }
 199         [ 3 src1 MR 4 src2 MR ]
 200     } cond ;
 201
 202 : clear-xer ( -- )
 203     0 0 LI
 204     0 MTXER ; inline
 205
 206 :: overflow-template ( src1 src2 insn func -- )
 207     "no-overflow" define-label
 208     clear-xer
 209     scratch-reg src2 src1 insn call
 210     scratch-reg ds-reg 0 STW
 211     "no-overflow" get BNO
 212     src1 src2 move>args
 213     %prepare-alien-invoke
 214     func f %alien-invoke
 215     "no-overflow" resolve-label ; inline
 216
 217 :: overflow-template-tail ( src1 src2 insn func -- )
 218     "overflow" define-label
 219     clear-xer
 220     scratch-reg src2 src1 insn call
 221     "overflow" get BO
 222     scratch-reg ds-reg 0 STW
 223     BLR
 224     "overflow" resolve-label
 225     src1 src2 move>args
 226     %prepare-alien-invoke
 227     func f %alien-invoke-tail ; inline
 228
 229 M: ppc %fixnum-add ( src1 src2 -- )
 230     [ ADDO. ] "overflow_fixnum_add" overflow-template ;
 231
 232 M: ppc %fixnum-add-tail ( src1 src2 -- )
 233     [ ADDO. ] "overflow_fixnum_add" overflow-template-tail ;
 234
 235 M: ppc %fixnum-sub ( src1 src2 -- )
 236     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template ;
 237
 238 M: ppc %fixnum-sub-tail ( src1 src2 -- )
 239     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template-tail ;
 240
 241 M:: ppc %fixnum-mul ( src1 src2 temp1 temp2 -- )
 242     "no-overflow" define-label
 243     clear-xer
 244     temp1 src1 tag-bits get SRAWI
 245     temp2 temp1 src2 MULLWO.
 246     temp2 ds-reg 0 STW
 247     "no-overflow" get BNO
 248     src2 src2 tag-bits get SRAWI
 249     temp1 src2 move>args
 250     %prepare-alien-invoke
 251     "overflow_fixnum_multiply" f %alien-invoke
 252     "no-overflow" resolve-label ;
 253
 254 M:: ppc %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 255     "overflow" define-label
 256     clear-xer
 257     temp1 src1 tag-bits get SRAWI
 258     temp2 temp1 src2 MULLWO.
 259     "overflow" get BO
 260     temp2 ds-reg 0 STW
 261     BLR
 262     "overflow" resolve-label
 263     src2 src2 tag-bits get SRAWI
 264     temp1 src2 move>args
 265     %prepare-alien-invoke
 266     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 267
 268 : bignum@ ( n -- offset ) cells bignum tag-number - ; inline
 269
 270 M:: ppc %integer>bignum ( dst src temp -- )
 271     [
 272         "end" define-label
 273         dst 0 >bignum %load-reference
 274         ! Is it zero? Then just go to the end and return this zero
 275         0 src 0 CMPI
 276         "end" get BEQ
 277         ! Allocate a bignum
 278         dst 4 cells bignum temp %allot
 279         ! Write length
 280         2 tag-fixnum temp LI
 281         temp dst 1 bignum@ STW
 282         ! Compute sign
 283         temp src MR
 284         temp temp cell-bits 1- SRAWI
 285         temp temp 1 ANDI
 286         ! Store sign
 287         temp dst 2 bignum@ STW
 288         ! Make negative value positive
 289         temp temp temp ADD
 290         temp temp NEG
 291         temp temp 1 ADDI
 292         temp src temp MULLW
 293         ! Store the bignum
 294         temp dst 3 bignum@ STW
 295         "end" resolve-label
 296     ] with-scope ;
 297
 298 M:: ppc %bignum>integer ( dst src temp -- )
 299     [
 300         "end" define-label
 301         temp src 1 bignum@ LWZ
 302         ! if the length is 1, its just the sign and nothing else,
 303         ! so output 0
 304         0 dst LI
 305         0 temp 1 tag-fixnum CMPI
 306         "end" get BEQ
 307         ! load the value
 308         dst src 3 bignum@ LWZ
 309         ! load the sign
 310         temp src 2 bignum@ LWZ
 311         ! branchless arithmetic: we want to turn 0 into 1,
 312         ! and 1 into -1
 313         temp temp temp ADD
 314         temp temp 1 SUBI
 315         temp temp NEG
 316         ! multiply value by sign
 317         dst dst temp MULLW
 318         "end" resolve-label
 319     ] with-scope ;
 320
 321 M: ppc %add-float FADD ;
 322 M: ppc %sub-float FSUB ;
 323 M: ppc %mul-float FMUL ;
 324 M: ppc %div-float FDIV ;
 325
 326 M:: ppc %integer>float ( dst src -- )
 327     HEX: 4330 scratch-reg LIS
 328     scratch-reg 1 0 scratch@ STW
 329     scratch-reg src MR
 330     scratch-reg dup HEX: 8000 XORIS
 331     scratch-reg 1 4 scratch@ STW
 332     dst 1 0 scratch@ LFD
 333     scratch-reg 4503601774854144.0 %load-reference
 334     fp-scratch-reg scratch-reg float-offset LFD
 335     dst dst fp-scratch-reg FSUB ;
 336
 337 M:: ppc %float>integer ( dst src -- )
 338     fp-scratch-reg src FCTIWZ
 339     fp-scratch-reg 1 0 scratch@ STFD
 340     dst 1 4 scratch@ LWZ ;
 341
 342 M: ppc %copy ( dst src -- ) MR ;
 343
 344 M: ppc %copy-float ( dst src -- ) FMR ;
 345
 346 M: ppc %unbox-float ( dst src -- ) float-offset LFD ;
 347
 348 M:: ppc %box-float ( dst src temp -- )
 349     dst 16 float temp %allot
 350     src dst float-offset STFD ;
 351
 352 M:: ppc %unbox-any-c-ptr ( dst src temp -- )
 353     [
 354         { "is-byte-array" "end" "start" } [ define-label ] each
 355         ! Address is computed in dst
 356         0 dst LI
 357         ! Load object into scratch-reg
 358         scratch-reg src MR
 359         ! We come back here with displaced aliens
 360         "start" resolve-label
 361         ! Is the object f?
 362         0 scratch-reg \ f tag-number CMPI
 363         ! If so, done
 364         "end" get BEQ
 365         ! Is the object an alien?
 366         0 scratch-reg header-offset LWZ
 367         0 0 alien type-number tag-fixnum CMPI
 368         "is-byte-array" get BNE
 369         ! If so, load the offset
 370         0 scratch-reg alien-offset LWZ
 371         ! Add it to address being computed
 372         dst dst 0 ADD
 373         ! Now recurse on the underlying alien
 374         scratch-reg scratch-reg underlying-alien-offset LWZ
 375         "start" get B
 376         "is-byte-array" resolve-label
 377         ! Add byte array address to address being computed
 378         dst dst scratch-reg ADD
 379         ! Add an offset to start of byte array's data area
 380         dst dst byte-array-offset ADDI
 381         "end" resolve-label
 382     ] with-scope ;
 383
 384 : alien@ ( n -- n' ) cells object tag-number - ;
 385
 386 M:: ppc %box-alien ( dst src temp -- )
 387     [
 388         "f" define-label
 389         dst \ f tag-number %load-immediate
 390         0 src 0 CMPI
 391         "f" get BEQ
 392         dst 4 cells alien temp %allot
 393         ! Store offset
 394         src dst 3 alien@ STW
 395         ! Store expired slot
 396         temp \ f tag-number %load-immediate
 397         temp dst 1 alien@ STW
 398         ! Store underlying-alien slot
 399         temp dst 2 alien@ STW
 400         "f" resolve-label
 401     ] with-scope ;
 402
 403 M: ppc %alien-unsigned-1 0 LBZ ;
 404 M: ppc %alien-unsigned-2 0 LHZ ;
 405
 406 M: ppc %alien-signed-1 dupd 0 LBZ dup EXTSB ;
 407 M: ppc %alien-signed-2 0 LHA ;
 408
 409 M: ppc %alien-cell 0 LWZ ;
 410
 411 M: ppc %alien-float 0 LFS ;
 412 M: ppc %alien-double 0 LFD ;
 413
 414 M: ppc %set-alien-integer-1 swap 0 STB ;
 415 M: ppc %set-alien-integer-2 swap 0 STH ;
 416
 417 M: ppc %set-alien-cell swap 0 STW ;
 418
 419 M: ppc %set-alien-float swap 0 STFS ;
 420 M: ppc %set-alien-double swap 0 STFD ;
 421
 422 : load-zone-ptr ( reg -- )
 423     "nursery" f %alien-global ;
 424
 425 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 426     [ drop load-zone-ptr ] [ swap 4 LWZ ] 2bi ;
 427
 428 :: inc-allot-ptr ( nursery-ptr allot-ptr n -- )
 429     scratch-reg allot-ptr n 8 align ADDI
 430     scratch-reg nursery-ptr 4 STW ;
 431
 432 :: store-header ( dst class -- )
 433     class type-number tag-fixnum scratch-reg LI
 434     scratch-reg dst 0 STW ;
 435
 436 : store-tagged ( dst tag -- )
 437     dupd tag-number ORI ;
 438
 439 M:: ppc %allot ( dst size class nursery-ptr -- )
 440     nursery-ptr dst load-allot-ptr
 441     nursery-ptr dst size inc-allot-ptr
 442     dst class store-header
 443     dst class store-tagged ;
 444
 445 : load-cards-offset ( dst -- )
 446     [ "cards_offset" f %alien-global ] [ dup 0 LWZ ] bi ;
 447
 448 : load-decks-offset ( dst -- )
 449     [ "decks_offset" f %alien-global ] [ dup 0 LWZ ] bi  ;
 450
 451 M:: ppc %write-barrier ( src card# table -- )
 452     card-mark scratch-reg LI
 453
 454     ! Mark the card
 455     table load-cards-offset
 456     src card# card-bits SRWI
 457     table scratch-reg card# STBX
 458
 459     ! Mark the card deck
 460     table load-decks-offset
 461     src card# deck-bits SRWI
 462     table scratch-reg card# STBX ;
 463
 464 M: ppc %gc
 465     "end" define-label
 466     12 load-zone-ptr
 467     11 12 cell LWZ ! nursery.here -> r11
 468     12 12 3 cells LWZ ! nursery.end -> r12
 469     11 11 1024 ADDI ! add ALLOT_BUFFER_ZONE to here
 470     11 0 12 CMP ! is here >= end?
 471     "end" get BLE
 472     %prepare-alien-invoke
 473     "minor_gc" f %alien-invoke
 474     "end" resolve-label ;
 475
 476 M: ppc %prologue ( n -- )
 477     0 11 LOAD32 rc-absolute-ppc-2/2 rel-this
 478     0 MFLR
 479     {
 480         [ [ 1 1 ] dip neg ADDI ]
 481         [ [ 11 1 ] dip xt-save STW ]
 482         [ 11 LI ]
 483         [ [ 11 1 ] dip next-save STW ]
 484         [ [ 0 1 ] dip lr-save + STW ]
 485     } cleave ;
 486
 487 M: ppc %epilogue ( n -- )
 488     #! At the end of each word that calls a subroutine, we store
 489     #! the previous link register value in r0 by popping it off
 490     #! the stack, set the link register to the contents of r0,
 491     #! and jump to the link register.
 492     [ [ 0 1 ] dip lr-save + LWZ ]
 493     [ [ 1 1 ] dip ADDI ] bi
 494     0 MTLR ;
 495
 496 :: (%boolean) ( dst temp word -- )
 497     "end" define-label
 498     dst \ f tag-number %load-immediate
 499     "end" get word execute
 500     dst \ t %load-reference
 501     "end" get resolve-label ; inline
 502
 503 : %boolean ( dst temp cc -- )
 504     negate-cc {
 505         { cc< [ \ BLT (%boolean) ] }
 506         { cc<= [ \ BLE (%boolean) ] }
 507         { cc> [ \ BGT (%boolean) ] }
 508         { cc>= [ \ BGE (%boolean) ] }
 509         { cc= [ \ BEQ (%boolean) ] }
 510         { cc/= [ \ BNE (%boolean) ] }
 511     } case ;
 512
 513 : (%compare) ( src1 src2 -- ) [ 0 ] dip CMP ; inline
 514 : (%compare-imm) ( src1 src2 -- ) [ 0 ] 2dip CMPI ; inline
 515 : (%compare-float) ( src1 src2 -- ) [ 0 ] dip FCMPU ; inline
 516
 517 M: ppc %compare (%compare) %boolean ;
 518 M: ppc %compare-imm (%compare-imm) %boolean ;
 519 M: ppc %compare-float (%compare-float) %boolean ;
 520
 521 : %branch ( label cc -- )
 522     {
 523         { cc< [ BLT ] }
 524         { cc<= [ BLE ] }
 525         { cc> [ BGT ] }
 526         { cc>= [ BGE ] }
 527         { cc= [ BEQ ] }
 528         { cc/= [ BNE ] }
 529     } case ;
 530
 531 M: ppc %compare-branch (%compare) %branch ;
 532 M: ppc %compare-imm-branch (%compare-imm) %branch ;
 533 M: ppc %compare-float-branch (%compare-float) %branch ;
 534
 535 M: ppc %spill-integer ( src n -- ) spill-integer@ 1 swap STW ;
 536 M: ppc %reload-integer ( dst n -- ) spill-integer@ 1 swap LWZ ;
 537
 538 M: ppc %spill-float ( src n -- ) spill-float@ 1 swap STFD ;
 539 M: ppc %reload-float ( dst n -- ) spill-float@ 1 swap LFD ;
 540
 541 M: ppc %loop-entry ;
 542
 543 M: int-regs return-reg drop 3 ;
 544 M: int-regs param-regs drop { 3 4 5 6 7 8 9 10 } ;
 545 M: float-regs return-reg drop 1 ;
 546
 547 M: int-regs %save-param-reg drop 1 rot local@ STW ;
 548 M: int-regs %load-param-reg drop 1 rot local@ LWZ ;
 549
 550 GENERIC: STF ( src dst off reg-class -- )
 551
 552 M: single-float-regs STF drop STFS ;
 553 M: double-float-regs STF drop STFD ;
 554
 555 M: float-regs %save-param-reg [ 1 rot local@ ] dip STF ;
 556
 557 GENERIC: LF ( dst src off reg-class -- )
 558
 559 M: single-float-regs LF drop LFS ;
 560 M: double-float-regs LF drop LFD ;
 561
 562 M: float-regs %load-param-reg [ 1 rot local@ ] dip LF ;
 563
 564 M: stack-params %load-param-reg ( stack reg reg-class -- )
 565     drop [ 0 1 rot local@ LWZ 0 1 ] dip param@ STW ;
 566
 567 : next-param@ ( n -- x ) param@ stack-frame get total-size>> + ;
 568
 569 M: stack-params %save-param-reg ( stack reg reg-class -- )
 570     #! Funky. Read the parameter from the caller's stack frame.
 571     #! This word is used in callbacks
 572     drop
 573     [ 0 1 ] dip next-param@ LWZ
 574     [ 0 1 ] dip local@ STW ;
 575
 576 M: ppc %prepare-unbox ( -- )
 577     ! First parameter is top of stack
 578     3 ds-reg 0 LWZ
 579     ds-reg dup cell SUBI ;
 580
 581 M: ppc %unbox ( n reg-class func -- )
 582     ! Value must be in r3
 583     ! Call the unboxer
 584     f %alien-invoke
 585     ! Store the return value on the C stack
 586     over [ [ return-reg ] keep %save-param-reg ] [ 2drop ] if ;
 587
 588 M: ppc %unbox-long-long ( n func -- )
 589     ! Value must be in r3:r4
 590     ! Call the unboxer
 591     f %alien-invoke
 592     ! Store the return value on the C stack
 593     [
 594         [ [ 3 1 ] dip local@ STW ]
 595         [ [ 4 1 ] dip cell + local@ STW ] bi
 596     ] when* ;
 597
 598 M: ppc %unbox-large-struct ( n c-type -- )
 599     ! Value must be in r3
 600     ! Compute destination address and load struct size
 601     [ [ 4 1 ] dip local@ ADDI ] [ heap-size 5 LI ] bi*
 602     ! Call the function
 603     "to_value_struct" f %alien-invoke ;
 604
 605 M: ppc %box ( n reg-class func -- )
 606     ! If the source is a stack location, load it into freg #0.
 607     ! If the source is f, then we assume the value is already in
 608     ! freg #0.
 609     [ over [ 0 over param-reg swap %load-param-reg ] [ 2drop ] if ] dip
 610     f %alien-invoke ;
 611
 612 M: ppc %box-long-long ( n func -- )
 613     [
 614         [
 615             [ [ 3 1 ] dip local@ LWZ ]
 616             [ [ 4 1 ] dip cell + local@ LWZ ] bi
 617         ] when*
 618     ] dip f %alien-invoke ;
 619
 620 : struct-return@ ( n -- n )
 621     [ stack-frame get params>> ] unless* local@ ;
 622
 623 M: ppc %prepare-box-struct ( -- )
 624     #! Compute target address for value struct return
 625     3 1 f struct-return@ ADDI
 626     3 1 0 local@ STW ;
 627
 628 M: ppc %box-large-struct ( n c-type -- )
 629     ! If n = f, then we're boxing a returned struct
 630     ! Compute destination address and load struct size
 631     [ [ 3 1 ] dip struct-return@ ADDI ] [ heap-size 4 LI ] bi*
 632     ! Call the function
 633     "box_value_struct" f %alien-invoke ;
 634
 635 M: ppc %prepare-alien-invoke
 636     #! Save Factor stack pointers in case the C code calls a
 637     #! callback which does a GC, which must reliably trace
 638     #! all roots.
 639     scratch-reg "stack_chain" f %alien-global
 640     scratch-reg scratch-reg 0 LWZ
 641     1 scratch-reg 0 STW
 642     ds-reg scratch-reg 8 STW
 643     rs-reg scratch-reg 12 STW ;
 644
 645 M: ppc %alien-invoke ( symbol dll -- )
 646     [ 11 ] 2dip %alien-global 11 MTLR BLRL ;
 647
 648 M: ppc %alien-callback ( quot -- )
 649     3 swap %load-reference "c_to_factor" f %alien-invoke ;
 650
 651 M: ppc %prepare-alien-indirect ( -- )
 652     "unbox_alien" f %alien-invoke
 653     15 3 MR ;
 654
 655 M: ppc %alien-indirect ( -- )
 656     15 MTLR BLRL ;
 657
 658 M: ppc %callback-value ( ctype -- )
 659     ! Save top of data stack
 660     3 ds-reg 0 LWZ
 661     3 1 0 local@ STW
 662     ! Restore data/call/retain stacks
 663     "unnest_stacks" f %alien-invoke
 664     ! Restore top of data stack
 665     3 1 0 local@ LWZ
 666     ! Unbox former top of data stack to return registers
 667     unbox-return ;
 668
 669 M: ppc small-enough? ( n -- ? ) -32768 32767 between? ;
 670
 671 M: ppc return-struct-in-registers? ( c-type -- ? )
 672     c-type return-in-registers?>> ;
 673
 674 M: ppc %box-small-struct ( c-type -- )
 675     #! Box a <= 16-byte struct returned in r3:r4:r5:r6
 676     heap-size 7 LI
 677     "box_medium_struct" f %alien-invoke ;
 678
 679 : %unbox-struct-1 ( -- )
 680     ! Alien must be in r3.
 681     "alien_offset" f %alien-invoke
 682     3 3 0 LWZ ;
 683
 684 : %unbox-struct-2 ( -- )
 685     ! Alien must be in r3.
 686     "alien_offset" f %alien-invoke
 687     4 3 4 LWZ
 688     3 3 0 LWZ ;
 689
 690 : %unbox-struct-4 ( -- )
 691     ! Alien must be in r3.
 692     "alien_offset" f %alien-invoke
 693     6 3 12 LWZ
 694     5 3 8 LWZ
 695     4 3 4 LWZ
 696     3 3 0 LWZ ;
 697
 698 M: ppc %unbox-small-struct ( size -- )
 699     #! Alien must be in EAX.
 700     heap-size cell align cell /i {
 701         { 1 [ %unbox-struct-1 ] }
 702         { 2 [ %unbox-struct-2 ] }
 703         { 4 [ %unbox-struct-4 ] }
 704     } case ;
 705
 706 USE: vocabs.loader
 707
 708 {
 709     { [ os macosx? ] [ "cpu.ppc.macosx" require ] }
 710     { [ os linux? ] [ "cpu.ppc.linux" require ] }
 711 } cond
 712
 713 "complex-double" c-type t >>return-in-registers? drop
 714
 715 [
 716     <c-type>
 717         [ alien-unsigned-4 c-bool> ] >>getter
 718         [ [ >c-bool ] 2dip set-alien-unsigned-4 ] >>setter
 719         4 >>size
 720         4 >>align
 721         "box_boolean" >>boxer
 722         "to_boolean" >>unboxer
 723     "bool" define-primitive-type
 724 ] with-compilation-unit