basis/cpu/x86/32/bootstrap.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bootstrap.image.private kernel kernel.private namespaces
   4 system cpu.x86.assembler cpu.x86.assembler.operands layouts
   5 vocabs parser compiler.constants sequences math math.private
   6 generic.single.private ;
   7 IN: bootstrap.x86
   8
   9 4 \ cell set
  10
  11 : stack-frame-size ( -- n ) 8 bootstrap-cells ;
  12 : shift-arg ( -- reg ) ECX ;
  13 : div-arg ( -- reg ) EAX ;
  14 : mod-arg ( -- reg ) EDX ;
  15 : temp0 ( -- reg ) EAX ;
  16 : temp1 ( -- reg ) EDX ;
  17 : temp2 ( -- reg ) ECX ;
  18 : temp3 ( -- reg ) EBX ;
  19 : safe-reg ( -- reg ) EAX ;
  20 : stack-reg ( -- reg ) ESP ;
  21 : frame-reg ( -- reg ) EBP ;
  22 : vm-reg ( -- reg ) EBP ;
  23 : ctx-reg ( -- reg ) ECX ;
  24 : nv-regs ( -- seq ) { ESI EDI EBX } ;
  25 : ds-reg ( -- reg ) ESI ;
  26 : rs-reg ( -- reg ) EDI ;
  27 : fixnum>slot@ ( -- ) temp0 2 SAR ;
  28 : rex-length ( -- n ) 0 ;
  29
  30 [
  31     ! save stack frame size
  32     stack-frame-size PUSH
  33     ! push XT
  34     0 PUSH rc-absolute-cell rt-this jit-rel
  35     ! alignment
  36     ESP stack-frame-size 3 bootstrap-cells - SUB
  37 ] jit-prolog jit-define
  38
  39 : jit-load-vm ( -- )
  40     vm-reg 0 MOV 0 rc-absolute-cell jit-vm ;
  41
  42 : jit-load-context ( -- )
  43     ! VM pointer must be in vm-reg already
  44     ctx-reg vm-reg vm-context-offset [+] MOV ;
  45
  46 : jit-save-context ( -- )
  47     jit-load-context
  48     EDX RSP -4 [+] LEA
  49     ctx-reg context-callstack-top-offset [+] EDX MOV
  50     ctx-reg context-datastack-offset [+] ds-reg MOV
  51     ctx-reg context-retainstack-offset [+] rs-reg MOV ;
  52
  53 : jit-restore-context ( -- )
  54     jit-load-context
  55     ds-reg ctx-reg context-datastack-offset [+] MOV
  56     rs-reg ctx-reg context-retainstack-offset [+] MOV ;
  57
  58 [
  59     jit-load-vm
  60     jit-save-context
  61     ! call the primitive
  62     ESP [] vm-reg MOV
  63     0 CALL rc-relative rt-primitive jit-rel
  64     ! restore ds, rs registers
  65     jit-restore-context
  66 ] jit-primitive jit-define
  67
  68 [
  69     ! Load quotation
  70     EAX EBP 8 [+] MOV
  71     ! save ctx->callstack_bottom, load ds, rs registers
  72     jit-load-vm
  73     jit-restore-context
  74     EDX stack-reg stack-frame-size 4 - [+] LEA
  75     ctx-reg context-callstack-bottom-offset [+] EDX MOV
  76     ! call the quotation
  77     EAX quot-xt-offset [+] CALL
  78     ! save ds, rs registers
  79     jit-save-context
  80 ] \ c-to-factor define-sub-primitive
  81
  82 [
  83     EAX ds-reg [] MOV
  84     ds-reg bootstrap-cell SUB
  85 ]
  86 [ EAX quot-xt-offset [+] CALL ]
  87 [ EAX quot-xt-offset [+] JMP ]
  88 \ (call) define-combinator-primitive
  89
  90 [
  91     ! Clear x87 stack, but preserve rounding mode and exception flags
  92     ESP 2 SUB
  93     ESP [] FNSTCW
  94     FNINIT
  95     ESP [] FLDCW
  96     ESP 2 ADD
  97
  98     ! Load arguments
  99     EAX ESP stack-frame-size [+] MOV
 100     EDX ESP stack-frame-size 4 + [+] MOV
 101
 102     ! Unwind stack frames
 103     ESP EDX MOV
 104
 105     ! Load ds and rs registers
 106     jit-load-vm
 107     jit-restore-context
 108
 109     ! Call quotation
 110     EAX quot-xt-offset [+] JMP
 111 ] \ unwind-native-frames define-sub-primitive
 112
 113 [
 114     ! Load callstack object
 115     EBX ds-reg [] MOV
 116     ds-reg bootstrap-cell SUB
 117     ! Get ctx->callstack_bottom
 118     jit-load-vm
 119     jit-load-context
 120     EAX ctx-reg context-callstack-bottom-offset [+] MOV
 121     ! Get top of callstack object -- 'src' for memcpy
 122     EBP EBX callstack-top-offset [+] LEA
 123     ! Get callstack length, in bytes --- 'len' for memcpy
 124     EDX EBX callstack-length-offset [+] MOV
 125     EDX tag-bits get SHR
 126     ! Compute new stack pointer -- 'dst' for memcpy
 127     EAX EDX SUB
 128     ! Install new stack pointer
 129     ESP EAX MOV
 130     ! Call memcpy
 131     EDX PUSH
 132     EBP PUSH
 133     EAX PUSH
 134     0 CALL "factor_memcpy" f rc-relative jit-dlsym
 135     ESP 12 ADD
 136     ! Return with new callstack
 137     0 RET
 138 ] \ set-callstack define-sub-primitive
 139
 140 [
 141     jit-load-vm
 142     jit-save-context
 143
 144     ! Store arguments
 145     ESP [] EAX MOV
 146     ESP 4 [+] vm-reg MOV
 147
 148     ! Call VM
 149     0 CALL "lazy_jit_compile" f rc-relative jit-dlsym
 150 ]
 151 [ EAX quot-xt-offset [+] CALL ]
 152 [ EAX quot-xt-offset [+] JMP ]
 153 \ lazy-jit-compile define-combinator-primitive
 154
 155 ! Inline cache miss entry points
 156 : jit-load-return-address ( -- )
 157     EBX ESP stack-frame-size bootstrap-cell - [+] MOV ;
 158
 159 ! These are always in tail position with an existing stack
 160 ! frame, and the stack. The frame setup takes this into account.
 161 : jit-inline-cache-miss ( -- )
 162     jit-load-vm
 163     jit-save-context
 164     ESP 4 [+] vm-reg MOV
 165     ESP [] EBX MOV
 166     0 CALL "inline_cache_miss" f rc-relative jit-dlsym
 167     jit-restore-context ;
 168
 169 [ jit-load-return-address jit-inline-cache-miss ]
 170 [ EAX CALL ]
 171 [ EAX JMP ]
 172 \ inline-cache-miss define-combinator-primitive
 173
 174 [ jit-inline-cache-miss ]
 175 [ EAX CALL ]
 176 [ EAX JMP ]
 177 \ inline-cache-miss-tail define-combinator-primitive
 178
 179 ! Overflowing fixnum arithmetic
 180 : jit-overflow ( insn func -- )
 181     ds-reg 4 SUB
 182     jit-load-vm
 183     jit-save-context
 184     EAX ds-reg [] MOV
 185     EDX ds-reg 4 [+] MOV
 186     ECX EAX MOV
 187     [ [ ECX EDX ] dip call( dst src -- ) ] dip
 188     ds-reg [] ECX MOV
 189     [ JNO ]
 190     [
 191         ESP [] EAX MOV
 192         ESP 4 [+] EDX MOV
 193         ESP 8 [+] EBP MOV
 194         [ 0 CALL ] dip f rc-relative jit-dlsym
 195     ]
 196     jit-conditional ;
 197
 198 [ [ ADD ] "overflow_fixnum_add" jit-overflow ] \ fixnum+ define-sub-primitive
 199
 200 [ [ SUB ] "overflow_fixnum_subtract" jit-overflow ] \ fixnum- define-sub-primitive
 201
 202 [
 203     ds-reg 4 SUB
 204     jit-load-vm
 205     jit-save-context
 206     ECX ds-reg [] MOV
 207     EAX ECX MOV
 208     EBX ds-reg 4 [+] MOV
 209     EBX tag-bits get SAR
 210     EBX IMUL
 211     ds-reg [] EAX MOV
 212     [ JNO ]
 213     [
 214         ECX tag-bits get SAR
 215         ESP [] ECX MOV
 216         ESP 4 [+] EBX MOV
 217         ESP 8 [+] EBP MOV
 218         0 CALL "overflow_fixnum_multiply" f rc-relative jit-dlsym
 219     ]
 220     jit-conditional
 221 ] \ fixnum* define-sub-primitive
 222
 223 << "vocab:cpu/x86/bootstrap.factor" parse-file suffix! >>
 224 call