basis/cpu/ppc/ppc.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs sequences kernel combinators make math
   4 math.order math.ranges system namespaces locals layouts words
   5 alien alien.c-types literals cpu.architecture cpu.ppc.assembler
   6 cpu.ppc.assembler.backend literals compiler.cfg.registers
   7 compiler.cfg.instructions compiler.constants compiler.codegen
   8 compiler.codegen.fixup compiler.cfg.intrinsics
   9 compiler.cfg.stack-frame ;
  10 IN: cpu.ppc
  11
  12 ! PowerPC register assignments:
  13 ! r2-r12: integer vregs
  14 ! r15-r29
  15 ! r30: integer scratch
  16 ! f0-f29: float vregs
  17 ! f30: float scratch
  18
  19 ! Add some methods to the assembler that are useful to us
  20 M: label (B) [ 0 ] 2dip (B) rc-relative-ppc-3 label-fixup ;
  21 M: label BC [ 0 BC ] dip rc-relative-ppc-2 label-fixup ;
  22
  23 enable-float-intrinsics
  24
  25 <<
  26 \ ##integer>float t frame-required? set-word-prop
  27 \ ##float>integer t frame-required? set-word-prop
  28 >>
  29
  30 M: ppc machine-registers
  31     {
  32         { int-regs $[ 2 12 [a,b] 15 29 [a,b] append ] }
  33         { double-float-regs $[ 0 29 [a,b] ] }
  34     } ;
  35
  36 CONSTANT: scratch-reg 30
  37 CONSTANT: fp-scratch-reg 30
  38
  39 M: ppc two-operand? f ;
  40
  41 M: ppc %load-immediate ( reg n -- ) swap LOAD ;
  42
  43 M: ppc %load-reference ( reg obj -- )
  44     [ 0 swap LOAD32 ] [ rc-absolute-ppc-2/2 rel-immediate ] bi* ;
  45
  46 M: ppc %alien-global ( register symbol dll -- )
  47     [ 0 swap LOAD32 ] 2dip rc-absolute-ppc-2/2 rel-dlsym ;
  48
  49 CONSTANT: ds-reg 13
  50 CONSTANT: rs-reg 14
  51
  52 GENERIC: loc-reg ( loc -- reg )
  53
  54 M: ds-loc loc-reg drop ds-reg ;
  55 M: rs-loc loc-reg drop rs-reg ;
  56
  57 : loc>operand ( loc -- reg n )
  58     [ loc-reg ] [ n>> cells neg ] bi ; inline
  59
  60 M: ppc %peek loc>operand LWZ ;
  61 M: ppc %replace loc>operand STW ;
  62
  63 : (%inc) ( n reg -- ) dup rot cells ADDI ; inline
  64
  65 M: ppc %inc-d ( n -- ) ds-reg (%inc) ;
  66 M: ppc %inc-r ( n -- ) rs-reg (%inc) ;
  67
  68 HOOK: reserved-area-size os ( -- n )
  69
  70 ! The start of the stack frame contains the size of this frame
  71 ! as well as the currently executing XT
  72 : factor-area-size ( -- n ) 2 cells ; foldable
  73 : next-save ( n -- i ) cell - ;
  74 : xt-save ( n -- i ) 2 cells - ;
  75
  76 ! Next, we have the spill area as well as the FFI parameter area.
  77 ! They overlap, since basic blocks with FFI calls will never
  78 ! spill.
  79 : param@ ( n -- x ) reserved-area-size + ; inline
  80
  81 : param-save-size ( -- n ) 8 cells ; foldable
  82
  83 : local@ ( n -- x )
  84     reserved-area-size param-save-size + + ; inline
  85
  86 : spill-integer-base ( -- n )
  87     stack-frame get spill-counts>> double-float-regs swap at
  88     double-float-regs reg-size * ;
  89
  90 : spill-integer@ ( n -- offset )
  91     cells spill-integer-base + param@ ;
  92
  93 : spill-float@ ( n -- offset )
  94     double-float-regs reg-size * param@ ;
  95
  96 ! Some FP intrinsics need a temporary scratch area in the stack
  97 ! frame, 8 bytes in size
  98 : scratch@ ( n -- offset )
  99     stack-frame get total-size>>
 100     factor-area-size -
 101     param-save-size -
 102     + ;
 103
 104 ! Finally we have the linkage area
 105 HOOK: lr-save os ( -- n )
 106
 107 M: ppc stack-frame-size ( stack-frame -- i )
 108     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
 109     [ params>> ]
 110     [ return>> ]
 111     tri + +
 112     param-save-size +
 113     reserved-area-size +
 114     factor-area-size +
 115     4 cells align ;
 116
 117 M: ppc %call ( word -- ) 0 BL rc-relative-ppc-3 rel-word-pic ;
 118
 119 M: ppc %jump ( word -- )
 120     0 6 LOAD32 8 rc-absolute-ppc-2/2 rel-here
 121     0 B rc-relative-ppc-3 rel-word-pic-tail ;
 122
 123 M: ppc %jump-label ( label -- ) B ;
 124 M: ppc %return ( -- ) BLR ;
 125
 126 M:: ppc %dispatch ( src temp offset -- )
 127     0 temp LOAD32
 128     4 offset + cells rc-absolute-ppc-2/2 rel-here
 129     temp temp src LWZX
 130     temp MTCTR
 131     BCTR ;
 132
 133 M: ppc %dispatch-label ( word -- )
 134     B{ 0 0 0 0 } % rc-absolute-cell rel-word ;
 135
 136 :: (%slot) ( obj slot tag temp -- reg offset )
 137     temp slot obj ADD
 138     temp tag neg ; inline
 139
 140 : (%slot-imm) ( obj slot tag -- reg offset )
 141     [ cells ] dip - ; inline
 142
 143 M: ppc %slot ( dst obj slot tag temp -- ) (%slot) LWZ ;
 144 M: ppc %slot-imm ( dst obj slot tag -- ) (%slot-imm) LWZ ;
 145 M: ppc %set-slot ( src obj slot tag temp -- ) (%slot) STW ;
 146 M: ppc %set-slot-imm ( src obj slot tag -- ) (%slot-imm) STW ;
 147
 148 M:: ppc %string-nth ( dst src index temp -- )
 149     [
 150         "end" define-label
 151         temp src index ADD
 152         dst temp string-offset LBZ
 153         0 dst HEX: 80 CMPI
 154         "end" get BLT
 155         temp src string-aux-offset LWZ
 156         temp temp index ADD
 157         temp temp index ADD
 158         temp temp byte-array-offset LHZ
 159         temp temp 7 SLWI
 160         dst dst temp XOR
 161         "end" resolve-label
 162     ] with-scope ;
 163
 164 M:: ppc %set-string-nth-fast ( ch obj index temp -- )
 165     temp obj index ADD
 166     ch temp string-offset STB ;
 167
 168 M: ppc %add     ADD ;
 169 M: ppc %add-imm ADDI ;
 170 M: ppc %sub     swap SUBF ;
 171 M: ppc %sub-imm SUBI ;
 172 M: ppc %mul     MULLW ;
 173 M: ppc %mul-imm MULLI ;
 174 M: ppc %and     AND ;
 175 M: ppc %and-imm ANDI ;
 176 M: ppc %or      OR ;
 177 M: ppc %or-imm  ORI ;
 178 M: ppc %xor     XOR ;
 179 M: ppc %xor-imm XORI ;
 180 M: ppc %shl-imm swapd SLWI ;
 181 M: ppc %shr-imm swapd SRWI ;
 182 M: ppc %sar-imm SRAWI ;
 183 M: ppc %not     NOT ;
 184
 185 : %alien-invoke-tail ( func dll -- )
 186     [ scratch-reg ] 2dip %alien-global scratch-reg MTCTR BCTR ;
 187
 188 :: exchange-regs ( r1 r2 -- )
 189     scratch-reg r1 MR
 190     r1 r2 MR
 191     r2 scratch-reg MR ;
 192
 193 : ?MR ( r1 r2 -- ) 2dup = [ 2drop ] [ MR ] if ;
 194
 195 :: move>args ( src1 src2 -- )
 196     {
 197         { [ src1 4 = ] [ 3 src2 ?MR 3 4 exchange-regs ] }
 198         { [ src1 3 = ] [ 4 src2 ?MR ] }
 199         { [ src2 3 = ] [ 4 src1 ?MR 3 4 exchange-regs ] }
 200         { [ src2 4 = ] [ 3 src1 ?MR ] }
 201         [ 3 src1 MR 4 src2 MR ]
 202     } cond ;
 203
 204 : clear-xer ( -- )
 205     0 0 LI
 206     0 MTXER ; inline
 207
 208 :: overflow-template ( src1 src2 insn func -- )
 209     "no-overflow" define-label
 210     clear-xer
 211     scratch-reg src2 src1 insn call
 212     scratch-reg ds-reg 0 STW
 213     "no-overflow" get BNO
 214     src1 src2 move>args
 215     %prepare-alien-invoke
 216     func f %alien-invoke
 217     "no-overflow" resolve-label ; inline
 218
 219 :: overflow-template-tail ( src1 src2 insn func -- )
 220     "overflow" define-label
 221     clear-xer
 222     scratch-reg src2 src1 insn call
 223     "overflow" get BO
 224     scratch-reg ds-reg 0 STW
 225     BLR
 226     "overflow" resolve-label
 227     src1 src2 move>args
 228     %prepare-alien-invoke
 229     func f %alien-invoke-tail ; inline
 230
 231 M: ppc %fixnum-add ( src1 src2 -- )
 232     [ ADDO. ] "overflow_fixnum_add" overflow-template ;
 233
 234 M: ppc %fixnum-add-tail ( src1 src2 -- )
 235     [ ADDO. ] "overflow_fixnum_add" overflow-template-tail ;
 236
 237 M: ppc %fixnum-sub ( src1 src2 -- )
 238     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template ;
 239
 240 M: ppc %fixnum-sub-tail ( src1 src2 -- )
 241     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template-tail ;
 242
 243 M:: ppc %fixnum-mul ( src1 src2 temp1 temp2 -- )
 244     "no-overflow" define-label
 245     clear-xer
 246     temp1 src1 tag-bits get SRAWI
 247     temp2 temp1 src2 MULLWO.
 248     temp2 ds-reg 0 STW
 249     "no-overflow" get BNO
 250     src2 src2 tag-bits get SRAWI
 251     temp1 src2 move>args
 252     %prepare-alien-invoke
 253     "overflow_fixnum_multiply" f %alien-invoke
 254     "no-overflow" resolve-label ;
 255
 256 M:: ppc %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 257     "overflow" define-label
 258     clear-xer
 259     temp1 src1 tag-bits get SRAWI
 260     temp2 temp1 src2 MULLWO.
 261     "overflow" get BO
 262     temp2 ds-reg 0 STW
 263     BLR
 264     "overflow" resolve-label
 265     src2 src2 tag-bits get SRAWI
 266     temp1 src2 move>args
 267     %prepare-alien-invoke
 268     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 269
 270 : bignum@ ( n -- offset ) cells bignum tag-number - ; inline
 271
 272 M:: ppc %integer>bignum ( dst src temp -- )
 273     [
 274         "end" define-label
 275         dst 0 >bignum %load-reference
 276         ! Is it zero? Then just go to the end and return this zero
 277         0 src 0 CMPI
 278         "end" get BEQ
 279         ! Allocate a bignum
 280         dst 4 cells bignum temp %allot
 281         ! Write length
 282         2 tag-fixnum temp LI
 283         temp dst 1 bignum@ STW
 284         ! Compute sign
 285         temp src MR
 286         temp temp cell-bits 1- SRAWI
 287         temp temp 1 ANDI
 288         ! Store sign
 289         temp dst 2 bignum@ STW
 290         ! Make negative value positive
 291         temp temp temp ADD
 292         temp temp NEG
 293         temp temp 1 ADDI
 294         temp src temp MULLW
 295         ! Store the bignum
 296         temp dst 3 bignum@ STW
 297         "end" resolve-label
 298     ] with-scope ;
 299
 300 M:: ppc %bignum>integer ( dst src temp -- )
 301     [
 302         "end" define-label
 303         temp src 1 bignum@ LWZ
 304         ! if the length is 1, its just the sign and nothing else,
 305         ! so output 0
 306         0 dst LI
 307         0 temp 1 tag-fixnum CMPI
 308         "end" get BEQ
 309         ! load the value
 310         dst src 3 bignum@ LWZ
 311         ! load the sign
 312         temp src 2 bignum@ LWZ
 313         ! branchless arithmetic: we want to turn 0 into 1,
 314         ! and 1 into -1
 315         temp temp temp ADD
 316         temp temp 1 SUBI
 317         temp temp NEG
 318         ! multiply value by sign
 319         dst dst temp MULLW
 320         "end" resolve-label
 321     ] with-scope ;
 322
 323 M: ppc %add-float FADD ;
 324 M: ppc %sub-float FSUB ;
 325 M: ppc %mul-float FMUL ;
 326 M: ppc %div-float FDIV ;
 327
 328 M:: ppc %integer>float ( dst src -- )
 329     HEX: 4330 scratch-reg LIS
 330     scratch-reg 1 0 scratch@ STW
 331     scratch-reg src MR
 332     scratch-reg dup HEX: 8000 XORIS
 333     scratch-reg 1 4 scratch@ STW
 334     dst 1 0 scratch@ LFD
 335     scratch-reg 4503601774854144.0 %load-reference
 336     fp-scratch-reg scratch-reg float-offset LFD
 337     dst dst fp-scratch-reg FSUB ;
 338
 339 M:: ppc %float>integer ( dst src -- )
 340     fp-scratch-reg src FCTIWZ
 341     fp-scratch-reg 1 0 scratch@ STFD
 342     dst 1 4 scratch@ LWZ ;
 343
 344 M: ppc %copy ( dst src -- ) MR ;
 345
 346 M: ppc %copy-float ( dst src -- ) FMR ;
 347
 348 M: ppc %unbox-float ( dst src -- ) float-offset LFD ;
 349
 350 M:: ppc %box-float ( dst src temp -- )
 351     dst 16 float temp %allot
 352     src dst float-offset STFD ;
 353
 354 M:: ppc %unbox-any-c-ptr ( dst src temp -- )
 355     [
 356         { "is-byte-array" "end" "start" } [ define-label ] each
 357         ! Address is computed in dst
 358         0 dst LI
 359         ! Load object into scratch-reg
 360         scratch-reg src MR
 361         ! We come back here with displaced aliens
 362         "start" resolve-label
 363         ! Is the object f?
 364         0 scratch-reg \ f tag-number CMPI
 365         ! If so, done
 366         "end" get BEQ
 367         ! Is the object an alien?
 368         0 scratch-reg header-offset LWZ
 369         0 0 alien type-number tag-fixnum CMPI
 370         "is-byte-array" get BNE
 371         ! If so, load the offset
 372         0 scratch-reg alien-offset LWZ
 373         ! Add it to address being computed
 374         dst dst 0 ADD
 375         ! Now recurse on the underlying alien
 376         scratch-reg scratch-reg underlying-alien-offset LWZ
 377         "start" get B
 378         "is-byte-array" resolve-label
 379         ! Add byte array address to address being computed
 380         dst dst scratch-reg ADD
 381         ! Add an offset to start of byte array's data area
 382         dst dst byte-array-offset ADDI
 383         "end" resolve-label
 384     ] with-scope ;
 385
 386 : alien@ ( n -- n' ) cells object tag-number - ;
 387
 388 M:: ppc %box-alien ( dst src temp -- )
 389     [
 390         "f" define-label
 391         dst \ f tag-number %load-immediate
 392         0 src 0 CMPI
 393         "f" get BEQ
 394         dst 4 cells alien temp %allot
 395         ! Store offset
 396         src dst 3 alien@ STW
 397         ! Store expired slot
 398         temp \ f tag-number %load-immediate
 399         temp dst 1 alien@ STW
 400         ! Store underlying-alien slot
 401         temp dst 2 alien@ STW
 402         "f" resolve-label
 403     ] with-scope ;
 404
 405 M: ppc %alien-unsigned-1 0 LBZ ;
 406 M: ppc %alien-unsigned-2 0 LHZ ;
 407
 408 M: ppc %alien-signed-1 dupd 0 LBZ dup EXTSB ;
 409 M: ppc %alien-signed-2 0 LHA ;
 410
 411 M: ppc %alien-cell 0 LWZ ;
 412
 413 M: ppc %alien-float 0 LFS ;
 414 M: ppc %alien-double 0 LFD ;
 415
 416 M: ppc %set-alien-integer-1 swap 0 STB ;
 417 M: ppc %set-alien-integer-2 swap 0 STH ;
 418
 419 M: ppc %set-alien-cell swap 0 STW ;
 420
 421 M: ppc %set-alien-float swap 0 STFS ;
 422 M: ppc %set-alien-double swap 0 STFD ;
 423
 424 : load-zone-ptr ( reg -- )
 425     "nursery" f %alien-global ;
 426
 427 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 428     [ drop load-zone-ptr ] [ swap 4 LWZ ] 2bi ;
 429
 430 :: inc-allot-ptr ( nursery-ptr allot-ptr n -- )
 431     scratch-reg allot-ptr n 8 align ADDI
 432     scratch-reg nursery-ptr 4 STW ;
 433
 434 :: store-header ( dst class -- )
 435     class type-number tag-fixnum scratch-reg LI
 436     scratch-reg dst 0 STW ;
 437
 438 : store-tagged ( dst tag -- )
 439     dupd tag-number ORI ;
 440
 441 M:: ppc %allot ( dst size class nursery-ptr -- )
 442     nursery-ptr dst load-allot-ptr
 443     nursery-ptr dst size inc-allot-ptr
 444     dst class store-header
 445     dst class store-tagged ;
 446
 447 : load-cards-offset ( dst -- )
 448     [ "cards_offset" f %alien-global ] [ dup 0 LWZ ] bi ;
 449
 450 : load-decks-offset ( dst -- )
 451     [ "decks_offset" f %alien-global ] [ dup 0 LWZ ] bi  ;
 452
 453 M:: ppc %write-barrier ( src card# table -- )
 454     card-mark scratch-reg LI
 455
 456     ! Mark the card
 457     table load-cards-offset
 458     src card# card-bits SRWI
 459     table scratch-reg card# STBX
 460
 461     ! Mark the card deck
 462     table load-decks-offset
 463     src card# deck-bits SRWI
 464     table scratch-reg card# STBX ;
 465
 466 M: ppc %gc
 467     "end" define-label
 468     12 load-zone-ptr
 469     11 12 cell LWZ ! nursery.here -> r11
 470     12 12 3 cells LWZ ! nursery.end -> r12
 471     11 11 1024 ADDI ! add ALLOT_BUFFER_ZONE to here
 472     11 0 12 CMP ! is here >= end?
 473     "end" get BLE
 474     %prepare-alien-invoke
 475     "minor_gc" f %alien-invoke
 476     "end" resolve-label ;
 477
 478 M: ppc %prologue ( n -- )
 479     0 11 LOAD32 rc-absolute-ppc-2/2 rel-this
 480     0 MFLR
 481     {
 482         [ [ 1 1 ] dip neg ADDI ]
 483         [ [ 11 1 ] dip xt-save STW ]
 484         [ 11 LI ]
 485         [ [ 11 1 ] dip next-save STW ]
 486         [ [ 0 1 ] dip lr-save + STW ]
 487     } cleave ;
 488
 489 M: ppc %epilogue ( n -- )
 490     #! At the end of each word that calls a subroutine, we store
 491     #! the previous link register value in r0 by popping it off
 492     #! the stack, set the link register to the contents of r0,
 493     #! and jump to the link register.
 494     [ [ 0 1 ] dip lr-save + LWZ ]
 495     [ [ 1 1 ] dip ADDI ] bi
 496     0 MTLR ;
 497
 498 :: (%boolean) ( dst temp word -- )
 499     "end" define-label
 500     dst \ f tag-number %load-immediate
 501     "end" get word execute
 502     dst \ t %load-reference
 503     "end" get resolve-label ; inline
 504
 505 : %boolean ( dst temp cc -- )
 506     negate-cc {
 507         { cc< [ \ BLT (%boolean) ] }
 508         { cc<= [ \ BLE (%boolean) ] }
 509         { cc> [ \ BGT (%boolean) ] }
 510         { cc>= [ \ BGE (%boolean) ] }
 511         { cc= [ \ BEQ (%boolean) ] }
 512         { cc/= [ \ BNE (%boolean) ] }
 513     } case ;
 514
 515 : (%compare) ( src1 src2 -- ) [ 0 ] dip CMP ; inline
 516 : (%compare-imm) ( src1 src2 -- ) [ 0 ] 2dip CMPI ; inline
 517 : (%compare-float) ( src1 src2 -- ) [ 0 ] dip FCMPU ; inline
 518
 519 M: ppc %compare (%compare) %boolean ;
 520 M: ppc %compare-imm (%compare-imm) %boolean ;
 521 M: ppc %compare-float (%compare-float) %boolean ;
 522
 523 : %branch ( label cc -- )
 524     {
 525         { cc< [ BLT ] }
 526         { cc<= [ BLE ] }
 527         { cc> [ BGT ] }
 528         { cc>= [ BGE ] }
 529         { cc= [ BEQ ] }
 530         { cc/= [ BNE ] }
 531     } case ;
 532
 533 M: ppc %compare-branch (%compare) %branch ;
 534 M: ppc %compare-imm-branch (%compare-imm) %branch ;
 535 M: ppc %compare-float-branch (%compare-float) %branch ;
 536
 537 M: ppc %spill-integer ( src n -- ) spill-integer@ 1 swap STW ;
 538 M: ppc %reload-integer ( dst n -- ) spill-integer@ 1 swap LWZ ;
 539
 540 M: ppc %spill-float ( src n -- ) spill-float@ 1 swap STFD ;
 541 M: ppc %reload-float ( dst n -- ) spill-float@ 1 swap LFD ;
 542
 543 M: ppc %loop-entry ;
 544
 545 M: int-regs return-reg drop 3 ;
 546 M: int-regs param-regs drop { 3 4 5 6 7 8 9 10 } ;
 547 M: float-regs return-reg drop 1 ;
 548
 549 M: int-regs %save-param-reg drop 1 rot local@ STW ;
 550 M: int-regs %load-param-reg drop 1 rot local@ LWZ ;
 551
 552 GENERIC: STF ( src dst off reg-class -- )
 553
 554 M: single-float-regs STF drop STFS ;
 555 M: double-float-regs STF drop STFD ;
 556
 557 M: float-regs %save-param-reg [ 1 rot local@ ] dip STF ;
 558
 559 GENERIC: LF ( dst src off reg-class -- )
 560
 561 M: single-float-regs LF drop LFS ;
 562 M: double-float-regs LF drop LFD ;
 563
 564 M: float-regs %load-param-reg [ 1 rot local@ ] dip LF ;
 565
 566 M: stack-params %load-param-reg ( stack reg reg-class -- )
 567     drop [ 0 1 rot local@ LWZ 0 1 ] dip param@ STW ;
 568
 569 : next-param@ ( n -- x ) param@ stack-frame get total-size>> + ;
 570
 571 M: stack-params %save-param-reg ( stack reg reg-class -- )
 572     #! Funky. Read the parameter from the caller's stack frame.
 573     #! This word is used in callbacks
 574     drop
 575     [ 0 1 ] dip next-param@ LWZ
 576     [ 0 1 ] dip local@ STW ;
 577
 578 M: ppc %prepare-unbox ( -- )
 579     ! First parameter is top of stack
 580     3 ds-reg 0 LWZ
 581     ds-reg dup cell SUBI ;
 582
 583 M: ppc %unbox ( n reg-class func -- )
 584     ! Value must be in r3
 585     ! Call the unboxer
 586     f %alien-invoke
 587     ! Store the return value on the C stack
 588     over [ [ return-reg ] keep %save-param-reg ] [ 2drop ] if ;
 589
 590 M: ppc %unbox-long-long ( n func -- )
 591     ! Value must be in r3:r4
 592     ! Call the unboxer
 593     f %alien-invoke
 594     ! Store the return value on the C stack
 595     [
 596         [ [ 3 1 ] dip local@ STW ]
 597         [ [ 4 1 ] dip cell + local@ STW ] bi
 598     ] when* ;
 599
 600 M: ppc %unbox-large-struct ( n c-type -- )
 601     ! Value must be in r3
 602     ! Compute destination address and load struct size
 603     [ [ 4 1 ] dip local@ ADDI ] [ heap-size 5 LI ] bi*
 604     ! Call the function
 605     "to_value_struct" f %alien-invoke ;
 606
 607 M: ppc %box ( n reg-class func -- )
 608     ! If the source is a stack location, load it into freg #0.
 609     ! If the source is f, then we assume the value is already in
 610     ! freg #0.
 611     [ over [ 0 over param-reg swap %load-param-reg ] [ 2drop ] if ] dip
 612     f %alien-invoke ;
 613
 614 M: ppc %box-long-long ( n func -- )
 615     [
 616         [
 617             [ [ 3 1 ] dip local@ LWZ ]
 618             [ [ 4 1 ] dip cell + local@ LWZ ] bi
 619         ] when*
 620     ] dip f %alien-invoke ;
 621
 622 : struct-return@ ( n -- n )
 623     [ stack-frame get params>> ] unless* local@ ;
 624
 625 M: ppc %prepare-box-struct ( -- )
 626     #! Compute target address for value struct return
 627     3 1 f struct-return@ ADDI
 628     3 1 0 local@ STW ;
 629
 630 M: ppc %box-large-struct ( n c-type -- )
 631     ! If n = f, then we're boxing a returned struct
 632     ! Compute destination address and load struct size
 633     [ [ 3 1 ] dip struct-return@ ADDI ] [ heap-size 4 LI ] bi*
 634     ! Call the function
 635     "box_value_struct" f %alien-invoke ;
 636
 637 M: ppc %prepare-alien-invoke
 638     #! Save Factor stack pointers in case the C code calls a
 639     #! callback which does a GC, which must reliably trace
 640     #! all roots.
 641     scratch-reg "stack_chain" f %alien-global
 642     scratch-reg scratch-reg 0 LWZ
 643     1 scratch-reg 0 STW
 644     ds-reg scratch-reg 8 STW
 645     rs-reg scratch-reg 12 STW ;
 646
 647 M: ppc %alien-invoke ( symbol dll -- )
 648     [ 11 ] 2dip %alien-global 11 MTLR BLRL ;
 649
 650 M: ppc %alien-callback ( quot -- )
 651     3 swap %load-reference "c_to_factor" f %alien-invoke ;
 652
 653 M: ppc %prepare-alien-indirect ( -- )
 654     "unbox_alien" f %alien-invoke
 655     15 3 MR ;
 656
 657 M: ppc %alien-indirect ( -- )
 658     15 MTLR BLRL ;
 659
 660 M: ppc %callback-value ( ctype -- )
 661     ! Save top of data stack
 662     3 ds-reg 0 LWZ
 663     3 1 0 local@ STW
 664     ! Restore data/call/retain stacks
 665     "unnest_stacks" f %alien-invoke
 666     ! Restore top of data stack
 667     3 1 0 local@ LWZ
 668     ! Unbox former top of data stack to return registers
 669     unbox-return ;
 670
 671 M: ppc small-enough? ( n -- ? ) -32768 32767 between? ;
 672
 673 M: ppc return-struct-in-registers? ( c-type -- ? )
 674     c-type return-in-registers?>> ;
 675
 676 M: ppc %box-small-struct ( c-type -- )
 677     #! Box a <= 16-byte struct returned in r3:r4:r5:r6
 678     heap-size 7 LI
 679     "box_medium_struct" f %alien-invoke ;
 680
 681 : %unbox-struct-1 ( -- )
 682     ! Alien must be in r3.
 683     "alien_offset" f %alien-invoke
 684     3 3 0 LWZ ;
 685
 686 : %unbox-struct-2 ( -- )
 687     ! Alien must be in r3.
 688     "alien_offset" f %alien-invoke
 689     4 3 4 LWZ
 690     3 3 0 LWZ ;
 691
 692 : %unbox-struct-4 ( -- )
 693     ! Alien must be in r3.
 694     "alien_offset" f %alien-invoke
 695     6 3 12 LWZ
 696     5 3 8 LWZ
 697     4 3 4 LWZ
 698     3 3 0 LWZ ;
 699
 700 M: ppc %unbox-small-struct ( size -- )
 701     #! Alien must be in EAX.
 702     heap-size cell align cell /i {
 703         { 1 [ %unbox-struct-1 ] }
 704         { 2 [ %unbox-struct-2 ] }
 705         { 4 [ %unbox-struct-4 ] }
 706     } case ;
 707
 708 USE: vocabs.loader
 709
 710 {
 711     { [ os macosx? ] [ "cpu.ppc.macosx" require ] }
 712     { [ os linux? ] [ "cpu.ppc.linux" require ] }
 713 } cond
 714
 715 "complex-double" c-type t >>return-in-registers? drop
 716 "bool" c-type 4 >>size 4 >>align drop