basis/cpu/x86/32/32.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: locals alien alien.c-types alien.libraries alien.syntax
   4 arrays kernel fry math namespaces sequences system layouts io
   5 vocabs.loader accessors init classes.struct combinators
   6 make words compiler.constants compiler.codegen.fixup
   7 compiler.cfg.instructions compiler.cfg.builder compiler.cfg.intrinsics
   8 compiler.cfg.stack-frame cpu.x86.assembler cpu.x86.assembler.operands
   9 cpu.x86 cpu.architecture vm ;
  10 FROM: layouts => cell ;
  11 IN: cpu.x86.32
  12
  13 M: x86.32 machine-registers
  14     {
  15         { int-regs { EAX ECX EDX EBP EBX } }
  16         { float-regs { XMM0 XMM1 XMM2 XMM3 XMM4 XMM5 XMM6 XMM7 } }
  17     } ;
  18
  19 M: x86.32 ds-reg ESI ;
  20 M: x86.32 rs-reg EDI ;
  21 M: x86.32 stack-reg ESP ;
  22 M: x86.32 frame-reg EBP ;
  23 M: x86.32 temp-reg ECX ;
  24
  25 M: x86.32 immediate-comparand? ( obj -- ? ) drop t ;
  26
  27 M:: x86.32 %load-vector ( dst val rep -- )
  28     dst 0 [] rep copy-memory* val rc-absolute rel-binary-literal ;
  29
  30 M: x86.32 %load-float ( dst val -- )
  31     <float> float-rep %load-vector ;
  32
  33 M: x86.32 %load-double ( dst val -- )
  34     <double> double-rep %load-vector ;
  35
  36 M: x86.32 %mov-vm-ptr ( reg -- )
  37     0 MOV 0 rc-absolute-cell rel-vm ;
  38
  39 M: x86.32 %vm-field ( dst field -- )
  40     [ 0 [] MOV ] dip rc-absolute-cell rel-vm ;
  41
  42 M: x86.32 %set-vm-field ( dst field -- )
  43     [ 0 [] swap MOV ] dip rc-absolute-cell rel-vm ;
  44
  45 M: x86.32 %vm-field-ptr ( dst field -- )
  46     [ 0 MOV ] dip rc-absolute-cell rel-vm ;
  47
  48 : local@ ( n -- op )
  49     stack-frame get extra-stack-space dup 16 assert= + stack@ ;
  50
  51 M: x86.32 extra-stack-space calls-vm?>> 16 0 ? ;
  52
  53 M: x86.32 %mark-card
  54     drop HEX: ffffffff [+] card-mark <byte> MOV
  55     building get pop
  56     rc-absolute-cell rel-cards-offset
  57     building get push ;
  58
  59 M: x86.32 %mark-deck
  60     drop HEX: ffffffff [+] card-mark <byte> MOV
  61     building get pop
  62     rc-absolute-cell rel-decks-offset
  63     building get push ;
  64
  65 M:: x86.32 %dispatch ( src temp -- )
  66     ! Load jump table base.
  67     temp src HEX: ffffffff [+] LEA
  68     building get length :> start
  69     0 rc-absolute-cell rel-here
  70     ! Go
  71     temp HEX: 7f [+] JMP
  72     building get length :> end
  73     ! Fix up the displacement above
  74     cell alignment
  75     [ end start - + building get dup pop* push ]
  76     [ (align-code) ]
  77     bi ;
  78
  79 M: x86.32 pic-tail-reg EDX ;
  80
  81 M: x86.32 reserved-stack-space 0 ;
  82
  83 M: x86.32 %alien-invoke 0 CALL rc-relative rel-dlsym ;
  84
  85 : save-vm-ptr ( n -- )
  86     stack@ 0 MOV 0 rc-absolute-cell rel-vm ;
  87
  88 M: x86.32 return-struct-in-registers? ( c-type -- ? )
  89     c-type
  90     [ return-in-registers?>> ]
  91     [ heap-size { 1 2 4 8 } member? ] bi
  92     os { linux netbsd solaris } member? not
  93     and or ;
  94
  95 ! On x86, parameters are usually never passed in registers,
  96 ! except with Microsoft's "thiscall" and "fastcall" abis
  97 M: int-regs return-reg drop EAX ;
  98 M: float-regs param-regs 2drop { } ;
  99
 100 M: int-regs param-regs
 101     nip {
 102         { thiscall [ { ECX } ] }
 103         { fastcall [ { ECX EDX } ] }
 104         [ drop { } ]
 105     } case ;
 106
 107 GENERIC: load-return-reg ( src rep -- )
 108 GENERIC: store-return-reg ( dst rep -- )
 109
 110 M: stack-params load-return-reg drop EAX swap MOV ;
 111 M: stack-params store-return-reg drop EAX MOV ;
 112
 113 M: int-rep load-return-reg drop EAX swap MOV ;
 114 M: int-rep store-return-reg drop EAX MOV ;
 115
 116 :: load-float-return ( src x87-insn sse-insn -- )
 117     src register? [
 118         ESP 4 SUB
 119         ESP [] src sse-insn execute
 120         ESP [] x87-insn execute
 121         ESP 4 ADD
 122     ] [
 123         src x87-insn execute
 124     ] if ; inline
 125
 126 :: store-float-return ( dst x87-insn sse-insn -- )
 127     dst register? [
 128         ESP 4 SUB
 129         ESP [] x87-insn execute
 130         dst ESP [] sse-insn execute
 131         ESP 4 ADD
 132     ] [
 133         dst x87-insn execute
 134     ] if ; inline
 135
 136 M: float-rep load-return-reg
 137     drop \ FLDS \ MOVSS load-float-return ;
 138
 139 M: float-rep store-return-reg
 140     drop \ FSTPS \ MOVSS store-float-return ;
 141
 142 M: double-rep load-return-reg
 143     drop \ FLDL \ MOVSD load-float-return ;
 144
 145 M: double-rep store-return-reg
 146     drop \ FSTPL \ MOVSD store-float-return ;
 147
 148 M: x86.32 %prologue ( n -- )
 149     dup PUSH
 150     0 PUSH rc-absolute-cell rel-this
 151     3 cells - decr-stack-reg ;
 152
 153 M: x86.32 %prepare-jump
 154     pic-tail-reg 0 MOV xt-tail-pic-offset rc-absolute-cell rel-here ;
 155
 156 :: call-unbox-func ( src func -- )
 157     EAX src tagged-rep %copy
 158     4 save-vm-ptr
 159     0 stack@ EAX MOV
 160     func f %alien-invoke ;
 161
 162 M:: x86.32 %unbox ( dst src func rep -- )
 163     src func call-unbox-func
 164     dst ?spill-slot rep store-return-reg ;
 165
 166 M:: x86.32 %store-return ( src rep -- )
 167     src ?spill-slot rep load-return-reg ;
 168
 169 M:: x86.32 %store-long-long-return ( src1 src2 -- )
 170     src2 EAX = [ src1 src2 XCHG src2 src1 ] [ src1 src2 ] if :> ( src1 src2 )
 171     EAX src1 int-rep %copy
 172     EDX src2 int-rep %copy ;
 173
 174 M:: x86.32 %store-struct-return ( src c-type -- )
 175     EAX src int-rep %copy
 176     EDX EAX 4 [+] MOV
 177     EAX EAX [] MOV ;
 178
 179 M: stack-params copy-register*
 180     drop
 181     {
 182         { [ dup  integer? ] [ EAX swap next-stack@ MOV  EAX MOV ] }
 183         { [ over integer? ] [ EAX swap MOV              param@ EAX MOV ] }
 184     } cond ;
 185
 186 M: x86.32 %save-param-reg [ local@ ] 2dip %copy ;
 187
 188 : (%box) ( n rep -- )
 189     #! If n is f, push the return register onto the stack; we
 190     #! are boxing a return value of a C function. If n is an
 191     #! integer, push [ESP+n] on the stack; we are boxing a
 192     #! parameter being passed to a callback from C.
 193     over [ [ local@ ] dip load-return-reg ] [ 2drop ] if ;
 194
 195 M:: x86.32 %box ( dst n rep func -- )
 196     n rep (%box)
 197     rep rep-size save-vm-ptr
 198     0 stack@ rep store-return-reg
 199     func f %alien-invoke
 200     dst EAX tagged-rep %copy ;
 201
 202 : (%box-long-long) ( n -- )
 203     [
 204         [ EDX swap next-stack@ MOV ]
 205         [ EAX swap cell - next-stack@ MOV ] bi
 206     ] when* ;
 207
 208 M:: x86.32 %box-long-long ( dst n func -- )
 209     n (%box-long-long)
 210     8 save-vm-ptr
 211     4 stack@ EDX MOV
 212     0 stack@ EAX MOV
 213     func f %alien-invoke
 214     dst EAX tagged-rep %copy ;
 215
 216 M: x86.32 struct-return@ ( n -- operand )
 217     [ next-stack@ ] [ stack-frame get params>> local@ ] if* ;
 218
 219 M:: x86.32 %box-large-struct ( dst n c-type -- )
 220     EDX n struct-return@ LEA
 221     8 save-vm-ptr
 222     4 stack@ c-type heap-size MOV
 223     0 stack@ EDX MOV
 224     "from_value_struct" f %alien-invoke
 225     dst EAX tagged-rep %copy ;
 226
 227 M:: x86.32 %box-small-struct ( dst c-type -- )
 228     #! Box a <= 8-byte struct returned in EAX:EDX. OS X only.
 229     12 save-vm-ptr
 230     8 stack@ c-type heap-size MOV
 231     4 stack@ EDX MOV
 232     0 stack@ EAX MOV
 233     "from_small_struct" f %alien-invoke
 234     dst EAX tagged-rep %copy ;
 235
 236 M: x86.32 %begin-callback ( -- )
 237     0 save-vm-ptr
 238     4 stack@ 0 MOV
 239     "begin_callback" f %alien-invoke ;
 240
 241 M: x86.32 %alien-callback ( quot -- )
 242     [ EAX ] dip %load-reference
 243     EAX quot-entry-point-offset [+] CALL ;
 244
 245 M: x86.32 %end-callback ( -- )
 246     0 save-vm-ptr
 247     "end_callback" f %alien-invoke ;
 248
 249 GENERIC: float-function-param ( stack-slot dst src -- )
 250
 251 M:: spill-slot float-function-param ( stack-slot dst src -- )
 252     ! We can clobber dst here since its going to contain the
 253     ! final result
 254     dst src double-rep %copy
 255     stack-slot dst double-rep %copy ;
 256
 257 M: register float-function-param
 258     nip double-rep %copy ;
 259
 260 : float-function-return ( reg -- )
 261     ESP [] FSTPL
 262     ESP [] MOVSD
 263     ESP 16 ADD ;
 264
 265 M:: x86.32 %unary-float-function ( dst src func -- )
 266     ESP -16 [+] dst src float-function-param
 267     ESP 16 SUB
 268     func "libm" load-library %alien-invoke
 269     dst float-function-return ;
 270
 271 M:: x86.32 %binary-float-function ( dst src1 src2 func -- )
 272     ESP -16 [+] dst src1 float-function-param
 273     ESP  -8 [+] dst src2 float-function-param
 274     ESP 16 SUB
 275     func "libm" load-library %alien-invoke
 276     dst float-function-return ;
 277
 278 : funny-large-struct-return? ( return abi -- ? )
 279     #! MINGW ABI incompatibility disaster
 280     [ large-struct? ] [ mingw eq? os windows? not or ] bi* and ;
 281
 282 M:: x86.32 stack-cleanup ( stack-size return abi -- n )
 283     #! a) Functions which are stdcall/fastcall/thiscall have to
 284     #! clean up the caller's stack frame.
 285     #! b) Functions returning large structs on MINGW have to
 286     #! fix ESP.
 287     {
 288         { [ abi callee-cleanup? ] [ stack-size ] }
 289         { [ return abi funny-large-struct-return? ] [ 4 ] }
 290         [ 0 ]
 291     } cond ;
 292
 293 M: x86.32 %cleanup ( n -- )
 294     [ ESP swap SUB ] unless-zero ;
 295
 296 M:: x86.32 %call-gc ( gc-roots -- )
 297     4 save-vm-ptr
 298     0 stack@ gc-roots gc-root-offsets %load-reference
 299     "inline_gc" f %alien-invoke ;
 300
 301 M: x86.32 dummy-stack-params? f ;
 302
 303 M: x86.32 dummy-int-params? f ;
 304
 305 M: x86.32 dummy-fp-params? f ;
 306
 307 M: x86.32 long-long-on-stack? t ;
 308
 309 M: x86.32 float-on-stack? t ;
 310
 311 M: x86.32 flatten-struct-type
 312     stack-size cell /i { int-rep t } <repetition> ;
 313
 314 M: x86.32 struct-return-on-stack? os linux? not ;
 315
 316 check-sse