basis/cpu/ppc/ppc.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs sequences kernel combinators make math
   4 math.order math.ranges system namespaces locals layouts words
   5 alien alien.accessors alien.c-types literals cpu.architecture
   6 cpu.ppc.assembler cpu.ppc.assembler.backend compiler.cfg.registers
   7 compiler.cfg.instructions compiler.constants compiler.codegen
   8 compiler.codegen.fixup compiler.cfg.intrinsics
   9 compiler.cfg.stack-frame compiler.cfg.build-stack-frame
  10 compiler.units ;
  11 FROM: cpu.ppc.assembler => B ;
  12 IN: cpu.ppc
  13
  14 ! PowerPC register assignments:
  15 ! r2-r12: integer vregs
  16 ! r15-r29
  17 ! r30: integer scratch
  18 ! f0-f29: float vregs
  19 ! f30: float scratch
  20
  21 ! Add some methods to the assembler that are useful to us
  22 M: label (B) [ 0 ] 2dip (B) rc-relative-ppc-3 label-fixup ;
  23 M: label BC [ 0 BC ] dip rc-relative-ppc-2 label-fixup ;
  24
  25 enable-float-intrinsics
  26
  27 <<
  28 \ ##integer>float t frame-required? set-word-prop
  29 \ ##float>integer t frame-required? set-word-prop
  30 >>
  31
  32 M: ppc machine-registers
  33     {
  34         { int-regs $[ 2 12 [a,b] 15 29 [a,b] append ] }
  35         { double-float-regs $[ 0 29 [a,b] ] }
  36     } ;
  37
  38 CONSTANT: scratch-reg 30
  39 CONSTANT: fp-scratch-reg 30
  40
  41 M: ppc two-operand? f ;
  42
  43 M: ppc %load-immediate ( reg n -- ) swap LOAD ;
  44
  45 M: ppc %load-reference ( reg obj -- )
  46     [ 0 swap LOAD32 ] [ rc-absolute-ppc-2/2 rel-immediate ] bi* ;
  47
  48 M: ppc %alien-global ( register symbol dll -- )
  49     [ 0 swap LOAD32 ] 2dip rc-absolute-ppc-2/2 rel-dlsym ;
  50
  51 CONSTANT: ds-reg 13
  52 CONSTANT: rs-reg 14
  53
  54 GENERIC: loc-reg ( loc -- reg )
  55
  56 M: ds-loc loc-reg drop ds-reg ;
  57 M: rs-loc loc-reg drop rs-reg ;
  58
  59 : loc>operand ( loc -- reg n )
  60     [ loc-reg ] [ n>> cells neg ] bi ; inline
  61
  62 M: ppc %peek loc>operand LWZ ;
  63 M: ppc %replace loc>operand STW ;
  64
  65 : (%inc) ( n reg -- ) dup rot cells ADDI ; inline
  66
  67 M: ppc %inc-d ( n -- ) ds-reg (%inc) ;
  68 M: ppc %inc-r ( n -- ) rs-reg (%inc) ;
  69
  70 HOOK: reserved-area-size os ( -- n )
  71
  72 ! The start of the stack frame contains the size of this frame
  73 ! as well as the currently executing XT
  74 : factor-area-size ( -- n ) 2 cells ; foldable
  75 : next-save ( n -- i ) cell - ;
  76 : xt-save ( n -- i ) 2 cells - ;
  77
  78 ! Next, we have the spill area as well as the FFI parameter area.
  79 ! They overlap, since basic blocks with FFI calls will never
  80 ! spill.
  81 : param@ ( n -- x ) reserved-area-size + ; inline
  82
  83 : param-save-size ( -- n ) 8 cells ; foldable
  84
  85 : local@ ( n -- x )
  86     reserved-area-size param-save-size + + ; inline
  87
  88 : spill-integer-base ( -- n )
  89     stack-frame get spill-counts>> double-float-regs swap at
  90     double-float-regs reg-size * ;
  91
  92 : spill-integer@ ( n -- offset )
  93     cells spill-integer-base + param@ ;
  94
  95 : spill-float@ ( n -- offset )
  96     double-float-regs reg-size * param@ ;
  97
  98 ! Some FP intrinsics need a temporary scratch area in the stack
  99 ! frame, 8 bytes in size
 100 : scratch@ ( n -- offset )
 101     stack-frame get total-size>>
 102     factor-area-size -
 103     param-save-size -
 104     + ;
 105
 106 ! Finally we have the linkage area
 107 HOOK: lr-save os ( -- n )
 108
 109 M: ppc stack-frame-size ( stack-frame -- i )
 110     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
 111     [ params>> ]
 112     [ return>> ]
 113     tri + +
 114     param-save-size +
 115     reserved-area-size +
 116     factor-area-size +
 117     4 cells align ;
 118
 119 M: ppc %call ( word -- ) 0 BL rc-relative-ppc-3 rel-word-pic ;
 120
 121 M: ppc %jump ( word -- )
 122     0 6 LOAD32 8 rc-absolute-ppc-2/2 rel-here
 123     0 B rc-relative-ppc-3 rel-word-pic-tail ;
 124
 125 M: ppc %jump-label ( label -- ) B ;
 126 M: ppc %return ( -- ) BLR ;
 127
 128 M:: ppc %dispatch ( src temp -- )
 129     0 temp LOAD32
 130     4 cells rc-absolute-ppc-2/2 rel-here
 131     temp temp src LWZX
 132     temp MTCTR
 133     BCTR ;
 134
 135 :: (%slot) ( obj slot tag temp -- reg offset )
 136     temp slot obj ADD
 137     temp tag neg ; inline
 138
 139 : (%slot-imm) ( obj slot tag -- reg offset )
 140     [ cells ] dip - ; inline
 141
 142 M: ppc %slot ( dst obj slot tag temp -- ) (%slot) LWZ ;
 143 M: ppc %slot-imm ( dst obj slot tag -- ) (%slot-imm) LWZ ;
 144 M: ppc %set-slot ( src obj slot tag temp -- ) (%slot) STW ;
 145 M: ppc %set-slot-imm ( src obj slot tag -- ) (%slot-imm) STW ;
 146
 147 M:: ppc %string-nth ( dst src index temp -- )
 148     [
 149         "end" define-label
 150         temp src index ADD
 151         dst temp string-offset LBZ
 152         0 dst HEX: 80 CMPI
 153         "end" get BLT
 154         temp src string-aux-offset LWZ
 155         temp temp index ADD
 156         temp temp index ADD
 157         temp temp byte-array-offset LHZ
 158         temp temp 7 SLWI
 159         dst dst temp XOR
 160         "end" resolve-label
 161     ] with-scope ;
 162
 163 M:: ppc %set-string-nth-fast ( ch obj index temp -- )
 164     temp obj index ADD
 165     ch temp string-offset STB ;
 166
 167 M: ppc %add     ADD ;
 168 M: ppc %add-imm ADDI ;
 169 M: ppc %sub     swap SUBF ;
 170 M: ppc %sub-imm SUBI ;
 171 M: ppc %mul     MULLW ;
 172 M: ppc %mul-imm MULLI ;
 173 M: ppc %and     AND ;
 174 M: ppc %and-imm ANDI ;
 175 M: ppc %or      OR ;
 176 M: ppc %or-imm  ORI ;
 177 M: ppc %xor     XOR ;
 178 M: ppc %xor-imm XORI ;
 179 M: ppc %shl-imm swapd SLWI ;
 180 M: ppc %shr-imm swapd SRWI ;
 181 M: ppc %sar-imm SRAWI ;
 182 M: ppc %not     NOT ;
 183
 184 : %alien-invoke-tail ( func dll -- )
 185     [ scratch-reg ] 2dip %alien-global scratch-reg MTCTR BCTR ;
 186
 187 :: exchange-regs ( r1 r2 -- )
 188     scratch-reg r1 MR
 189     r1 r2 MR
 190     r2 scratch-reg MR ;
 191
 192 : ?MR ( r1 r2 -- ) 2dup = [ 2drop ] [ MR ] if ;
 193
 194 :: move>args ( src1 src2 -- )
 195     {
 196         { [ src1 4 = ] [ 3 src2 ?MR 3 4 exchange-regs ] }
 197         { [ src1 3 = ] [ 4 src2 ?MR ] }
 198         { [ src2 3 = ] [ 4 src1 ?MR 3 4 exchange-regs ] }
 199         { [ src2 4 = ] [ 3 src1 ?MR ] }
 200         [ 3 src1 MR 4 src2 MR ]
 201     } cond ;
 202
 203 : clear-xer ( -- )
 204     0 0 LI
 205     0 MTXER ; inline
 206
 207 :: overflow-template ( src1 src2 insn func -- )
 208     "no-overflow" define-label
 209     clear-xer
 210     scratch-reg src2 src1 insn call
 211     scratch-reg ds-reg 0 STW
 212     "no-overflow" get BNO
 213     src1 src2 move>args
 214     %prepare-alien-invoke
 215     func f %alien-invoke
 216     "no-overflow" resolve-label ; inline
 217
 218 :: overflow-template-tail ( src1 src2 insn func -- )
 219     "overflow" define-label
 220     clear-xer
 221     scratch-reg src2 src1 insn call
 222     "overflow" get BO
 223     scratch-reg ds-reg 0 STW
 224     BLR
 225     "overflow" resolve-label
 226     src1 src2 move>args
 227     %prepare-alien-invoke
 228     func f %alien-invoke-tail ; inline
 229
 230 M: ppc %fixnum-add ( src1 src2 -- )
 231     [ ADDO. ] "overflow_fixnum_add" overflow-template ;
 232
 233 M: ppc %fixnum-add-tail ( src1 src2 -- )
 234     [ ADDO. ] "overflow_fixnum_add" overflow-template-tail ;
 235
 236 M: ppc %fixnum-sub ( src1 src2 -- )
 237     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template ;
 238
 239 M: ppc %fixnum-sub-tail ( src1 src2 -- )
 240     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template-tail ;
 241
 242 M:: ppc %fixnum-mul ( src1 src2 temp1 temp2 -- )
 243     "no-overflow" define-label
 244     clear-xer
 245     temp1 src1 tag-bits get SRAWI
 246     temp2 temp1 src2 MULLWO.
 247     temp2 ds-reg 0 STW
 248     "no-overflow" get BNO
 249     src2 src2 tag-bits get SRAWI
 250     temp1 src2 move>args
 251     %prepare-alien-invoke
 252     "overflow_fixnum_multiply" f %alien-invoke
 253     "no-overflow" resolve-label ;
 254
 255 M:: ppc %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 256     "overflow" define-label
 257     clear-xer
 258     temp1 src1 tag-bits get SRAWI
 259     temp2 temp1 src2 MULLWO.
 260     "overflow" get BO
 261     temp2 ds-reg 0 STW
 262     BLR
 263     "overflow" resolve-label
 264     src2 src2 tag-bits get SRAWI
 265     temp1 src2 move>args
 266     %prepare-alien-invoke
 267     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 268
 269 : bignum@ ( n -- offset ) cells bignum tag-number - ; inline
 270
 271 M:: ppc %integer>bignum ( dst src temp -- )
 272     [
 273         "end" define-label
 274         dst 0 >bignum %load-reference
 275         ! Is it zero? Then just go to the end and return this zero
 276         0 src 0 CMPI
 277         "end" get BEQ
 278         ! Allocate a bignum
 279         dst 4 cells bignum temp %allot
 280         ! Write length
 281         2 tag-fixnum temp LI
 282         temp dst 1 bignum@ STW
 283         ! Compute sign
 284         temp src MR
 285         temp temp cell-bits 1- SRAWI
 286         temp temp 1 ANDI
 287         ! Store sign
 288         temp dst 2 bignum@ STW
 289         ! Make negative value positive
 290         temp temp temp ADD
 291         temp temp NEG
 292         temp temp 1 ADDI
 293         temp src temp MULLW
 294         ! Store the bignum
 295         temp dst 3 bignum@ STW
 296         "end" resolve-label
 297     ] with-scope ;
 298
 299 M:: ppc %bignum>integer ( dst src temp -- )
 300     [
 301         "end" define-label
 302         temp src 1 bignum@ LWZ
 303         ! if the length is 1, its just the sign and nothing else,
 304         ! so output 0
 305         0 dst LI
 306         0 temp 1 tag-fixnum CMPI
 307         "end" get BEQ
 308         ! load the value
 309         dst src 3 bignum@ LWZ
 310         ! load the sign
 311         temp src 2 bignum@ LWZ
 312         ! branchless arithmetic: we want to turn 0 into 1,
 313         ! and 1 into -1
 314         temp temp temp ADD
 315         temp temp 1 SUBI
 316         temp temp NEG
 317         ! multiply value by sign
 318         dst dst temp MULLW
 319         "end" resolve-label
 320     ] with-scope ;
 321
 322 M: ppc %add-float FADD ;
 323 M: ppc %sub-float FSUB ;
 324 M: ppc %mul-float FMUL ;
 325 M: ppc %div-float FDIV ;
 326
 327 M:: ppc %integer>float ( dst src -- )
 328     HEX: 4330 scratch-reg LIS
 329     scratch-reg 1 0 scratch@ STW
 330     scratch-reg src MR
 331     scratch-reg dup HEX: 8000 XORIS
 332     scratch-reg 1 4 scratch@ STW
 333     dst 1 0 scratch@ LFD
 334     scratch-reg 4503601774854144.0 %load-reference
 335     fp-scratch-reg scratch-reg float-offset LFD
 336     dst dst fp-scratch-reg FSUB ;
 337
 338 M:: ppc %float>integer ( dst src -- )
 339     fp-scratch-reg src FCTIWZ
 340     fp-scratch-reg 1 0 scratch@ STFD
 341     dst 1 4 scratch@ LWZ ;
 342
 343 M: ppc %copy ( dst src -- ) MR ;
 344
 345 M: ppc %copy-float ( dst src -- ) FMR ;
 346
 347 M: ppc %unbox-float ( dst src -- ) float-offset LFD ;
 348
 349 M:: ppc %box-float ( dst src temp -- )
 350     dst 16 float temp %allot
 351     src dst float-offset STFD ;
 352
 353 M:: ppc %unbox-any-c-ptr ( dst src temp -- )
 354     [
 355         { "is-byte-array" "end" "start" } [ define-label ] each
 356         ! Address is computed in dst
 357         0 dst LI
 358         ! Load object into scratch-reg
 359         scratch-reg src MR
 360         ! We come back here with displaced aliens
 361         "start" resolve-label
 362         ! Is the object f?
 363         0 scratch-reg \ f tag-number CMPI
 364         ! If so, done
 365         "end" get BEQ
 366         ! Is the object an alien?
 367         0 scratch-reg header-offset LWZ
 368         0 0 alien type-number tag-fixnum CMPI
 369         "is-byte-array" get BNE
 370         ! If so, load the offset
 371         0 scratch-reg alien-offset LWZ
 372         ! Add it to address being computed
 373         dst dst 0 ADD
 374         ! Now recurse on the underlying alien
 375         scratch-reg scratch-reg underlying-alien-offset LWZ
 376         "start" get B
 377         "is-byte-array" resolve-label
 378         ! Add byte array address to address being computed
 379         dst dst scratch-reg ADD
 380         ! Add an offset to start of byte array's data area
 381         dst dst byte-array-offset ADDI
 382         "end" resolve-label
 383     ] with-scope ;
 384
 385 : alien@ ( n -- n' ) cells object tag-number - ;
 386
 387 M:: ppc %box-alien ( dst src temp -- )
 388     [
 389         "f" define-label
 390         dst \ f tag-number %load-immediate
 391         0 src 0 CMPI
 392         "f" get BEQ
 393         dst 4 cells alien temp %allot
 394         ! Store offset
 395         src dst 3 alien@ STW
 396         ! Store expired slot
 397         temp \ f tag-number %load-immediate
 398         temp dst 1 alien@ STW
 399         ! Store underlying-alien slot
 400         temp dst 2 alien@ STW
 401         "f" resolve-label
 402     ] with-scope ;
 403
 404 M: ppc %alien-unsigned-1 0 LBZ ;
 405 M: ppc %alien-unsigned-2 0 LHZ ;
 406
 407 M: ppc %alien-signed-1 dupd 0 LBZ dup EXTSB ;
 408 M: ppc %alien-signed-2 0 LHA ;
 409
 410 M: ppc %alien-cell 0 LWZ ;
 411
 412 M: ppc %alien-float 0 LFS ;
 413 M: ppc %alien-double 0 LFD ;
 414
 415 M: ppc %set-alien-integer-1 swap 0 STB ;
 416 M: ppc %set-alien-integer-2 swap 0 STH ;
 417
 418 M: ppc %set-alien-cell swap 0 STW ;
 419
 420 M: ppc %set-alien-float swap 0 STFS ;
 421 M: ppc %set-alien-double swap 0 STFD ;
 422
 423 : load-zone-ptr ( reg -- )
 424     "nursery" f %alien-global ;
 425
 426 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 427     [ drop load-zone-ptr ] [ swap 4 LWZ ] 2bi ;
 428
 429 :: inc-allot-ptr ( nursery-ptr allot-ptr n -- )
 430     scratch-reg allot-ptr n 8 align ADDI
 431     scratch-reg nursery-ptr 4 STW ;
 432
 433 :: store-header ( dst class -- )
 434     class type-number tag-fixnum scratch-reg LI
 435     scratch-reg dst 0 STW ;
 436
 437 : store-tagged ( dst tag -- )
 438     dupd tag-number ORI ;
 439
 440 M:: ppc %allot ( dst size class nursery-ptr -- )
 441     nursery-ptr dst load-allot-ptr
 442     nursery-ptr dst size inc-allot-ptr
 443     dst class store-header
 444     dst class store-tagged ;
 445
 446 : load-cards-offset ( dst -- )
 447     [ "cards_offset" f %alien-global ] [ dup 0 LWZ ] bi ;
 448
 449 : load-decks-offset ( dst -- )
 450     [ "decks_offset" f %alien-global ] [ dup 0 LWZ ] bi  ;
 451
 452 M:: ppc %write-barrier ( src card# table -- )
 453     card-mark scratch-reg LI
 454
 455     ! Mark the card
 456     table load-cards-offset
 457     src card# card-bits SRWI
 458     table scratch-reg card# STBX
 459
 460     ! Mark the card deck
 461     table load-decks-offset
 462     src card# deck-bits SRWI
 463     table scratch-reg card# STBX ;
 464
 465 M:: ppc %gc ( temp1 temp2 gc-roots gc-root-count -- )
 466     "end" define-label
 467     temp2 load-zone-ptr
 468     temp1 temp2 cell LWZ
 469     temp2 temp2 3 cells LWZ
 470     temp1 temp1 1024 ADDI ! add ALLOT_BUFFER_ZONE to here
 471     temp1 0 temp2 CMP ! is here >= end?
 472     "end" get BLE
 473     %prepare-alien-invoke
 474     0 3 LI
 475     0 4 LI
 476     "inline_gc" f %alien-invoke
 477     "end" resolve-label ;
 478
 479 M: ppc %prologue ( n -- )
 480     0 11 LOAD32 rc-absolute-ppc-2/2 rel-this
 481     0 MFLR
 482     {
 483         [ [ 1 1 ] dip neg ADDI ]
 484         [ [ 11 1 ] dip xt-save STW ]
 485         [ 11 LI ]
 486         [ [ 11 1 ] dip next-save STW ]
 487         [ [ 0 1 ] dip lr-save + STW ]
 488     } cleave ;
 489
 490 M: ppc %epilogue ( n -- )
 491     #! At the end of each word that calls a subroutine, we store
 492     #! the previous link register value in r0 by popping it off
 493     #! the stack, set the link register to the contents of r0,
 494     #! and jump to the link register.
 495     [ [ 0 1 ] dip lr-save + LWZ ]
 496     [ [ 1 1 ] dip ADDI ] bi
 497     0 MTLR ;
 498
 499 :: (%boolean) ( dst temp word -- )
 500     "end" define-label
 501     dst \ f tag-number %load-immediate
 502     "end" get word execute
 503     dst \ t %load-reference
 504     "end" get resolve-label ; inline
 505
 506 : %boolean ( dst temp cc -- )
 507     negate-cc {
 508         { cc< [ \ BLT (%boolean) ] }
 509         { cc<= [ \ BLE (%boolean) ] }
 510         { cc> [ \ BGT (%boolean) ] }
 511         { cc>= [ \ BGE (%boolean) ] }
 512         { cc= [ \ BEQ (%boolean) ] }
 513         { cc/= [ \ BNE (%boolean) ] }
 514     } case ;
 515
 516 : (%compare) ( src1 src2 -- ) [ 0 ] dip CMP ; inline
 517 : (%compare-imm) ( src1 src2 -- ) [ 0 ] 2dip CMPI ; inline
 518 : (%compare-float) ( src1 src2 -- ) [ 0 ] dip FCMPU ; inline
 519
 520 M: ppc %compare (%compare) %boolean ;
 521 M: ppc %compare-imm (%compare-imm) %boolean ;
 522 M: ppc %compare-float (%compare-float) %boolean ;
 523
 524 : %branch ( label cc -- )
 525     {
 526         { cc< [ BLT ] }
 527         { cc<= [ BLE ] }
 528         { cc> [ BGT ] }
 529         { cc>= [ BGE ] }
 530         { cc= [ BEQ ] }
 531         { cc/= [ BNE ] }
 532     } case ;
 533
 534 M: ppc %compare-branch (%compare) %branch ;
 535 M: ppc %compare-imm-branch (%compare-imm) %branch ;
 536 M: ppc %compare-float-branch (%compare-float) %branch ;
 537
 538 M: ppc %spill-integer ( src n -- ) spill-integer@ 1 swap STW ;
 539 M: ppc %reload-integer ( dst n -- ) spill-integer@ 1 swap LWZ ;
 540
 541 M: ppc %spill-float ( src n -- ) spill-float@ 1 swap STFD ;
 542 M: ppc %reload-float ( dst n -- ) spill-float@ 1 swap LFD ;
 543
 544 M: ppc %loop-entry ;
 545
 546 M: int-regs return-reg drop 3 ;
 547 M: int-regs param-regs drop { 3 4 5 6 7 8 9 10 } ;
 548 M: float-regs return-reg drop 1 ;
 549
 550 M: int-regs %save-param-reg drop 1 rot local@ STW ;
 551 M: int-regs %load-param-reg drop 1 rot local@ LWZ ;
 552
 553 GENERIC: STF ( src dst off reg-class -- )
 554
 555 M: single-float-regs STF drop STFS ;
 556 M: double-float-regs STF drop STFD ;
 557
 558 M: float-regs %save-param-reg [ 1 rot local@ ] dip STF ;
 559
 560 GENERIC: LF ( dst src off reg-class -- )
 561
 562 M: single-float-regs LF drop LFS ;
 563 M: double-float-regs LF drop LFD ;
 564
 565 M: float-regs %load-param-reg [ 1 rot local@ ] dip LF ;
 566
 567 M: stack-params %load-param-reg ( stack reg reg-class -- )
 568     drop [ 0 1 rot local@ LWZ 0 1 ] dip param@ STW ;
 569
 570 : next-param@ ( n -- x ) param@ stack-frame get total-size>> + ;
 571
 572 M: stack-params %save-param-reg ( stack reg reg-class -- )
 573     #! Funky. Read the parameter from the caller's stack frame.
 574     #! This word is used in callbacks
 575     drop
 576     [ 0 1 ] dip next-param@ LWZ
 577     [ 0 1 ] dip local@ STW ;
 578
 579 M: ppc %prepare-unbox ( -- )
 580     ! First parameter is top of stack
 581     3 ds-reg 0 LWZ
 582     ds-reg dup cell SUBI ;
 583
 584 M: ppc %unbox ( n reg-class func -- )
 585     ! Value must be in r3
 586     ! Call the unboxer
 587     f %alien-invoke
 588     ! Store the return value on the C stack
 589     over [ [ return-reg ] keep %save-param-reg ] [ 2drop ] if ;
 590
 591 M: ppc %unbox-long-long ( n func -- )
 592     ! Value must be in r3:r4
 593     ! Call the unboxer
 594     f %alien-invoke
 595     ! Store the return value on the C stack
 596     [
 597         [ [ 3 1 ] dip local@ STW ]
 598         [ [ 4 1 ] dip cell + local@ STW ] bi
 599     ] when* ;
 600
 601 M: ppc %unbox-large-struct ( n c-type -- )
 602     ! Value must be in r3
 603     ! Compute destination address and load struct size
 604     [ [ 4 1 ] dip local@ ADDI ] [ heap-size 5 LI ] bi*
 605     ! Call the function
 606     "to_value_struct" f %alien-invoke ;
 607
 608 M: ppc %box ( n reg-class func -- )
 609     ! If the source is a stack location, load it into freg #0.
 610     ! If the source is f, then we assume the value is already in
 611     ! freg #0.
 612     [ over [ 0 over param-reg swap %load-param-reg ] [ 2drop ] if ] dip
 613     f %alien-invoke ;
 614
 615 M: ppc %box-long-long ( n func -- )
 616     [
 617         [
 618             [ [ 3 1 ] dip local@ LWZ ]
 619             [ [ 4 1 ] dip cell + local@ LWZ ] bi
 620         ] when*
 621     ] dip f %alien-invoke ;
 622
 623 : struct-return@ ( n -- n )
 624     [ stack-frame get params>> ] unless* local@ ;
 625
 626 M: ppc %prepare-box-struct ( -- )
 627     #! Compute target address for value struct return
 628     3 1 f struct-return@ ADDI
 629     3 1 0 local@ STW ;
 630
 631 M: ppc %box-large-struct ( n c-type -- )
 632     ! If n = f, then we're boxing a returned struct
 633     ! Compute destination address and load struct size
 634     [ [ 3 1 ] dip struct-return@ ADDI ] [ heap-size 4 LI ] bi*
 635     ! Call the function
 636     "box_value_struct" f %alien-invoke ;
 637
 638 M: ppc %prepare-alien-invoke
 639     #! Save Factor stack pointers in case the C code calls a
 640     #! callback which does a GC, which must reliably trace
 641     #! all roots.
 642     scratch-reg "stack_chain" f %alien-global
 643     scratch-reg scratch-reg 0 LWZ
 644     1 scratch-reg 0 STW
 645     ds-reg scratch-reg 8 STW
 646     rs-reg scratch-reg 12 STW ;
 647
 648 M: ppc %alien-invoke ( symbol dll -- )
 649     [ 11 ] 2dip %alien-global 11 MTLR BLRL ;
 650
 651 M: ppc %alien-callback ( quot -- )
 652     3 swap %load-reference "c_to_factor" f %alien-invoke ;
 653
 654 M: ppc %prepare-alien-indirect ( -- )
 655     "unbox_alien" f %alien-invoke
 656     15 3 MR ;
 657
 658 M: ppc %alien-indirect ( -- )
 659     15 MTLR BLRL ;
 660
 661 M: ppc %callback-value ( ctype -- )
 662     ! Save top of data stack
 663     3 ds-reg 0 LWZ
 664     3 1 0 local@ STW
 665     ! Restore data/call/retain stacks
 666     "unnest_stacks" f %alien-invoke
 667     ! Restore top of data stack
 668     3 1 0 local@ LWZ
 669     ! Unbox former top of data stack to return registers
 670     unbox-return ;
 671
 672 M: ppc small-enough? ( n -- ? ) -32768 32767 between? ;
 673
 674 M: ppc return-struct-in-registers? ( c-type -- ? )
 675     c-type return-in-registers?>> ;
 676
 677 M: ppc %box-small-struct ( c-type -- )
 678     #! Box a <= 16-byte struct returned in r3:r4:r5:r6
 679     heap-size 7 LI
 680     "box_medium_struct" f %alien-invoke ;
 681
 682 : %unbox-struct-1 ( -- )
 683     ! Alien must be in r3.
 684     "alien_offset" f %alien-invoke
 685     3 3 0 LWZ ;
 686
 687 : %unbox-struct-2 ( -- )
 688     ! Alien must be in r3.
 689     "alien_offset" f %alien-invoke
 690     4 3 4 LWZ
 691     3 3 0 LWZ ;
 692
 693 : %unbox-struct-4 ( -- )
 694     ! Alien must be in r3.
 695     "alien_offset" f %alien-invoke
 696     6 3 12 LWZ
 697     5 3 8 LWZ
 698     4 3 4 LWZ
 699     3 3 0 LWZ ;
 700
 701 M: ppc %unbox-small-struct ( size -- )
 702     #! Alien must be in EAX.
 703     heap-size cell align cell /i {
 704         { 1 [ %unbox-struct-1 ] }
 705         { 2 [ %unbox-struct-2 ] }
 706         { 4 [ %unbox-struct-4 ] }
 707     } case ;
 708
 709 USE: vocabs.loader
 710
 711 {
 712     { [ os macosx? ] [ "cpu.ppc.macosx" require ] }
 713     { [ os linux? ] [ "cpu.ppc.linux" require ] }
 714 } cond
 715
 716 "complex-double" c-type t >>return-in-registers? drop
 717
 718 [
 719     <c-type>
 720         [ alien-unsigned-4 c-bool> ] >>getter
 721         [ [ >c-bool ] 2dip set-alien-unsigned-4 ] >>setter
 722         4 >>size
 723         4 >>align
 724         "box_boolean" >>boxer
 725         "to_boolean" >>unboxer
 726     "bool" define-primitive-type
 727 ] with-compilation-unit