basis/cpu/x86/32/bootstrap.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: bootstrap.image.private kernel kernel.private namespaces
   4 system cpu.x86.assembler cpu.x86.assembler.operands layouts
   5 vocabs parser compiler.constants sequences math math.private
   6 generic.single.private ;
   7 IN: bootstrap.x86
   8
   9 4 \ cell set
  10
  11 : stack-frame-size ( -- n ) 8 bootstrap-cells ;
  12 : shift-arg ( -- reg ) ECX ;
  13 : div-arg ( -- reg ) EAX ;
  14 : mod-arg ( -- reg ) EDX ;
  15 : temp0 ( -- reg ) EAX ;
  16 : temp1 ( -- reg ) EDX ;
  17 : temp2 ( -- reg ) ECX ;
  18 : temp3 ( -- reg ) EBX ;
  19 : safe-reg ( -- reg ) EAX ;
  20 : stack-reg ( -- reg ) ESP ;
  21 : frame-reg ( -- reg ) EBP ;
  22 : vm-reg ( -- reg ) EBP ;
  23 : ctx-reg ( -- reg ) ECX ;
  24 : nv-regs ( -- seq ) { ESI EDI EBX } ;
  25 : ds-reg ( -- reg ) ESI ;
  26 : rs-reg ( -- reg ) EDI ;
  27 : fixnum>slot@ ( -- ) temp0 2 SAR ;
  28 : rex-length ( -- n ) 0 ;
  29
  30 [
  31     ! save stack frame size
  32     stack-frame-size PUSH
  33     ! push XT
  34     0 PUSH rc-absolute-cell rt-this jit-rel
  35     ! alignment
  36     ESP stack-frame-size 3 bootstrap-cells - SUB
  37 ] jit-prolog jit-define
  38
  39 : jit-load-vm ( -- )
  40     vm-reg 0 MOV 0 rc-absolute-cell jit-vm ;
  41
  42 : jit-load-context ( -- )
  43     ! VM pointer must be in vm-reg already
  44     ctx-reg vm-reg vm-context-offset [+] MOV ;
  45
  46 : jit-save-context ( -- )
  47     jit-load-context
  48     EDX RSP -4 [+] LEA
  49     ctx-reg context-callstack-top-offset [+] EDX MOV
  50     ctx-reg context-datastack-offset [+] ds-reg MOV
  51     ctx-reg context-retainstack-offset [+] rs-reg MOV ;
  52
  53 : jit-restore-context ( -- )
  54     jit-load-context
  55     ds-reg ctx-reg context-datastack-offset [+] MOV
  56     rs-reg ctx-reg context-retainstack-offset [+] MOV ;
  57
  58 [
  59     jit-load-vm
  60     jit-save-context
  61     ! call the primitive
  62     ESP [] vm-reg MOV
  63     0 CALL rc-relative rt-primitive jit-rel
  64     ! restore ds, rs registers
  65     jit-restore-context
  66 ] jit-primitive jit-define
  67
  68 [
  69     ! Load quotation
  70     EAX EBP 8 [+] MOV
  71     ! save ctx->callstack_bottom, load ds, rs registers
  72     jit-load-vm
  73     jit-restore-context
  74     EDX stack-reg stack-frame-size 4 - [+] LEA
  75     ctx-reg context-callstack-bottom-offset [+] EDX MOV
  76     ! call the quotation
  77     EAX quot-xt-offset [+] CALL
  78     ! save ds, rs registers
  79     jit-load-vm
  80     jit-save-context
  81 ] \ c-to-factor define-sub-primitive
  82
  83 [
  84     EAX ds-reg [] MOV
  85     ds-reg bootstrap-cell SUB
  86 ]
  87 [ EAX quot-xt-offset [+] CALL ]
  88 [ EAX quot-xt-offset [+] JMP ]
  89 \ (call) define-combinator-primitive
  90
  91 [
  92     ! Clear x87 stack, but preserve rounding mode and exception flags
  93     ESP 2 SUB
  94     ESP [] FNSTCW
  95     FNINIT
  96     ESP [] FLDCW
  97     ESP 2 ADD
  98
  99     ! Load arguments
 100     EAX ESP stack-frame-size [+] MOV
 101     EDX ESP stack-frame-size 4 + [+] MOV
 102
 103     ! Unwind stack frames
 104     ESP EDX MOV
 105
 106     ! Load ds and rs registers
 107     jit-load-vm
 108     jit-restore-context
 109
 110     ! Call quotation
 111     EAX quot-xt-offset [+] JMP
 112 ] \ unwind-native-frames define-sub-primitive
 113
 114 [
 115     ! Load callstack object
 116     EBX ds-reg [] MOV
 117     ds-reg bootstrap-cell SUB
 118     ! Get ctx->callstack_bottom
 119     jit-load-vm
 120     jit-load-context
 121     EAX ctx-reg context-callstack-bottom-offset [+] MOV
 122     ! Get top of callstack object -- 'src' for memcpy
 123     EBP EBX callstack-top-offset [+] LEA
 124     ! Get callstack length, in bytes --- 'len' for memcpy
 125     EDX EBX callstack-length-offset [+] MOV
 126     EDX tag-bits get SHR
 127     ! Compute new stack pointer -- 'dst' for memcpy
 128     EAX EDX SUB
 129     ! Install new stack pointer
 130     ESP EAX MOV
 131     ! Call memcpy
 132     EDX PUSH
 133     EBP PUSH
 134     EAX PUSH
 135     0 CALL "factor_memcpy" f rc-relative jit-dlsym
 136     ESP 12 ADD
 137     ! Return with new callstack
 138     0 RET
 139 ] \ set-callstack define-sub-primitive
 140
 141 [
 142     jit-load-vm
 143     jit-save-context
 144
 145     ! Store arguments
 146     ESP [] EAX MOV
 147     ESP 4 [+] vm-reg MOV
 148
 149     ! Call VM
 150     0 CALL "lazy_jit_compile" f rc-relative jit-dlsym
 151 ]
 152 [ EAX quot-xt-offset [+] CALL ]
 153 [ EAX quot-xt-offset [+] JMP ]
 154 \ lazy-jit-compile define-combinator-primitive
 155
 156 ! Inline cache miss entry points
 157 : jit-load-return-address ( -- )
 158     EBX ESP stack-frame-size bootstrap-cell - [+] MOV ;
 159
 160 ! These are always in tail position with an existing stack
 161 ! frame, and the stack. The frame setup takes this into account.
 162 : jit-inline-cache-miss ( -- )
 163     jit-load-vm
 164     jit-save-context
 165     ESP 4 [+] vm-reg MOV
 166     ESP [] EBX MOV
 167     0 CALL "inline_cache_miss" f rc-relative jit-dlsym
 168     jit-restore-context ;
 169
 170 [ jit-load-return-address jit-inline-cache-miss ]
 171 [ EAX CALL ]
 172 [ EAX JMP ]
 173 \ inline-cache-miss define-combinator-primitive
 174
 175 [ jit-inline-cache-miss ]
 176 [ EAX CALL ]
 177 [ EAX JMP ]
 178 \ inline-cache-miss-tail define-combinator-primitive
 179
 180 ! Overflowing fixnum arithmetic
 181 : jit-overflow ( insn func -- )
 182     ds-reg 4 SUB
 183     jit-load-vm
 184     jit-save-context
 185     EAX ds-reg [] MOV
 186     EDX ds-reg 4 [+] MOV
 187     ECX EAX MOV
 188     [ [ ECX EDX ] dip call( dst src -- ) ] dip
 189     ds-reg [] ECX MOV
 190     [ JNO ]
 191     [
 192         ESP [] EAX MOV
 193         ESP 4 [+] EDX MOV
 194         ESP 8 [+] EBP MOV
 195         [ 0 CALL ] dip f rc-relative jit-dlsym
 196     ]
 197     jit-conditional ;
 198
 199 [ [ ADD ] "overflow_fixnum_add" jit-overflow ] \ fixnum+ define-sub-primitive
 200
 201 [ [ SUB ] "overflow_fixnum_subtract" jit-overflow ] \ fixnum- define-sub-primitive
 202
 203 [
 204     ds-reg 4 SUB
 205     jit-load-vm
 206     jit-save-context
 207     ECX ds-reg [] MOV
 208     EAX ECX MOV
 209     EBX ds-reg 4 [+] MOV
 210     EBX tag-bits get SAR
 211     EBX IMUL
 212     ds-reg [] EAX MOV
 213     [ JNO ]
 214     [
 215         ECX tag-bits get SAR
 216         ESP [] ECX MOV
 217         ESP 4 [+] EBX MOV
 218         ESP 8 [+] EBP MOV
 219         0 CALL "overflow_fixnum_multiply" f rc-relative jit-dlsym
 220     ]
 221     jit-conditional
 222 ] \ fixnum* define-sub-primitive
 223
 224 << "vocab:cpu/x86/bootstrap.factor" parse-file suffix! >>
 225 call