basis/cpu/ppc/ppc.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs sequences kernel combinators make math
   4 math.order math.ranges system namespaces locals layouts words
   5 alien alien.c-types literals cpu.architecture cpu.ppc.assembler
   6 literals compiler.cfg.registers compiler.cfg.instructions
   7 compiler.constants compiler.codegen compiler.codegen.fixup
   8 compiler.cfg.intrinsics compiler.cfg.stack-frame ;
   9 IN: cpu.ppc
  10
  11 ! PowerPC register assignments:
  12 ! r2-r12: integer vregs
  13 ! r15-r29
  14 ! r30: integer scratch
  15 ! f0-f29: float vregs
  16 ! f30: float scratch
  17
  18 ! Add some methods to the assembler that are useful to us
  19 M: label (B) [ 0 ] 2dip (B) rc-relative-ppc-3 label-fixup ;
  20 M: label BC [ 0 BC ] dip rc-relative-ppc-2 label-fixup ;
  21
  22 enable-float-intrinsics
  23
  24 <<
  25 \ ##integer>float t frame-required? set-word-prop
  26 \ ##float>integer t frame-required? set-word-prop
  27 >>
  28
  29 M: ppc machine-registers
  30     {
  31         { int-regs $[ 2 12 [a,b] 15 29 [a,b] append ] }
  32         { double-float-regs $[ 0 29 [a,b] ] }
  33     } ;
  34
  35 CONSTANT: scratch-reg 30
  36 CONSTANT: fp-scratch-reg 30
  37
  38 M: ppc two-operand? f ;
  39
  40 M: ppc %load-immediate ( reg n -- ) swap LOAD ;
  41
  42 M: ppc %load-reference ( reg obj -- )
  43     [ 0 swap LOAD32 ] [ rc-absolute-ppc-2/2 rel-immediate ] bi* ;
  44
  45 M: ppc %alien-global ( register symbol dll -- )
  46     [ 0 swap LOAD32 ] 2dip rc-absolute-ppc-2/2 rel-dlsym ;
  47
  48 CONSTANT: ds-reg 13
  49 CONSTANT: rs-reg 14
  50
  51 GENERIC: loc-reg ( loc -- reg )
  52
  53 M: ds-loc loc-reg drop ds-reg ;
  54 M: rs-loc loc-reg drop rs-reg ;
  55
  56 : loc>operand ( loc -- reg n )
  57     [ loc-reg ] [ n>> cells neg ] bi ; inline
  58
  59 M: ppc %peek loc>operand LWZ ;
  60 M: ppc %replace loc>operand STW ;
  61
  62 : (%inc) ( n reg -- ) dup rot cells ADDI ; inline
  63
  64 M: ppc %inc-d ( n -- ) ds-reg (%inc) ;
  65 M: ppc %inc-r ( n -- ) rs-reg (%inc) ;
  66
  67 HOOK: reserved-area-size os ( -- n )
  68
  69 ! The start of the stack frame contains the size of this frame
  70 ! as well as the currently executing XT
  71 : factor-area-size ( -- n ) 2 cells ; foldable
  72 : next-save ( n -- i ) cell - ;
  73 : xt-save ( n -- i ) 2 cells - ;
  74
  75 ! Next, we have the spill area as well as the FFI parameter area.
  76 ! They overlap, since basic blocks with FFI calls will never
  77 ! spill.
  78 : param@ ( n -- x ) reserved-area-size + ; inline
  79
  80 : param-save-size ( -- n ) 8 cells ; foldable
  81
  82 : local@ ( n -- x )
  83     reserved-area-size param-save-size + + ; inline
  84
  85 : spill-integer-base ( -- n )
  86     stack-frame get spill-counts>> double-float-regs swap at
  87     double-float-regs reg-size * ;
  88
  89 : spill-integer@ ( n -- offset )
  90     cells spill-integer-base + param@ ;
  91
  92 : spill-float@ ( n -- offset )
  93     double-float-regs reg-size * param@ ;
  94
  95 ! Some FP intrinsics need a temporary scratch area in the stack
  96 ! frame, 8 bytes in size
  97 : scratch@ ( n -- offset )
  98     stack-frame get total-size>>
  99     factor-area-size -
 100     param-save-size -
 101     + ;
 102
 103 ! Finally we have the linkage area
 104 HOOK: lr-save os ( -- n )
 105
 106 M: ppc stack-frame-size ( stack-frame -- i )
 107     [ spill-counts>> [ swap reg-size * ] { } assoc>map sum ]
 108     [ params>> ]
 109     [ return>> ]
 110     tri + +
 111     param-save-size +
 112     reserved-area-size +
 113     factor-area-size +
 114     4 cells align ;
 115
 116 M: ppc %call ( word -- ) 0 BL rc-relative-ppc-3 rel-word-pic ;
 117 M: ppc %jump ( word -- ) 0 B rc-relative-ppc-3 rel-word ;
 118 M: ppc %jump-label ( label -- ) B ;
 119 M: ppc %return ( -- ) BLR ;
 120
 121 M:: ppc %dispatch ( src temp offset -- )
 122     0 temp LOAD32
 123     4 offset + cells rc-absolute-ppc-2/2 rel-here
 124     temp temp src LWZX
 125     temp MTCTR
 126     BCTR ;
 127
 128 M: ppc %dispatch-label ( word -- )
 129     0 , rc-absolute-cell rel-word ;
 130
 131 :: (%slot) ( obj slot tag temp -- reg offset )
 132     temp slot obj ADD
 133     temp tag neg ; inline
 134
 135 : (%slot-imm) ( obj slot tag -- reg offset )
 136     [ cells ] dip - ; inline
 137
 138 M: ppc %slot ( dst obj slot tag temp -- ) (%slot) LWZ ;
 139 M: ppc %slot-imm ( dst obj slot tag -- ) (%slot-imm) LWZ ;
 140 M: ppc %set-slot ( src obj slot tag temp -- ) (%slot) STW ;
 141 M: ppc %set-slot-imm ( src obj slot tag -- ) (%slot-imm) STW ;
 142
 143 M:: ppc %string-nth ( dst src index temp -- )
 144     [
 145         "end" define-label
 146         temp src index ADD
 147         dst temp string-offset LBZ
 148         0 dst HEX: 80 CMPI
 149         "end" get BLT
 150         temp src string-aux-offset LWZ
 151         temp temp index ADD
 152         temp temp index ADD
 153         temp temp byte-array-offset LHZ
 154         temp temp 7 SLWI
 155         dst dst temp XOR
 156         "end" resolve-label
 157     ] with-scope ;
 158
 159 M:: ppc %set-string-nth-fast ( ch obj index temp -- )
 160     temp obj index ADD
 161     ch temp string-offset STB ;
 162
 163 M: ppc %add     ADD ;
 164 M: ppc %add-imm ADDI ;
 165 M: ppc %sub     swap SUBF ;
 166 M: ppc %sub-imm SUBI ;
 167 M: ppc %mul     MULLW ;
 168 M: ppc %mul-imm MULLI ;
 169 M: ppc %and     AND ;
 170 M: ppc %and-imm ANDI ;
 171 M: ppc %or      OR ;
 172 M: ppc %or-imm  ORI ;
 173 M: ppc %xor     XOR ;
 174 M: ppc %xor-imm XORI ;
 175 M: ppc %shl-imm swapd SLWI ;
 176 M: ppc %shr-imm swapd SRWI ;
 177 M: ppc %sar-imm SRAWI ;
 178 M: ppc %not     NOT ;
 179
 180 : %alien-invoke-tail ( func dll -- )
 181     [ scratch-reg ] 2dip %alien-global scratch-reg MTCTR BCTR ;
 182
 183 :: exchange-regs ( r1 r2 -- )
 184     scratch-reg r1 MR
 185     r1 r2 MR
 186     r2 scratch-reg MR ;
 187
 188 : ?MR ( r1 r2 -- ) 2dup = [ 2drop ] [ MR ] if ;
 189
 190 :: move>args ( src1 src2 -- )
 191     {
 192         { [ src1 4 = ] [ 3 src2 ?MR 3 4 exchange-regs ] }
 193         { [ src1 3 = ] [ 4 src2 ?MR ] }
 194         { [ src2 3 = ] [ 4 src1 ?MR 3 4 exchange-regs ] }
 195         { [ src2 4 = ] [ 3 src1 ?MR ] }
 196         [ 3 src1 MR 4 src2 MR ]
 197     } cond ;
 198
 199 : clear-xer ( -- )
 200     0 0 LI
 201     0 MTXER ; inline
 202
 203 :: overflow-template ( src1 src2 insn func -- )
 204     "no-overflow" define-label
 205     clear-xer
 206     scratch-reg src2 src1 insn call
 207     scratch-reg ds-reg 0 STW
 208     "no-overflow" get BNO
 209     src1 src2 move>args
 210     %prepare-alien-invoke
 211     func f %alien-invoke
 212     "no-overflow" resolve-label ; inline
 213
 214 :: overflow-template-tail ( src1 src2 insn func -- )
 215     "overflow" define-label
 216     clear-xer
 217     scratch-reg src2 src1 insn call
 218     "overflow" get BO
 219     scratch-reg ds-reg 0 STW
 220     BLR
 221     "overflow" resolve-label
 222     src1 src2 move>args
 223     %prepare-alien-invoke
 224     func f %alien-invoke-tail ; inline
 225
 226 M: ppc %fixnum-add ( src1 src2 -- )
 227     [ ADDO. ] "overflow_fixnum_add" overflow-template ;
 228
 229 M: ppc %fixnum-add-tail ( src1 src2 -- )
 230     [ ADDO. ] "overflow_fixnum_add" overflow-template-tail ;
 231
 232 M: ppc %fixnum-sub ( src1 src2 -- )
 233     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template ;
 234
 235 M: ppc %fixnum-sub-tail ( src1 src2 -- )
 236     [ SUBFO. ] "overflow_fixnum_subtract" overflow-template-tail ;
 237
 238 M:: ppc %fixnum-mul ( src1 src2 temp1 temp2 -- )
 239     "no-overflow" define-label
 240     clear-xer
 241     temp1 src1 tag-bits get SRAWI
 242     temp2 temp1 src2 MULLWO.
 243     temp2 ds-reg 0 STW
 244     "no-overflow" get BNO
 245     src2 src2 tag-bits get SRAWI
 246     temp1 src2 move>args
 247     %prepare-alien-invoke
 248     "overflow_fixnum_multiply" f %alien-invoke
 249     "no-overflow" resolve-label ;
 250
 251 M:: ppc %fixnum-mul-tail ( src1 src2 temp1 temp2 -- )
 252     "overflow" define-label
 253     clear-xer
 254     temp1 src1 tag-bits get SRAWI
 255     temp2 temp1 src2 MULLWO.
 256     "overflow" get BO
 257     temp2 ds-reg 0 STW
 258     BLR
 259     "overflow" resolve-label
 260     src2 src2 tag-bits get SRAWI
 261     temp1 src2 move>args
 262     %prepare-alien-invoke
 263     "overflow_fixnum_multiply" f %alien-invoke-tail ;
 264
 265 : bignum@ ( n -- offset ) cells bignum tag-number - ; inline
 266
 267 M:: ppc %integer>bignum ( dst src temp -- )
 268     [
 269         "end" define-label
 270         dst 0 >bignum %load-reference
 271         ! Is it zero? Then just go to the end and return this zero
 272         0 src 0 CMPI
 273         "end" get BEQ
 274         ! Allocate a bignum
 275         dst 4 cells bignum temp %allot
 276         ! Write length
 277         2 tag-fixnum temp LI
 278         temp dst 1 bignum@ STW
 279         ! Compute sign
 280         temp src MR
 281         temp temp cell-bits 1- SRAWI
 282         temp temp 1 ANDI
 283         ! Store sign
 284         temp dst 2 bignum@ STW
 285         ! Make negative value positive
 286         temp temp temp ADD
 287         temp temp NEG
 288         temp temp 1 ADDI
 289         temp src temp MULLW
 290         ! Store the bignum
 291         temp dst 3 bignum@ STW
 292         "end" resolve-label
 293     ] with-scope ;
 294
 295 M:: ppc %bignum>integer ( dst src temp -- )
 296     [
 297         "end" define-label
 298         temp src 1 bignum@ LWZ
 299         ! if the length is 1, its just the sign and nothing else,
 300         ! so output 0
 301         0 dst LI
 302         0 temp 1 tag-fixnum CMPI
 303         "end" get BEQ
 304         ! load the value
 305         dst src 3 bignum@ LWZ
 306         ! load the sign
 307         temp src 2 bignum@ LWZ
 308         ! branchless arithmetic: we want to turn 0 into 1,
 309         ! and 1 into -1
 310         temp temp temp ADD
 311         temp temp 1 SUBI
 312         temp temp NEG
 313         ! multiply value by sign
 314         dst dst temp MULLW
 315         "end" resolve-label
 316     ] with-scope ;
 317
 318 M: ppc %add-float FADD ;
 319 M: ppc %sub-float FSUB ;
 320 M: ppc %mul-float FMUL ;
 321 M: ppc %div-float FDIV ;
 322
 323 M:: ppc %integer>float ( dst src -- )
 324     HEX: 4330 scratch-reg LIS
 325     scratch-reg 1 0 scratch@ STW
 326     scratch-reg src MR
 327     scratch-reg dup HEX: 8000 XORIS
 328     scratch-reg 1 4 scratch@ STW
 329     dst 1 0 scratch@ LFD
 330     scratch-reg 4503601774854144.0 %load-reference
 331     fp-scratch-reg scratch-reg float-offset LFD
 332     dst dst fp-scratch-reg FSUB ;
 333
 334 M:: ppc %float>integer ( dst src -- )
 335     fp-scratch-reg src FCTIWZ
 336     fp-scratch-reg 1 0 scratch@ STFD
 337     dst 1 4 scratch@ LWZ ;
 338
 339 M: ppc %copy ( dst src -- ) MR ;
 340
 341 M: ppc %copy-float ( dst src -- ) FMR ;
 342
 343 M: ppc %unbox-float ( dst src -- ) float-offset LFD ;
 344
 345 M:: ppc %box-float ( dst src temp -- )
 346     dst 16 float temp %allot
 347     src dst float-offset STFD ;
 348
 349 M:: ppc %unbox-any-c-ptr ( dst src temp -- )
 350     [
 351         { "is-byte-array" "end" "start" } [ define-label ] each
 352         ! Address is computed in dst
 353         0 dst LI
 354         ! Load object into scratch-reg
 355         scratch-reg src MR
 356         ! We come back here with displaced aliens
 357         "start" resolve-label
 358         ! Is the object f?
 359         0 scratch-reg \ f tag-number CMPI
 360         ! If so, done
 361         "end" get BEQ
 362         ! Is the object an alien?
 363         0 scratch-reg header-offset LWZ
 364         0 0 alien type-number tag-fixnum CMPI
 365         "is-byte-array" get BNE
 366         ! If so, load the offset
 367         0 scratch-reg alien-offset LWZ
 368         ! Add it to address being computed
 369         dst dst 0 ADD
 370         ! Now recurse on the underlying alien
 371         scratch-reg scratch-reg underlying-alien-offset LWZ
 372         "start" get B
 373         "is-byte-array" resolve-label
 374         ! Add byte array address to address being computed
 375         dst dst scratch-reg ADD
 376         ! Add an offset to start of byte array's data area
 377         dst dst byte-array-offset ADDI
 378         "end" resolve-label
 379     ] with-scope ;
 380
 381 : alien@ ( n -- n' ) cells object tag-number - ;
 382
 383 M:: ppc %box-alien ( dst src temp -- )
 384     [
 385         "f" define-label
 386         dst \ f tag-number %load-immediate
 387         0 src 0 CMPI
 388         "f" get BEQ
 389         dst 4 cells alien temp %allot
 390         ! Store offset
 391         src dst 3 alien@ STW
 392         ! Store expired slot
 393         temp \ f tag-number %load-immediate
 394         temp dst 1 alien@ STW
 395         ! Store underlying-alien slot
 396         temp dst 2 alien@ STW
 397         "f" resolve-label
 398     ] with-scope ;
 399
 400 M: ppc %alien-unsigned-1 0 LBZ ;
 401 M: ppc %alien-unsigned-2 0 LHZ ;
 402
 403 M: ppc %alien-signed-1 dupd 0 LBZ dup EXTSB ;
 404 M: ppc %alien-signed-2 0 LHA ;
 405
 406 M: ppc %alien-cell 0 LWZ ;
 407
 408 M: ppc %alien-float 0 LFS ;
 409 M: ppc %alien-double 0 LFD ;
 410
 411 M: ppc %set-alien-integer-1 swap 0 STB ;
 412 M: ppc %set-alien-integer-2 swap 0 STH ;
 413
 414 M: ppc %set-alien-cell swap 0 STW ;
 415
 416 M: ppc %set-alien-float swap 0 STFS ;
 417 M: ppc %set-alien-double swap 0 STFD ;
 418
 419 : load-zone-ptr ( reg -- )
 420     "nursery" f %alien-global ;
 421
 422 : load-allot-ptr ( nursery-ptr allot-ptr -- )
 423     [ drop load-zone-ptr ] [ swap 4 LWZ ] 2bi ;
 424
 425 :: inc-allot-ptr ( nursery-ptr allot-ptr n -- )
 426     scratch-reg allot-ptr n 8 align ADDI
 427     scratch-reg nursery-ptr 4 STW ;
 428
 429 :: store-header ( dst class -- )
 430     class type-number tag-fixnum scratch-reg LI
 431     scratch-reg dst 0 STW ;
 432
 433 : store-tagged ( dst tag -- )
 434     dupd tag-number ORI ;
 435
 436 M:: ppc %allot ( dst size class nursery-ptr -- )
 437     nursery-ptr dst load-allot-ptr
 438     nursery-ptr dst size inc-allot-ptr
 439     dst class store-header
 440     dst class store-tagged ;
 441
 442 : load-cards-offset ( dst -- )
 443     [ "cards_offset" f %alien-global ] [ dup 0 LWZ ] bi ;
 444
 445 : load-decks-offset ( dst -- )
 446     [ "decks_offset" f %alien-global ] [ dup 0 LWZ ] bi  ;
 447
 448 M:: ppc %write-barrier ( src card# table -- )
 449     card-mark scratch-reg LI
 450
 451     ! Mark the card
 452     table load-cards-offset
 453     src card# card-bits SRWI
 454     table scratch-reg card# STBX
 455
 456     ! Mark the card deck
 457     table load-decks-offset
 458     src card# deck-bits SRWI
 459     table scratch-reg card# STBX ;
 460
 461 M: ppc %gc
 462     "end" define-label
 463     12 load-zone-ptr
 464     11 12 cell LWZ ! nursery.here -> r11
 465     12 12 3 cells LWZ ! nursery.end -> r12
 466     11 11 1024 ADDI ! add ALLOT_BUFFER_ZONE to here
 467     11 0 12 CMP ! is here >= end?
 468     "end" get BLE
 469     %prepare-alien-invoke
 470     "minor_gc" f %alien-invoke
 471     "end" resolve-label ;
 472
 473 M: ppc %prologue ( n -- )
 474     0 11 LOAD32 rc-absolute-ppc-2/2 rel-this
 475     0 MFLR
 476     {
 477         [ [ 1 1 ] dip neg ADDI ]
 478         [ [ 11 1 ] dip xt-save STW ]
 479         [ 11 LI ]
 480         [ [ 11 1 ] dip next-save STW ]
 481         [ [ 0 1 ] dip lr-save + STW ]
 482     } cleave ;
 483
 484 M: ppc %epilogue ( n -- )
 485     #! At the end of each word that calls a subroutine, we store
 486     #! the previous link register value in r0 by popping it off
 487     #! the stack, set the link register to the contents of r0,
 488     #! and jump to the link register.
 489     [ [ 0 1 ] dip lr-save + LWZ ]
 490     [ [ 1 1 ] dip ADDI ] bi
 491     0 MTLR ;
 492
 493 :: (%boolean) ( dst temp word -- )
 494     "end" define-label
 495     dst \ f tag-number %load-immediate
 496     "end" get word execute
 497     dst \ t %load-reference
 498     "end" get resolve-label ; inline
 499
 500 : %boolean ( dst temp cc -- )
 501     negate-cc {
 502         { cc< [ \ BLT (%boolean) ] }
 503         { cc<= [ \ BLE (%boolean) ] }
 504         { cc> [ \ BGT (%boolean) ] }
 505         { cc>= [ \ BGE (%boolean) ] }
 506         { cc= [ \ BEQ (%boolean) ] }
 507         { cc/= [ \ BNE (%boolean) ] }
 508     } case ;
 509
 510 : (%compare) ( src1 src2 -- ) [ 0 ] dip CMP ; inline
 511 : (%compare-imm) ( src1 src2 -- ) [ 0 ] 2dip CMPI ; inline
 512 : (%compare-float) ( src1 src2 -- ) [ 0 ] dip FCMPU ; inline
 513
 514 M: ppc %compare (%compare) %boolean ;
 515 M: ppc %compare-imm (%compare-imm) %boolean ;
 516 M: ppc %compare-float (%compare-float) %boolean ;
 517
 518 : %branch ( label cc -- )
 519     {
 520         { cc< [ BLT ] }
 521         { cc<= [ BLE ] }
 522         { cc> [ BGT ] }
 523         { cc>= [ BGE ] }
 524         { cc= [ BEQ ] }
 525         { cc/= [ BNE ] }
 526     } case ;
 527
 528 M: ppc %compare-branch (%compare) %branch ;
 529 M: ppc %compare-imm-branch (%compare-imm) %branch ;
 530 M: ppc %compare-float-branch (%compare-float) %branch ;
 531
 532 M: ppc %spill-integer ( src n -- ) spill-integer@ 1 swap STW ;
 533 M: ppc %reload-integer ( dst n -- ) spill-integer@ 1 swap LWZ ;
 534
 535 M: ppc %spill-float ( src n -- ) spill-float@ 1 swap STFD ;
 536 M: ppc %reload-float ( dst n -- ) spill-float@ 1 swap LFD ;
 537
 538 M: ppc %loop-entry ;
 539
 540 M: int-regs return-reg drop 3 ;
 541 M: int-regs param-regs drop { 3 4 5 6 7 8 9 10 } ;
 542 M: float-regs return-reg drop 1 ;
 543
 544 M: int-regs %save-param-reg drop 1 rot local@ STW ;
 545 M: int-regs %load-param-reg drop 1 rot local@ LWZ ;
 546
 547 GENERIC: STF ( src dst off reg-class -- )
 548
 549 M: single-float-regs STF drop STFS ;
 550 M: double-float-regs STF drop STFD ;
 551
 552 M: float-regs %save-param-reg [ 1 rot local@ ] dip STF ;
 553
 554 GENERIC: LF ( dst src off reg-class -- )
 555
 556 M: single-float-regs LF drop LFS ;
 557 M: double-float-regs LF drop LFD ;
 558
 559 M: float-regs %load-param-reg [ 1 rot local@ ] dip LF ;
 560
 561 M: stack-params %load-param-reg ( stack reg reg-class -- )
 562     drop [ 0 1 rot local@ LWZ 0 1 ] dip param@ STW ;
 563
 564 : next-param@ ( n -- x ) param@ stack-frame get total-size>> + ;
 565
 566 M: stack-params %save-param-reg ( stack reg reg-class -- )
 567     #! Funky. Read the parameter from the caller's stack frame.
 568     #! This word is used in callbacks
 569     drop
 570     [ 0 1 ] dip next-param@ LWZ
 571     [ 0 1 ] dip local@ STW ;
 572
 573 M: ppc %prepare-unbox ( -- )
 574     ! First parameter is top of stack
 575     3 ds-reg 0 LWZ
 576     ds-reg dup cell SUBI ;
 577
 578 M: ppc %unbox ( n reg-class func -- )
 579     ! Value must be in r3
 580     ! Call the unboxer
 581     f %alien-invoke
 582     ! Store the return value on the C stack
 583     over [ [ return-reg ] keep %save-param-reg ] [ 2drop ] if ;
 584
 585 M: ppc %unbox-long-long ( n func -- )
 586     ! Value must be in r3:r4
 587     ! Call the unboxer
 588     f %alien-invoke
 589     ! Store the return value on the C stack
 590     [
 591         [ [ 3 1 ] dip local@ STW ]
 592         [ [ 4 1 ] dip cell + local@ STW ] bi
 593     ] when* ;
 594
 595 M: ppc %unbox-large-struct ( n c-type -- )
 596     ! Value must be in r3
 597     ! Compute destination address and load struct size
 598     [ [ 4 1 ] dip local@ ADDI ] [ heap-size 5 LI ] bi*
 599     ! Call the function
 600     "to_value_struct" f %alien-invoke ;
 601
 602 M: ppc %box ( n reg-class func -- )
 603     ! If the source is a stack location, load it into freg #0.
 604     ! If the source is f, then we assume the value is already in
 605     ! freg #0.
 606     [ over [ 0 over param-reg swap %load-param-reg ] [ 2drop ] if ] dip
 607     f %alien-invoke ;
 608
 609 M: ppc %box-long-long ( n func -- )
 610     [
 611         [
 612             [ [ 3 1 ] dip local@ LWZ ]
 613             [ [ 4 1 ] dip cell + local@ LWZ ] bi
 614         ] when*
 615     ] dip f %alien-invoke ;
 616
 617 : struct-return@ ( n -- n )
 618     [ stack-frame get params>> ] unless* local@ ;
 619
 620 M: ppc %prepare-box-struct ( -- )
 621     #! Compute target address for value struct return
 622     3 1 f struct-return@ ADDI
 623     3 1 0 local@ STW ;
 624
 625 M: ppc %box-large-struct ( n c-type -- )
 626     ! If n = f, then we're boxing a returned struct
 627     ! Compute destination address and load struct size
 628     [ [ 3 1 ] dip struct-return@ ADDI ] [ heap-size 4 LI ] bi*
 629     ! Call the function
 630     "box_value_struct" f %alien-invoke ;
 631
 632 M: ppc %prepare-alien-invoke
 633     #! Save Factor stack pointers in case the C code calls a
 634     #! callback which does a GC, which must reliably trace
 635     #! all roots.
 636     scratch-reg "stack_chain" f %alien-global
 637     scratch-reg scratch-reg 0 LWZ
 638     1 scratch-reg 0 STW
 639     ds-reg scratch-reg 8 STW
 640     rs-reg scratch-reg 12 STW ;
 641
 642 M: ppc %alien-invoke ( symbol dll -- )
 643     [ 11 ] 2dip %alien-global 11 MTLR BLRL ;
 644
 645 M: ppc %alien-callback ( quot -- )
 646     3 swap %load-reference "c_to_factor" f %alien-invoke ;
 647
 648 M: ppc %prepare-alien-indirect ( -- )
 649     "unbox_alien" f %alien-invoke
 650     13 3 MR ;
 651
 652 M: ppc %alien-indirect ( -- )
 653     13 MTLR BLRL ;
 654
 655 M: ppc %callback-value ( ctype -- )
 656     ! Save top of data stack
 657     3 ds-reg 0 LWZ
 658     3 1 0 local@ STW
 659     ! Restore data/call/retain stacks
 660     "unnest_stacks" f %alien-invoke
 661     ! Restore top of data stack
 662     3 1 0 local@ LWZ
 663     ! Unbox former top of data stack to return registers
 664     unbox-return ;
 665
 666 M: ppc small-enough? ( n -- ? ) -32768 32767 between? ;
 667
 668 M: ppc return-struct-in-registers? ( c-type -- ? )
 669     c-type return-in-registers?>> ;
 670
 671 M: ppc %box-small-struct ( c-type -- )
 672     #! Box a <= 16-byte struct returned in r3:r4:r5:r6
 673     heap-size 7 LI
 674     "box_medium_struct" f %alien-invoke ;
 675
 676 : %unbox-struct-1 ( -- )
 677     ! Alien must be in r3.
 678     "alien_offset" f %alien-invoke
 679     3 3 0 LWZ ;
 680
 681 : %unbox-struct-2 ( -- )
 682     ! Alien must be in r3.
 683     "alien_offset" f %alien-invoke
 684     4 3 4 LWZ
 685     3 3 0 LWZ ;
 686
 687 : %unbox-struct-4 ( -- )
 688     ! Alien must be in r3.
 689     "alien_offset" f %alien-invoke
 690     6 3 12 LWZ
 691     5 3 8 LWZ
 692     4 3 4 LWZ
 693     3 3 0 LWZ ;
 694
 695 M: ppc %unbox-small-struct ( size -- )
 696     #! Alien must be in EAX.
 697     heap-size cell align cell /i {
 698         { 1 [ %unbox-struct-1 ] }
 699         { 2 [ %unbox-struct-2 ] }
 700         { 4 [ %unbox-struct-4 ] }
 701     } case ;
 702
 703 USE: vocabs.loader
 704
 705 {
 706     { [ os macosx? ] [ "cpu.ppc.macosx" require ] }
 707     { [ os linux? ] [ "cpu.ppc.linux" require ] }
 708 } cond
 709
 710 "complex-double" c-type t >>return-in-registers? drop