basis/cpu/x86/32/bootstrap.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bootstrap.image.private kernel kernel.private namespaces
   4 system cpu.x86.assembler cpu.x86.assembler.operands layouts
   5 vocabs parser compiler.constants sequences math math.private
   6 generic.single.private threads.private ;
   7 IN: bootstrap.x86
   8
   9 4 \ cell set
  10
  11 : stack-frame-size ( -- n ) 8 bootstrap-cells ;
  12 : shift-arg ( -- reg ) ECX ;
  13 : div-arg ( -- reg ) EAX ;
  14 : mod-arg ( -- reg ) EDX ;
  15 : temp0 ( -- reg ) EAX ;
  16 : temp1 ( -- reg ) EDX ;
  17 : temp2 ( -- reg ) ECX ;
  18 : temp3 ( -- reg ) EBX ;
  19 : stack-reg ( -- reg ) ESP ;
  20 : frame-reg ( -- reg ) EBP ;
  21 : vm-reg ( -- reg ) ECX ;
  22 : ctx-reg ( -- reg ) EBP ;
  23 : nv-regs ( -- seq ) { ESI EDI EBX } ;
  24 : nv-reg ( -- reg ) EBX ;
  25 : ds-reg ( -- reg ) ESI ;
  26 : rs-reg ( -- reg ) EDI ;
  27 : fixnum>slot@ ( -- ) temp0 2 SAR ;
  28 : rex-length ( -- n ) 0 ;
  29
  30 : jit-call ( name -- )
  31     0 CALL rc-relative jit-dlsym ;
  32
  33 [
  34     ! save stack frame size
  35     stack-frame-size PUSH
  36     ! push entry point
  37     0 PUSH rc-absolute-cell rt-this jit-rel
  38     ! alignment
  39     ESP stack-frame-size 3 bootstrap-cells - SUB
  40 ] jit-prolog jit-define
  41
  42 [
  43     temp3 0 MOV rc-absolute-cell rt-here jit-rel
  44     0 JMP rc-relative rt-entry-point-pic-tail jit-rel
  45 ] jit-word-jump jit-define
  46
  47 : jit-load-vm ( -- )
  48     vm-reg 0 MOV 0 rc-absolute-cell jit-vm ;
  49
  50 : jit-load-context ( -- )
  51     ! VM pointer must be in vm-reg already
  52     ctx-reg vm-reg vm-context-offset [+] MOV ;
  53
  54 : jit-save-context ( -- )
  55     jit-load-context
  56     EDX ESP -4 [+] LEA
  57     ctx-reg context-callstack-top-offset [+] EDX MOV
  58     ctx-reg context-datastack-offset [+] ds-reg MOV
  59     ctx-reg context-retainstack-offset [+] rs-reg MOV ;
  60
  61 : jit-restore-context ( -- )
  62     ds-reg ctx-reg context-datastack-offset [+] MOV
  63     rs-reg ctx-reg context-retainstack-offset [+] MOV ;
  64
  65 [
  66     ! ctx-reg is preserved across the call because it is non-volatile
  67     ! in the C ABI
  68     jit-load-vm
  69     jit-save-context
  70     ! call the primitive
  71     ESP [] vm-reg MOV
  72     0 CALL rc-relative rt-dlsym jit-rel
  73     jit-restore-context
  74 ] jit-primitive jit-define
  75
  76 : jit-jump-quot ( -- )
  77     EAX quot-entry-point-offset [+] JMP ;
  78
  79 : jit-call-quot ( -- )
  80     EAX quot-entry-point-offset [+] CALL ;
  81
  82 [
  83     jit-load-vm
  84     ESP [] vm-reg MOV
  85     EAX EBP 8 [+] MOV
  86     ESP 4 [+] EAX MOV
  87     "begin_callback" jit-call
  88
  89     jit-load-vm
  90     jit-load-context
  91     jit-restore-context
  92
  93     jit-call-quot
  94
  95     jit-load-vm
  96     jit-save-context
  97
  98     ESP [] vm-reg MOV
  99     "end_callback" jit-call
 100 ] \ c-to-factor define-sub-primitive
 101
 102 [
 103     EAX ds-reg [] MOV
 104     ds-reg bootstrap-cell SUB
 105 ]
 106 [ jit-call-quot ]
 107 [ jit-jump-quot ]
 108 \ (call) define-combinator-primitive
 109
 110 [
 111     ! Clear x87 stack, but preserve rounding mode and exception flags
 112     ESP 2 SUB
 113     ESP [] FNSTCW
 114     FNINIT
 115     ESP [] FLDCW
 116     ESP 2 ADD
 117
 118     ! Load arguments
 119     EAX ESP stack-frame-size [+] MOV
 120     EDX ESP stack-frame-size 4 + [+] MOV
 121
 122     ! Unwind stack frames
 123     ESP EDX MOV
 124
 125     ! Load ds and rs registers
 126     jit-load-vm
 127     jit-load-context
 128     jit-restore-context
 129
 130     jit-jump-quot
 131 ] \ unwind-native-frames define-sub-primitive
 132
 133 [
 134     ! Load callstack object
 135     EBX ds-reg [] MOV
 136     ds-reg bootstrap-cell SUB
 137     ! Get ctx->callstack_bottom
 138     jit-load-vm
 139     jit-load-context
 140     EAX ctx-reg context-callstack-bottom-offset [+] MOV
 141     ! Get top of callstack object -- 'src' for memcpy
 142     EBP EBX callstack-top-offset [+] LEA
 143     ! Get callstack length, in bytes --- 'len' for memcpy
 144     EDX EBX callstack-length-offset [+] MOV
 145     EDX tag-bits get SHR
 146     ! Compute new stack pointer -- 'dst' for memcpy
 147     EAX EDX SUB
 148     ! Install new stack pointer
 149     ESP EAX MOV
 150     ! Call memcpy
 151     EDX PUSH
 152     EBP PUSH
 153     EAX PUSH
 154     "factor_memcpy" jit-call
 155     ESP 12 ADD
 156     ! Return with new callstack
 157     0 RET
 158 ] \ set-callstack define-sub-primitive
 159
 160 [
 161     jit-load-vm
 162     jit-save-context
 163
 164     ! Store arguments
 165     ESP [] EAX MOV
 166     ESP 4 [+] vm-reg MOV
 167
 168     ! Call VM
 169     "lazy_jit_compile" jit-call
 170 ]
 171 [ jit-call-quot ]
 172 [ jit-jump-quot ]
 173 \ lazy-jit-compile define-combinator-primitive
 174
 175 ! Inline cache miss entry points
 176 : jit-load-return-address ( -- )
 177     EBX ESP stack-frame-size bootstrap-cell - [+] MOV ;
 178
 179 ! These are always in tail position with an existing stack
 180 ! frame, and the stack. The frame setup takes this into account.
 181 : jit-inline-cache-miss ( -- )
 182     jit-load-vm
 183     jit-save-context
 184     ESP 4 [+] vm-reg MOV
 185     ESP [] EBX MOV
 186     "inline_cache_miss" jit-call
 187     jit-restore-context ;
 188
 189 [ jit-load-return-address jit-inline-cache-miss ]
 190 [ EAX CALL ]
 191 [ EAX JMP ]
 192 \ inline-cache-miss define-combinator-primitive
 193
 194 [ jit-inline-cache-miss ]
 195 [ EAX CALL ]
 196 [ EAX JMP ]
 197 \ inline-cache-miss-tail define-combinator-primitive
 198
 199 ! Overflowing fixnum arithmetic
 200 : jit-overflow ( insn func -- )
 201     ds-reg 4 SUB
 202     jit-load-vm
 203     jit-save-context
 204     EAX ds-reg [] MOV
 205     EDX ds-reg 4 [+] MOV
 206     EBX EAX MOV
 207     [ [ EBX EDX ] dip call( dst src -- ) ] dip
 208     ds-reg [] EBX MOV
 209     [ JNO ]
 210     [
 211         ESP [] EAX MOV
 212         ESP 4 [+] EDX MOV
 213         ESP 8 [+] vm-reg MOV
 214         jit-call
 215     ]
 216     jit-conditional ;
 217
 218 [ [ ADD ] "overflow_fixnum_add" jit-overflow ] \ fixnum+ define-sub-primitive
 219
 220 [ [ SUB ] "overflow_fixnum_subtract" jit-overflow ] \ fixnum- define-sub-primitive
 221
 222 [
 223     ds-reg 4 SUB
 224     jit-load-vm
 225     jit-save-context
 226     EBX ds-reg [] MOV
 227     EAX EBX MOV
 228     EBP ds-reg 4 [+] MOV
 229     EBP tag-bits get SAR
 230     EBP IMUL
 231     ds-reg [] EAX MOV
 232     [ JNO ]
 233     [
 234         EBX tag-bits get SAR
 235         ESP [] EBX MOV
 236         ESP 4 [+] EBP MOV
 237         ESP 8 [+] vm-reg MOV
 238         "overflow_fixnum_multiply" jit-call
 239     ]
 240     jit-conditional
 241 ] \ fixnum* define-sub-primitive
 242
 243 ! Contexts
 244 : jit-switch-context ( reg -- )
 245     ! Save ds, rs registers
 246     jit-load-vm
 247     jit-save-context
 248
 249     ! Make the new context the current one
 250     ctx-reg swap MOV
 251     vm-reg vm-context-offset [+] ctx-reg MOV
 252
 253     ! Load new stack pointer
 254     ESP ctx-reg context-callstack-top-offset [+] MOV
 255
 256     ! Load new ds, rs registers
 257     jit-restore-context ;
 258
 259 : jit-set-context ( -- )
 260     ! Load context and parameter from datastack
 261     EAX ds-reg [] MOV
 262     EAX EAX alien-offset [+] MOV
 263     EBX ds-reg -4 [+] MOV
 264     ds-reg 8 SUB
 265
 266     ! Make the new context active
 267     EAX jit-switch-context
 268
 269     ! Twiddle stack for return
 270     ESP 4 ADD
 271
 272     ! Store parameter to datastack
 273     ds-reg 4 ADD
 274     ds-reg [] EBX MOV ;
 275
 276 [ jit-set-context ] \ (set-context) define-sub-primitive
 277
 278 : jit-start-context ( -- )
 279     ! Create the new context in return-reg
 280     jit-load-vm
 281     ESP [] vm-reg MOV
 282     "new_context" jit-call
 283
 284     ! Save pointer to quotation and parameter
 285     EBX ds-reg MOV
 286     ds-reg 8 SUB
 287
 288     ! Make the new context active
 289     EAX jit-switch-context
 290
 291     ! Push parameter
 292     EAX EBX -4 [+] MOV
 293     ds-reg 4 ADD
 294     ds-reg [] EAX MOV
 295
 296     ! Jump to initial quotation
 297     EAX EBX [] MOV
 298     jit-jump-quot ;
 299
 300 [ jit-start-context ] \ (start-context) define-sub-primitive
 301
 302 : jit-delete-current-context ( -- )
 303     jit-load-vm
 304     jit-load-context
 305     ESP [] vm-reg MOV
 306     ESP 4 [+] ctx-reg MOV
 307     "delete_context" jit-call ;
 308
 309 [
 310     jit-delete-current-context
 311     jit-set-context
 312 ] \ (set-context-and-delete) define-sub-primitive
 313
 314 [
 315     jit-delete-current-context
 316     jit-start-context
 317 ] \ (start-context-and-delete) define-sub-primitive
 318
 319 << "vocab:cpu/x86/bootstrap.factor" parse-file suffix! >>
 320 call