basis/cpu/x86/32/bootstrap.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bootstrap.image.private kernel kernel.private namespaces
   4 system cpu.x86.assembler cpu.x86.assembler.operands layouts
   5 vocabs parser compiler.constants sequences math math.private
   6 generic.single.private threads.private ;
   7 IN: bootstrap.x86
   8
   9 4 \ cell set
  10
  11 : stack-frame-size ( -- n ) 8 bootstrap-cells ;
  12 : shift-arg ( -- reg ) ECX ;
  13 : div-arg ( -- reg ) EAX ;
  14 : mod-arg ( -- reg ) EDX ;
  15 : temp0 ( -- reg ) EAX ;
  16 : temp1 ( -- reg ) EDX ;
  17 : temp2 ( -- reg ) ECX ;
  18 : temp3 ( -- reg ) EBX ;
  19 : stack-reg ( -- reg ) ESP ;
  20 : frame-reg ( -- reg ) EBP ;
  21 : vm-reg ( -- reg ) ECX ;
  22 : ctx-reg ( -- reg ) EBP ;
  23 : nv-regs ( -- seq ) { ESI EDI EBX } ;
  24 : nv-reg ( -- reg ) EBX ;
  25 : ds-reg ( -- reg ) ESI ;
  26 : rs-reg ( -- reg ) EDI ;
  27 : fixnum>slot@ ( -- ) temp0 2 SAR ;
  28 : rex-length ( -- n ) 0 ;
  29
  30 : jit-call ( name -- )
  31     0 CALL rc-relative jit-dlsym ;
  32
  33 [
  34     ! save stack frame size
  35     stack-frame-size PUSH
  36     ! push entry point
  37     0 PUSH rc-absolute-cell rt-this jit-rel
  38     ! alignment
  39     ESP stack-frame-size 3 bootstrap-cells - SUB
  40 ] jit-prolog jit-define
  41
  42 [
  43     temp3 0 MOV rc-absolute-cell rt-here jit-rel
  44     0 JMP rc-relative rt-entry-point-pic-tail jit-rel
  45 ] jit-word-jump jit-define
  46
  47 : jit-load-vm ( -- )
  48     vm-reg 0 MOV 0 rc-absolute-cell jit-vm ;
  49
  50 : jit-load-context ( -- )
  51     ! VM pointer must be in vm-reg already
  52     ctx-reg vm-reg vm-context-offset [+] MOV ;
  53
  54 : jit-save-context ( -- )
  55     jit-load-context
  56     EDX ESP -4 [+] LEA
  57     ctx-reg context-callstack-top-offset [+] EDX MOV
  58     ctx-reg context-datastack-offset [+] ds-reg MOV
  59     ctx-reg context-retainstack-offset [+] rs-reg MOV ;
  60
  61 : jit-restore-context ( -- )
  62     ds-reg ctx-reg context-datastack-offset [+] MOV
  63     rs-reg ctx-reg context-retainstack-offset [+] MOV ;
  64
  65 [
  66     jit-load-vm
  67     jit-save-context
  68     ! call the primitive
  69     ESP [] vm-reg MOV
  70     0 CALL rc-relative rt-dlsym jit-rel
  71     ! restore ds, rs registers
  72     jit-restore-context
  73 ] jit-primitive jit-define
  74
  75 [
  76     jit-load-vm
  77     ESP [] vm-reg MOV
  78     "begin_callback" jit-call
  79
  80     ! load quotation - EBP is ctx-reg so it will get clobbered
  81     ! later on
  82     EAX EBP 8 [+] MOV
  83
  84     jit-load-vm
  85     jit-load-context
  86     jit-restore-context
  87
  88     ! save C callstack pointer
  89     ctx-reg context-callstack-save-offset [+] ESP MOV
  90
  91     ! load Factor callstack pointer
  92     ESP ctx-reg context-callstack-bottom-offset [+] MOV
  93     ESP 4 ADD
  94
  95     ! call the quotation
  96     EAX quot-entry-point-offset [+] CALL
  97
  98     jit-load-vm
  99     jit-save-context
 100
 101     ! load C callstack pointer
 102     ESP ctx-reg context-callstack-save-offset [+] MOV
 103
 104     ESP [] vm-reg MOV
 105     "end_callback" jit-call
 106 ] \ c-to-factor define-sub-primitive
 107
 108 [
 109     EAX ds-reg [] MOV
 110     ds-reg bootstrap-cell SUB
 111 ]
 112 [ EAX quot-entry-point-offset [+] CALL ]
 113 [ EAX quot-entry-point-offset [+] JMP ]
 114 \ (call) define-combinator-primitive
 115
 116 [
 117     ! Clear x87 stack, but preserve rounding mode and exception flags
 118     ESP 2 SUB
 119     ESP [] FNSTCW
 120     FNINIT
 121     ESP [] FLDCW
 122     ESP 2 ADD
 123
 124     ! Load arguments
 125     EAX ESP stack-frame-size [+] MOV
 126     EDX ESP stack-frame-size 4 + [+] MOV
 127
 128     ! Unwind stack frames
 129     ESP EDX MOV
 130
 131     ! Load ds and rs registers
 132     jit-load-vm
 133     jit-load-context
 134     jit-restore-context
 135
 136     ! Call quotation
 137     EAX quot-entry-point-offset [+] JMP
 138 ] \ unwind-native-frames define-sub-primitive
 139
 140 [
 141     ! Load callstack object
 142     EBX ds-reg [] MOV
 143     ds-reg bootstrap-cell SUB
 144     ! Get ctx->callstack_bottom
 145     jit-load-vm
 146     jit-load-context
 147     EAX ctx-reg context-callstack-bottom-offset [+] MOV
 148     ! Get top of callstack object -- 'src' for memcpy
 149     EBP EBX callstack-top-offset [+] LEA
 150     ! Get callstack length, in bytes --- 'len' for memcpy
 151     EDX EBX callstack-length-offset [+] MOV
 152     EDX tag-bits get SHR
 153     ! Compute new stack pointer -- 'dst' for memcpy
 154     EAX EDX SUB
 155     ! Install new stack pointer
 156     ESP EAX MOV
 157     ! Call memcpy
 158     EDX PUSH
 159     EBP PUSH
 160     EAX PUSH
 161     "factor_memcpy" jit-call
 162     ESP 12 ADD
 163     ! Return with new callstack
 164     0 RET
 165 ] \ set-callstack define-sub-primitive
 166
 167 [
 168     jit-load-vm
 169     jit-save-context
 170
 171     ! Store arguments
 172     ESP [] EAX MOV
 173     ESP 4 [+] vm-reg MOV
 174
 175     ! Call VM
 176     "lazy_jit_compile" jit-call
 177 ]
 178 [ EAX quot-entry-point-offset [+] CALL ]
 179 [ EAX quot-entry-point-offset [+] JMP ]
 180 \ lazy-jit-compile define-combinator-primitive
 181
 182 ! Inline cache miss entry points
 183 : jit-load-return-address ( -- )
 184     EBX ESP stack-frame-size bootstrap-cell - [+] MOV ;
 185
 186 ! These are always in tail position with an existing stack
 187 ! frame, and the stack. The frame setup takes this into account.
 188 : jit-inline-cache-miss ( -- )
 189     jit-load-vm
 190     jit-save-context
 191     ESP 4 [+] vm-reg MOV
 192     ESP [] EBX MOV
 193     "inline_cache_miss" jit-call
 194     jit-restore-context ;
 195
 196 [ jit-load-return-address jit-inline-cache-miss ]
 197 [ EAX CALL ]
 198 [ EAX JMP ]
 199 \ inline-cache-miss define-combinator-primitive
 200
 201 [ jit-inline-cache-miss ]
 202 [ EAX CALL ]
 203 [ EAX JMP ]
 204 \ inline-cache-miss-tail define-combinator-primitive
 205
 206 ! Overflowing fixnum arithmetic
 207 : jit-overflow ( insn func -- )
 208     ds-reg 4 SUB
 209     jit-load-vm
 210     jit-save-context
 211     EAX ds-reg [] MOV
 212     EDX ds-reg 4 [+] MOV
 213     EBX EAX MOV
 214     [ [ EBX EDX ] dip call( dst src -- ) ] dip
 215     ds-reg [] EBX MOV
 216     [ JNO ]
 217     [
 218         ESP [] EAX MOV
 219         ESP 4 [+] EDX MOV
 220         ESP 8 [+] vm-reg MOV
 221         jit-call
 222     ]
 223     jit-conditional ;
 224
 225 [ [ ADD ] "overflow_fixnum_add" jit-overflow ] \ fixnum+ define-sub-primitive
 226
 227 [ [ SUB ] "overflow_fixnum_subtract" jit-overflow ] \ fixnum- define-sub-primitive
 228
 229 [
 230     ds-reg 4 SUB
 231     jit-load-vm
 232     jit-save-context
 233     EBX ds-reg [] MOV
 234     EAX EBX MOV
 235     EBP ds-reg 4 [+] MOV
 236     EBP tag-bits get SAR
 237     EBP IMUL
 238     ds-reg [] EAX MOV
 239     [ JNO ]
 240     [
 241         EBX tag-bits get SAR
 242         ESP [] EBX MOV
 243         ESP 4 [+] EBP MOV
 244         ESP 8 [+] vm-reg MOV
 245         "overflow_fixnum_multiply" jit-call
 246     ]
 247     jit-conditional
 248 ] \ fixnum* define-sub-primitive
 249
 250 ! Threads
 251 : jit-set-context ( reg -- )
 252     ! Save ds, rs registers
 253     jit-load-vm
 254     jit-save-context
 255
 256     ! Make the new context the current one
 257     ctx-reg swap MOV
 258     vm-reg vm-context-offset [+] ctx-reg MOV
 259
 260     ! Load new stack pointer
 261     ESP ctx-reg context-callstack-top-offset [+] MOV
 262
 263     ! Load new ds, rs registers
 264     jit-restore-context ;
 265
 266 [
 267     ! Create the new context in return-reg
 268     jit-load-vm
 269     ESP [] vm-reg MOV
 270     "new_context" jit-call
 271
 272     ! Save pointer to quotation and parameter, pop them off the
 273     ! datastack
 274     EBX ds-reg MOV
 275     ds-reg 8 SUB
 276
 277     ! Make the new context the active context
 278     EAX jit-set-context
 279
 280     ! Push parameter
 281     EAX EBX -4 [+] MOV
 282     ds-reg 4 ADD
 283     ds-reg [] EAX MOV
 284
 285     ! Jump to initial quotation
 286     EAX EBX [] MOV
 287     EAX quot-entry-point-offset [+] JMP
 288 ] \ (start-context) define-sub-primitive
 289
 290 [
 291     ! Load context from datastack
 292     EAX ds-reg [] MOV
 293     EAX EAX alien-offset [+] MOV
 294     ds-reg 4 SUB
 295
 296     ! Make it the active context
 297     EAX jit-set-context
 298
 299     ! Twiddle stack for return
 300     ESP 4 ADD
 301 ] \ (set-context) define-sub-primitive
 302
 303 << "vocab:cpu/x86/bootstrap.factor" parse-file suffix! >>
 304 call