basis/cpu/x86/32/bootstrap.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bootstrap.image.private kernel kernel.private namespaces
   4 system cpu.x86.assembler cpu.x86.assembler.operands layouts
   5 vocabs parser compiler.constants sequences math math.private
   6 generic.single.private ;
   7 IN: bootstrap.x86
   8
   9 4 \ cell set
  10
  11 : stack-frame-size ( -- n ) 8 bootstrap-cells ;
  12 : shift-arg ( -- reg ) ECX ;
  13 : div-arg ( -- reg ) EAX ;
  14 : mod-arg ( -- reg ) EDX ;
  15 : temp0 ( -- reg ) EAX ;
  16 : temp1 ( -- reg ) EDX ;
  17 : temp2 ( -- reg ) ECX ;
  18 : temp3 ( -- reg ) EBX ;
  19 : safe-reg ( -- reg ) EAX ;
  20 : stack-reg ( -- reg ) ESP ;
  21 : frame-reg ( -- reg ) EBP ;
  22 : vm-reg ( -- reg ) EBP ;
  23 : ctx-reg ( -- reg ) ECX ;
  24 : nv-regs ( -- seq ) { ESI EDI EBX } ;
  25 : ds-reg ( -- reg ) ESI ;
  26 : rs-reg ( -- reg ) EDI ;
  27 : fixnum>slot@ ( -- ) temp0 2 SAR ;
  28 : rex-length ( -- n ) 0 ;
  29
  30 [
  31     ! save stack frame size
  32     stack-frame-size PUSH
  33     ! push XT
  34     0 PUSH rc-absolute-cell rt-this jit-rel
  35     ! alignment
  36     ESP stack-frame-size 3 bootstrap-cells - SUB
  37 ] jit-prolog jit-define
  38
  39 : jit-load-vm ( -- )
  40     vm-reg 0 MOV 0 rc-absolute-cell jit-vm ;
  41
  42 : jit-load-context ( -- )
  43     ! VM pointer must be in vm-reg already
  44     ctx-reg vm-reg vm-context-offset [+] MOV ;
  45
  46 : jit-save-context ( -- )
  47     jit-load-context
  48     EDX RSP -4 [+] LEA
  49     ctx-reg context-callstack-top-offset [+] EDX MOV
  50     ctx-reg context-datastack-offset [+] ds-reg MOV
  51     ctx-reg context-retainstack-offset [+] rs-reg MOV ;
  52
  53 : jit-restore-context ( -- )
  54     jit-load-context
  55     ds-reg ctx-reg context-datastack-offset [+] MOV
  56     rs-reg ctx-reg context-retainstack-offset [+] MOV ;
  57
  58 [
  59     jit-load-vm
  60     jit-save-context
  61     ! call the primitive
  62     ESP [] vm-reg MOV
  63     0 CALL rc-relative rt-primitive jit-rel
  64     ! restore ds, rs registers
  65     jit-restore-context
  66 ] jit-primitive jit-define
  67
  68 [
  69     ! Load quotation
  70     EAX EBP 8 [+] MOV
  71     ! save ctx->callstack_bottom, load ds, rs registers
  72     jit-load-vm
  73     jit-restore-context
  74     EDX stack-reg stack-frame-size 4 - [+] LEA
  75     ctx-reg context-callstack-bottom-offset [+] EDX MOV
  76     ! call the quotation
  77     EAX quot-xt-offset [+] CALL
  78     ! save ds, rs registers
  79     jit-save-context
  80 ] \ c-to-factor define-sub-primitive
  81
  82 [
  83     EAX ds-reg [] MOV
  84     ds-reg bootstrap-cell SUB
  85 ]
  86 [ EAX quot-xt-offset [+] CALL ]
  87 [ EAX quot-xt-offset [+] JMP ]
  88 \ (call) define-combinator-primitive
  89
  90 [
  91     ! Clear x87 stack, but preserve rounding mode and exception flags
  92     ESP 2 SUB
  93     ESP [] FNSTCW
  94     FNINIT
  95     ESP [] FLDCW
  96     ESP 2 ADD
  97
  98     ! Load arguments
  99     EAX ESP stack-frame-size [+] MOV
 100     EDX ESP stack-frame-size 4 + [+] MOV
 101
 102     ! Unwind stack frames
 103     ESP EDX MOV
 104
 105     ! Load ds and rs registers
 106     jit-load-vm
 107     jit-restore-context
 108
 109     ! Call quotation
 110     EAX quot-xt-offset [+] JMP
 111 ] \ unwind-native-frames define-sub-primitive
 112
 113 [
 114     ! Load callstack object
 115     EBX ds-reg [] MOV
 116     ds-reg bootstrap-cell SUB
 117     ! Get ctx->callstack_bottom
 118     jit-load-vm
 119     jit-load-context
 120     EAX ctx-reg context-callstack-bottom-offset [+] MOV
 121     ! Get top of callstack object -- 'src' for memcpy
 122     EBP EBX callstack-top-offset [+] LEA
 123     ! Get callstack length, in bytes --- 'len' for memcpy
 124     EDX EBX callstack-length-offset [+] MOV
 125     EDX tag-bits get SHR
 126     ! Compute new stack pointer -- 'dst' for memcpy
 127     EAX EDX SUB
 128     ! Install new stack pointer
 129     RSP EAX MOV
 130     ! Call memcpy
 131     ESP 8 [+] EDX MOV
 132     ESP 4 [+] EBP MOV
 133     ESP [] EAX MOV
 134     0 CALL "memcpy" f rc-relative jit-dlsym
 135     ! Return with new callstack
 136     0 RET
 137 ] \ set-callstack define-sub-primitive
 138
 139 [
 140     jit-load-vm
 141     jit-save-context
 142
 143     ! Store arguments
 144     ESP [] EAX MOV
 145     ESP 4 [+] vm-reg MOV
 146
 147     ! Call VM
 148     0 CALL "lazy_jit_compile" f rc-relative jit-dlsym
 149 ]
 150 [ EAX quot-xt-offset [+] CALL ]
 151 [ EAX quot-xt-offset [+] JMP ]
 152 \ lazy-jit-compile define-combinator-primitive
 153
 154 ! Inline cache miss entry points
 155 : jit-load-return-address ( -- )
 156     EBX ESP stack-frame-size bootstrap-cell - [+] MOV ;
 157
 158 ! These are always in tail position with an existing stack
 159 ! frame, and the stack. The frame setup takes this into account.
 160 : jit-inline-cache-miss ( -- )
 161     jit-load-vm
 162     jit-save-context
 163     ESP 4 [+] vm-reg MOV
 164     ESP [] EBX MOV
 165     0 CALL "inline_cache_miss" f rc-relative jit-dlsym
 166     jit-restore-context ;
 167
 168 [ jit-load-return-address jit-inline-cache-miss ]
 169 [ EAX CALL ]
 170 [ EAX JMP ]
 171 \ inline-cache-miss define-combinator-primitive
 172
 173 [ jit-inline-cache-miss ]
 174 [ EAX CALL ]
 175 [ EAX JMP ]
 176 \ inline-cache-miss-tail define-combinator-primitive
 177
 178 ! Overflowing fixnum arithmetic
 179 : jit-overflow ( insn func -- )
 180     ds-reg 4 SUB
 181     jit-load-vm
 182     jit-save-context
 183     EAX ds-reg [] MOV
 184     EDX ds-reg 4 [+] MOV
 185     ECX EAX MOV
 186     [ [ ECX EDX ] dip call( dst src -- ) ] dip
 187     ds-reg [] ECX MOV
 188     [ JNO ]
 189     [
 190         ESP [] EAX MOV
 191         ESP 4 [+] EDX MOV
 192         ESP 8 [+] EBP MOV
 193         [ 0 CALL ] dip f rc-relative jit-dlsym
 194     ]
 195     jit-conditional ;
 196
 197 [ [ ADD ] "overflow_fixnum_add" jit-overflow ] \ fixnum+ define-sub-primitive
 198
 199 [ [ SUB ] "overflow_fixnum_subtract" jit-overflow ] \ fixnum- define-sub-primitive
 200
 201 [
 202     ds-reg 4 SUB
 203     jit-load-vm
 204     jit-save-context
 205     ECX ds-reg [] MOV
 206     EAX ECX MOV
 207     EBX ds-reg 4 [+] MOV
 208     EBX tag-bits get SAR
 209     EBX IMUL
 210     ds-reg [] EAX MOV
 211     [ JNO ]
 212     [
 213         ECX tag-bits get SAR
 214         ESP [] ECX MOV
 215         ESP 4 [+] EBX MOV
 216         ESP 8 [+] EBP MOV
 217         0 CALL "overflow_fixnum_multiply" f rc-relative jit-dlsym
 218     ]
 219     jit-conditional
 220 ] \ fixnum* define-sub-primitive
 221
 222 << "vocab:cpu/x86/bootstrap.factor" parse-file suffix! >>
 223 call