basis/cpu/x86/32/32.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: locals alien alien.c-types alien.libraries alien.syntax
   4 arrays kernel fry math namespaces sequences system layouts io
   5 vocabs.loader accessors init classes.struct combinators
   6 command-line make words compiler compiler.units
   7 compiler.constants compiler.alien compiler.codegen
   8 compiler.codegen.fixup compiler.cfg.instructions
   9 compiler.cfg.builder compiler.cfg.builder.alien
  10 compiler.cfg.builder.alien.params
  11 compiler.cfg.intrinsics compiler.cfg.stack-frame
  12 cpu.x86.assembler cpu.x86.assembler.operands cpu.x86
  13 cpu.architecture vm ;
  14 FROM: layouts => cell ;
  15 IN: cpu.x86.32
  16
  17 M: x86.32 machine-registers
  18     {
  19         { int-regs { EAX ECX EDX EBP EBX } }
  20         { float-regs { XMM0 XMM1 XMM2 XMM3 XMM4 XMM5 XMM6 XMM7 } }
  21     } ;
  22
  23 M: x86.32 ds-reg ESI ;
  24 M: x86.32 rs-reg EDI ;
  25 M: x86.32 stack-reg ESP ;
  26 M: x86.32 frame-reg EBP ;
  27 M: x86.32 temp-reg ECX ;
  28
  29 M: x86.32 immediate-comparand? ( obj -- ? ) drop t ;
  30
  31 M:: x86.32 %load-vector ( dst val rep -- )
  32     dst 0 [] rep copy-memory* val rc-absolute rel-binary-literal ;
  33
  34 M: x86.32 %load-float ( dst val -- )
  35     <float> float-rep %load-vector ;
  36
  37 M: x86.32 %load-double ( dst val -- )
  38     <double> double-rep %load-vector ;
  39
  40 M: x86.32 %mov-vm-ptr ( reg -- )
  41     0 MOV 0 rc-absolute-cell rel-vm ;
  42
  43 M: x86.32 %vm-field ( dst field -- )
  44     [ 0 [] MOV ] dip rc-absolute-cell rel-vm ;
  45
  46 M: x86.32 %set-vm-field ( dst field -- )
  47     [ 0 [] swap MOV ] dip rc-absolute-cell rel-vm ;
  48
  49 M: x86.32 %vm-field-ptr ( dst field -- )
  50     [ 0 MOV ] dip rc-absolute-cell rel-vm ;
  51
  52 : local@ ( n -- op )
  53     stack-frame get extra-stack-space dup 16 assert= + stack@ ;
  54
  55 M: x86.32 extra-stack-space calls-vm?>> 16 0 ? ;
  56
  57 M: x86.32 %mark-card
  58     drop HEX: ffffffff [+] card-mark <byte> MOV
  59     building get pop
  60     rc-absolute-cell rel-cards-offset
  61     building get push ;
  62
  63 M: x86.32 %mark-deck
  64     drop HEX: ffffffff [+] card-mark <byte> MOV
  65     building get pop
  66     rc-absolute-cell rel-decks-offset
  67     building get push ;
  68
  69 M:: x86.32 %dispatch ( src temp -- )
  70     ! Load jump table base.
  71     temp src HEX: ffffffff [+] LEA
  72     building get length :> start
  73     0 rc-absolute-cell rel-here
  74     ! Go
  75     temp HEX: 7f [+] JMP
  76     building get length :> end
  77     ! Fix up the displacement above
  78     cell alignment
  79     [ end start - + building get dup pop* push ]
  80     [ (align-code) ]
  81     bi ;
  82
  83 M: x86.32 pic-tail-reg EDX ;
  84
  85 M: x86.32 reserved-stack-space 0 ;
  86
  87 M: x86.32 %alien-invoke 0 CALL rc-relative rel-dlsym ;
  88
  89 : save-vm-ptr ( n -- )
  90     stack@ 0 MOV 0 rc-absolute-cell rel-vm ;
  91
  92 M: x86.32 return-struct-in-registers? ( c-type -- ? )
  93     c-type
  94     [ return-in-registers?>> ]
  95     [ heap-size { 1 2 4 8 } member? ] bi
  96     os { linux netbsd solaris } member? not
  97     and or ;
  98
  99 ! On x86, parameters are usually never passed in registers,
 100 ! except with Microsoft's "thiscall" and "fastcall" abis
 101 M: int-regs return-reg drop EAX ;
 102 M: float-regs param-regs 2drop { } ;
 103
 104 M: int-regs param-regs
 105     nip {
 106         { thiscall [ { ECX } ] }
 107         { fastcall [ { ECX EDX } ] }
 108         [ drop { } ]
 109     } case ;
 110
 111 GENERIC: load-return-reg ( src rep -- )
 112 GENERIC: store-return-reg ( dst rep -- )
 113
 114 M: stack-params load-return-reg drop EAX swap MOV ;
 115 M: stack-params store-return-reg drop EAX MOV ;
 116
 117 M: int-rep load-return-reg drop EAX swap MOV ;
 118 M: int-rep store-return-reg drop EAX MOV ;
 119
 120 :: load-float-return ( src x87-insn sse-insn -- )
 121     src register? [
 122         ESP 4 SUB
 123         ESP [] src sse-insn execute
 124         ESP [] x87-insn execute
 125         ESP 4 ADD
 126     ] [
 127         src x87-insn execute
 128     ] if ; inline
 129
 130 :: store-float-return ( dst x87-insn sse-insn -- )
 131     dst register? [
 132         ESP 4 SUB
 133         ESP [] x87-insn execute
 134         dst ESP [] sse-insn execute
 135         ESP 4 ADD
 136     ] [
 137         dst x87-insn execute
 138     ] if ; inline
 139
 140 M: float-rep load-return-reg
 141     drop \ FLDS \ MOVSS load-float-return ;
 142
 143 M: float-rep store-return-reg
 144     drop \ FSTPS \ MOVSS store-float-return ;
 145
 146 M: double-rep load-return-reg
 147     drop \ FLDL \ MOVSD load-float-return ;
 148
 149 M: double-rep store-return-reg
 150     drop \ FSTPL \ MOVSD store-float-return ;
 151
 152 M: x86.32 %prologue ( n -- )
 153     dup PUSH
 154     0 PUSH rc-absolute-cell rel-this
 155     3 cells - decr-stack-reg ;
 156
 157 M: x86.32 %prepare-jump
 158     pic-tail-reg 0 MOV xt-tail-pic-offset rc-absolute-cell rel-here ;
 159
 160 :: call-unbox-func ( src func -- )
 161     EAX src tagged-rep %copy
 162     4 save-vm-ptr
 163     0 stack@ EAX MOV
 164     func f %alien-invoke ;
 165
 166 M:: x86.32 %unbox ( dst src func rep -- )
 167     src func call-unbox-func
 168     dst ?spill-slot rep store-return-reg ;
 169
 170 M:: x86.32 %store-return ( src rep -- )
 171     src ?spill-slot rep load-return-reg ;
 172
 173 M:: x86.32 %store-long-long-return ( src1 src2 -- )
 174     src2 EAX = [ src1 src2 XCHG src2 src1 ] [ src1 src2 ] if :> ( src1 src2 )
 175     EAX src1 int-rep %copy
 176     EDX src2 int-rep %copy ;
 177
 178 M:: x86.32 %store-struct-return ( src c-type -- )
 179     EAX src int-rep %copy
 180     EDX EAX 4 [+] MOV
 181     EAX EAX [] MOV ;
 182
 183 M: stack-params copy-register*
 184     drop
 185     {
 186         { [ dup  integer? ] [ EAX swap next-stack@ MOV  EAX MOV ] }
 187         { [ over integer? ] [ EAX swap MOV              param@ EAX MOV ] }
 188     } cond ;
 189
 190 M: x86.32 %save-param-reg [ local@ ] 2dip %copy ;
 191
 192 : (%box) ( n rep -- )
 193     #! If n is f, push the return register onto the stack; we
 194     #! are boxing a return value of a C function. If n is an
 195     #! integer, push [ESP+n] on the stack; we are boxing a
 196     #! parameter being passed to a callback from C.
 197     over [ [ local@ ] dip load-return-reg ] [ 2drop ] if ;
 198
 199 M:: x86.32 %box ( dst n rep func -- )
 200     n rep (%box)
 201     rep rep-size save-vm-ptr
 202     0 stack@ rep store-return-reg
 203     func f %alien-invoke
 204     dst EAX tagged-rep %copy ;
 205
 206 : (%box-long-long) ( n -- )
 207     [
 208         [ EDX swap next-stack@ MOV ]
 209         [ EAX swap cell - next-stack@ MOV ] bi
 210     ] when* ;
 211
 212 M:: x86.32 %box-long-long ( dst n func -- )
 213     n (%box-long-long)
 214     8 save-vm-ptr
 215     4 stack@ EDX MOV
 216     0 stack@ EAX MOV
 217     func f %alien-invoke
 218     dst EAX tagged-rep %copy ;
 219
 220 M: x86.32 struct-return@ ( n -- operand )
 221     [ next-stack@ ] [ stack-frame get params>> local@ ] if* ;
 222
 223 M:: x86.32 %box-large-struct ( dst n c-type -- )
 224     EDX n struct-return@ LEA
 225     8 save-vm-ptr
 226     4 stack@ c-type heap-size MOV
 227     0 stack@ EDX MOV
 228     "from_value_struct" f %alien-invoke
 229     dst EAX tagged-rep %copy ;
 230
 231 M:: x86.32 %box-small-struct ( dst c-type -- )
 232     #! Box a <= 8-byte struct returned in EAX:EDX. OS X only.
 233     12 save-vm-ptr
 234     8 stack@ c-type heap-size MOV
 235     4 stack@ EDX MOV
 236     0 stack@ EAX MOV
 237     "from_small_struct" f %alien-invoke
 238     dst EAX tagged-rep %copy ;
 239
 240 M: x86.32 %begin-callback ( -- )
 241     0 save-vm-ptr
 242     4 stack@ 0 MOV
 243     "begin_callback" f %alien-invoke ;
 244
 245 M: x86.32 %alien-callback ( quot -- )
 246     [ EAX ] dip %load-reference
 247     EAX quot-entry-point-offset [+] CALL ;
 248
 249 M: x86.32 %end-callback ( -- )
 250     0 save-vm-ptr
 251     "end_callback" f %alien-invoke ;
 252
 253 GENERIC: float-function-param ( stack-slot dst src -- )
 254
 255 M:: spill-slot float-function-param ( stack-slot dst src -- )
 256     ! We can clobber dst here since its going to contain the
 257     ! final result
 258     dst src double-rep %copy
 259     stack-slot dst double-rep %copy ;
 260
 261 M: register float-function-param
 262     nip double-rep %copy ;
 263
 264 : float-function-return ( reg -- )
 265     ESP [] FSTPL
 266     ESP [] MOVSD
 267     ESP 16 ADD ;
 268
 269 M:: x86.32 %unary-float-function ( dst src func -- )
 270     ESP -16 [+] dst src float-function-param
 271     ESP 16 SUB
 272     func "libm" load-library %alien-invoke
 273     dst float-function-return ;
 274
 275 M:: x86.32 %binary-float-function ( dst src1 src2 func -- )
 276     ESP -16 [+] dst src1 float-function-param
 277     ESP  -8 [+] dst src2 float-function-param
 278     ESP 16 SUB
 279     func "libm" load-library %alien-invoke
 280     dst float-function-return ;
 281
 282 : funny-large-struct-return? ( params -- ? )
 283     #! MINGW ABI incompatibility disaster
 284     [ return>> large-struct? ]
 285     [ abi>> mingw eq? os windows? not or ]
 286     bi and ;
 287
 288 : stack-arg-size ( params -- n )
 289     dup abi>> [
 290         alien-parameters flatten-c-types
 291         [ alloc-parameter 2drop ] each
 292         stack-params get
 293     ] with-param-regs ;
 294
 295 M: x86.32 stack-cleanup ( params -- n )
 296     #! a) Functions which are stdcall/fastcall/thiscall have to
 297     #! clean up the caller's stack frame.
 298     #! b) Functions returning large structs on MINGW have to
 299     #! fix ESP.
 300     {
 301         { [ dup abi>> callee-cleanup? ] [ stack-arg-size ] }
 302         { [ dup funny-large-struct-return? ] [ drop 4 ] }
 303         [ drop 0 ]
 304     } cond ;
 305
 306 M: x86.32 %cleanup ( n -- )
 307     [ ESP swap SUB ] unless-zero ;
 308
 309 M:: x86.32 %call-gc ( gc-roots -- )
 310     4 save-vm-ptr
 311     0 stack@ gc-roots gc-root-offsets %load-reference
 312     "inline_gc" f %alien-invoke ;
 313
 314 M: x86.32 dummy-stack-params? f ;
 315
 316 M: x86.32 dummy-int-params? f ;
 317
 318 M: x86.32 dummy-fp-params? f ;
 319
 320 M: x86.32 long-long-on-stack? t ;
 321
 322 M: x86.32 float-on-stack? t ;
 323
 324 M: x86.32 flatten-struct-type
 325     stack-size cell /i { int-rep t } <repetition> ;
 326
 327 M: x86.32 struct-return-on-stack? os linux? not ;
 328
 329 check-sse