basis/cpu/ppc/ppc.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs sequences kernel combinators make math
   4 math.order math.ranges system namespaces locals layouts words
   5 alien alien.accessors alien.c-types literals cpu.architecture
   6 cpu.ppc.assembler cpu.ppc.assembler.backend literals compiler.cfg.registers
   7 compiler.cfg.instructions compiler.constants compiler.codegen
   8 compiler.codegen.fixup compiler.cfg.intrinsics
   9 compiler.cfg.stack-frame compiler.units ;
  10 FROM: cpu.ppc.assembler => B ;
  11 IN: cpu.ppc
  12
  13 ! PowerPC register assignments:
  14 ! r2-r12: integer vregs
  15 ! r15-r29
  16 ! r30: integer scratch
  17 ! f0-f29: float vregs
  18 ! f30: float scratch
  19
  20 ! Add some methods to the assembler that are useful to us
  21 M: label (B) [ 0 ] 2dip (B) rc-relative-ppc-3 label-fixup ;
  22 M: label BC [ 0 BC ] dip rc-relative-ppc-2 label-fixup ;
  23
  24 enable-float-intrinsics
  25
  26 <<
  27 \ ##integer>float t frame-required? set-word-prop
  28 \ ##float>integer t frame-required? set-word-prop
  29 >>
  30
  31 M: ppc machine-registers
  32     {
  33         { int-regs $[ 2 12 [a,b] 15 29 [a,b] append ] }
  34         { double-float-regs $[ 0 29 [a,b] ] }
  35     } ;
  36
  37 CONSTANT: scratch-reg 30
  38 CONSTANT: fp-scratch-reg 30
  39
  40 M: ppc two-operand? f ;
  41
  42 M: ppc %load-immediate ( reg n -- ) swap LOAD ;
  43
  44 M: ppc %load-reference ( reg obj -- )
  45     [ 0 swap LOAD32 ] [ rc-absolute-ppc-2/2 rel-immediate ] bi* ;
  46
  47 M: ppc %alien-global ( register symbol dll -- )
  48     [ 0 swap LOAD32 ] 2dip rc-absolute-ppc-2/2 rel-dlsym ;
  49
  50 CONSTANT: ds-reg 13
  51 CONSTANT: rs-reg 14
  52
  53 GENERIC: loc-reg ( loc -- reg )
  54
  55 M: ds-loc loc-reg drop ds-reg ;
  56 M: rs-loc loc-reg drop rs-reg ;
  57
  58 : loc>operand ( loc -- reg n )
  59     [ loc-reg ] [ n>> cells neg ] bi ; inline
  60
  61 M: ppc %peek loc>operand LWZ ;
  62 M: ppc %replace loc>operand STW ;
  63
  64 : (%inc) ( n reg -- ) dup rot cells ADDI ; inline
  65
  66 M: ppc %inc-d ( n -- ) ds-reg (%inc) ;
  67 M: ppc %inc-r ( n -- ) rs-reg (%inc) ;
  68
  69 HOOK: reserved-area-size os ( -- n )
  70
  71 ! The start of the stack frame contains the size of this frame
  72 ! as well as the currently executing XT
  73 : factor-area-size ( -- n ) 2 cells ; foldable
  74 : next-save ( n -- i ) cell - ;
  75 : xt-save ( n -- i ) 2 cells - ;
  76
  77 ! Next, we have the spill area as well as the FFI parameter area.
  78 ! They overlap, since basic blocks with FFI calls will never
  79 ! spill.
  80 : param@ ( n -- x ) reserved-area-size + ; inline
  81
  82 : param-save-size ( -- n ) 8 cells ; foldable
  83
  84 : local@ ( n -- x )
  85     reserved-area-size param-save-size + + ; inline
  86
  87 : spill-integer-base ( -- n )
  88     stack-frame get spill-counts>> double-float-regs swap at
  89     double-float-regs reg-size * ;
  90
  91 : spill-integer@ ( n -- offset )
  92     cells spill-integer-base + param@ ;
  93
  94 : spill-float@ ( n -- offset )
  95     double-float-regs reg-size * param@ ;
  96
  97 ! Some FP intrinsics need a temporary scratch area in the stack
  98 ! frame, 8 bytes in size
  99 : scratch@ ( n -- offset )
 100     stack-frame get total-size>>
 101     factor-area-size -
 102     param-save-size -
 103     + ;
 104
 105 ! Finally we have the linkage area
 106 HOOK: lr-save os ( -- n )
 107
 108 M: ppc stack-frame-size ( stack-frame -- i )
 109     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
 110     [ params>> ]
 111     [ return>> ]
 112     tri + +
 113     param-save-size +
 114     reserved-area-size +
 115     factor-area-size +
 116     4 cells align ;
 117
 118 M: ppc %call ( word -- ) 0 BL rc-relative-ppc-3 rel-word-pic ;
 119
 120 M: ppc %jump ( word -- )
 121     0 6 LOAD32 8 rc-absolute-ppc-2/2 rel-here
 122     0 B rc-relative-ppc-3 rel-word-pic-tail ;
 123
 124 M: ppc %jump-label ( label -- ) B ;
 125 M: ppc %return ( -- ) BLR ;
 126
 127 M:: ppc %dispatch ( src temp offset -- )
 128     0 temp LOAD32
 129     4 offset + cells rc-absolute-ppc-2/2 rel-here
 130     temp temp src LWZX
 131     temp MTCTR
 132     BCTR ;
 133
 134 M: ppc %dispatch-label ( word -- )
 135     B{ 0 0 0 0 } % rc-absolute-cell rel-word ;
 136
 137 :: (%slot) ( obj slot tag temp -- reg offset )
 138     temp slot obj ADD
 139     temp tag neg ; inline
 140
 141 : (%slot-imm) ( obj slot tag -- reg offset )
 142     [ cells ] dip - ; inline
 143
 144 M: ppc %slot ( dst obj slot tag temp -- ) (%slot) LWZ ;
 145 M: ppc %slot-imm ( dst obj slot tag -- ) (%slot-imm) LWZ ;
 146 M: ppc %set-slot ( src obj slot tag temp -- ) (%slot) STW ;
 147 M: ppc %set-slot-imm ( src obj slot tag -- ) (%slot-imm) STW ;
 148
 149 M:: ppc %string-nth ( dst src index temp -- )
 150     [
 151         "end" define-label
 152         temp src index ADD
 153         dst temp string-offset LBZ
 154         0 dst HEX: 80 CMPI
 155         "end" get BLT
 156         temp src string-aux-offset LWZ
 157         temp temp index ADD
 158         temp temp index ADD
 159         temp temp byte-array-offset LHZ
 160         temp temp 7 SLWI
 161         dst dst temp XOR
 162         "end" resolve-label
 163     ] with-scope ;
 164
 165 M:: ppc %set-string-nth-fast ( ch obj index temp -- )
 166     temp obj index ADD
 167     ch temp string-offset STB ;
 168
 169 M: ppc %add     ADD ;
 170 M: ppc %add-imm ADDI ;
 171 M: ppc %sub     swap SUBF ;
 172 M: ppc %sub-imm SUBI ;
 173 M: ppc %mul     MULLW ;
 174 M: ppc %mul-imm MULLI ;
 175 M: ppc %and     AND ;
 176 M: ppc %and-imm ANDI ;
 177 M: ppc %or      OR ;
 178 M: ppc %or-imm  ORI ;
 179 M: ppc %xor     XOR ;
 180 M: ppc %xor-imm XORI ;
 181 M: ppc %shl-imm swapd SLWI ;
 182 M: ppc %shr-imm swapd SRWI ;
 183 M: ppc %sar-imm SRAWI ;
 184 M: ppc %not     NOT ;
 185
 186 : %alien-invoke-tail ( func dll -- )
 187     [ scratch-reg ] 2dip %alien-global scratch-reg MTCTR BCTR ;
 188
 189 :: exchange-regs ( r1 r2 -- )
 190     scratch-reg r1 MR
 191     r1 r2 MR
 192     r2 scratch-reg MR ;
 193
 194 : ?MR ( r1 r2 -- ) 2dup = [ 2drop ] [ MR ] if ;
 195
 196 :: move>args ( src1 src2 -- )
 197     {
 198         { [ src1 4 = ] [ 3 src2 ?MR 3 4 exchange-regs ] }
 199         { [ src1 3 = ] [ 4 src2 ?MR ] }
 200         { [ src2 3 = ] [ 4 src1 ?MR 3 4 exchange-regs ] }
 201         { [ src2 4 = ] [ 3 src1 ?MR ] }
 202         [ 3 src1 MR 4 src2 MR ]
 203     } cond ;
 204
 205 : clear-xer ( -- )
 206     0 0 LI
 207     0 MTXER ; inline
 208
 209 :: overflow-template ( src1 src2 insn func -- )
 210     "no-overflow" define-label
 211     clear-xer
 212     scratch-reg src2 src1 insn call
 213     scratch-reg ds-reg 0 STW
 214     "no-overflow" get BNO
 215     src1 src2 move>args
 216     %prepare-alien-invoke
 217     func f %alien-invoke
 218     "no-overflow" resolve-label ; inline
 219
 220 :: overflow-template-tail ( src1 src2 insn func -- )
 221     "overflow" define-label
 222     clear-xer
 223     scratch-reg src2 src1 insn call
 224     "overflow" get BO
 225     scratch-reg ds-reg 0 STW
 226     BLR
 227     "overflow" resolve-label
 228     src1 src2 move>args
 229     %prepare-alien-invoke
 230     func f %alien-invoke-tail ; inline
 231
 232 M: ppc %fixnum-add ( src1 src2 -- )
 233     [ ADDO. ] "overflow_fixnum_add" overflow-template ;
 234
 235 M: ppc %fixnum-add-tail ( src1 src2 -- )
 236     [ ADDO. ] "overflow_fixnum_add" overflow-template-tail ;
 237
 238 M: ppc %fixnum-sub ( src1 src2 -- )
 239     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template ;
 240
 241 M: ppc %fixnum-sub-tail ( src1 src2 -- )
 242     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template-tail ;
 243
 244 M:: ppc %fixnum-mul ( src1 src2 temp1 temp2 -- )
 245     "no-overflow" define-label
 246     clear-xer
 247     temp1 src1 tag-bits get SRAWI
 248     temp2 temp1 src2 MULLWO.
 249     temp2 ds-reg 0 STW
 250     "no-overflow" get BNO
 251     src2 src2 tag-bits get SRAWI
 252     temp1 src2 move>args
 253     %prepare-alien-invoke
 254     "overflow_fixnum_multiply" f %alien-invoke
 255     "no-overflow" resolve-label ;
 256
 257 M:: ppc %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 258     "overflow" define-label
 259     clear-xer
 260     temp1 src1 tag-bits get SRAWI
 261     temp2 temp1 src2 MULLWO.
 262     "overflow" get BO
 263     temp2 ds-reg 0 STW
 264     BLR
 265     "overflow" resolve-label
 266     src2 src2 tag-bits get SRAWI
 267     temp1 src2 move>args
 268     %prepare-alien-invoke
 269     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 270
 271 : bignum@ ( n -- offset ) cells bignum tag-number - ; inline
 272
 273 M:: ppc %integer>bignum ( dst src temp -- )
 274     [
 275         "end" define-label
 276         dst 0 >bignum %load-reference
 277         ! Is it zero? Then just go to the end and return this zero
 278         0 src 0 CMPI
 279         "end" get BEQ
 280         ! Allocate a bignum
 281         dst 4 cells bignum temp %allot
 282         ! Write length
 283         2 tag-fixnum temp LI
 284         temp dst 1 bignum@ STW
 285         ! Compute sign
 286         temp src MR
 287         temp temp cell-bits 1- SRAWI
 288         temp temp 1 ANDI
 289         ! Store sign
 290         temp dst 2 bignum@ STW
 291         ! Make negative value positive
 292         temp temp temp ADD
 293         temp temp NEG
 294         temp temp 1 ADDI
 295         temp src temp MULLW
 296         ! Store the bignum
 297         temp dst 3 bignum@ STW
 298         "end" resolve-label
 299     ] with-scope ;
 300
 301 M:: ppc %bignum>integer ( dst src temp -- )
 302     [
 303         "end" define-label
 304         temp src 1 bignum@ LWZ
 305         ! if the length is 1, its just the sign and nothing else,
 306         ! so output 0
 307         0 dst LI
 308         0 temp 1 tag-fixnum CMPI
 309         "end" get BEQ
 310         ! load the value
 311         dst src 3 bignum@ LWZ
 312         ! load the sign
 313         temp src 2 bignum@ LWZ
 314         ! branchless arithmetic: we want to turn 0 into 1,
 315         ! and 1 into -1
 316         temp temp temp ADD
 317         temp temp 1 SUBI
 318         temp temp NEG
 319         ! multiply value by sign
 320         dst dst temp MULLW
 321         "end" resolve-label
 322     ] with-scope ;
 323
 324 M: ppc %add-float FADD ;
 325 M: ppc %sub-float FSUB ;
 326 M: ppc %mul-float FMUL ;
 327 M: ppc %div-float FDIV ;
 328
 329 M:: ppc %integer>float ( dst src -- )
 330     HEX: 4330 scratch-reg LIS
 331     scratch-reg 1 0 scratch@ STW
 332     scratch-reg src MR
 333     scratch-reg dup HEX: 8000 XORIS
 334     scratch-reg 1 4 scratch@ STW
 335     dst 1 0 scratch@ LFD
 336     scratch-reg 4503601774854144.0 %load-reference
 337     fp-scratch-reg scratch-reg float-offset LFD
 338     dst dst fp-scratch-reg FSUB ;
 339
 340 M:: ppc %float>integer ( dst src -- )
 341     fp-scratch-reg src FCTIWZ
 342     fp-scratch-reg 1 0 scratch@ STFD
 343     dst 1 4 scratch@ LWZ ;
 344
 345 M: ppc %copy ( dst src -- ) MR ;
 346
 347 M: ppc %copy-float ( dst src -- ) FMR ;
 348
 349 M: ppc %unbox-float ( dst src -- ) float-offset LFD ;
 350
 351 M:: ppc %box-float ( dst src temp -- )
 352     dst 16 float temp %allot
 353     src dst float-offset STFD ;
 354
 355 M:: ppc %unbox-any-c-ptr ( dst src temp -- )
 356     [
 357         { "is-byte-array" "end" "start" } [ define-label ] each
 358         ! Address is computed in dst
 359         0 dst LI
 360         ! Load object into scratch-reg
 361         scratch-reg src MR
 362         ! We come back here with displaced aliens
 363         "start" resolve-label
 364         ! Is the object f?
 365         0 scratch-reg \ f tag-number CMPI
 366         ! If so, done
 367         "end" get BEQ
 368         ! Is the object an alien?
 369         0 scratch-reg header-offset LWZ
 370         0 0 alien type-number tag-fixnum CMPI
 371         "is-byte-array" get BNE
 372         ! If so, load the offset
 373         0 scratch-reg alien-offset LWZ
 374         ! Add it to address being computed
 375         dst dst 0 ADD
 376         ! Now recurse on the underlying alien
 377         scratch-reg scratch-reg underlying-alien-offset LWZ
 378         "start" get B
 379         "is-byte-array" resolve-label
 380         ! Add byte array address to address being computed
 381         dst dst scratch-reg ADD
 382         ! Add an offset to start of byte array's data area
 383         dst dst byte-array-offset ADDI
 384         "end" resolve-label
 385     ] with-scope ;
 386
 387 : alien@ ( n -- n' ) cells object tag-number - ;
 388
 389 M:: ppc %box-alien ( dst src temp -- )
 390     [
 391         "f" define-label
 392         dst \ f tag-number %load-immediate
 393         0 src 0 CMPI
 394         "f" get BEQ
 395         dst 4 cells alien temp %allot
 396         ! Store offset
 397         src dst 3 alien@ STW
 398         ! Store expired slot
 399         temp \ f tag-number %load-immediate
 400         temp dst 1 alien@ STW
 401         ! Store underlying-alien slot
 402         temp dst 2 alien@ STW
 403         "f" resolve-label
 404     ] with-scope ;
 405
 406 M: ppc %alien-unsigned-1 0 LBZ ;
 407 M: ppc %alien-unsigned-2 0 LHZ ;
 408
 409 M: ppc %alien-signed-1 dupd 0 LBZ dup EXTSB ;
 410 M: ppc %alien-signed-2 0 LHA ;
 411
 412 M: ppc %alien-cell 0 LWZ ;
 413
 414 M: ppc %alien-float 0 LFS ;
 415 M: ppc %alien-double 0 LFD ;
 416
 417 M: ppc %set-alien-integer-1 swap 0 STB ;
 418 M: ppc %set-alien-integer-2 swap 0 STH ;
 419
 420 M: ppc %set-alien-cell swap 0 STW ;
 421
 422 M: ppc %set-alien-float swap 0 STFS ;
 423 M: ppc %set-alien-double swap 0 STFD ;
 424
 425 : load-zone-ptr ( reg -- )
 426     "nursery" f %alien-global ;
 427
 428 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 429     [ drop load-zone-ptr ] [ swap 4 LWZ ] 2bi ;
 430
 431 :: inc-allot-ptr ( nursery-ptr allot-ptr n -- )
 432     scratch-reg allot-ptr n 8 align ADDI
 433     scratch-reg nursery-ptr 4 STW ;
 434
 435 :: store-header ( dst class -- )
 436     class type-number tag-fixnum scratch-reg LI
 437     scratch-reg dst 0 STW ;
 438
 439 : store-tagged ( dst tag -- )
 440     dupd tag-number ORI ;
 441
 442 M:: ppc %allot ( dst size class nursery-ptr -- )
 443     nursery-ptr dst load-allot-ptr
 444     nursery-ptr dst size inc-allot-ptr
 445     dst class store-header
 446     dst class store-tagged ;
 447
 448 : load-cards-offset ( dst -- )
 449     [ "cards_offset" f %alien-global ] [ dup 0 LWZ ] bi ;
 450
 451 : load-decks-offset ( dst -- )
 452     [ "decks_offset" f %alien-global ] [ dup 0 LWZ ] bi  ;
 453
 454 M:: ppc %write-barrier ( src card# table -- )
 455     card-mark scratch-reg LI
 456
 457     ! Mark the card
 458     table load-cards-offset
 459     src card# card-bits SRWI
 460     table scratch-reg card# STBX
 461
 462     ! Mark the card deck
 463     table load-decks-offset
 464     src card# deck-bits SRWI
 465     table scratch-reg card# STBX ;
 466
 467 M: ppc %gc
 468     "end" define-label
 469     12 load-zone-ptr
 470     11 12 cell LWZ ! nursery.here -> r11
 471     12 12 3 cells LWZ ! nursery.end -> r12
 472     11 11 1024 ADDI ! add ALLOT_BUFFER_ZONE to here
 473     11 0 12 CMP ! is here >= end?
 474     "end" get BLE
 475     %prepare-alien-invoke
 476     "minor_gc" f %alien-invoke
 477     "end" resolve-label ;
 478
 479 M: ppc %prologue ( n -- )
 480     0 11 LOAD32 rc-absolute-ppc-2/2 rel-this
 481     0 MFLR
 482     {
 483         [ [ 1 1 ] dip neg ADDI ]
 484         [ [ 11 1 ] dip xt-save STW ]
 485         [ 11 LI ]
 486         [ [ 11 1 ] dip next-save STW ]
 487         [ [ 0 1 ] dip lr-save + STW ]
 488     } cleave ;
 489
 490 M: ppc %epilogue ( n -- )
 491     #! At the end of each word that calls a subroutine, we store
 492     #! the previous link register value in r0 by popping it off
 493     #! the stack, set the link register to the contents of r0,
 494     #! and jump to the link register.
 495     [ [ 0 1 ] dip lr-save + LWZ ]
 496     [ [ 1 1 ] dip ADDI ] bi
 497     0 MTLR ;
 498
 499 :: (%boolean) ( dst temp word -- )
 500     "end" define-label
 501     dst \ f tag-number %load-immediate
 502     "end" get word execute
 503     dst \ t %load-reference
 504     "end" get resolve-label ; inline
 505
 506 : %boolean ( dst temp cc -- )
 507     negate-cc {
 508         { cc< [ \ BLT (%boolean) ] }
 509         { cc<= [ \ BLE (%boolean) ] }
 510         { cc> [ \ BGT (%boolean) ] }
 511         { cc>= [ \ BGE (%boolean) ] }
 512         { cc= [ \ BEQ (%boolean) ] }
 513         { cc/= [ \ BNE (%boolean) ] }
 514     } case ;
 515
 516 : (%compare) ( src1 src2 -- ) [ 0 ] dip CMP ; inline
 517 : (%compare-imm) ( src1 src2 -- ) [ 0 ] 2dip CMPI ; inline
 518 : (%compare-float) ( src1 src2 -- ) [ 0 ] dip FCMPU ; inline
 519
 520 M: ppc %compare (%compare) %boolean ;
 521 M: ppc %compare-imm (%compare-imm) %boolean ;
 522 M: ppc %compare-float (%compare-float) %boolean ;
 523
 524 : %branch ( label cc -- )
 525     {
 526         { cc< [ BLT ] }
 527         { cc<= [ BLE ] }
 528         { cc> [ BGT ] }
 529         { cc>= [ BGE ] }
 530         { cc= [ BEQ ] }
 531         { cc/= [ BNE ] }
 532     } case ;
 533
 534 M: ppc %compare-branch (%compare) %branch ;
 535 M: ppc %compare-imm-branch (%compare-imm) %branch ;
 536 M: ppc %compare-float-branch (%compare-float) %branch ;
 537
 538 M: ppc %spill-integer ( src n -- ) spill-integer@ 1 swap STW ;
 539 M: ppc %reload-integer ( dst n -- ) spill-integer@ 1 swap LWZ ;
 540
 541 M: ppc %spill-float ( src n -- ) spill-float@ 1 swap STFD ;
 542 M: ppc %reload-float ( dst n -- ) spill-float@ 1 swap LFD ;
 543
 544 M: ppc %loop-entry ;
 545
 546 M: int-regs return-reg drop 3 ;
 547 M: int-regs param-regs drop { 3 4 5 6 7 8 9 10 } ;
 548 M: float-regs return-reg drop 1 ;
 549
 550 M: int-regs %save-param-reg drop 1 rot local@ STW ;
 551 M: int-regs %load-param-reg drop 1 rot local@ LWZ ;
 552
 553 GENERIC: STF ( src dst off reg-class -- )
 554
 555 M: single-float-regs STF drop STFS ;
 556 M: double-float-regs STF drop STFD ;
 557
 558 M: float-regs %save-param-reg [ 1 rot local@ ] dip STF ;
 559
 560 GENERIC: LF ( dst src off reg-class -- )
 561
 562 M: single-float-regs LF drop LFS ;
 563 M: double-float-regs LF drop LFD ;
 564
 565 M: float-regs %load-param-reg [ 1 rot local@ ] dip LF ;
 566
 567 M: stack-params %load-param-reg ( stack reg reg-class -- )
 568     drop [ 0 1 rot local@ LWZ 0 1 ] dip param@ STW ;
 569
 570 : next-param@ ( n -- x ) param@ stack-frame get total-size>> + ;
 571
 572 M: stack-params %save-param-reg ( stack reg reg-class -- )
 573     #! Funky. Read the parameter from the caller's stack frame.
 574     #! This word is used in callbacks
 575     drop
 576     [ 0 1 ] dip next-param@ LWZ
 577     [ 0 1 ] dip local@ STW ;
 578
 579 M: ppc %prepare-unbox ( -- )
 580     ! First parameter is top of stack
 581     3 ds-reg 0 LWZ
 582     ds-reg dup cell SUBI ;
 583
 584 M: ppc %unbox ( n reg-class func -- )
 585     ! Value must be in r3
 586     ! Call the unboxer
 587     f %alien-invoke
 588     ! Store the return value on the C stack
 589     over [ [ return-reg ] keep %save-param-reg ] [ 2drop ] if ;
 590
 591 M: ppc %unbox-long-long ( n func -- )
 592     ! Value must be in r3:r4
 593     ! Call the unboxer
 594     f %alien-invoke
 595     ! Store the return value on the C stack
 596     [
 597         [ [ 3 1 ] dip local@ STW ]
 598         [ [ 4 1 ] dip cell + local@ STW ] bi
 599     ] when* ;
 600
 601 M: ppc %unbox-large-struct ( n c-type -- )
 602     ! Value must be in r3
 603     ! Compute destination address and load struct size
 604     [ [ 4 1 ] dip local@ ADDI ] [ heap-size 5 LI ] bi*
 605     ! Call the function
 606     "to_value_struct" f %alien-invoke ;
 607
 608 M: ppc %box ( n reg-class func -- )
 609     ! If the source is a stack location, load it into freg #0.
 610     ! If the source is f, then we assume the value is already in
 611     ! freg #0.
 612     [ over [ 0 over param-reg swap %load-param-reg ] [ 2drop ] if ] dip
 613     f %alien-invoke ;
 614
 615 M: ppc %box-long-long ( n func -- )
 616     [
 617         [
 618             [ [ 3 1 ] dip local@ LWZ ]
 619             [ [ 4 1 ] dip cell + local@ LWZ ] bi
 620         ] when*
 621     ] dip f %alien-invoke ;
 622
 623 : struct-return@ ( n -- n )
 624     [ stack-frame get params>> ] unless* local@ ;
 625
 626 M: ppc %prepare-box-struct ( -- )
 627     #! Compute target address for value struct return
 628     3 1 f struct-return@ ADDI
 629     3 1 0 local@ STW ;
 630
 631 M: ppc %box-large-struct ( n c-type -- )
 632     ! If n = f, then we're boxing a returned struct
 633     ! Compute destination address and load struct size
 634     [ [ 3 1 ] dip struct-return@ ADDI ] [ heap-size 4 LI ] bi*
 635     ! Call the function
 636     "box_value_struct" f %alien-invoke ;
 637
 638 M: ppc %prepare-alien-invoke
 639     #! Save Factor stack pointers in case the C code calls a
 640     #! callback which does a GC, which must reliably trace
 641     #! all roots.
 642     scratch-reg "stack_chain" f %alien-global
 643     scratch-reg scratch-reg 0 LWZ
 644     1 scratch-reg 0 STW
 645     ds-reg scratch-reg 8 STW
 646     rs-reg scratch-reg 12 STW ;
 647
 648 M: ppc %alien-invoke ( symbol dll -- )
 649     [ 11 ] 2dip %alien-global 11 MTLR BLRL ;
 650
 651 M: ppc %alien-callback ( quot -- )
 652     3 swap %load-reference "c_to_factor" f %alien-invoke ;
 653
 654 M: ppc %prepare-alien-indirect ( -- )
 655     "unbox_alien" f %alien-invoke
 656     15 3 MR ;
 657
 658 M: ppc %alien-indirect ( -- )
 659     15 MTLR BLRL ;
 660
 661 M: ppc %callback-value ( ctype -- )
 662     ! Save top of data stack
 663     3 ds-reg 0 LWZ
 664     3 1 0 local@ STW
 665     ! Restore data/call/retain stacks
 666     "unnest_stacks" f %alien-invoke
 667     ! Restore top of data stack
 668     3 1 0 local@ LWZ
 669     ! Unbox former top of data stack to return registers
 670     unbox-return ;
 671
 672 M: ppc small-enough? ( n -- ? ) -32768 32767 between? ;
 673
 674 M: ppc return-struct-in-registers? ( c-type -- ? )
 675     c-type return-in-registers?>> ;
 676
 677 M: ppc %box-small-struct ( c-type -- )
 678     #! Box a <= 16-byte struct returned in r3:r4:r5:r6
 679     heap-size 7 LI
 680     "box_medium_struct" f %alien-invoke ;
 681
 682 : %unbox-struct-1 ( -- )
 683     ! Alien must be in r3.
 684     "alien_offset" f %alien-invoke
 685     3 3 0 LWZ ;
 686
 687 : %unbox-struct-2 ( -- )
 688     ! Alien must be in r3.
 689     "alien_offset" f %alien-invoke
 690     4 3 4 LWZ
 691     3 3 0 LWZ ;
 692
 693 : %unbox-struct-4 ( -- )
 694     ! Alien must be in r3.
 695     "alien_offset" f %alien-invoke
 696     6 3 12 LWZ
 697     5 3 8 LWZ
 698     4 3 4 LWZ
 699     3 3 0 LWZ ;
 700
 701 M: ppc %unbox-small-struct ( size -- )
 702     #! Alien must be in EAX.
 703     heap-size cell align cell /i {
 704         { 1 [ %unbox-struct-1 ] }
 705         { 2 [ %unbox-struct-2 ] }
 706         { 4 [ %unbox-struct-4 ] }
 707     } case ;
 708
 709 USE: vocabs.loader
 710
 711 {
 712     { [ os macosx? ] [ "cpu.ppc.macosx" require ] }
 713     { [ os linux? ] [ "cpu.ppc.linux" require ] }
 714 } cond
 715
 716 "complex-double" c-type t >>return-in-registers? drop
 717
 718 [
 719     <c-type>
 720         [ alien-unsigned-4 c-bool> ] >>getter
 721         [ [ >c-bool ] 2dip set-alien-unsigned-4 ] >>setter
 722         4 >>size
 723         4 >>align
 724         "box_boolean" >>boxer
 725         "to_boolean" >>unboxer
 726     "bool" define-primitive-type
 727 ] with-compilation-unit