basis/cpu/x86/32/bootstrap.factor

   1 ! Copyright (C) 2007, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bootstrap.image.private kernel kernel.private namespaces
   4 system cpu.x86.assembler cpu.x86.assembler.operands layouts
   5 vocabs parser compiler.constants sequences math math.private
   6 generic.single.private ;
   7 IN: bootstrap.x86
   8
   9 4 \ cell set
  10
  11 : stack-frame-size ( -- n ) 8 bootstrap-cells ;
  12 : shift-arg ( -- reg ) ECX ;
  13 : div-arg ( -- reg ) EAX ;
  14 : mod-arg ( -- reg ) EDX ;
  15 : temp0 ( -- reg ) EAX ;
  16 : temp1 ( -- reg ) EDX ;
  17 : temp2 ( -- reg ) ECX ;
  18 : temp3 ( -- reg ) EBX ;
  19 : safe-reg ( -- reg ) EAX ;
  20 : stack-reg ( -- reg ) ESP ;
  21 : frame-reg ( -- reg ) EBP ;
  22 : nv-regs ( -- seq ) { ESI EDI EBX } ;
  23 : ds-reg ( -- reg ) ESI ;
  24 : rs-reg ( -- reg ) EDI ;
  25 : fixnum>slot@ ( -- ) temp0 2 SAR ;
  26 : rex-length ( -- n ) 0 ;
  27
  28 [
  29     ! save stack frame size
  30     stack-frame-size PUSH
  31     ! push XT
  32     0 PUSH rc-absolute-cell rt-this jit-rel
  33     ! alignment
  34     ESP stack-frame-size 3 bootstrap-cells - SUB
  35 ] jit-prolog jit-define
  36
  37 : jit-load-vm ( -- )
  38     EBP 0 MOV 0 rc-absolute-cell jit-vm ;
  39
  40 : jit-save-context ( -- )
  41     ! VM pointer must be in EBP already
  42     ECX EBP [] MOV
  43     ! save ctx->callstack_top
  44     EAX ESP -4 [+] LEA
  45     ECX [] EAX MOV
  46     ! save ctx->datastack
  47     ECX 8 [+] ds-reg MOV
  48     ! save ctx->retainstack
  49     ECX 12 [+] rs-reg MOV ;
  50
  51 : jit-restore-context ( -- )
  52     ! VM pointer must be in EBP already
  53     ECX EBP [] MOV
  54     ! restore ctx->datastack
  55     ds-reg ECX 8 [+] MOV
  56     ! restore ctx->retainstack
  57     rs-reg ECX 12 [+] MOV ;
  58
  59 [
  60     jit-load-vm
  61     ! save ds, rs registers
  62     jit-save-context
  63     ! call the primitive
  64     ESP [] EBP MOV
  65     0 CALL rc-relative rt-primitive jit-rel
  66     ! restore ds, rs registers
  67     jit-restore-context
  68 ] jit-primitive jit-define
  69
  70 [
  71     ! load from stack
  72     EAX ds-reg [] MOV
  73     ! pop stack
  74     ds-reg bootstrap-cell SUB
  75     ! load VM pointer
  76     EDX 0 MOV 0 rc-absolute-cell jit-vm
  77 ]
  78 [ EAX quot-xt-offset [+] CALL ]
  79 [ EAX quot-xt-offset [+] JMP ]
  80 \ (call) define-combinator-primitive
  81
  82 ! Inline cache miss entry points
  83 : jit-load-return-address ( -- )
  84     EBX ESP stack-frame-size bootstrap-cell - [+] MOV ;
  85
  86 ! These are always in tail position with an existing stack
  87 ! frame, and the stack. The frame setup takes this into account.
  88 : jit-inline-cache-miss ( -- )
  89     jit-load-vm
  90     jit-save-context
  91     ESP 4 [+] EBP MOV
  92     ESP [] EBX MOV
  93     0 CALL "inline_cache_miss" f rc-relative jit-dlsym
  94     jit-restore-context ;
  95
  96 [ jit-load-return-address jit-inline-cache-miss ]
  97 [ EAX CALL ]
  98 [ EAX JMP ]
  99 \ inline-cache-miss define-combinator-primitive
 100
 101 [ jit-inline-cache-miss ]
 102 [ EAX CALL ]
 103 [ EAX JMP ]
 104 \ inline-cache-miss-tail define-combinator-primitive
 105
 106 ! Overflowing fixnum arithmetic
 107 : jit-overflow ( insn func -- )
 108     ds-reg 4 SUB
 109     jit-load-vm
 110     jit-save-context
 111     EAX ds-reg [] MOV
 112     EDX ds-reg 4 [+] MOV
 113     ECX EAX MOV
 114     [ [ ECX EDX ] dip call( dst src -- ) ] dip
 115     ds-reg [] ECX MOV
 116     [ JNO ]
 117     [
 118         ESP [] EAX MOV
 119         ESP 4 [+] EDX MOV
 120         ESP 8 [+] EBP MOV
 121         [ 0 CALL ] dip f rc-relative jit-dlsym
 122     ]
 123     jit-conditional ;
 124
 125 [ [ ADD ] "overflow_fixnum_add" jit-overflow ] \ fixnum+ define-sub-primitive
 126
 127 [ [ SUB ] "overflow_fixnum_subtract" jit-overflow ] \ fixnum- define-sub-primitive
 128
 129 [
 130     ds-reg 4 SUB
 131     jit-load-vm
 132     jit-save-context
 133     ECX ds-reg [] MOV
 134     EAX ECX MOV
 135     EBX ds-reg 4 [+] MOV
 136     EBX tag-bits get SAR
 137     EBX IMUL
 138     ds-reg [] EAX MOV
 139     [ JNO ]
 140     [
 141         ECX tag-bits get SAR
 142         ESP [] ECX MOV
 143         ESP 4 [+] EBX MOV
 144         ESP 8 [+] EBP MOV
 145         0 CALL "overflow_fixnum_multiply" f rc-relative jit-dlsym
 146     ]
 147     jit-conditional
 148 ] \ fixnum* define-sub-primitive
 149
 150 << "vocab:cpu/x86/bootstrap.factor" parse-file suffix! >>
 151 call