basis/cpu/x86/32/bootstrap.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bootstrap.image.private kernel kernel.private namespaces
   4 system cpu.x86.assembler cpu.x86.assembler.operands layouts
   5 vocabs parser compiler.constants sequences math math.private
   6 generic.single.private threads.private ;
   7 IN: bootstrap.x86
   8
   9 4 \ cell set
  10
  11 : stack-frame-size ( -- n ) 8 bootstrap-cells ;
  12 : shift-arg ( -- reg ) ECX ;
  13 : div-arg ( -- reg ) EAX ;
  14 : mod-arg ( -- reg ) EDX ;
  15 : temp0 ( -- reg ) EAX ;
  16 : temp1 ( -- reg ) ECX ;
  17 : temp2 ( -- reg ) EBX ;
  18 : temp3 ( -- reg ) EDX ;
  19 : pic-tail-reg ( -- reg ) EDX ;
  20 : stack-reg ( -- reg ) ESP ;
  21 : frame-reg ( -- reg ) EBP ;
  22 : vm-reg ( -- reg ) EBX ;
  23 : ctx-reg ( -- reg ) EBP ;
  24 : nv-regs ( -- seq ) { ESI EDI EBX } ;
  25 : nv-reg ( -- reg ) ESI ;
  26 : ds-reg ( -- reg ) ESI ;
  27 : rs-reg ( -- reg ) EDI ;
  28 : fixnum>slot@ ( -- ) temp0 2 SAR ;
  29 : rex-length ( -- n ) 0 ;
  30
  31 : jit-call ( name -- )
  32     0 CALL rc-relative jit-dlsym ;
  33
  34 [
  35     ! save stack frame size
  36     stack-frame-size PUSH
  37     ! push entry point
  38     0 PUSH rc-absolute-cell rt-this jit-rel
  39     ! alignment
  40     ESP stack-frame-size 3 bootstrap-cells - SUB
  41 ] jit-prolog jit-define
  42
  43 [
  44     pic-tail-reg 0 MOV rc-absolute-cell rt-here jit-rel
  45     0 JMP rc-relative rt-entry-point-pic-tail jit-rel
  46 ] jit-word-jump jit-define
  47
  48 : jit-load-vm ( -- )
  49     vm-reg 0 MOV 0 rc-absolute-cell jit-vm ;
  50
  51 : jit-load-context ( -- )
  52     ! VM pointer must be in vm-reg already
  53     ctx-reg vm-reg vm-context-offset [+] MOV ;
  54
  55 : jit-save-context ( -- )
  56     jit-load-context
  57     ECX ESP -4 [+] LEA
  58     ctx-reg context-callstack-top-offset [+] ECX MOV
  59     ctx-reg context-datastack-offset [+] ds-reg MOV
  60     ctx-reg context-retainstack-offset [+] rs-reg MOV ;
  61
  62 : jit-restore-context ( -- )
  63     ds-reg ctx-reg context-datastack-offset [+] MOV
  64     rs-reg ctx-reg context-retainstack-offset [+] MOV ;
  65
  66 [
  67     ! ctx-reg is preserved across the call because it is non-volatile
  68     ! in the C ABI
  69     jit-load-vm
  70     jit-save-context
  71     ! call the primitive
  72     ESP [] vm-reg MOV
  73     0 CALL rc-relative rt-dlsym jit-rel
  74     jit-restore-context
  75 ] jit-primitive jit-define
  76
  77 : jit-jump-quot ( -- )
  78     EAX quot-entry-point-offset [+] JMP ;
  79
  80 : jit-call-quot ( -- )
  81     EAX quot-entry-point-offset [+] CALL ;
  82
  83 [
  84     jit-load-vm
  85     ESP [] vm-reg MOV
  86     EAX EBP 8 [+] MOV
  87     ESP 4 [+] EAX MOV
  88     "begin_callback" jit-call
  89
  90     jit-load-vm
  91     jit-load-context
  92     jit-restore-context
  93
  94     jit-call-quot
  95
  96     jit-load-vm
  97     jit-save-context
  98
  99     ESP [] vm-reg MOV
 100     "end_callback" jit-call
 101 ] \ c-to-factor define-sub-primitive
 102
 103 [
 104     EAX ds-reg [] MOV
 105     ds-reg bootstrap-cell SUB
 106 ]
 107 [ jit-call-quot ]
 108 [ jit-jump-quot ]
 109 \ (call) define-combinator-primitive
 110
 111 [
 112     ! Load ds and rs registers
 113     jit-load-vm
 114     jit-load-context
 115     jit-restore-context
 116
 117     ! Windows-specific setup
 118     ctx-reg jit-update-seh
 119
 120     ! Clear x87 stack, but preserve rounding mode and exception flags
 121     ESP 2 SUB
 122     ESP [] FNSTCW
 123     FNINIT
 124     ESP [] FLDCW
 125     ESP 2 ADD
 126
 127     ! Load arguments
 128     EAX ESP stack-frame-size [+] MOV
 129     EDX ESP stack-frame-size 4 + [+] MOV
 130
 131     ! Unwind stack frames
 132     ESP EDX MOV
 133
 134     jit-jump-quot
 135 ] \ unwind-native-frames define-sub-primitive
 136
 137 [
 138     ! Load callstack object
 139     temp3 ds-reg [] MOV
 140     ds-reg bootstrap-cell SUB
 141     ! Get ctx->callstack_bottom
 142     jit-load-vm
 143     jit-load-context
 144     temp0 ctx-reg context-callstack-bottom-offset [+] MOV
 145     ! Get top of callstack object -- 'src' for memcpy
 146     temp1 temp3 callstack-top-offset [+] LEA
 147     ! Get callstack length, in bytes --- 'len' for memcpy
 148     temp2 temp3 callstack-length-offset [+] MOV
 149     temp2 tag-bits get SHR
 150     ! Compute new stack pointer -- 'dst' for memcpy
 151     temp0 temp2 SUB
 152     ! Install new stack pointer
 153     ESP temp0 MOV
 154     ! Call memcpy
 155     temp2 PUSH
 156     temp1 PUSH
 157     temp0 PUSH
 158     "factor_memcpy" jit-call
 159     ESP 12 ADD
 160     ! Return with new callstack
 161     0 RET
 162 ] \ set-callstack define-sub-primitive
 163
 164 [
 165     jit-load-vm
 166     jit-save-context
 167
 168     ! Store arguments
 169     ESP [] EAX MOV
 170     ESP 4 [+] vm-reg MOV
 171
 172     ! Call VM
 173     "lazy_jit_compile" jit-call
 174 ]
 175 [ jit-call-quot ]
 176 [ jit-jump-quot ]
 177 \ lazy-jit-compile define-combinator-primitive
 178
 179 [
 180     temp1 HEX: ffffffff CMP rc-absolute-cell rt-literal jit-rel
 181 ] pic-check-tuple jit-define
 182
 183 ! Inline cache miss entry points
 184 : jit-load-return-address ( -- )
 185     pic-tail-reg ESP stack-frame-size bootstrap-cell - [+] MOV ;
 186
 187 ! These are always in tail position with an existing stack
 188 ! frame, and the stack. The frame setup takes this into account.
 189 : jit-inline-cache-miss ( -- )
 190     jit-load-vm
 191     jit-save-context
 192     ESP 4 [+] vm-reg MOV
 193     ESP [] pic-tail-reg MOV
 194     "inline_cache_miss" jit-call
 195     jit-restore-context ;
 196
 197 [ jit-load-return-address jit-inline-cache-miss ]
 198 [ EAX CALL ]
 199 [ EAX JMP ]
 200 \ inline-cache-miss define-combinator-primitive
 201
 202 [ jit-inline-cache-miss ]
 203 [ EAX CALL ]
 204 [ EAX JMP ]
 205 \ inline-cache-miss-tail define-combinator-primitive
 206
 207 ! Overflowing fixnum arithmetic
 208 : jit-overflow ( insn func -- )
 209     ds-reg 4 SUB
 210     jit-load-vm
 211     jit-save-context
 212     EAX ds-reg [] MOV
 213     EDX ds-reg 4 [+] MOV
 214     EBX EAX MOV
 215     [ [ EBX EDX ] dip call( dst src -- ) ] dip
 216     ds-reg [] EBX MOV
 217     [ JNO ]
 218     [
 219         ESP [] EAX MOV
 220         ESP 4 [+] EDX MOV
 221         jit-load-vm
 222         ESP 8 [+] vm-reg MOV
 223         jit-call
 224     ]
 225     jit-conditional ;
 226
 227 [ [ ADD ] "overflow_fixnum_add" jit-overflow ] \ fixnum+ define-sub-primitive
 228
 229 [ [ SUB ] "overflow_fixnum_subtract" jit-overflow ] \ fixnum- define-sub-primitive
 230
 231 [
 232     ds-reg 4 SUB
 233     jit-load-vm
 234     jit-save-context
 235     EBX ds-reg [] MOV
 236     EAX EBX MOV
 237     EBP ds-reg 4 [+] MOV
 238     EBP tag-bits get SAR
 239     EBP IMUL
 240     ds-reg [] EAX MOV
 241     [ JNO ]
 242     [
 243         EBX tag-bits get SAR
 244         ESP [] EBX MOV
 245         ESP 4 [+] EBP MOV
 246         jit-load-vm
 247         ESP 8 [+] vm-reg MOV
 248         "overflow_fixnum_multiply" jit-call
 249     ]
 250     jit-conditional
 251 ] \ fixnum* define-sub-primitive
 252
 253 ! Contexts
 254 : jit-switch-context ( reg -- )
 255     ! Dummy return address -- it never gets returned to but it
 256     ! must point to inside the current code block
 257     ESP -4 [+] HEX: ffffffff MOV rc-absolute-cell rt-this jit-rel
 258
 259     ! Save ds, rs registers
 260     jit-load-vm
 261     jit-save-context
 262
 263     ! Make the new context the current one
 264     ctx-reg swap MOV
 265     vm-reg vm-context-offset [+] ctx-reg MOV
 266
 267     ! Load new stack pointer
 268     ESP ctx-reg context-callstack-top-offset [+] MOV
 269
 270     ! Windows-specific setup
 271     ctx-reg jit-update-tib
 272
 273     ! Load new ds, rs registers
 274     jit-restore-context ;
 275
 276 : jit-set-context ( -- )
 277     ! Load context and parameter from datastack
 278     EAX ds-reg [] MOV
 279     EAX EAX alien-offset [+] MOV
 280     EDX ds-reg -4 [+] MOV
 281     ds-reg 8 SUB
 282
 283     ! Make the new context active
 284     EAX jit-switch-context
 285
 286     ! Windows-specific setup
 287     ctx-reg jit-update-seh
 288
 289     ! Twiddle stack for return
 290     ESP 4 ADD
 291
 292     ! Store parameter to datastack
 293     ds-reg 4 ADD
 294     ds-reg [] EDX MOV ;
 295
 296 [ jit-set-context ] \ (set-context) define-sub-primitive
 297
 298 : jit-start-context ( -- )
 299     ! Create the new context in return-reg
 300     jit-load-vm
 301     ESP [] vm-reg MOV
 302     "new_context" jit-call
 303
 304     ! Save pointer to quotation and parameter
 305     EDX ds-reg MOV
 306     ds-reg 8 SUB
 307
 308     ! Make the new context active
 309     EAX jit-switch-context
 310
 311     ! Push parameter
 312     EAX EDX -4 [+] MOV
 313     ds-reg 4 ADD
 314     ds-reg [] EAX MOV
 315
 316     ! Windows-specific setup
 317     jit-install-seh
 318
 319     ! Push a fake return address
 320     0 PUSH
 321
 322     ! Jump to initial quotation
 323     EAX EDX [] MOV
 324     jit-jump-quot ;
 325
 326 [ jit-start-context ] \ (start-context) define-sub-primitive
 327
 328 : jit-delete-current-context ( -- )
 329     jit-load-vm
 330     jit-load-context
 331     ESP [] vm-reg MOV
 332     ESP 4 [+] ctx-reg MOV
 333     "delete_context" jit-call ;
 334
 335 [
 336     jit-delete-current-context
 337     jit-set-context
 338 ] \ (set-context-and-delete) define-sub-primitive
 339
 340 [
 341     jit-delete-current-context
 342     jit-start-context
 343 ] \ (start-context-and-delete) define-sub-primitive