basis/cpu/x86/32/32.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: locals alien alien.c-types alien.libraries alien.syntax
   4 arrays kernel fry math namespaces sequences system layouts io
   5 vocabs.loader accessors init classes.struct combinators
   6 command-line make words compiler compiler.units
   7 compiler.constants compiler.alien compiler.codegen
   8 compiler.codegen.fixup compiler.cfg.instructions
   9 compiler.cfg.builder compiler.cfg.builder.alien
  10 compiler.cfg.intrinsics compiler.cfg.stack-frame
  11 cpu.x86.assembler cpu.x86.assembler.operands cpu.x86
  12 cpu.architecture vm ;
  13 FROM: layouts => cell ;
  14 IN: cpu.x86.32
  15
  16 M: x86.32 machine-registers
  17     {
  18         { int-regs { EAX ECX EDX EBP EBX } }
  19         { float-regs { XMM0 XMM1 XMM2 XMM3 XMM4 XMM5 XMM6 XMM7 } }
  20     } ;
  21
  22 M: x86.32 ds-reg ESI ;
  23 M: x86.32 rs-reg EDI ;
  24 M: x86.32 stack-reg ESP ;
  25 M: x86.32 frame-reg EBP ;
  26 M: x86.32 temp-reg ECX ;
  27
  28 M: x86.32 immediate-comparand? ( obj -- ? ) drop t ;
  29
  30 M:: x86.32 %load-vector ( dst val rep -- )
  31     dst 0 [] rep copy-memory* val rc-absolute rel-binary-literal ;
  32
  33 M: x86.32 %load-float ( dst val -- )
  34     <float> float-rep %load-vector ;
  35
  36 M: x86.32 %load-double ( dst val -- )
  37     <double> double-rep %load-vector ;
  38
  39 M: x86.32 %mov-vm-ptr ( reg -- )
  40     0 MOV 0 rc-absolute-cell rel-vm ;
  41
  42 M: x86.32 %vm-field ( dst field -- )
  43     [ 0 [] MOV ] dip rc-absolute-cell rel-vm ;
  44
  45 M: x86.32 %set-vm-field ( dst field -- )
  46     [ 0 [] swap MOV ] dip rc-absolute-cell rel-vm ;
  47
  48 M: x86.32 %vm-field-ptr ( dst field -- )
  49     [ 0 MOV ] dip rc-absolute-cell rel-vm ;
  50
  51 : local@ ( n -- op )
  52     stack-frame get extra-stack-space dup 16 assert= + stack@ ;
  53
  54 M: x86.32 extra-stack-space calls-vm?>> 16 0 ? ;
  55
  56 M: x86.32 %mark-card
  57     drop HEX: ffffffff [+] card-mark <byte> MOV
  58     building get pop
  59     rc-absolute-cell rel-cards-offset
  60     building get push ;
  61
  62 M: x86.32 %mark-deck
  63     drop HEX: ffffffff [+] card-mark <byte> MOV
  64     building get pop
  65     rc-absolute-cell rel-decks-offset
  66     building get push ;
  67
  68 M:: x86.32 %dispatch ( src temp -- )
  69     ! Load jump table base.
  70     temp src HEX: ffffffff [+] LEA
  71     building get length :> start
  72     0 rc-absolute-cell rel-here
  73     ! Go
  74     temp HEX: 7f [+] JMP
  75     building get length :> end
  76     ! Fix up the displacement above
  77     cell alignment
  78     [ end start - + building get dup pop* push ]
  79     [ (align-code) ]
  80     bi ;
  81
  82 M: x86.32 pic-tail-reg EDX ;
  83
  84 M: x86.32 reserved-stack-space 0 ;
  85
  86 M: x86.32 %alien-invoke 0 CALL rc-relative rel-dlsym ;
  87
  88 : save-vm-ptr ( n -- )
  89     stack@ 0 MOV 0 rc-absolute-cell rel-vm ;
  90
  91 M: x86.32 return-struct-in-registers? ( c-type -- ? )
  92     c-type
  93     [ return-in-registers?>> ]
  94     [ heap-size { 1 2 4 8 } member? ] bi
  95     os { linux netbsd solaris } member? not
  96     and or ;
  97
  98 ! On x86, parameters are usually never passed in registers,
  99 ! except with Microsoft's "thiscall" and "fastcall" abis
 100 M: int-regs return-reg drop EAX ;
 101 M: float-regs param-regs 2drop { } ;
 102
 103 M: int-regs param-regs
 104     nip {
 105         { thiscall [ { ECX } ] }
 106         { fastcall [ { ECX EDX } ] }
 107         [ drop { } ]
 108     } case ;
 109
 110 GENERIC: load-return-reg ( src rep -- )
 111 GENERIC: store-return-reg ( dst rep -- )
 112
 113 M: stack-params load-return-reg drop EAX swap MOV ;
 114 M: stack-params store-return-reg drop EAX MOV ;
 115
 116 M: int-rep load-return-reg drop EAX swap MOV ;
 117 M: int-rep store-return-reg drop EAX MOV ;
 118
 119 M: float-rep load-return-reg drop FLDS ;
 120 M: float-rep store-return-reg drop FSTPS ;
 121
 122 M: double-rep load-return-reg drop FLDL ;
 123 M: double-rep store-return-reg drop FSTPL ;
 124
 125 M: x86.32 %prologue ( n -- )
 126     dup PUSH
 127     0 PUSH rc-absolute-cell rel-this
 128     3 cells - decr-stack-reg ;
 129
 130 M: x86.32 %prepare-jump
 131     pic-tail-reg 0 MOV xt-tail-pic-offset rc-absolute-cell rel-here ;
 132
 133 :: call-unbox-func ( src func -- )
 134     EAX src tagged-rep %copy
 135     4 save-vm-ptr
 136     0 stack@ EAX MOV
 137     func f %alien-invoke ;
 138
 139 M:: x86.32 %unbox ( dst src func rep -- )
 140     src func call-unbox-func
 141     dst rep reg-class-of return-reg rep %copy ;
 142
 143 M:: x86.32 %store-long-long-return ( src1 src2 n func -- )
 144     src2 EAX = [ src1 src2 XCHG src2 src1 ] [ src1 src2 ] if :> ( src1 src2 )
 145     EAX src1 int-rep %copy
 146     EDX src2 int-rep %copy ;
 147
 148 M:: x86.32 %store-struct-return ( src c-type -- )
 149     EAX src int-rep %copy
 150     EDX EAX 4 [+] MOV
 151     EAX EAX [] MOV ;
 152
 153 M: stack-params copy-register*
 154     drop
 155     {
 156         { [ dup  integer? ] [ EAX swap next-stack@ MOV  EAX MOV ] }
 157         { [ over integer? ] [ EAX swap MOV              param@ EAX MOV ] }
 158     } cond ;
 159
 160 M: x86.32 %save-param-reg [ local@ ] 2dip %copy ;
 161
 162 : (%box) ( n rep -- )
 163     #! If n is f, push the return register onto the stack; we
 164     #! are boxing a return value of a C function. If n is an
 165     #! integer, push [ESP+n] on the stack; we are boxing a
 166     #! parameter being passed to a callback from C.
 167     over [ [ local@ ] dip load-return-reg ] [ 2drop ] if ;
 168
 169 M:: x86.32 %box ( dst n rep func -- )
 170     n rep (%box)
 171     rep rep-size save-vm-ptr
 172     0 stack@ rep store-return-reg
 173     func f %alien-invoke
 174     dst EAX tagged-rep %copy ;
 175
 176 : (%box-long-long) ( n -- )
 177     [
 178         [ EDX swap next-stack@ MOV ]
 179         [ EAX swap cell - next-stack@ MOV ] bi
 180     ] when* ;
 181
 182 M:: x86.32 %box-long-long ( dst n func -- )
 183     n (%box-long-long)
 184     8 save-vm-ptr
 185     4 stack@ EDX MOV
 186     0 stack@ EAX MOV
 187     func f %alien-invoke
 188     dst EAX tagged-rep %copy ;
 189
 190 M: x86.32 struct-return@ ( n -- operand )
 191     [ next-stack@ ] [ stack-frame get params>> local@ ] if* ;
 192
 193 M:: x86.32 %box-large-struct ( dst n c-type -- )
 194     EDX n struct-return@ LEA
 195     8 save-vm-ptr
 196     4 stack@ c-type heap-size MOV
 197     0 stack@ EDX MOV
 198     "from_value_struct" f %alien-invoke
 199     dst EAX tagged-rep %copy ;
 200
 201 M:: x86.32 %box-small-struct ( dst c-type -- )
 202     #! Box a <= 8-byte struct returned in EAX:EDX. OS X only.
 203     12 save-vm-ptr
 204     8 stack@ c-type heap-size MOV
 205     4 stack@ EDX MOV
 206     0 stack@ EAX MOV
 207     "from_small_struct" f %alien-invoke
 208     dst EAX tagged-rep %copy ;
 209
 210 M: x86.32 %begin-callback ( -- )
 211     0 save-vm-ptr
 212     4 stack@ 0 MOV
 213     "begin_callback" f %alien-invoke ;
 214
 215 M: x86.32 %alien-callback ( quot -- )
 216     [ EAX ] dip %load-reference
 217     EAX quot-entry-point-offset [+] CALL ;
 218
 219 M: x86.32 %end-callback ( -- )
 220     0 save-vm-ptr
 221     "end_callback" f %alien-invoke ;
 222
 223 GENERIC: float-function-param ( stack-slot dst src -- )
 224
 225 M:: spill-slot float-function-param ( stack-slot dst src -- )
 226     ! We can clobber dst here since its going to contain the
 227     ! final result
 228     dst src double-rep %copy
 229     stack-slot dst double-rep %copy ;
 230
 231 M: register float-function-param
 232     nip double-rep %copy ;
 233
 234 : float-function-return ( reg -- )
 235     ESP [] FSTPL
 236     ESP [] MOVSD
 237     ESP 16 ADD ;
 238
 239 M:: x86.32 %unary-float-function ( dst src func -- )
 240     ESP -16 [+] dst src float-function-param
 241     ESP 16 SUB
 242     func "libm" load-library %alien-invoke
 243     dst float-function-return ;
 244
 245 M:: x86.32 %binary-float-function ( dst src1 src2 func -- )
 246     ESP -16 [+] dst src1 float-function-param
 247     ESP  -8 [+] dst src2 float-function-param
 248     ESP 16 SUB
 249     func "libm" load-library %alien-invoke
 250     dst float-function-return ;
 251
 252 : funny-large-struct-return? ( params -- ? )
 253     #! MINGW ABI incompatibility disaster
 254     [ return>> large-struct? ]
 255     [ abi>> mingw eq? os windows? not or ]
 256     bi and ;
 257
 258 : stack-arg-size ( params -- n )
 259     dup abi>> '[
 260         alien-parameters flatten-c-types
 261         [ _ alloc-parameter 2drop ] each
 262         stack-params get
 263     ] with-param-regs ;
 264
 265 M: x86.32 stack-cleanup ( params -- n )
 266     #! a) Functions which are stdcall/fastcall/thiscall have to
 267     #! clean up the caller's stack frame.
 268     #! b) Functions returning large structs on MINGW have to
 269     #! fix ESP.
 270     {
 271         { [ dup abi>> callee-cleanup? ] [ stack-arg-size ] }
 272         { [ dup funny-large-struct-return? ] [ drop 4 ] }
 273         [ drop 0 ]
 274     } cond ;
 275
 276 M: x86.32 %cleanup ( n -- )
 277     [ ESP swap SUB ] unless-zero ;
 278
 279 M:: x86.32 %call-gc ( gc-roots -- )
 280     4 save-vm-ptr
 281     0 stack@ gc-roots gc-root-offsets %load-reference
 282     "inline_gc" f %alien-invoke ;
 283
 284 M: x86.32 dummy-stack-params? f ;
 285
 286 M: x86.32 dummy-int-params? f ;
 287
 288 M: x86.32 dummy-fp-params? f ;
 289
 290 M: x86.32 long-long-on-stack? t ;
 291
 292 M: x86.32 structs-on-stack? t ;
 293
 294 M: x86.32 struct-return-on-stack? os linux? not ;
 295
 296 check-sse