basis/cpu/x86/64/64.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel math namespaces make sequences system
   4 layouts alien alien.c-types alien.accessors slots
   5 splitting assocs combinators locals compiler.constants
   6 compiler.codegen compiler.codegen.fixup compiler.cfg.instructions
   7 compiler.cfg.builder compiler.cfg.intrinsics compiler.cfg.stack-frame
   8 cpu.x86.assembler cpu.x86.assembler.operands cpu.x86 cpu.architecture ;
   9 IN: cpu.x86.64
  10
  11 M: x86.64 machine-registers
  12     {
  13         { int-regs { RAX RCX RDX RBX RBP RSI RDI R8 R9 R10 R11 R12 R13 } }
  14         { float-regs {
  15             XMM0 XMM1 XMM2 XMM3 XMM4 XMM5 XMM6 XMM7
  16             XMM8 XMM9 XMM10 XMM11 XMM12 XMM13 XMM14 XMM15
  17         } }
  18     } ;
  19
  20 M: x86.64 ds-reg R14 ;
  21 M: x86.64 rs-reg R15 ;
  22 M: x86.64 stack-reg RSP ;
  23
  24 M:: x86.64 %dispatch ( src temp -- )
  25     building get length :> start
  26     ! Load jump table base.
  27     temp HEX: ffffffff MOV
  28     0 rc-absolute-cell rel-here
  29     ! Add jump table base
  30     temp src ADD
  31     temp HEX: 7f [+] JMP
  32     building get length :> end
  33     ! Fix up the displacement above
  34     cell code-alignment
  35     [ end start - 2 - + building get dup pop* push ]
  36     [ align-code ]
  37     bi ;
  38
  39 M: x86.64 param-reg-1 int-regs param-regs first ;
  40 M: x86.64 param-reg-2 int-regs param-regs second ;
  41 : param-reg-3 ( -- reg ) int-regs param-regs third ; inline
  42
  43 M: x86.64 pic-tail-reg RBX ;
  44
  45 M: int-regs return-reg drop RAX ;
  46 M: float-regs return-reg drop XMM0 ;
  47
  48 M: x86.64 %prologue ( n -- )
  49     temp-reg 0 MOV rc-absolute-cell rel-this
  50     dup PUSH
  51     temp-reg PUSH
  52     stack-reg swap 3 cells - SUB ;
  53
  54 M: stack-params copy-register*
  55     drop
  56     {
  57         { [ dup  integer? ] [ R11 swap next-stack@ MOV  R11 MOV ] }
  58         { [ over integer? ] [ R11 swap MOV              param@ R11 MOV ] }
  59     } cond ;
  60
  61 M: x86 %save-param-reg [ param@ ] 2dip copy-register ;
  62
  63 M: x86 %load-param-reg [ swap param@ ] dip copy-register ;
  64
  65 : with-return-regs ( quot -- )
  66     [
  67         V{ RDX RAX } clone int-regs set
  68         V{ XMM1 XMM0 } clone float-regs set
  69         call
  70     ] with-scope ; inline
  71
  72 M: x86.64 %prepare-unbox ( -- )
  73     ! First parameter is top of stack
  74     param-reg-1 R14 [] MOV
  75     R14 cell SUB ;
  76
  77 M:: x86.64 %unbox ( n rep func -- )
  78     ! Call the unboxer
  79     func f %alien-invoke
  80     ! Store the return value on the C stack if this is an
  81     ! alien-invoke, otherwise leave it the return register if
  82     ! this is the end of alien-callback
  83     n [ n rep reg-class-of return-reg rep %save-param-reg ] when ;
  84
  85 M: x86.64 %unbox-long-long ( n func -- )
  86     [ int-rep ] dip %unbox ;
  87
  88 : %unbox-struct-field ( c-type i -- )
  89     ! Alien must be in param-reg-1.
  90     R11 swap cells [+] swap rep>> reg-class-of {
  91         { int-regs [ int-regs get pop swap MOV ] }
  92         { float-regs [ float-regs get pop swap MOVSD ] }
  93     } case ;
  94
  95 M: x86.64 %unbox-small-struct ( c-type -- )
  96     ! Alien must be in param-reg-1.
  97     "alien_offset" f %alien-invoke
  98     ! Move alien_offset() return value to R11 so that we don't
  99     ! clobber it.
 100     R11 RAX MOV
 101     [
 102         flatten-value-type [ %unbox-struct-field ] each-index
 103     ] with-return-regs ;
 104
 105 M:: x86.64 %unbox-large-struct ( n c-type -- )
 106     ! Source is in param-reg-1
 107     ! Load destination address into param-reg-2
 108     param-reg-2 n param@ LEA
 109     ! Load structure size into param-reg-3
 110     param-reg-3 c-type heap-size MOV
 111     ! Copy the struct to the C stack
 112     "to_value_struct" f %alien-invoke ;
 113
 114 : load-return-value ( rep -- )
 115     [ [ 0 ] dip reg-class-of param-reg ]
 116     [ reg-class-of return-reg ]
 117     [ ]
 118     tri copy-register ;
 119
 120 M:: x86.64 %box ( n rep func -- )
 121     n [
 122         n
 123         0 rep reg-class-of param-reg
 124         rep %load-param-reg
 125     ] [
 126         rep load-return-value
 127     ] if
 128     func f %alien-invoke ;
 129
 130 M: x86.64 %box-long-long ( n func -- )
 131     [ int-rep ] dip %box ;
 132
 133 : box-struct-field@ ( i -- operand ) 1 + cells param@ ;
 134
 135 : %box-struct-field ( c-type i -- )
 136     box-struct-field@ swap c-type-rep reg-class-of {
 137         { int-regs [ int-regs get pop MOV ] }
 138         { float-regs [ float-regs get pop MOVSD ] }
 139     } case ;
 140
 141 M: x86.64 %box-small-struct ( c-type -- )
 142     #! Box a <= 16-byte struct.
 143     [
 144         [ flatten-value-type [ %box-struct-field ] each-index ]
 145         [ param-reg-3 swap heap-size MOV ] bi
 146         param-reg-1 0 box-struct-field@ MOV
 147         param-reg-2 1 box-struct-field@ MOV
 148         "box_small_struct" f %alien-invoke
 149     ] with-return-regs ;
 150
 151 : struct-return@ ( n -- operand )
 152     [ stack-frame get params>> ] unless* param@ ;
 153
 154 M: x86.64 %box-large-struct ( n c-type -- )
 155     ! Struct size is parameter 2
 156     param-reg-2 swap heap-size MOV
 157     ! Compute destination address
 158     param-reg-1 swap struct-return@ LEA
 159     ! Copy the struct from the C stack
 160     "box_value_struct" f %alien-invoke ;
 161
 162 M: x86.64 %prepare-box-struct ( -- )
 163     ! Compute target address for value struct return
 164     RAX f struct-return@ LEA
 165     ! Store it as the first parameter
 166     0 param@ RAX MOV ;
 167
 168 M: x86.64 %prepare-var-args RAX RAX XOR ;
 169
 170 M: x86.64 %alien-invoke
 171     R11 0 MOV
 172     rc-absolute-cell rel-dlsym
 173     R11 CALL ;
 174
 175 M: x86.64 %vm-invoke-1st-arg ( function -- )
 176     param-reg-1 0 MOV rc-absolute-cell rt-vm rel-fixup
 177     f %alien-invoke ;
 178
 179 M: x86.64 %vm-invoke-3rd-arg ( function -- )
 180     param-reg-3 0 MOV rc-absolute-cell rt-vm rel-fixup
 181     f %alien-invoke ;
 182
 183 M: x86.64 %prepare-alien-indirect ( -- )
 184     "unbox_alien" f %alien-invoke
 185     RBP RAX MOV ;
 186
 187 M: x86.64 %alien-indirect ( -- )
 188     RBP CALL ;
 189
 190 M: x86.64 %alien-callback ( quot -- )
 191     param-reg-1 swap %load-reference
 192     "c_to_factor" f %alien-invoke ;
 193
 194 M: x86.64 %callback-value ( ctype -- )
 195     ! Save top of data stack
 196     %prepare-unbox
 197     ! Save top of data stack
 198     RSP 8 SUB
 199     param-reg-1 PUSH
 200     ! Restore data/call/retain stacks
 201     "unnest_stacks" f %alien-invoke
 202     ! Put former top of data stack in param-reg-1
 203     param-reg-1 POP
 204     RSP 8 ADD
 205     ! Unbox former top of data stack to return registers
 206     unbox-return ;
 207
 208 : float-function-param ( i spill-slot -- )
 209     [ float-regs param-regs nth ] [ n>> spill@ ] bi* MOVSD ;
 210
 211 : float-function-return ( reg -- )
 212     float-regs return-reg double-rep copy-register ;
 213
 214 M:: x86.64 %unary-float-function ( dst src func -- )
 215     0 src float-function-param
 216     func f %alien-invoke
 217     dst float-function-return ;
 218
 219 M:: x86.64 %binary-float-function ( dst src1 src2 func -- )
 220     0 src1 float-function-param
 221     1 src2 float-function-param
 222     func f %alien-invoke
 223     dst float-function-return ;
 224
 225 ! The result of reading 4 bytes from memory is a fixnum on
 226 ! x86-64.
 227 enable-alien-4-intrinsics
 228
 229 ! Enable fast calling of libc math functions
 230 enable-float-functions
 231
 232 USE: vocabs.loader
 233
 234 {
 235     { [ os unix? ] [ "cpu.x86.64.unix" require ] }
 236     { [ os winnt? ] [ "cpu.x86.64.winnt" require ] }
 237 } cond
 238
 239 "cpu.x86.features" require