basis/cpu/ppc/ppc.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs sequences kernel combinators make math
   4 math.order math.ranges system namespaces locals layouts words
   5 alien alien.c-types literals cpu.architecture cpu.ppc.assembler
   6 literals compiler.cfg.registers compiler.cfg.instructions
   7 compiler.constants compiler.codegen compiler.codegen.fixup
   8 compiler.cfg.intrinsics compiler.cfg.stack-frame ;
   9 IN: cpu.ppc
  10
  11 ! PowerPC register assignments:
  12 ! r2-r12: integer vregs
  13 ! r15-r29
  14 ! r30: integer scratch
  15 ! f0-f29: float vregs
  16 ! f30: float scratch
  17
  18 ! Add some methods to the assembler that are useful to us
  19 M: label (B) [ 0 ] 2dip (B) rc-relative-ppc-3 label-fixup ;
  20 M: label BC [ 0 BC ] dip rc-relative-ppc-2 label-fixup ;
  21
  22 enable-float-intrinsics
  23
  24 <<
  25 \ ##integer>float t frame-required? set-word-prop
  26 \ ##float>integer t frame-required? set-word-prop
  27 >>
  28
  29 M: ppc machine-registers
  30     {
  31         { int-regs $[ 2 12 [a,b] 15 29 [a,b] append ] }
  32         { double-float-regs $[ 0 29 [a,b] ] }
  33     } ;
  34
  35 CONSTANT: scratch-reg 30
  36 CONSTANT: fp-scratch-reg 30
  37
  38 M: ppc two-operand? f ;
  39
  40 M: ppc %load-immediate ( reg n -- ) swap LOAD ;
  41
  42 M: ppc %load-reference ( reg obj -- )
  43     [ 0 swap LOAD32 ] [ rc-absolute-ppc-2/2 rel-immediate ] bi* ;
  44
  45 M: ppc %alien-global ( register symbol dll -- )
  46     [ 0 swap LOAD32 ] 2dip rc-absolute-ppc-2/2 rel-dlsym ;
  47
  48 CONSTANT: ds-reg 13
  49 CONSTANT: rs-reg 14
  50
  51 GENERIC: loc-reg ( loc -- reg )
  52
  53 M: ds-loc loc-reg drop ds-reg ;
  54 M: rs-loc loc-reg drop rs-reg ;
  55
  56 : loc>operand ( loc -- reg n )
  57     [ loc-reg ] [ n>> cells neg ] bi ; inline
  58
  59 M: ppc %peek loc>operand LWZ ;
  60 M: ppc %replace loc>operand STW ;
  61
  62 : (%inc) ( n reg -- ) dup rot cells ADDI ; inline
  63
  64 M: ppc %inc-d ( n -- ) ds-reg (%inc) ;
  65 M: ppc %inc-r ( n -- ) rs-reg (%inc) ;
  66
  67 HOOK: reserved-area-size os ( -- n )
  68
  69 ! The start of the stack frame contains the size of this frame
  70 ! as well as the currently executing XT
  71 : factor-area-size ( -- n ) 2 cells ; foldable
  72 : next-save ( n -- i ) cell - ;
  73 : xt-save ( n -- i ) 2 cells - ;
  74
  75 ! Next, we have the spill area as well as the FFI parameter area.
  76 ! They overlap, since basic blocks with FFI calls will never
  77 ! spill.
  78 : param@ ( n -- x ) reserved-area-size + ; inline
  79
  80 : param-save-size ( -- n ) 8 cells ; foldable
  81
  82 : local@ ( n -- x )
  83     reserved-area-size param-save-size + + ; inline
  84
  85 : spill-integer-base ( -- n )
  86     stack-frame get spill-counts>> double-float-regs swap at
  87     double-float-regs reg-size * ;
  88
  89 : spill-integer@ ( n -- offset )
  90     cells spill-integer-base + param@ ;
  91
  92 : spill-float@ ( n -- offset )
  93     double-float-regs reg-size * param@ ;
  94
  95 ! Some FP intrinsics need a temporary scratch area in the stack
  96 ! frame, 8 bytes in size
  97 : scratch@ ( n -- offset )
  98     stack-frame get total-size>>
  99     factor-area-size -
 100     param-save-size -
 101     + ;
 102
 103 ! Finally we have the linkage area
 104 HOOK: lr-save os ( -- n )
 105
 106 M: ppc stack-frame-size ( stack-frame -- i )
 107     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
 108     [ params>> ]
 109     [ return>> ]
 110     tri + +
 111     param-save-size +
 112     reserved-area-size +
 113     factor-area-size +
 114     4 cells align ;
 115
 116 M: ppc %call ( word -- ) 0 BL rc-relative-ppc-3 rel-word-pic ;
 117
 118 M: ppc %jump ( word -- )
 119     0 3 LOAD32 rc-absolute-ppc-2/2 rel-here
 120     0 B rc-relative-ppc-3 rel-word-pic-tail ;
 121
 122 M: ppc %jump-label ( label -- ) B ;
 123 M: ppc %return ( -- ) BLR ;
 124
 125 M:: ppc %dispatch ( src temp offset -- )
 126     0 temp LOAD32
 127     4 offset + cells rc-absolute-ppc-2/2 rel-here
 128     temp temp src LWZX
 129     temp MTCTR
 130     BCTR ;
 131
 132 M: ppc %dispatch-label ( word -- )
 133     0 , rc-absolute-cell rel-word ;
 134
 135 :: (%slot) ( obj slot tag temp -- reg offset )
 136     temp slot obj ADD
 137     temp tag neg ; inline
 138
 139 : (%slot-imm) ( obj slot tag -- reg offset )
 140     [ cells ] dip - ; inline
 141
 142 M: ppc %slot ( dst obj slot tag temp -- ) (%slot) LWZ ;
 143 M: ppc %slot-imm ( dst obj slot tag -- ) (%slot-imm) LWZ ;
 144 M: ppc %set-slot ( src obj slot tag temp -- ) (%slot) STW ;
 145 M: ppc %set-slot-imm ( src obj slot tag -- ) (%slot-imm) STW ;
 146
 147 M:: ppc %string-nth ( dst src index temp -- )
 148     [
 149         "end" define-label
 150         temp src index ADD
 151         dst temp string-offset LBZ
 152         0 dst HEX: 80 CMPI
 153         "end" get BLT
 154         temp src string-aux-offset LWZ
 155         temp temp index ADD
 156         temp temp index ADD
 157         temp temp byte-array-offset LHZ
 158         temp temp 7 SLWI
 159         dst dst temp XOR
 160         "end" resolve-label
 161     ] with-scope ;
 162
 163 M:: ppc %set-string-nth-fast ( ch obj index temp -- )
 164     temp obj index ADD
 165     ch temp string-offset STB ;
 166
 167 M: ppc %add     ADD ;
 168 M: ppc %add-imm ADDI ;
 169 M: ppc %sub     swap SUBF ;
 170 M: ppc %sub-imm SUBI ;
 171 M: ppc %mul     MULLW ;
 172 M: ppc %mul-imm MULLI ;
 173 M: ppc %and     AND ;
 174 M: ppc %and-imm ANDI ;
 175 M: ppc %or      OR ;
 176 M: ppc %or-imm  ORI ;
 177 M: ppc %xor     XOR ;
 178 M: ppc %xor-imm XORI ;
 179 M: ppc %shl-imm swapd SLWI ;
 180 M: ppc %shr-imm swapd SRWI ;
 181 M: ppc %sar-imm SRAWI ;
 182 M: ppc %not     NOT ;
 183
 184 : %alien-invoke-tail ( func dll -- )
 185     [ scratch-reg ] 2dip %alien-global scratch-reg MTCTR BCTR ;
 186
 187 :: exchange-regs ( r1 r2 -- )
 188     scratch-reg r1 MR
 189     r1 r2 MR
 190     r2 scratch-reg MR ;
 191
 192 : ?MR ( r1 r2 -- ) 2dup = [ 2drop ] [ MR ] if ;
 193
 194 :: move>args ( src1 src2 -- )
 195     {
 196         { [ src1 4 = ] [ 3 src2 ?MR 3 4 exchange-regs ] }
 197         { [ src1 3 = ] [ 4 src2 ?MR ] }
 198         { [ src2 3 = ] [ 4 src1 ?MR 3 4 exchange-regs ] }
 199         { [ src2 4 = ] [ 3 src1 ?MR ] }
 200         [ 3 src1 MR 4 src2 MR ]
 201     } cond ;
 202
 203 : clear-xer ( -- )
 204     0 0 LI
 205     0 MTXER ; inline
 206
 207 :: overflow-template ( src1 src2 insn func -- )
 208     "no-overflow" define-label
 209     clear-xer
 210     scratch-reg src2 src1 insn call
 211     scratch-reg ds-reg 0 STW
 212     "no-overflow" get BNO
 213     src1 src2 move>args
 214     %prepare-alien-invoke
 215     func f %alien-invoke
 216     "no-overflow" resolve-label ; inline
 217
 218 :: overflow-template-tail ( src1 src2 insn func -- )
 219     "overflow" define-label
 220     clear-xer
 221     scratch-reg src2 src1 insn call
 222     "overflow" get BO
 223     scratch-reg ds-reg 0 STW
 224     BLR
 225     "overflow" resolve-label
 226     src1 src2 move>args
 227     %prepare-alien-invoke
 228     func f %alien-invoke-tail ; inline
 229
 230 M: ppc %fixnum-add ( src1 src2 -- )
 231     [ ADDO. ] "overflow_fixnum_add" overflow-template ;
 232
 233 M: ppc %fixnum-add-tail ( src1 src2 -- )
 234     [ ADDO. ] "overflow_fixnum_add" overflow-template-tail ;
 235
 236 M: ppc %fixnum-sub ( src1 src2 -- )
 237     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template ;
 238
 239 M: ppc %fixnum-sub-tail ( src1 src2 -- )
 240     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template-tail ;
 241
 242 M:: ppc %fixnum-mul ( src1 src2 temp1 temp2 -- )
 243     "no-overflow" define-label
 244     clear-xer
 245     temp1 src1 tag-bits get SRAWI
 246     temp2 temp1 src2 MULLWO.
 247     temp2 ds-reg 0 STW
 248     "no-overflow" get BNO
 249     src2 src2 tag-bits get SRAWI
 250     temp1 src2 move>args
 251     %prepare-alien-invoke
 252     "overflow_fixnum_multiply" f %alien-invoke
 253     "no-overflow" resolve-label ;
 254
 255 M:: ppc %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 256     "overflow" define-label
 257     clear-xer
 258     temp1 src1 tag-bits get SRAWI
 259     temp2 temp1 src2 MULLWO.
 260     "overflow" get BO
 261     temp2 ds-reg 0 STW
 262     BLR
 263     "overflow" resolve-label
 264     src2 src2 tag-bits get SRAWI
 265     temp1 src2 move>args
 266     %prepare-alien-invoke
 267     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 268
 269 : bignum@ ( n -- offset ) cells bignum tag-number - ; inline
 270
 271 M:: ppc %integer>bignum ( dst src temp -- )
 272     [
 273         "end" define-label
 274         dst 0 >bignum %load-reference
 275         ! Is it zero? Then just go to the end and return this zero
 276         0 src 0 CMPI
 277         "end" get BEQ
 278         ! Allocate a bignum
 279         dst 4 cells bignum temp %allot
 280         ! Write length
 281         2 tag-fixnum temp LI
 282         temp dst 1 bignum@ STW
 283         ! Compute sign
 284         temp src MR
 285         temp temp cell-bits 1- SRAWI
 286         temp temp 1 ANDI
 287         ! Store sign
 288         temp dst 2 bignum@ STW
 289         ! Make negative value positive
 290         temp temp temp ADD
 291         temp temp NEG
 292         temp temp 1 ADDI
 293         temp src temp MULLW
 294         ! Store the bignum
 295         temp dst 3 bignum@ STW
 296         "end" resolve-label
 297     ] with-scope ;
 298
 299 M:: ppc %bignum>integer ( dst src temp -- )
 300     [
 301         "end" define-label
 302         temp src 1 bignum@ LWZ
 303         ! if the length is 1, its just the sign and nothing else,
 304         ! so output 0
 305         0 dst LI
 306         0 temp 1 tag-fixnum CMPI
 307         "end" get BEQ
 308         ! load the value
 309         dst src 3 bignum@ LWZ
 310         ! load the sign
 311         temp src 2 bignum@ LWZ
 312         ! branchless arithmetic: we want to turn 0 into 1,
 313         ! and 1 into -1
 314         temp temp temp ADD
 315         temp temp 1 SUBI
 316         temp temp NEG
 317         ! multiply value by sign
 318         dst dst temp MULLW
 319         "end" resolve-label
 320     ] with-scope ;
 321
 322 M: ppc %add-float FADD ;
 323 M: ppc %sub-float FSUB ;
 324 M: ppc %mul-float FMUL ;
 325 M: ppc %div-float FDIV ;
 326
 327 M:: ppc %integer>float ( dst src -- )
 328     HEX: 4330 scratch-reg LIS
 329     scratch-reg 1 0 scratch@ STW
 330     scratch-reg src MR
 331     scratch-reg dup HEX: 8000 XORIS
 332     scratch-reg 1 4 scratch@ STW
 333     dst 1 0 scratch@ LFD
 334     scratch-reg 4503601774854144.0 %load-reference
 335     fp-scratch-reg scratch-reg float-offset LFD
 336     dst dst fp-scratch-reg FSUB ;
 337
 338 M:: ppc %float>integer ( dst src -- )
 339     fp-scratch-reg src FCTIWZ
 340     fp-scratch-reg 1 0 scratch@ STFD
 341     dst 1 4 scratch@ LWZ ;
 342
 343 M: ppc %copy ( dst src -- ) MR ;
 344
 345 M: ppc %copy-float ( dst src -- ) FMR ;
 346
 347 M: ppc %unbox-float ( dst src -- ) float-offset LFD ;
 348
 349 M:: ppc %box-float ( dst src temp -- )
 350     dst 16 float temp %allot
 351     src dst float-offset STFD ;
 352
 353 M:: ppc %unbox-any-c-ptr ( dst src temp -- )
 354     [
 355         { "is-byte-array" "end" "start" } [ define-label ] each
 356         ! Address is computed in dst
 357         0 dst LI
 358         ! Load object into scratch-reg
 359         scratch-reg src MR
 360         ! We come back here with displaced aliens
 361         "start" resolve-label
 362         ! Is the object f?
 363         0 scratch-reg \ f tag-number CMPI
 364         ! If so, done
 365         "end" get BEQ
 366         ! Is the object an alien?
 367         0 scratch-reg header-offset LWZ
 368         0 0 alien type-number tag-fixnum CMPI
 369         "is-byte-array" get BNE
 370         ! If so, load the offset
 371         0 scratch-reg alien-offset LWZ
 372         ! Add it to address being computed
 373         dst dst 0 ADD
 374         ! Now recurse on the underlying alien
 375         scratch-reg scratch-reg underlying-alien-offset LWZ
 376         "start" get B
 377         "is-byte-array" resolve-label
 378         ! Add byte array address to address being computed
 379         dst dst scratch-reg ADD
 380         ! Add an offset to start of byte array's data area
 381         dst dst byte-array-offset ADDI
 382         "end" resolve-label
 383     ] with-scope ;
 384
 385 : alien@ ( n -- n' ) cells object tag-number - ;
 386
 387 M:: ppc %box-alien ( dst src temp -- )
 388     [
 389         "f" define-label
 390         dst \ f tag-number %load-immediate
 391         0 src 0 CMPI
 392         "f" get BEQ
 393         dst 4 cells alien temp %allot
 394         ! Store offset
 395         src dst 3 alien@ STW
 396         ! Store expired slot
 397         temp \ f tag-number %load-immediate
 398         temp dst 1 alien@ STW
 399         ! Store underlying-alien slot
 400         temp dst 2 alien@ STW
 401         "f" resolve-label
 402     ] with-scope ;
 403
 404 M: ppc %alien-unsigned-1 0 LBZ ;
 405 M: ppc %alien-unsigned-2 0 LHZ ;
 406
 407 M: ppc %alien-signed-1 dupd 0 LBZ dup EXTSB ;
 408 M: ppc %alien-signed-2 0 LHA ;
 409
 410 M: ppc %alien-cell 0 LWZ ;
 411
 412 M: ppc %alien-float 0 LFS ;
 413 M: ppc %alien-double 0 LFD ;
 414
 415 M: ppc %set-alien-integer-1 swap 0 STB ;
 416 M: ppc %set-alien-integer-2 swap 0 STH ;
 417
 418 M: ppc %set-alien-cell swap 0 STW ;
 419
 420 M: ppc %set-alien-float swap 0 STFS ;
 421 M: ppc %set-alien-double swap 0 STFD ;
 422
 423 : load-zone-ptr ( reg -- )
 424     "nursery" f %alien-global ;
 425
 426 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 427     [ drop load-zone-ptr ] [ swap 4 LWZ ] 2bi ;
 428
 429 :: inc-allot-ptr ( nursery-ptr allot-ptr n -- )
 430     scratch-reg allot-ptr n 8 align ADDI
 431     scratch-reg nursery-ptr 4 STW ;
 432
 433 :: store-header ( dst class -- )
 434     class type-number tag-fixnum scratch-reg LI
 435     scratch-reg dst 0 STW ;
 436
 437 : store-tagged ( dst tag -- )
 438     dupd tag-number ORI ;
 439
 440 M:: ppc %allot ( dst size class nursery-ptr -- )
 441     nursery-ptr dst load-allot-ptr
 442     nursery-ptr dst size inc-allot-ptr
 443     dst class store-header
 444     dst class store-tagged ;
 445
 446 : load-cards-offset ( dst -- )
 447     [ "cards_offset" f %alien-global ] [ dup 0 LWZ ] bi ;
 448
 449 : load-decks-offset ( dst -- )
 450     [ "decks_offset" f %alien-global ] [ dup 0 LWZ ] bi  ;
 451
 452 M:: ppc %write-barrier ( src card# table -- )
 453     card-mark scratch-reg LI
 454
 455     ! Mark the card
 456     table load-cards-offset
 457     src card# card-bits SRWI
 458     table scratch-reg card# STBX
 459
 460     ! Mark the card deck
 461     table load-decks-offset
 462     src card# deck-bits SRWI
 463     table scratch-reg card# STBX ;
 464
 465 M: ppc %gc
 466     "end" define-label
 467     12 load-zone-ptr
 468     11 12 cell LWZ ! nursery.here -> r11
 469     12 12 3 cells LWZ ! nursery.end -> r12
 470     11 11 1024 ADDI ! add ALLOT_BUFFER_ZONE to here
 471     11 0 12 CMP ! is here >= end?
 472     "end" get BLE
 473     %prepare-alien-invoke
 474     "minor_gc" f %alien-invoke
 475     "end" resolve-label ;
 476
 477 M: ppc %prologue ( n -- )
 478     0 11 LOAD32 rc-absolute-ppc-2/2 rel-this
 479     0 MFLR
 480     {
 481         [ [ 1 1 ] dip neg ADDI ]
 482         [ [ 11 1 ] dip xt-save STW ]
 483         [ 11 LI ]
 484         [ [ 11 1 ] dip next-save STW ]
 485         [ [ 0 1 ] dip lr-save + STW ]
 486     } cleave ;
 487
 488 M: ppc %epilogue ( n -- )
 489     #! At the end of each word that calls a subroutine, we store
 490     #! the previous link register value in r0 by popping it off
 491     #! the stack, set the link register to the contents of r0,
 492     #! and jump to the link register.
 493     [ [ 0 1 ] dip lr-save + LWZ ]
 494     [ [ 1 1 ] dip ADDI ] bi
 495     0 MTLR ;
 496
 497 :: (%boolean) ( dst temp word -- )
 498     "end" define-label
 499     dst \ f tag-number %load-immediate
 500     "end" get word execute
 501     dst \ t %load-reference
 502     "end" get resolve-label ; inline
 503
 504 : %boolean ( dst temp cc -- )
 505     negate-cc {
 506         { cc< [ \ BLT (%boolean) ] }
 507         { cc<= [ \ BLE (%boolean) ] }
 508         { cc> [ \ BGT (%boolean) ] }
 509         { cc>= [ \ BGE (%boolean) ] }
 510         { cc= [ \ BEQ (%boolean) ] }
 511         { cc/= [ \ BNE (%boolean) ] }
 512     } case ;
 513
 514 : (%compare) ( src1 src2 -- ) [ 0 ] dip CMP ; inline
 515 : (%compare-imm) ( src1 src2 -- ) [ 0 ] 2dip CMPI ; inline
 516 : (%compare-float) ( src1 src2 -- ) [ 0 ] dip FCMPU ; inline
 517
 518 M: ppc %compare (%compare) %boolean ;
 519 M: ppc %compare-imm (%compare-imm) %boolean ;
 520 M: ppc %compare-float (%compare-float) %boolean ;
 521
 522 : %branch ( label cc -- )
 523     {
 524         { cc< [ BLT ] }
 525         { cc<= [ BLE ] }
 526         { cc> [ BGT ] }
 527         { cc>= [ BGE ] }
 528         { cc= [ BEQ ] }
 529         { cc/= [ BNE ] }
 530     } case ;
 531
 532 M: ppc %compare-branch (%compare) %branch ;
 533 M: ppc %compare-imm-branch (%compare-imm) %branch ;
 534 M: ppc %compare-float-branch (%compare-float) %branch ;
 535
 536 M: ppc %spill-integer ( src n -- ) spill-integer@ 1 swap STW ;
 537 M: ppc %reload-integer ( dst n -- ) spill-integer@ 1 swap LWZ ;
 538
 539 M: ppc %spill-float ( src n -- ) spill-float@ 1 swap STFD ;
 540 M: ppc %reload-float ( dst n -- ) spill-float@ 1 swap LFD ;
 541
 542 M: ppc %loop-entry ;
 543
 544 M: int-regs return-reg drop 3 ;
 545 M: int-regs param-regs drop { 3 4 5 6 7 8 9 10 } ;
 546 M: float-regs return-reg drop 1 ;
 547
 548 M: int-regs %save-param-reg drop 1 rot local@ STW ;
 549 M: int-regs %load-param-reg drop 1 rot local@ LWZ ;
 550
 551 GENERIC: STF ( src dst off reg-class -- )
 552
 553 M: single-float-regs STF drop STFS ;
 554 M: double-float-regs STF drop STFD ;
 555
 556 M: float-regs %save-param-reg [ 1 rot local@ ] dip STF ;
 557
 558 GENERIC: LF ( dst src off reg-class -- )
 559
 560 M: single-float-regs LF drop LFS ;
 561 M: double-float-regs LF drop LFD ;
 562
 563 M: float-regs %load-param-reg [ 1 rot local@ ] dip LF ;
 564
 565 M: stack-params %load-param-reg ( stack reg reg-class -- )
 566     drop [ 0 1 rot local@ LWZ 0 1 ] dip param@ STW ;
 567
 568 : next-param@ ( n -- x ) param@ stack-frame get total-size>> + ;
 569
 570 M: stack-params %save-param-reg ( stack reg reg-class -- )
 571     #! Funky. Read the parameter from the caller's stack frame.
 572     #! This word is used in callbacks
 573     drop
 574     [ 0 1 ] dip next-param@ LWZ
 575     [ 0 1 ] dip local@ STW ;
 576
 577 M: ppc %prepare-unbox ( -- )
 578     ! First parameter is top of stack
 579     3 ds-reg 0 LWZ
 580     ds-reg dup cell SUBI ;
 581
 582 M: ppc %unbox ( n reg-class func -- )
 583     ! Value must be in r3
 584     ! Call the unboxer
 585     f %alien-invoke
 586     ! Store the return value on the C stack
 587     over [ [ return-reg ] keep %save-param-reg ] [ 2drop ] if ;
 588
 589 M: ppc %unbox-long-long ( n func -- )
 590     ! Value must be in r3:r4
 591     ! Call the unboxer
 592     f %alien-invoke
 593     ! Store the return value on the C stack
 594     [
 595         [ [ 3 1 ] dip local@ STW ]
 596         [ [ 4 1 ] dip cell + local@ STW ] bi
 597     ] when* ;
 598
 599 M: ppc %unbox-large-struct ( n c-type -- )
 600     ! Value must be in r3
 601     ! Compute destination address and load struct size
 602     [ [ 4 1 ] dip local@ ADDI ] [ heap-size 5 LI ] bi*
 603     ! Call the function
 604     "to_value_struct" f %alien-invoke ;
 605
 606 M: ppc %box ( n reg-class func -- )
 607     ! If the source is a stack location, load it into freg #0.
 608     ! If the source is f, then we assume the value is already in
 609     ! freg #0.
 610     [ over [ 0 over param-reg swap %load-param-reg ] [ 2drop ] if ] dip
 611     f %alien-invoke ;
 612
 613 M: ppc %box-long-long ( n func -- )
 614     [
 615         [
 616             [ [ 3 1 ] dip local@ LWZ ]
 617             [ [ 4 1 ] dip cell + local@ LWZ ] bi
 618         ] when*
 619     ] dip f %alien-invoke ;
 620
 621 : struct-return@ ( n -- n )
 622     [ stack-frame get params>> ] unless* local@ ;
 623
 624 M: ppc %prepare-box-struct ( -- )
 625     #! Compute target address for value struct return
 626     3 1 f struct-return@ ADDI
 627     3 1 0 local@ STW ;
 628
 629 M: ppc %box-large-struct ( n c-type -- )
 630     ! If n = f, then we're boxing a returned struct
 631     ! Compute destination address and load struct size
 632     [ [ 3 1 ] dip struct-return@ ADDI ] [ heap-size 4 LI ] bi*
 633     ! Call the function
 634     "box_value_struct" f %alien-invoke ;
 635
 636 M: ppc %prepare-alien-invoke
 637     #! Save Factor stack pointers in case the C code calls a
 638     #! callback which does a GC, which must reliably trace
 639     #! all roots.
 640     scratch-reg "stack_chain" f %alien-global
 641     scratch-reg scratch-reg 0 LWZ
 642     1 scratch-reg 0 STW
 643     ds-reg scratch-reg 8 STW
 644     rs-reg scratch-reg 12 STW ;
 645
 646 M: ppc %alien-invoke ( symbol dll -- )
 647     [ 11 ] 2dip %alien-global 11 MTLR BLRL ;
 648
 649 M: ppc %alien-callback ( quot -- )
 650     3 swap %load-reference "c_to_factor" f %alien-invoke ;
 651
 652 M: ppc %prepare-alien-indirect ( -- )
 653     "unbox_alien" f %alien-invoke
 654     13 3 MR ;
 655
 656 M: ppc %alien-indirect ( -- )
 657     13 MTLR BLRL ;
 658
 659 M: ppc %callback-value ( ctype -- )
 660     ! Save top of data stack
 661     3 ds-reg 0 LWZ
 662     3 1 0 local@ STW
 663     ! Restore data/call/retain stacks
 664     "unnest_stacks" f %alien-invoke
 665     ! Restore top of data stack
 666     3 1 0 local@ LWZ
 667     ! Unbox former top of data stack to return registers
 668     unbox-return ;
 669
 670 M: ppc small-enough? ( n -- ? ) -32768 32767 between? ;
 671
 672 M: ppc return-struct-in-registers? ( c-type -- ? )
 673     c-type return-in-registers?>> ;
 674
 675 M: ppc %box-small-struct ( c-type -- )
 676     #! Box a <= 16-byte struct returned in r3:r4:r5:r6
 677     heap-size 7 LI
 678     "box_medium_struct" f %alien-invoke ;
 679
 680 : %unbox-struct-1 ( -- )
 681     ! Alien must be in r3.
 682     "alien_offset" f %alien-invoke
 683     3 3 0 LWZ ;
 684
 685 : %unbox-struct-2 ( -- )
 686     ! Alien must be in r3.
 687     "alien_offset" f %alien-invoke
 688     4 3 4 LWZ
 689     3 3 0 LWZ ;
 690
 691 : %unbox-struct-4 ( -- )
 692     ! Alien must be in r3.
 693     "alien_offset" f %alien-invoke
 694     6 3 12 LWZ
 695     5 3 8 LWZ
 696     4 3 4 LWZ
 697     3 3 0 LWZ ;
 698
 699 M: ppc %unbox-small-struct ( size -- )
 700     #! Alien must be in EAX.
 701     heap-size cell align cell /i {
 702         { 1 [ %unbox-struct-1 ] }
 703         { 2 [ %unbox-struct-2 ] }
 704         { 4 [ %unbox-struct-4 ] }
 705     } case ;
 706
 707 USE: vocabs.loader
 708
 709 {
 710     { [ os macosx? ] [ "cpu.ppc.macosx" require ] }
 711     { [ os linux? ] [ "cpu.ppc.linux" require ] }
 712 } cond
 713
 714 "complex-double" c-type t >>return-in-registers? drop