basis/cpu/x86/32/bootstrap.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bootstrap.image.private kernel kernel.private namespaces
   4 system cpu.x86.assembler cpu.x86.assembler.operands layouts
   5 vocabs parser compiler.constants sequences math math.private
   6 generic.single.private ;
   7 IN: bootstrap.x86
   8
   9 4 \ cell set
  10
  11 : stack-frame-size ( -- n ) 8 bootstrap-cells ;
  12 : shift-arg ( -- reg ) ECX ;
  13 : div-arg ( -- reg ) EAX ;
  14 : mod-arg ( -- reg ) EDX ;
  15 : temp0 ( -- reg ) EAX ;
  16 : temp1 ( -- reg ) EDX ;
  17 : temp2 ( -- reg ) ECX ;
  18 : temp3 ( -- reg ) EBX ;
  19 : stack-reg ( -- reg ) ESP ;
  20 : frame-reg ( -- reg ) EBP ;
  21 : vm-reg ( -- reg ) ECX ;
  22 : ctx-reg ( -- reg ) EBP ;
  23 : nv-regs ( -- seq ) { ESI EDI EBX } ;
  24 : nv-reg ( -- reg ) nv-regs first ;
  25 : ds-reg ( -- reg ) ESI ;
  26 : rs-reg ( -- reg ) EDI ;
  27 : fixnum>slot@ ( -- ) temp0 2 SAR ;
  28 : rex-length ( -- n ) 0 ;
  29
  30 : jit-call ( name -- )
  31     0 CALL rc-relative jit-dlsym ;
  32
  33 [
  34     ! save stack frame size
  35     stack-frame-size PUSH
  36     ! push entry point
  37     0 PUSH rc-absolute-cell rt-this jit-rel
  38     ! alignment
  39     ESP stack-frame-size 3 bootstrap-cells - SUB
  40 ] jit-prolog jit-define
  41
  42 [
  43     temp3 0 MOV rc-absolute-cell rt-here jit-rel
  44     0 JMP rc-relative rt-entry-point-pic-tail jit-rel
  45 ] jit-word-jump jit-define
  46
  47 : jit-load-vm ( -- )
  48     vm-reg 0 MOV 0 rc-absolute-cell jit-vm ;
  49
  50 : jit-load-context ( -- )
  51     ! VM pointer must be in vm-reg already
  52     ctx-reg vm-reg vm-context-offset [+] MOV ;
  53
  54 : jit-save-context ( -- )
  55     EDX ESP -4 [+] LEA
  56     ctx-reg context-callstack-top-offset [+] EDX MOV
  57     ctx-reg context-datastack-offset [+] ds-reg MOV
  58     ctx-reg context-retainstack-offset [+] rs-reg MOV ;
  59
  60 : jit-restore-context ( -- )
  61     ds-reg ctx-reg context-datastack-offset [+] MOV
  62     rs-reg ctx-reg context-retainstack-offset [+] MOV ;
  63
  64 [
  65     jit-load-vm
  66     jit-load-context
  67     jit-save-context
  68     ! call the primitive
  69     ESP [] vm-reg MOV
  70     0 CALL rc-relative rt-dlsym jit-rel
  71     ! restore ds, rs registers
  72     jit-restore-context
  73 ] jit-primitive jit-define
  74
  75 [
  76     jit-load-vm
  77     ESP [] vm-reg MOV
  78     "begin_callback" jit-call
  79
  80     ! load quotation - EBP is ctx-reg so it will get clobbered
  81     ! later on
  82     EAX EBP 8 [+] MOV
  83
  84     jit-load-vm
  85     jit-load-context
  86     jit-restore-context
  87
  88     ! save C callstack pointer
  89     ctx-reg context-callstack-save-offset [+] ESP MOV
  90
  91     ! load Factor callstack pointer
  92     ESP ctx-reg context-callstack-bottom-offset [+] MOV
  93     ESP 4 ADD
  94
  95     ! call the quotation
  96     EAX quot-entry-point-offset [+] CALL
  97
  98     jit-load-vm
  99     jit-load-context
 100     jit-save-context
 101
 102     ! load C callstack pointer
 103     ESP ctx-reg context-callstack-save-offset [+] MOV
 104
 105     ESP [] vm-reg MOV
 106     "end_callback" jit-call
 107 ] \ c-to-factor define-sub-primitive
 108
 109 [
 110     EAX ds-reg [] MOV
 111     ds-reg bootstrap-cell SUB
 112 ]
 113 [ EAX quot-entry-point-offset [+] CALL ]
 114 [ EAX quot-entry-point-offset [+] JMP ]
 115 \ (call) define-combinator-primitive
 116
 117 [
 118     ! Clear x87 stack, but preserve rounding mode and exception flags
 119     ESP 2 SUB
 120     ESP [] FNSTCW
 121     FNINIT
 122     ESP [] FLDCW
 123     ESP 2 ADD
 124
 125     ! Load arguments
 126     EAX ESP stack-frame-size [+] MOV
 127     EDX ESP stack-frame-size 4 + [+] MOV
 128
 129     ! Unwind stack frames
 130     ESP EDX MOV
 131
 132     ! Load ds and rs registers
 133     jit-load-vm
 134     jit-load-context
 135     jit-restore-context
 136
 137     ! Call quotation
 138     EAX quot-entry-point-offset [+] JMP
 139 ] \ unwind-native-frames define-sub-primitive
 140
 141 [
 142     ! Load callstack object
 143     EBX ds-reg [] MOV
 144     ds-reg bootstrap-cell SUB
 145     ! Get ctx->callstack_bottom
 146     jit-load-vm
 147     jit-load-context
 148     EAX ctx-reg context-callstack-bottom-offset [+] MOV
 149     ! Get top of callstack object -- 'src' for memcpy
 150     EBP EBX callstack-top-offset [+] LEA
 151     ! Get callstack length, in bytes --- 'len' for memcpy
 152     EDX EBX callstack-length-offset [+] MOV
 153     EDX tag-bits get SHR
 154     ! Compute new stack pointer -- 'dst' for memcpy
 155     EAX EDX SUB
 156     ! Install new stack pointer
 157     ESP EAX MOV
 158     ! Call memcpy
 159     EDX PUSH
 160     EBP PUSH
 161     EAX PUSH
 162     "factor_memcpy" jit-call
 163     ESP 12 ADD
 164     ! Return with new callstack
 165     0 RET
 166 ] \ set-callstack define-sub-primitive
 167
 168 [
 169     jit-load-vm
 170     jit-load-context
 171     jit-save-context
 172
 173     ! Store arguments
 174     ESP [] EAX MOV
 175     ESP 4 [+] vm-reg MOV
 176
 177     ! Call VM
 178     "lazy_jit_compile" jit-call
 179 ]
 180 [ EAX quot-entry-point-offset [+] CALL ]
 181 [ EAX quot-entry-point-offset [+] JMP ]
 182 \ lazy-jit-compile define-combinator-primitive
 183
 184 ! Inline cache miss entry points
 185 : jit-load-return-address ( -- )
 186     EBX ESP stack-frame-size bootstrap-cell - [+] MOV ;
 187
 188 ! These are always in tail position with an existing stack
 189 ! frame, and the stack. The frame setup takes this into account.
 190 : jit-inline-cache-miss ( -- )
 191     jit-load-vm
 192     jit-load-context
 193     jit-save-context
 194     ESP 4 [+] vm-reg MOV
 195     ESP [] EBX MOV
 196     "inline_cache_miss" jit-call
 197     jit-restore-context ;
 198
 199 [ jit-load-return-address jit-inline-cache-miss ]
 200 [ EAX CALL ]
 201 [ EAX JMP ]
 202 \ inline-cache-miss define-combinator-primitive
 203
 204 [ jit-inline-cache-miss ]
 205 [ EAX CALL ]
 206 [ EAX JMP ]
 207 \ inline-cache-miss-tail define-combinator-primitive
 208
 209 ! Overflowing fixnum arithmetic
 210 : jit-overflow ( insn func -- )
 211     ds-reg 4 SUB
 212     jit-load-vm
 213     jit-load-context
 214     jit-save-context
 215     EAX ds-reg [] MOV
 216     EDX ds-reg 4 [+] MOV
 217     EBX EAX MOV
 218     [ [ EBX EDX ] dip call( dst src -- ) ] dip
 219     ds-reg [] EBX MOV
 220     [ JNO ]
 221     [
 222         ESP [] EAX MOV
 223         ESP 4 [+] EDX MOV
 224         ESP 8 [+] vm-reg MOV
 225         jit-call
 226     ]
 227     jit-conditional ;
 228
 229 [ [ ADD ] "overflow_fixnum_add" jit-overflow ] \ fixnum+ define-sub-primitive
 230
 231 [ [ SUB ] "overflow_fixnum_subtract" jit-overflow ] \ fixnum- define-sub-primitive
 232
 233 [
 234     ds-reg 4 SUB
 235     jit-load-vm
 236     jit-load-context
 237     jit-save-context
 238     EBX ds-reg [] MOV
 239     EAX EBX MOV
 240     EBP ds-reg 4 [+] MOV
 241     EBP tag-bits get SAR
 242     EBP IMUL
 243     ds-reg [] EAX MOV
 244     [ JNO ]
 245     [
 246         EBX tag-bits get SAR
 247         ESP [] EBX MOV
 248         ESP 4 [+] EBP MOV
 249         ESP 8 [+] vm-reg MOV
 250         "overflow_fixnum_multiply" jit-call
 251     ]
 252     jit-conditional
 253 ] \ fixnum* define-sub-primitive
 254
 255 << "vocab:cpu/x86/bootstrap.factor" parse-file suffix! >>
 256 call