basis/cpu/x86/32/32.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: locals alien alien.c-types alien.libraries alien.syntax
   4 arrays kernel fry math namespaces sequences system layouts io
   5 vocabs.loader accessors init classes.struct combinators make
   6 words compiler.constants compiler.codegen.fixup
   7 compiler.cfg.instructions compiler.cfg.builder
   8 compiler.cfg.builder.alien.boxing compiler.cfg.intrinsics
   9 compiler.cfg.stack-frame cpu.x86.assembler
  10 cpu.x86.assembler.operands cpu.x86 cpu.architecture vm vocabs ;
  11 FROM: layouts => cell ;
  12 IN: cpu.x86.32
  13
  14 : x86-float-regs ( -- seq )
  15     "cpu.x86.sse" vocab
  16     { XMM0 XMM1 XMM2 XMM3 XMM4 XMM5 XMM6 XMM7 }
  17     { ST0 ST1 ST2 ST3 ST4 ST5 ST6 }
  18     ? ;
  19
  20 M: x86.32 machine-registers
  21     { int-regs { EAX ECX EDX EBP EBX } }
  22     float-regs x86-float-regs 2array
  23     2array ;
  24
  25 M: x86.32 ds-reg ESI ;
  26 M: x86.32 rs-reg EDI ;
  27 M: x86.32 stack-reg ESP ;
  28 M: x86.32 frame-reg EBP ;
  29
  30 M: x86.32 immediate-comparand? ( obj -- ? ) drop t ;
  31
  32 M:: x86.32 %load-vector ( dst val rep -- )
  33     dst 0 [] rep copy-memory* val rc-absolute rel-binary-literal ;
  34
  35 M: x86.32 %mov-vm-ptr ( reg -- )
  36     0 MOV 0 rc-absolute-cell rel-vm ;
  37
  38 M: x86.32 %vm-field ( dst field -- )
  39     [ 0 [] MOV ] dip rc-absolute-cell rel-vm ;
  40
  41 M: x86.32 %set-vm-field ( dst field -- )
  42     [ 0 [] swap MOV ] dip rc-absolute-cell rel-vm ;
  43
  44 M: x86.32 %vm-field-ptr ( dst field -- )
  45     [ 0 MOV ] dip rc-absolute-cell rel-vm ;
  46
  47 M: x86.32 %mark-card
  48     drop HEX: ffffffff [+] card-mark <byte> MOV
  49     building get pop
  50     rc-absolute-cell rel-cards-offset
  51     building get push ;
  52
  53 M: x86.32 %mark-deck
  54     drop HEX: ffffffff [+] card-mark <byte> MOV
  55     building get pop
  56     rc-absolute-cell rel-decks-offset
  57     building get push ;
  58
  59 M: x86.32 pic-tail-reg EDX ;
  60
  61 M: x86.32 reserved-stack-space 0 ;
  62
  63 M: x86.32 vm-stack-space 16 ;
  64
  65 : save-vm-ptr ( n -- )
  66     stack@ 0 MOV 0 rc-absolute-cell rel-vm ;
  67
  68 M: x86.32 return-struct-in-registers? ( c-type -- ? )
  69     c-type
  70     [ return-in-registers?>> ]
  71     [ heap-size { 1 2 4 8 } member? ] bi
  72     os { linux netbsd solaris } member? not
  73     and or ;
  74
  75 ! On x86, parameters are usually never passed in registers,
  76 ! except with Microsoft's "thiscall" and "fastcall" abis
  77 M: x86.32 param-regs
  78     {
  79         { thiscall [ { { int-regs { ECX } } { float-regs { } } } ] }
  80         { fastcall [ { { int-regs { ECX EDX } } { float-regs { } } } ] }
  81         [ drop { { int-regs { } } { float-regs { } } } ]
  82     } case ;
  83
  84 ! Need a fake return-reg for floats
  85 M: x86.32 return-regs
  86     {
  87         { int-regs { EAX EDX } }
  88         { float-regs { ST0 } }
  89     } ;
  90
  91 M: x86.32 %prologue ( n -- )
  92     dup PUSH
  93     0 PUSH rc-absolute-cell rel-this
  94     3 cells - decr-stack-reg ;
  95
  96 M: x86.32 %prepare-jump
  97     pic-tail-reg 0 MOV xt-tail-pic-offset rc-absolute-cell rel-here ;
  98
  99 M: x86.32 %load-stack-param ( dst rep n -- )
 100     next-stack@ swap pick register? [ %copy ] [
 101         {
 102             { int-rep [ [ EAX ] dip MOV ?spill-slot EAX MOV ] }
 103             { float-rep [ FLDS ?spill-slot FSTPS ] }
 104             { double-rep [ FLDL ?spill-slot FSTPL ] }
 105         } case
 106     ] if ;
 107
 108 M: x86.32 %store-stack-param ( src rep n -- )
 109     stack@ swap pick register? [ [ swap ] dip %copy ] [
 110         {
 111             { int-rep [ [ [ EAX ] dip ?spill-slot MOV ] [ EAX MOV ] bi* ] }
 112             { float-rep [ [ ?spill-slot FLDS ] [ FSTPS ] bi* ] }
 113             { double-rep [ [ ?spill-slot FLDL ] [ FSTPL ] bi* ] }
 114         } case
 115     ] if ;
 116
 117 :: load-float-return ( dst x87-insn rep -- )
 118     dst register? [
 119         ESP 4 SUB
 120         ESP [] x87-insn execute
 121         dst ESP [] rep %copy
 122         ESP 4 ADD
 123     ] [
 124         dst ?spill-slot x87-insn execute
 125     ] if ; inline
 126
 127 M: x86.32 %load-reg-param ( vreg rep reg -- )
 128     swap {
 129         { int-rep [ int-rep %copy ] }
 130         { float-rep [ drop \ FSTPS float-rep load-float-return ] }
 131         { double-rep [ drop \ FSTPL double-rep load-float-return ] }
 132     } case ;
 133
 134 :: store-float-return ( src x87-insn rep -- )
 135     src register? [
 136         ESP 4 SUB
 137         ESP [] src rep %copy
 138         ESP [] x87-insn execute
 139         ESP 4 ADD
 140     ] [
 141         src ?spill-slot x87-insn execute
 142     ] if ; inline
 143
 144 M: x86.32 %store-reg-param ( vreg rep reg -- )
 145     swap {
 146         { int-rep [ swap int-rep %copy ] }
 147         { float-rep [ drop \ FLDS float-rep store-float-return ] }
 148         { double-rep [ drop \ FLDL double-rep store-float-return ] }
 149     } case ;
 150
 151 :: call-unbox-func ( src func -- )
 152     EAX src tagged-rep %copy
 153     4 save-vm-ptr
 154     0 stack@ EAX MOV
 155     func f f %c-invoke ;
 156
 157 M:: x86.32 %unbox ( dst src func rep -- )
 158     src func call-unbox-func
 159     dst rep %load-return ;
 160
 161 M:: x86.32 %unbox-long-long ( dst1 dst2 src func -- )
 162     src int-rep 0 %store-stack-param
 163     4 save-vm-ptr
 164     func f f %c-invoke
 165     dst1 EAX int-rep %copy
 166     dst2 EDX int-rep %copy ;
 167
 168 M:: x86.32 %box ( dst src func rep gc-map -- )
 169     src rep 0 %store-stack-param
 170     rep rep-size save-vm-ptr
 171     func f gc-map %c-invoke
 172     dst EAX tagged-rep %copy ;
 173
 174 M:: x86.32 %box-long-long ( dst src1 src2 func gc-map -- )
 175     src1 int-rep 0 %store-stack-param
 176     src2 int-rep 4 %store-stack-param
 177     8 save-vm-ptr
 178     func f gc-map %c-invoke
 179     dst EAX tagged-rep %copy ;
 180
 181 M: x86.32 %c-invoke
 182     [ 0 CALL rc-relative rel-dlsym ] dip gc-map-here ;
 183
 184 M: x86.32 %begin-callback ( -- )
 185     0 save-vm-ptr
 186     4 stack@ 0 MOV
 187     "begin_callback" f f %c-invoke ;
 188
 189 M: x86.32 %alien-callback ( quot -- )
 190     [ EAX ] dip %load-reference
 191     EAX quot-entry-point-offset [+] CALL ;
 192
 193 M: x86.32 %end-callback ( -- )
 194     0 save-vm-ptr
 195     "end_callback" f f %c-invoke ;
 196
 197 M:: x86.32 %unary-float-function ( dst src func -- )
 198     src double-rep 0 %store-stack-param
 199     func "libm" load-library f %c-invoke
 200     dst double-rep %load-return ;
 201
 202 M:: x86.32 %binary-float-function ( dst src1 src2 func -- )
 203     src1 double-rep 0 %store-stack-param
 204     src2 double-rep 8 %store-stack-param
 205     func "libm" load-library f %c-invoke
 206     dst double-rep %load-return ;
 207
 208 : funny-large-struct-return? ( return abi -- ? )
 209     #! MINGW ABI incompatibility disaster
 210     [ large-struct? ] [ mingw eq? os windows? not or ] bi* and ;
 211
 212 M:: x86.32 stack-cleanup ( stack-size return abi -- n )
 213     #! a) Functions which are stdcall/fastcall/thiscall have to
 214     #! clean up the caller's stack frame.
 215     #! b) Functions returning large structs on MINGW have to
 216     #! fix ESP.
 217     {
 218         { [ abi callee-cleanup? ] [ stack-size ] }
 219         { [ return abi funny-large-struct-return? ] [ 4 ] }
 220         [ 0 ]
 221     } cond ;
 222
 223 M: x86.32 %cleanup ( n -- )
 224     [ ESP swap SUB ] unless-zero ;
 225
 226 M: x86.32 dummy-stack-params? f ;
 227
 228 M: x86.32 dummy-int-params? f ;
 229
 230 M: x86.32 dummy-fp-params? f ;
 231
 232 M: x86.32 long-long-on-stack? t ;
 233
 234 M: x86.32 float-on-stack? t ;
 235
 236 M: x86.32 flatten-struct-type
 237     call-next-method [ first t 2array ] map ;
 238
 239 M: x86.32 struct-return-on-stack? os linux? not ;
 240
 241 check-sse