basis/cpu/x86/64/64.factor

   1 ! Copyright (C) 2005, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays kernel math namespaces make sequences
   4 system layouts alien alien.c-types alien.accessors alien.libraries
   5 slots splitting assocs combinators locals compiler.constants
   6 compiler.codegen compiler.codegen.fixup
   7 compiler.cfg.instructions compiler.cfg.builder
   8 compiler.cfg.intrinsics compiler.cfg.stack-frame
   9 cpu.x86.assembler cpu.x86.assembler.operands cpu.x86
  10 cpu.architecture vm ;
  11 FROM: layouts => cell cells ;
  12 IN: cpu.x86.64
  13
  14 : param-reg-0 ( -- reg ) 0 int-regs param-reg ; inline
  15 : param-reg-1 ( -- reg ) 1 int-regs param-reg ; inline
  16 : param-reg-2 ( -- reg ) 2 int-regs param-reg ; inline
  17 : param-reg-3 ( -- reg ) 3 int-regs param-reg ; inline
  18
  19 M: x86.64 pic-tail-reg RBX ;
  20
  21 M: int-regs return-reg drop RAX ;
  22 M: float-regs return-reg drop XMM0 ;
  23
  24 M: x86.64 ds-reg R14 ;
  25 M: x86.64 rs-reg R15 ;
  26 M: x86.64 stack-reg RSP ;
  27 M: x86.64 frame-reg RBP ;
  28
  29 M: x86.64 extra-stack-space drop 0 ;
  30
  31 M: x86.64 machine-registers
  32     {
  33         { int-regs { RAX RCX RDX RBX RBP RSI RDI R8 R9 R10 R11 R12 } }
  34         { float-regs {
  35             XMM0 XMM1 XMM2 XMM3 XMM4 XMM5 XMM6 XMM7
  36             XMM8 XMM9 XMM10 XMM11 XMM12 XMM13 XMM14 XMM15
  37         } }
  38     } ;
  39
  40 : vm-reg ( -- reg ) R13 ; inline
  41
  42 M: x86.64 %mov-vm-ptr ( reg -- )
  43     vm-reg MOV ;
  44
  45 M: x86.64 %vm-field-ptr ( dst field -- )
  46     [ vm-reg ] dip vm-field-offset [+] LEA ;
  47
  48 : param@ ( n -- op ) reserved-stack-space + stack@ ;
  49
  50 M: x86.64 %prologue ( n -- )
  51     temp-reg 0 MOV rc-absolute-cell rel-this
  52     dup PUSH
  53     temp-reg PUSH
  54     stack-reg swap 3 cells - SUB ;
  55
  56 : load-cards-offset ( dst -- )
  57     0 MOV rc-absolute-cell rel-cards-offset ;
  58
  59 M: x86.64 %mark-card
  60     dup load-cards-offset
  61     [+] card-mark <byte> MOV ;
  62
  63 : load-decks-offset ( dst -- )
  64     0 MOV rc-absolute-cell rel-decks-offset ;
  65
  66 M: x86.64 %mark-deck
  67     dup load-decks-offset
  68     [+] card-mark <byte> MOV ;
  69
  70 M:: x86.64 %dispatch ( src temp -- )
  71     ! Load jump table base.
  72     temp HEX: ffffffff MOV
  73     building get length :> start
  74     0 rc-absolute-cell rel-here
  75     ! Add jump table base
  76     temp src ADD
  77     temp HEX: 7f [+] JMP
  78     building get length :> end
  79     ! Fix up the displacement above
  80     cell code-alignment
  81     [ end start - + building get dup pop* push ]
  82     [ align-code ]
  83     bi ;
  84
  85 M: stack-params copy-register*
  86     drop
  87     {
  88         { [ dup  integer? ] [ R11 swap next-stack@ MOV  R11 MOV ] }
  89         { [ over integer? ] [ R11 swap MOV              param@ R11 MOV ] }
  90     } cond ;
  91
  92 M: x86.64 %save-param-reg [ param@ ] 2dip %copy ;
  93
  94 M: x86.64 %load-param-reg [ swap param@ ] dip %copy ;
  95
  96 : with-return-regs ( quot -- )
  97     [
  98         V{ RDX RAX } clone int-regs set
  99         V{ XMM1 XMM0 } clone float-regs set
 100         call
 101     ] with-scope ; inline
 102
 103 M: x86.64 %pop-stack ( n -- )
 104     param-reg-0 swap ds-reg reg-stack MOV ;
 105
 106 M: x86.64 %pop-context-stack ( -- )
 107     temp-reg %load-context-datastack
 108     param-reg-0 temp-reg [] MOV
 109     param-reg-0 param-reg-0 [] MOV
 110     temp-reg [] bootstrap-cell SUB ;
 111
 112 M:: x86.64 %unbox ( n rep func -- )
 113     param-reg-1 %mov-vm-ptr
 114     ! Call the unboxer
 115     func f %alien-invoke
 116     ! Store the return value on the C stack if this is an
 117     ! alien-invoke, otherwise leave it the return register if
 118     ! this is the end of alien-callback
 119     n [ n rep reg-class-of return-reg rep %save-param-reg ] when ;
 120
 121 : %unbox-struct-field ( c-type i -- )
 122     ! Alien must be in param-reg-0.
 123     R11 swap cells [+] swap rep>> reg-class-of {
 124         { int-regs [ int-regs get pop swap MOV ] }
 125         { float-regs [ float-regs get pop swap MOVSD ] }
 126     } case ;
 127
 128 M: x86.64 %unbox-small-struct ( c-type -- )
 129     ! Alien must be in param-reg-0.
 130     param-reg-1 %mov-vm-ptr
 131     "alien_offset" f %alien-invoke
 132     ! Move alien_offset() return value to R11 so that we don't
 133     ! clobber it.
 134     R11 RAX MOV
 135     [
 136         flatten-value-type [ %unbox-struct-field ] each-index
 137     ] with-return-regs ;
 138
 139 M:: x86.64 %unbox-large-struct ( n c-type -- )
 140     ! Source is in param-reg-0
 141     ! Load destination address into param-reg-1
 142     param-reg-1 n param@ LEA
 143     ! Load structure size into param-reg-2
 144     param-reg-2 c-type heap-size MOV
 145     param-reg-3 %mov-vm-ptr
 146     ! Copy the struct to the C stack
 147     "to_value_struct" f %alien-invoke ;
 148
 149 : load-return-value ( rep -- )
 150     [ [ 0 ] dip reg-class-of param-reg ]
 151     [ reg-class-of return-reg ]
 152     [ ]
 153     tri %copy ;
 154
 155 M:: x86.64 %box ( n rep func -- )
 156     n [
 157         n
 158         0 rep reg-class-of param-reg
 159         rep %load-param-reg
 160     ] [
 161         rep load-return-value
 162     ] if
 163     rep int-rep?
 164     cpu x86.64? os windows? and or
 165     param-reg-1 param-reg-0 ? %mov-vm-ptr
 166     func f %alien-invoke ;
 167
 168 : box-struct-field@ ( i -- operand ) 1 + cells param@ ;
 169
 170 : %box-struct-field ( c-type i -- )
 171     box-struct-field@ swap c-type-rep reg-class-of {
 172         { int-regs [ int-regs get pop MOV ] }
 173         { float-regs [ float-regs get pop MOVSD ] }
 174     } case ;
 175
 176 M: x86.64 %box-small-struct ( c-type -- )
 177     #! Box a <= 16-byte struct.
 178     [
 179         [ flatten-value-type [ %box-struct-field ] each-index ]
 180         [ param-reg-2 swap heap-size MOV ] bi
 181         param-reg-0 0 box-struct-field@ MOV
 182         param-reg-1 1 box-struct-field@ MOV
 183         param-reg-3 %mov-vm-ptr
 184         "from_small_struct" f %alien-invoke
 185     ] with-return-regs ;
 186
 187 : struct-return@ ( n -- operand )
 188     [ stack-frame get params>> ] unless* param@ ;
 189
 190 M: x86.64 %box-large-struct ( n c-type -- )
 191     ! Struct size is parameter 2
 192     param-reg-1 swap heap-size MOV
 193     ! Compute destination address
 194     param-reg-0 swap struct-return@ LEA
 195     param-reg-2 %mov-vm-ptr
 196     ! Copy the struct from the C stack
 197     "from_value_struct" f %alien-invoke ;
 198
 199 M: x86.64 %prepare-box-struct ( -- )
 200     ! Compute target address for value struct return
 201     RAX f struct-return@ LEA
 202     ! Store it as the first parameter
 203     0 param@ RAX MOV ;
 204
 205 M: x86.64 %prepare-var-args RAX RAX XOR ;
 206
 207 M: x86.64 %alien-invoke
 208     R11 0 MOV
 209     rc-absolute-cell rel-dlsym
 210     R11 CALL ;
 211
 212 M: x86.64 %nest-stacks ( -- )
 213     param-reg-0 %mov-vm-ptr
 214     "nest_stacks" f %alien-invoke ;
 215
 216 M: x86.64 %unnest-stacks ( -- )
 217     param-reg-0 %mov-vm-ptr
 218     "unnest_stacks" f %alien-invoke ;
 219
 220 M: x86.64 %prepare-alien-indirect ( -- )
 221     param-reg-0 ds-reg [] MOV
 222     ds-reg 8 SUB
 223     param-reg-1 %mov-vm-ptr
 224     "pinned_alien_offset" f %alien-invoke
 225     RBP RAX MOV ;
 226
 227 M: x86.64 %alien-indirect ( -- )
 228     RBP CALL ;
 229
 230 M: x86.64 %alien-callback ( quot -- )
 231     param-reg-0 param-reg-1 %restore-context
 232     param-reg-0 swap %load-reference
 233     param-reg-0 quot-entry-point-offset [+] CALL
 234     param-reg-0 param-reg-1 %save-context ;
 235
 236 M: x86.64 %callback-value ( ctype -- )
 237     %pop-context-stack
 238     RSP 8 SUB
 239     param-reg-0 PUSH
 240     param-reg-0 %mov-vm-ptr
 241     ! Restore data/call/retain stacks
 242     "unnest_stacks" f %alien-invoke
 243     ! Put former top of data stack in param-reg-0
 244     param-reg-0 POP
 245     RSP 8 ADD
 246     ! Unbox former top of data stack to return registers
 247     unbox-return ;
 248
 249 : float-function-param ( i src -- )
 250     [ float-regs param-regs nth ] dip double-rep %copy ;
 251
 252 : float-function-return ( reg -- )
 253     float-regs return-reg double-rep %copy ;
 254
 255 M:: x86.64 %unary-float-function ( dst src func -- )
 256     0 src float-function-param
 257     func "libm" load-library %alien-invoke
 258     dst float-function-return ;
 259
 260 M:: x86.64 %binary-float-function ( dst src1 src2 func -- )
 261     ! src1 might equal dst; otherwise it will be a spill slot
 262     ! src2 is always a spill slot
 263     0 src1 float-function-param
 264     1 src2 float-function-param
 265     func "libm" load-library %alien-invoke
 266     dst float-function-return ;
 267
 268 M:: x86.64 %call-gc ( gc-root-count temp -- )
 269     ! Pass pointer to start of GC roots as first parameter
 270     param-reg-0 gc-root-base param@ LEA
 271     ! Pass number of roots as second parameter
 272     param-reg-1 gc-root-count MOV
 273     ! Pass VM ptr as third parameter
 274     param-reg-2 %mov-vm-ptr
 275     ! Call GC
 276     "inline_gc" f %alien-invoke ;
 277
 278 ! The result of reading 4 bytes from memory is a fixnum on
 279 ! x86-64.
 280 enable-alien-4-intrinsics
 281
 282 USE: vocabs.loader
 283
 284 {
 285     { [ os unix? ] [ "cpu.x86.64.unix" require ] }
 286     { [ os winnt? ] [ "cpu.x86.64.winnt" require ] }
 287 } cond
 288
 289 check-sse